Ändert die Anzahl an Zeichen im RichText-Format, die in das RichEdit-Control eingetippt, eingefügt oder gestreamt werden kann
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetLimitOnText ( $hWnd, $iNewLimit )
$hWnd | Handle des Controls |
$iNewLimit | Neue maximale Anzahl (0 setzt als Obergrenze 65536) |
Erfolg: | True |
Fehler: | False und setzt das @error Flag auf ungleich null |
@error: | 101 - $hWnd ist kein Handle 102 - $iNewLimit ist weder positiv noch null |
Diese Funktion setzt die maximale Anzahl von Zeichen, die der Benutzer in das Control eingeben oder einfügen kann.
Sie begrenzt auch die Zeichenanzahl, die unter Verwendung von _GUICtrlRichEdit_StreamFromFile() und _GUICtrlRichEdit_StreamFromVar()
in das RichEdit-Control gestreamt werden kann.
Die Menge an Klartext, die in das RichEdit-Control gesendet werden kann, wird dadurch nicht begrenzt.
Vor dem ersten Aufruf von _GUICtrlRichEdit_SetLimitOnText() beträgt die Obergrenze 32767 Zeichen.
- - - - - - - - Erklärung der Controls - - - - - - - -
_GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar
Suche nach EM_EXLIMITTEXT in der MSDN Bibliothek.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
Local $g_idLblMsg, $hRichEdit
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "Absatz 1")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetLimitOnText($hRichEdit, 0)
GUICtrlSetData($g_idLblMsg, "1. Limit auf 65536 Zeichen gesetzt")
Case 2
_GUICtrlRichEdit_SetLimitOnText($hRichEdit, 100000)
GUICtrlSetData($g_idLblMsg, "2. Limit auf 100000 Zeichen gesetzt")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example