_GUICtrlRichEdit_StreamToVar

Beschreibung anzeigen in

Gibt den gesamten Inhalt eines Controls zurück

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamToVar ( $hWnd [, $bRtf = True [, $bIncludeCOM = True [, $iOpts = 0 [, $iCodePage = 0]]]] )

Parameter

$hWnd	Handle des Controls
$bRtf	[optional] True - schreibt in Rich Text Format (RTF) (Standard) False - Schreibt nur Text
$bIncludeCOM	[optional] True (Standard): Wenn in RTF geschrieben wird, werden alle COM-Objekte mitgeschrieben. Wenn nur Text, wird eine Text-Wiedergabe der COM-Objekte gespeichert. False: Ignoriert COM-Objekte.
$iOpts	[optional] Zusätzliche Optionen: (Standard: 0) $SFF_PLAINRTF - Schreibt nur RT-Schlüsselwörter, die üblich in allen Sprachen sind $SF_UNICODE - Schreibt in Unicode
$iCodePage	[optional] True: Generiere UTF-8 und Text durch Benutzung dieses Seitenformates (Standard: False)

Rückgabewert

Erfolg:	RTF oder Text aus dem Control.
Fehler:	"" und setzt das @error Flag auf ungleich null.
@error:	101 - $hWnd ist kein Handle 1041 - $SFF_PLAINRTF ist ungültig für eine Textdatei 1042 - $iOpts ist ungültig 1043 - $SF_UNICODE ist nur gültig für eine Textdatei 700 - Interner Fehler

Bemerkungen

$SF_*, $SFF_* Die Konstanten sind in RichEditConstants.au3 definiert.
Wenn Text ausgewählt ist, wird nur dieser zurückgegeben.

Falls die Erweiterung in $sFileSpec .rtf ist, so wird RTF geschrieben ansonsten Text

Es ist _GUICtrlRichEdit_IsModified() zu benutzen um herauszufinden, ob der Text sich verändert hat.

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_STREAMIN in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui, $iMsg, $idBtnNext, $iStep = 0, $idLblMsg, $hRichEdit, $s
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Das ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $idBtnNext = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Erster Abschnitt")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
            Case $iMsg = $idBtnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                        GUICtrlSetData($idLblMsg, "Gestreamt in Variable")
                    Case 2
                        _GUICtrlRichEdit_SetText($hRichEdit, "")
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($idLblMsg, "Gestreamt aus Variable")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                        _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                        GUICtrlSetData($idLblMsg, "Einfügen an gewählter Position: Ein absichtliches Durcheinander!")
                        GUICtrlSetState($idBtnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Example