Hallo allerseits!
ICh habe heute wieder drei Fragen:
1: Ist es möglich eine Progress-Bar "in den Leerlauf zu versetzen"? Also das z.B. bei Vista der grüne Klecks immer von Null zu hundert und wieder und wieder...
2: Gleiches wie oben, nur dass der Klecks von Null nach Hundert und wieder zurück nach null soll.
3: Kann ich wie bei VB etc. die Shell von Microsoft verwenden (Console.WriteLine("Hallo!") z.B.)
Dankeschön!
Schau dir mal die ersten Konstanten in der ProgressConstants.au3 an
lgE
Danke, aber was ist hier falsch?:
[autoit]
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
$Form1 = GUICreate("Form1", 560, 57, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Progress1 = GUICtrlCreateProgress(0, 16, 545, 25)
GuiCTrlSetState(-1, $PBS_MARQUEE)
GUISetState(@SW_SHOW)
While 1
Sleep(100)
WEnd
Func Form1Close()
Exit
EndFunc
Hi, schonmal drüber nachgedacht die Hilfe zu benutzen? 
#include <WindowsConstants.au3>
#include <SendMessage.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
Opt("GUIOnEventMode", 1)
[/autoit] [autoit][/autoit] [autoit]$Form1 = GUICreate("Form1", 545, 25, -1, -1, $WS_POPUP, $WS_EX_TOOLWINDOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Progress1 = GUICtrlCreateProgress(0, 0, 545, 25, $PBS_MARQUEE)
$hProgress = GUICtrlGetHandle($Progress1)
_SendMessage($hProgress, $PBM_SETMARQUEE, True, 10)
GUISetState(@SW_SHOW)
While 1
Sleep(100)
WEnd
Func Form1Close()
Exit
EndFunc ;==>Form1Close
anno2008 
Danke! Dann ist Frage 1 geklärt, aber was ist mit 2 und 3?
anno2008: Wie hast du die Form verschwinden lassen? Welcher PArameter war dafür verantwortlich?
Danke für die Beantwortung der Frage 1!
$WS_POPUP --> keine "GUI-Ränder"
$WS_EX_TOOLWINDOW --> wird nicht in Taskleiste angezeigt.
Aonsonsten hab ich den Slider nur genauso groß wie die GUI gemacht.
Achso. Danke!
Hat den noch jemand eine Idee zu 2. oder 3.?
zu 3.:
Geht auf jeden fall, wenn man im CUI modus kompiliert
dann hat man aber keine gui...
falls du darauf verzichten kannst nimm (im CUI modus) ConsoleWrite() her
kannst die progressbars auch in andere exe dateien auslagern^^
Padmak
Danke!
Jetzt brauch ich nur noch 2 
Zu 2.: Es gibt kein Rückwärtsmarquee.
Aber vielleicht wäre es möglich, ein Ctrl zu drehen?
Man kann sich doch problemlos Code stricken, der von 0 auf 100 und zurück läuft oder eben von 0 bis 100 und von vorne? 
peethebee
vielleicht ist das so etwas was du meinst?
#include<SliderConstants.au3>
#include<StaticConstants.au3>
#include<GUIConstantsEx.au3>
#include<ProgressConstants.au3>
Global $hGui = GUICreate('Klassische Progressbar', 420, 280, -1, -1)
[/autoit] [autoit][/autoit] [autoit]DllCall('uxtheme.dll', 'none', 'SetThemeAppProperties', 'int', 0) ; auf den klassischen Style umschalten
Global $hProgress1 = GUICtrlCreateProgress(15, 20, 384, 20, $PBS_SMOOTH) ; obere Progressbar erstellen
GUICtrlSetColor(-1, 0x22FF22)
GUICtrlSetBkColor(-1, 0xEEEEEE)
GUICtrlCreateLabel('|', 18, 40, 20, 16) ; Anzeige von 0%
GUICtrlCreateLabel('0%', 11, 56, 25, 16, $SS_CENTER)
GUICtrlCreateLabel('|', 396, 40, 20, 16) ; Anzeige von 100%
GUICtrlCreateLabel('100%', 389, 56, 25, 16, $SS_CENTER)
Global $hLabel1 = GUICtrlCreateLabel('0%', 190, 24, 30, 14, $SS_CENTER) ; Prozentanzeige innerhalb der Progressbar
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT) ; Transparenter Hintergrund für das Label
Global $hProgress2 = GUICtrlCreateProgress(15, 160, 384, 20, $PBS_SMOOTH) ; untere Progressbar erstellen
GUICtrlSetColor(-1, 0xC83131)
GUICtrlSetBkColor(-1, 0xEEEEEE)
DllCall('uxtheme.dll', 'none', 'SetThemeAppProperties', 'int', 7) ; zurück zum Standard-Windowsstyle
For $i = 0 To 100 Step 10 ; die Anzeige für die Prozentwerte der unteren Progressbar erstellen
GUICtrlCreateLabel('|', 16 + $i * 3.8, 180, 20, 16)
GUICtrlCreateLabel($i & '%', 9 + $i * 3.8, 196, 25, 16, $SS_CENTER)
Next
Global $hSlider = GUICtrlCreateSlider(5, 130, 404, 28, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS))
GUICtrlSetData(-1, 33) ; Sliderwert auf 33% setzen (als Beispiel)
Global $hClose = GUICtrlCreateButton('Close', 180, 240, 60, 24)
GUISetState(@SW_SHOW)
Global $iAddend = 1 ; globale Variable (dient als Summand für _SetProgress)
AdlibEnable('_SetProgress', 30)
While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $hClose
Exit
EndSwitch
WEnd
Func _SetProgress()
Local $iPercent = GUICtrlRead($hProgress1) ; Prozentwert der oberen Progressbar auslesen
If $iPercent = 100 Or $iPercent = 0 Then $iAddend = -$iAddend ; wenn 100 oder Null, dann den Summand negieren
GUICtrlSetData($hProgress1, $iPercent + $iAddend) ; neuen Wert der oberen Progressbar schreiben
GUICtrlSetData($hLabel1, $iPercent + $iAddend & '%') ; neuen Wert für das Label schreiben
GUICtrlSetData($hProgress2, GUICtrlRead($hSlider)) ; und den Wert vom Slider in die untere Progressbar schreiben
EndFunc ;==>_SetProgress
Also, erst mal danke an alle!
Schnuffel: Ich meinte es etwas anders, aber dein Programm hat mich auf eine Idee für mein Projekt gebracht! Danke!!! 
Also, ich dachte mir das so ungefähr, wie L3viathan2142 (ging dein Name nicht noch ein bisschen komplizierter 
Ein Marquee das auf 100 läuft, dann zurück auf 0 dann wieder auf 100,
so wie man es von manchen PRogrammen kennt, die eine Serververbindung aufbauen...
Meinst du sowas?
Mit AdlibDisable() läßt sich das dann Beenden.
Global $SwipBar[2], $aSwipPos[4], $xSwip, $up = True
[/autoit] [autoit][/autoit] [autoit]$gui = GUICreate('test')
GUISetState()
$arBar = _SwipBarOn(10, 10, 300, 17)
$t = TimerInit()
Do
If TimerDiff($t) > 5000 Then _SwipBarOff() ; nach 5 Sekunden wird Bar gelöscht
Until GUIGetMsg() = -3
Func _SwipBarOn($x, $y, $width, $heigth, $iCol=0xff0000, $iBkCol=0x0000ff)
Local $swipWidth = Floor($width/3)
$SwipBar[0] = GUICtrlCreateLabel('', $x, $y, $width, $heigth)
GUICtrlSetBkColor(-1, $iBkCol)
$SwipBar[1] = GUICtrlCreateLabel('', $x, $y, $swipWidth, $heigth)
GUICtrlSetBkColor(-1, $iCol)
$aSwipPos[0] = $x
$aSwipPos[1] = $y
$aSwipPos[2] = $swipWidth
$aSwipPos[3] = $width
AdlibEnable('_swip', 30)
Return $SwipBar
EndFunc
Func _swip()
If $up Then
$xSwip += 5
Else
$xSwip -= 5
EndIf
If $up And ($xSwip + $aSwipPos[2] >= $aSwipPos[0] + $aSwipPos[3]) Then $up = False
If Not $up And ($xSwip <= $aSwipPos[0]) Then $up = True
ControlMove($gui, '', $SwipBar[1], $xSwip, $aSwipPos[1])
EndFunc
Func _SwipBarOff()
AdlibDisable()
GUICtrlDelete($arBar[0])
GUICtrlDelete($arBar[1])
EndFunc
Ja genau so!
Geht das auch im "Vista-Style"?
Edit: Also geht es nicht als Progress selbst?
Vista-Style? Keine Ahnung. Stylemäßig ist bei mir ausschließlich "Windows-Klassik", was anderes verwende ich nicht.
Als Progress kannst du es nicht so machen, da ein Progress entweder von links nach rechts oder umgekehrt "gefüllt" wird.
Wenn du einen Anderen Style haben willst kannst du doch die Labels durch Pics erstezen, und dir dann die Passenden bilder selber machen, also deinen eigenen Style!
Wie lässt sich die denn anders rum füllen?
Vllt. finde ich ja noch eine UDF oder so...
Ich hab mal was mit einem schönen Style gemacht! Die kann man auch ganz leicht umbauen, also das es nur bewegt und nicht füllt oder das sie sich von rechts nach links füllt!
