ist das nicht genau das gleiche wie im anderen thread nur das du P2 mit M und P3 mit P2 ersetzt hast? 
EDIT: oder soll P1 und P2 auf der gleichen höhe liegen? wenn ja dan gehts 
oder ist MP1 und MP2 gleich lang?
P2 (x,y)
x=Mx+MP1 x cos ( 180 - ß - ATan((P1y-My)/(P1x-Mx)))
y=My+MP1 x sin ( 180 - ß - ATan ((P1y-My)/(P1x-Mx)))
ich wette es gibt ne einfache möglichkeit 
Mx heißt x coordinate von M 
...
ich hoffe das ist alles richtig ( habs nicht ausprobiert )
EDIT: ATan ist ja in radians 
x=Mx+MP1 x cos ( Pi - ß - ATan((P1y-My)/(Mx-P1x)))
y=My+MP1 x sin ( Pi - ß - ATan ((P1y-My)/(Mx-P1x)))
hab mal versucht das ein bisschen zu erklären
hoffe es funktioniert 
jo danke. ich werds mir morgen mal genauer ansehen.. ich hab heute Abend leider keine zeit mehr.
aber thx schonmal für deine mühe
hab ich jetzt eine andere Idee zur Lösung meines 3D Problems...
Von 3D ist weit und breit nichts zu sehen....
Wenn es aber schon an der Spiegelung eines Punktes an einer Gerade hapert....dann wirds mit 3D auch so schnell nichts...
Mal "zu Fuß" erklärt...
Es bietet sich an, das Verfahren in eine Funktion zu packen, aber das sollte man alleine hinbekommen
;Spiegelung Punkt P an einer Geraden y=mx+b ergibt P2
[/autoit][autoit][/autoit][autoit];Verfahren:
;1) Geradengleichung der Senkrechten auf die Spiegelgerade finden durch den Punkt P
;2) Der Schnittpunkt der Senkrechten und der Spiegelgeraden ergibt S
;3) Auf der Gerade durch P und S liegt P2 im Abstand 2*PS
;Punkt P auf der Ebene
$Px = 1
$Py = -5
;Geradengleichung y=mx+b
$m = -0.5
$b = 3
;$y = $m * $x + $b
;1) Zur Spiegelgeraden senkrechte Geraden haben alle die Steigung ms=-1/m
$ms = -1 / $m
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $ms = ' & $ms & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
;gesucht wird eine auf die Spiegelgerade senkrechte Gerade durch den Punkt P
;Geradengleichung senkrechte Gerade: y=ms*x+bs
;$Py = $ms * $Px + $bs
$bs = $Py - ($ms * $Px)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $bs = ' & $bs & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
;2) Schnittpunkt beider Geraden
;$ys = $m * $xs + $b = $ms * $xs + $bs
$xs = ($bs - $b) / ($m - $ms)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $xs = ' & $xs & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
$ys = $ms * $xs + $bs
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $ys = ' & $ys & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
;PS liegt in der Hälfte zwischen P1 und P2
;3) Geradengleichung durch P und S
;2*Abstand PS ergibt P2
$P2x = $Px + 2 * ($xs - $Px)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $P2x = ' & $P2x & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
$P2y = $Py + 2 * ($ys - $Py)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $P2y = ' & $P2y & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
So?
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Local $hGUI, $hGraphics, $hBackbuffer, $hBitmap, $hBrush, $hPen
Local $iX = 800, $iY = 600
; Initialize GDI+
_GDIPlus_Startup()
$hGUI = GUICreate("Spiegeln", $iX, $iY)
GUISetState()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hBitmap = _GDIPlus_BitmapCreateFromGraphics($iX, $iY, $hGraphics)
$hBackbuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
; Using antialiasing
_GDIPlus_GraphicsSetSmoothingMode($hBackbuffer, 2)
; Create a Pen object
$hBrush = _GDIPlus_BrushCreateSolid(0)
$hPen = _GDIPlus_PenCreate(0xFF000000)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
[/autoit] [autoit][/autoit] [autoit]Local $P1_x = 100
Local $P1_y = 100
Local $P2_x = 300
Local $P2_y = 400
Local $P3_x, $P3_y, $PT_x, $PT_y
While Sleep(20)
_GDIPlus_GraphicsClear($hBackbuffer, 0xFFFFFFFF)
$P3_x = $P1_x + 2 * ($P2_x - $P1_x)
$P3_y = $P1_y - 5
_GDIPlus_PenSetColor($hPen, 0xFF000000)
_GDIPlus_GraphicsDrawLine($hBackbuffer, $P1_x, $P1_y, $P2_x, $P2_y, $hPen)
_GDIPlus_GraphicsDrawLine($hBackbuffer, $P2_x, $P2_y, $P3_x, $P3_y, $hPen)
_GDIPlus_PenSetColor($hPen, 0xFF0000FF)
_GDIPlus_GraphicsDrawLine($hBackbuffer, $P2_x, $P1_y - 40, $P2_x, $P2_y + 40, $hPen)
;Punkt 1
_GDIPlus_BrushSetSolidColor($hBrush, 0xFFFF0000)
_GDIPlus_GraphicsFillEllipse($hBackbuffer, $P1_x - 5, $P1_y - 5, 10, 10, $hBrush)
;Punkt 2
_GDIPlus_BrushSetSolidColor($hBrush, 0xFF00FF00)
_GDIPlus_GraphicsFillEllipse($hBackbuffer, $P2_x - 5, $P2_y - 5, 10, 10, $hBrush)
;Punkt 3 (Spiegel von Punkt 1)
_GDIPlus_BrushSetSolidColor($hBrush, 0xFF0000FF)
_GDIPlus_GraphicsFillEllipse($hBackbuffer, $P3_x - 5, $P3_y - 5, 10, 10, $hBrush)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $iX, $iY)
WEnd
Func _Exit()
; Clean up
_GDIPlus_PenDispose($hPen)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_GraphicsDispose($hBackbuffer)
_GDIPlus_GraphicsDispose($hGraphics)
; Uninitialize GDI+
_GDIPlus_Shutdown()
Exit
EndFunc
Gruß,
UEZ
ist die spiegelachse immer vertikal?
konnte man aus der zeichnung iwie nicht sehen
wenn ja, dann macht es das ja viel einfacher 
ist die spiegelachse immer vertikal?
wenn das so wäre, dann reduziert sich das ganze Problem auf eine Addition, das sollte dann auch ein 2.-Klässler schaffen...
Denn dann wäre Y2 = Y1 und X2= X1 + (XS-X1) + (XS-X1)
Als Funktion
[autoit]Func _Punkt_gespiegelt_an_Gerade($m, $b, $Px, $Py) ;y=mx+b , Koordinaten P, return=array mit P'x und P'y
Local $a[2]
$a[0] = $Px + 2 * (((($Py - ((-1 / $m) * $Px)) - $b) / ($m - (-1 / $m))) - $Px)
$a[1] = $Py + 2 * (((-1 / $m) * ((($Py - ((-1 / $m) * $Px)) - $b) / ($m - (-1 / $m))) + ($Py - ((-1 / $m) * $Px))) - $Py)
Return $a
EndFunc ;==>_Punkt_gespiegelt_an Gerade
$koordinaten=_Punkt_gespiegelt_an_Gerade(-0.5, 3, 1, -5)
_arraydisplay($koordinaten)
Die Mittelsenkrechte des Winkels? Oha, meinst du ggf. die Winkelhalbierende als "Spiegelachse"?
Dann könnte man die "Spiegelung" als Drehung von P um Punkt S mit dem Winkel alpha auffassen?(was aufs Gleiche wie die Spiegelung rausläuft)
So?
Func _Punkt_gedreht_um_Winkel($Px, $Py, $alpha, $DPx, $DPy) ;Koordinaten Punkt, Winkel in Grad Drehrichtung nach RECHTS, Koordinaten Drehpunkt
Local $Hx = $Px - $DPx
Local $Hy = $Py - $DPy
;$degToRad = atan(1)*4 / 180 ;atan(1)*4=pi
$degtorad = 0.0174532925
$sinus = Sin(-$alpha * $degtorad)
$cosinus = Cos(-$alpha * $degtorad)
Local $a[2] ;array koordinaten
$a[0] = $DPx + Round($Hx * $cosinus - $Hy * $sinus,2) ;2 Nachkommastellen sollten reichen
$a[1] = $DPy + Round($Hx * $sinus + $Hy * $cosinus,2)
Return $a
EndFunc ;==>_Punkt_gedreht_um_Winkel
$koordinaten = _Punkt_gedreht_um_Winkel(2, 5, 90, 3, 3)
_ArrayDisplay($koordinaten)
Die Mittelsenkrechte des Winkels? Oha, meinst du ggf. die Winkelhalbierende als "Spiegelachse"?
Dann könnte man die "Spiegelung" als Drehung von P um Punkt S mit dem Winkel alpha auffassenwas aufs Gleiche wie die Spiegelung rausläuft)
ja quasi eine Drehung (bei mir in der skizze oben heißt der winkel beta, aber das spielt ja auch keine rolle...), oder halt die Winkelhalbierende als Spiegelachse. welches der beiden varianten ist mir eigentlich egal.
Edit: ah danke für die Funktion. ich werde sie mir nachher mal ansehen..
ich brauch nur den rechenweg, nix mit GDI+.. trotzdem thx..
GDI+ ist doch nicht der Rechner, sondern die Projektion des Gerechneten! Der Rechenweg steht doch dort geschrieben!
Du musst nur beachten, dass hier P(0,0) oben links in der Ecke ist - in der Schule ist ja der Mittelpunkt i.d.R. wo anders.
Gruß,
UEZ
Um jetzt beide Funktionen zu nutzen, könnte man ja erst den Punkt P um die Winkelhalbierende drehen um so den Punkt M' zu erhalten (M und M' wären dann die Spiegelachse) und dann P an der Spiegelachse spiegeln 
Die Darstellung der Spiegelung mittel GDI+:
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Opt("MustDeclareVars", 1)
Opt("GUIOnEventMode", 1)
Local $hGUI, $hGraphics, $hBackbuffer, $hBitmap, $hBrush, $hPen
Local $iX = 800, $iY = 600
; Initialize GDI+
_GDIPlus_Startup()
$hGUI = GUICreate("Spiegeln von P1 an der Achse P2 von UEZ 2010", $iX, $iY)
GUISetState()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hBitmap = _GDIPlus_BitmapCreateFromGraphics($iX, $iY, $hGraphics)
$hBackbuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
; Using antialiasing
_GDIPlus_GraphicsSetSmoothingMode($hBackbuffer, 2)
; Create a Pen object
$hBrush = _GDIPlus_BrushCreateSolid(0)
$hPen = _GDIPlus_PenCreate(0xFF000000)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
[/autoit] [autoit][/autoit] [autoit]Local $deg = ACos(-1) / 180
Local $rad = 180 / ACos(-1)
Local $P1_x = 300
Local $P1_y = 100
Local $P2_x = 150
Local $P2_y = 500
Local $alpha = 60
Local $P3_x, $P3_y
Local $radius = Pixel_Distance($P1_x, $P1_y, $P2_x, $P2_y)
;Winkel von Punkt1 berechnen
Local $mwx = $P1_x - $P2_x
Local $mwy = $P2_y - $P1_y
Local $P1angle = -ATan($mwy / $mwx) * $rad
If $mwx < 0 Then
$P1angle = -180 + $P1angle
ElseIf $mwx >= 0 And $mwy < 0 Then
$P1angle = -360 + $P1angle
EndIf
;Spiegel berechnen
Local $PT_x = $P2_x + Cos(($alpha / 2 + $P1angle) * $deg) * $radius * 1.25
Local $PT_y = $P2_y + Sin(($alpha / 2 + $P1angle) * $deg) * $radius * 1.25
While Sleep(40)
_GDIPlus_GraphicsClear($hBackbuffer, 0xFFFFFFFF)
$P3_x = $P2_x + Cos(($alpha + $P1angle) * $deg) * $radius
$P3_y = $P2_y + Sin(($alpha + $P1angle) * $deg) * $radius
_GDIPlus_PenSetColor($hPen, 0xFF000000)
_GDIPlus_GraphicsDrawLine($hBackbuffer, $P1_x, $P1_y, $P2_x, $P2_y, $hPen)
_GDIPlus_GraphicsDrawLine($hBackbuffer, $P2_x, $P2_y, $P3_x, $P3_y, $hPen)
;~ _GDIPlus_GraphicsDrawEllipse($hBackbuffer, $P2_x - $radius, $P2_y - $radius, 2 * $radius, 2 * $radius, $hPen)
_GDIPlus_PenSetColor($hPen, 0xFF0000FF)
_GDIPlus_GraphicsDrawLine($hBackbuffer, $P2_x, $P2_y, $PT_x, $PT_y, $hPen)
;Punkt 1
_GDIPlus_BrushSetSolidColor($hBrush, 0xFFFF0000)
_GDIPlus_GraphicsFillEllipse($hBackbuffer, $P1_x - 5, $P1_y - 5, 10, 10, $hBrush)
;Punkt 2
_GDIPlus_BrushSetSolidColor($hBrush, 0xFF00FF00)
_GDIPlus_GraphicsFillEllipse($hBackbuffer, $P2_x - 5, $P2_y - 5, 10, 10, $hBrush)
;Punkt 3 (Spiegel von Punkt 1)
_GDIPlus_BrushSetSolidColor($hBrush, 0xFF0000FF)
_GDIPlus_GraphicsFillEllipse($hBackbuffer, $P3_x - 5, $P3_y - 5, 10, 10, $hBrush)
_GDIPlus_GraphicsDrawString($hBackbuffer, "P1" & @CRLF & "(" & Int($P1_x) & "," & Int($P1_y) & ")", $P1_x - 25, $P1_y - 40)
_GDIPlus_GraphicsDrawString($hBackbuffer, "P2" & @CRLF & "(" & Int($P2_x) & "," & Int($P2_y) & ")", $P2_x - 25, $P2_y - 40)
_GDIPlus_GraphicsDrawString($hBackbuffer, "Winkel alpha = " & $alpha, $P2_x - 45, $P2_y + 10)
_GDIPlus_GraphicsDrawString($hBackbuffer, "P3" & @CRLF & "(" & Int($P3_x) & "," & Int($P3_y) & ")", $P3_x - 25, $P3_y - 40)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $iX, $iY)
WEnd
Func Pixel_Distance($x1, $y1, $x2, $y2) ;Pythagoras theorem
Local $a, $b, $c
If $x2 = $x1 And $y2 = $y1 Then
Return 0
Else
$a = $y2 - $y1
$b = $x2 - $x1
$c = Sqrt($a * $a + $b * $b)
Return $c
EndIf
EndFunc ;==>Pixel_Distance
Func _Exit()
; Clean up
_GDIPlus_PenDispose($hPen)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_GraphicsDispose($hBackbuffer)
_GDIPlus_GraphicsDispose($hGraphics)
; Uninitialize GDI+
_GDIPlus_Shutdown()
Exit
EndFunc
Gruß,
UEZ
ok danke für alle antworten
und nochmal speziell thx @ andy, für die funktion, die ich gesucht hab 
danke! problem ist somit gelöst
