Borderless Fullscreen Windowed mit jedem Fenster

**Xorianator**

Hallo Leute,
da einige Spiele keinen Vollbild-Fenstermodus unterstützen, ich aber auf 2 Bildschirmen arbeite und beim kurz aus dem Fenster gehen um was bei Facebook oder so zu schreiben, brauchte ich eine Lösung.
Kurze Rede, kürzerer Sinn, das Script macht aus jedem Fenster mit der Tastenkombi STRG+ALT+UP ein Vollbild mit ohne Rand

[autoit]

#include <WindowsConstants.au3>
#include <Misc.au3>
#include <Constants.au3>
#include <WinApi.au3>
While Sleep(20)
If _IsPressed("11") and _IsPressed("26") and _IsPressed("12") Then
$wintitle = WinGetTitle("[active]")
_WinAPI_SetWindowLong(WinGetHandle($wintitle), $GWL_STYLE, $WS_POPUPWINDOW) ;Eigentliche Funktion
WinSetState($wintitle, "", @SW_MAXIMIZE) ;Maximieren für Vollbild
WinSetState($wintitle, "", @SW_SHOW) ;Fenster ist sonst sichtbar aber wird "durchdrungen"
EndIf
WEnd

[/autoit]

Vielleicht kanns ja jemand gebrauchen
€: Ich habs irgendwie nicht hinbekommen den Style für ein normales Fenster zu finden, vielleicht lässt sich da ja jemand herab und verrät mir welcher Style das ist, dann gibts auch n Back mode

Friesel

Zitat von Xorianator

€: Ich habs irgendwie nicht hinbekommen den Style für ein normales Fenster zu finden, vielleicht lässt sich da ja jemand herab und verrät mir welcher Style das ist, dann gibts auch n Back mode

Moin!

Hier mal mein Vorschlag:

[autoit]

#include <WindowsConstants.au3>
#include <Misc.au3>
#include <Constants.au3>
#include <WinApi.au3>

[/autoit][autoit][/autoit][autoit]

Global $iStyle, $fPressed = False

[/autoit][autoit][/autoit][autoit]

While Sleep(20)
If _IsPressed("11") and _IsPressed("26") and _IsPressed("12") And $fPressed = False Then ;==> <STRG+ALT+UP>
$wintitle = WinGetTitle("[active]")
$aPos = WinGetPos($wintitle) ;ursprüngliche Position und Grösse ermitteln
$iStyle = _WinAPI_GetWindowLong(WinGetHandle($wintitle), $GWL_STYLE) ;ursprünglichen Stil ermitteln
_WinAPI_SetWindowLong(WinGetHandle($wintitle), $GWL_STYLE, $WS_POPUPWINDOW) ;Eigentliche Funktion
WinSetState($wintitle, "", @SW_MAXIMIZE) ;Maximieren für Vollbild
;WinSetState($wintitle, "", @SW_SHOW) ;Fenster ist sonst sichtbar aber wird "durchdrungen"
$fPressed = True
ElseIf _IsPressed("11") and _IsPressed("28") and _IsPressed("12") And $fPressed = True Then ;==> <STRG+ALT+DOWN>
$wintitle = WinGetTitle("[active]")
_WinAPI_SetWindowLong(WinGetHandle($wintitle), $GWL_STYLE, $iStyle) ;ursprünglichen Stil wiederherstellen
WinMove($wintitle, "", $aPos[0], $aPos[1], $aPos[2], $aPos[3]) ;ursprüngliche Position und Grösse wiederherstellen
;WinSetState($wintitle, "", @SW_RESTORE) ;ursprüngliche Grösse wird so nicht wiedrhergestellt
;WinSetState($wintitle, "", @SW_SHOW) ;Fenster ist sonst sichtbar aber wird "durchdrungen"
$fPressed = False
EndIf
WEnd

[/autoit]

Ich finde es besser, den ursprünglichen Stil wiederherzustellen, als einen Standard Stil zu setzen, der unter Umständen nicht dem ursprünglichen Stil entspricht.
Zeile 15 (WinSetState($wintitle, "", @SW_SHOW) ) habe ich auskommentiert, weil es bei mir keinen Unterschied macht. Was meinst du mit "durchdrungen"?
Da der Status @SW_RESTORE anscheinend nicht die ursprüngliche Grösse wiederherstellt, habe ich das mit WinGetPos/WinMove erledigt...
Achtung: Nicht auf mehrere Fenster anwenden, dazu bedarf es weiterer Überprüfungen, wozu ich zu faul war

Sanfte Grüße

**alpines**

Was mich aber an diesem Script (dem 2.) wundert ist, wenn man die Tastenkombination drückt, dann wechselt der doch die ganze Zeit dazwischen?
Warum stellt man es nicht so ein, das $fPressed (wtf, warum f und nicht b xD) erst True ist, wenn in

[autoit]

If _IsPressed("11") and _IsPressed("26") and _IsPressed("12") And $fPressed = False Then

[/autoit]

noch das gilt:

[autoit]

While _IsPressed("11") and _IsPressed("26") and _IsPressed("12")
$fPressed = True
WEnd

[/autoit]

Ich hab das jetzt einfach so ausm Kopf hingeschrieben, bin mir nicht ganz sicher ob es funktioniert.
Jedenfalls sollte man aus dem 1. If erst raus, wenn die Tasten losgelassen sind, da das Script durchrattert.
Das gleiche sollte man beim 2. If auch machen!

**chesstiger**

[OT]
Warum b, und nicht f?
Laut Systems Hungarian, also der ungarischen Notation, hättest du recht, ja. Allerdings wird in AutoIt eine andere Notation verwendet (Was auch Sinn macht, AutoIt kennt ja z.B. keine Char-Variablen, auch nicht implizit). Die Liste für AutoIt findest du hier (Oder auch in meinem Tutorial - Siehe Signatur. ).

lg
[/OT]

**alpines**

Naja, ist letzendlich der Stil den jeder für sich wählt. Da macht ein Buchstabe so viel nun auch wieder nicht aus

Friesel

Zitat von alpines

Was mich aber an diesem Script (dem 2.) wundert ist, wenn man die Tastenkombination drückt, dann wechselt der doch die ganze Zeit dazwischen?
Warum stellt man es nicht so ein, das $fPressed (wtf, warum f und nicht b xD) erst True ist, wenn in
[autoit]
If _IsPressed("11") and _IsPressed("26") and _IsPressed("12") And $fPressed = False Then
[/autoit]

noch das gilt:
[autoit]
While _IsPressed("11") and _IsPressed("26") and _IsPressed("12")
$fPressed = True
WEnd
[/autoit]

Ich hab das jetzt einfach so ausm Kopf hingeschrieben, bin mir nicht ganz sicher ob es funktioniert.
Jedenfalls sollte man aus dem 1. If erst raus, wenn die Tasten losgelassen sind, da das Script durchrattert.
Das gleiche sollte man beim 2. If auch machen!

Alles anzeigen

Also bei mir rattert nichts durch Wenn man einmal Strg-Alt-Up drückt, dann kommt man kein zweites mal in die If-Abfrage, sondern muss zuerst Strg-Alt-Down drücken, um das Fenster wiederherzustellen.
Möglicherweise hast du übersehen, dass ich in der zweiten If-Abfrage eine andere Taste abfrage, als in der ersten (einmal Curser hoch, einmal Curser runter).

Zitat von alpines

wtf, warum f und nicht b xD

Du hast natürlich vollkommen Recht! Das 'f' sollte eigendlich für 'F'lag stehen, weil ich die Notation falsch in Erinnerung hatte und das Skript auch nur mal schnell hingeklatscht hab

Zitat von chesstiger

Oder auch in meinem Tutorial - Siehe Signatur. ]

Du wirst lachen, genau an dein Tutorial "versuche" ich mich zu halten. Das 'f' war schlichtweg ein Irrtum

**alpines**

Ah tut mir leid!
Ich hab nicht gesehen das das 2. _IsPressed Down war und nicht Up!
Das was ich gepostet hab gilt natürlich nur wenn man beide auf einen "Hotkey" legt!

**chesstiger**

Was?

Zitat

Das 'f' war schlichtweg ein Irrtum

f ist das richtige Präfix für eine Boolean-Variable.

lg

**alpines**

Kommt natürlich darauf an welche Notation man verwendet

Friesel

Zitat von chesstiger

Was?

f ist das richtige Präfix für eine Boolean-Variable.

lg

Wie was??? :wacko:
Ich "versuche" mich an dein Tutorial zu halten, und dort nehme ich die "Neue Präfixliste", laut der $b für Boolean und $f für Floating point number steht...

Neue Präfixliste

Zitat

$a<letter> - Array (the following letter describes the data type taken from the rest of the data types below, if it varies then v should be used. A counter as the first element is ignored, so the array returned by StringSplit (with default options) would actually be marked as $as despite the integer in the zeroeth element).

$d - Binary data.

$h - Handle, usually to a file or window. NB: AutoIt handled controls return IDs, and so use $id instead.

$id - An AutoIt control Id.

$i - Integer.

$b - Boolean.

$f - Floating point number.

$n - general number with no preference for floating point or integral.

$s - String.

$v - Variant (unknown/variable type of data) .

$p - Pointer. It is assumed that it points to a struct so no further letters are needed. The type of struct being pointed to should be inferrable from the variable name e.g. $pWindowRect can be assumed to be a pointer to a $tagRECT structure.

$t - Structure returned from DllStructCreate.

$tag - Struct definition string.Structure definitions should conform to the structure guidelines.

Quelle

f sollte ja für Flag stehen, womit ich laut alter Präfixliste ja dann richtig lag, was aber eher Zufall war

**Xorianator**

Whoa, da erhält der Thread erst gar keine Aufmerksamkeit und auf einmal muss ich mir hier total viel durchlesen
Eigentlich hätte ich auf das SetLong und GetLong schon selbst kommen müssen, wenn das eine setzt dann nimmt das andere

Mit dem

[autoit]

WinSetState($wintitle, "", @SW_SHOW) ;Fenster ist sonst sichtbar aber wird "durchdrungen"

[/autoit]

das ist bei Godus ein Problem, man sieht zwar das Fenster, das ist aber quasi ein Hologramm (besser kann ich es jetzt nciht beschreiben) - Man kann durchfassen. Das heißt, man klickt in das Fenster aber klickt auf das darunter liegende... verstanden?

Friesel

Zitat von Xorianator

Eigentlich hätte ich auf das SetLong und GetLong schon selbst kommen müssen, wenn das eine setzt dann nimmt das andere

Ich habe das Skript mal verkürzt und erweitert
Da _WinAPI_SetWindowLong den ursprünglichen Stil zurückgibt, kann man sich _WinAPI_GetWindowLong sparen.
Ausserdem kann man das Fensterhandle direkt ermitteln und muss nicht erst den Umweg über WinGetTitle machen, was eine weitere Zeile spart

Zitat von Xorianator

das ist bei Godus ein Problem, man sieht zwar das Fenster, das ist aber quasi ein Hologramm (besser kann ich es jetzt nciht beschreiben) - Man kann durchfassen. Das heißt, man klickt in das Fenster aber klickt auf das darunter liegende... verstanden?

Ja, verstanden
Man kann diesen "Effekt" ebenfalls mit _WinAPI_SetWindowLong erreichen. Clickthrough nennt sich das...
Ich hab das im Skript mal eingefügt.
Mit <STRG+ALT+SPACE> kannst du das ein- bzw ausschalten. Bei "normalen" Fenstern funktionierts, ob das bei deinem Spiel auch funktioniert kannst du ja mal versuchen...
...oder natürlich einfach WinSetState($wintitle, "", @SW_SHOW) benutzen, wie du's eh schon gemacht hast

[autoit]

#include <WindowsConstants.au3>
#include <Misc.au3>
#include <Constants.au3>
#include <WinApi.au3>

[/autoit][autoit][/autoit][autoit]

Global $iOrgStyle, $fPressed = False

[/autoit][autoit][/autoit][autoit]

While Sleep(20)
If _IsPressed("11") and _IsPressed("26") and _IsPressed("12") And $fPressed = False Then ;==> <STRG+ALT+UP>
$hWinHandle = WinGetHandle("[active]")
$aPos = WinGetPos($hWinHandle) ;ursprüngliche Position und Grösse ermitteln
$iOrgStyle = _WinAPI_SetWindowLong($hWinHandle, $GWL_STYLE, $WS_POPUPWINDOW) ;Rückgabewert ist der ursprüngliche Stil
WinSetState($hWinHandle, "", @SW_MAXIMIZE) ;Maximieren für Vollbild
$fPressed = True
ElseIf _IsPressed("11") and _IsPressed("28") and _IsPressed("12") And $fPressed = True Then ;==> <STRG+ALT+DOWN>
_WinAPI_SetWindowLong($hWinHandle, $GWL_STYLE, $iOrgStyle) ;ursprünglichen Stil wiederherstellen
WinMove($hWinHandle, "", $aPos[0], $aPos[1], $aPos[2], $aPos[3]) ;ursprünglichen Position und Grösse wiederherstellen
$fPressed = False
ElseIf _IsPressed("11") and _IsPressed("20") and _IsPressed("12") Then ;==> <STRG+ALT+SPACE>
Sleep(100) ;==> ohne kleine "Pause" gehts leider nicht
$hWinHandle = WinGetHandle("[active]")
;==> "Clickthrough" an/aus
_WinAPI_SetWindowLong($hWinHandle,$GWL_EXSTYLE,BitOR(_WinAPI_GetWindowLong($hWinHandle,$GWL_EXSTYLE),$WS_EX_TRANSPARENT))
WinSetTrans($hWinHandle,"",255)
EndIf
WEnd

[/autoit]

Sanfte Grüße

**Xorianator**

Setz sicherheitshalber noch n @SW_SHOW, sonst kommt dann ein "hologramm Fenster raus"