Listview flackert beim einlesen von Daten

  • Wie schon in der Überschrift beschrieben habe ich ein Problem mit dem einlesen von Kunden in ein Listview.
    Problem ist das das Listview anfängt zu flackern während die Daten in das Listview geschrieben werden.
    Außerdem dauert es relativ lange bis alle Einträge angezeigt werden.

    Habe mit $GUI_HIDE und $GUI_SHOW es hinbekommen, dass die Tabelle sehr viel schneller angezeigt wird und das flackern sehr verringert wird.

    Ich lese ca 1000 Kundendaten in das erste Listview welches wohl das flackern hervorruft.
    Habe schon versucht mit _GUICtrlListView_BeginUpdate() zu arbeiten aber das hatte irgendwie garkeinen effekt.

    Ich kann hier natürlich keine Kundendatenposten deshalb hoffe ich das dieser Code-Schnipsel genügt um mir zu helfen :)

    Spoiler anzeigen
    [autoit]

    Func LV_update()

    [/autoit] [autoit][/autoit] [autoit]

    GUICtrlSetState($ListView1, $GUI_HIDE)
    GUICtrlSetState($ListView2, $GUI_HIDE)
    GUICtrlSetState($ListView3, $GUI_HIDE)
    GUICtrlSetState($ListView4, $GUI_HIDE)

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlListView_DeleteAllItems($ListView1)
    _SQLite_Exec(-1, "Create table if not exists Kunden (KdNr,Name,Straße,PLZ,Ort);")
    _SQLite_GetTable2d(-1, "Select * From Kunden", $aResult, $iRows, $iColumns)

    [/autoit] [autoit][/autoit] [autoit]

    For $iR = 1 To $iRows
    $sItem = ""
    For $iC = 0 To $iColumns - 1
    $sItem &= $aResult[$iR][$iC] & "|"
    Next
    GUICtrlCreateListViewItem(StringTrimRight($sItem, 1), $ListView1)

    [/autoit] [autoit][/autoit] [autoit]

    Next
    $fSortSense1 = False
    _GUICtrlListView_SimpleSort($ListView1, $fSortSense1, 0)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    _SQLite_Exec(-1, "Create table if not exists Geräte (GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort);")
    _SQLite_GetTable2d(-1, "Select GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort From Geräte Where Eigentümer = 'Werkstatt' and not Standort = 'Werkstatt'", $aResult, $iRows, $iColumns)
    _GUICtrlListView_DeleteAllItems($ListView2)
    For $iR = 1 To $iRows
    $sItem = ""
    For $iC = 0 To $iColumns - 1
    $sItem &= $aResult[$iR][$iC] & "|"
    Next
    GUICtrlCreateListViewItem(StringTrimRight($sItem, 1), $ListView2)
    _SetItemColor(-1, 0xFFFF33)
    Next

    [/autoit] [autoit][/autoit] [autoit]

    _SQLite_GetTable2d(-1, "Select GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort From Geräte Where not Standort = Eigentümer and not Standort ='Werkstatt' and not Eigentümer ='Werkstatt'", $aResult, $iRows, $iColumns)

    [/autoit] [autoit][/autoit] [autoit]

    For $iR = 1 To $iRows
    $sItem = ""
    For $iC = 0 To $iColumns - 1
    $sItem &= $aResult[$iR][$iC] & "|"
    Next
    GUICtrlCreateListViewItem(StringTrimRight($sItem, 1), $ListView2)
    _SetItemColor(-1, 0xFF6600)
    Next

    [/autoit] [autoit][/autoit] [autoit]

    _SQLite_GetTable2d(-1, "Select GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort From Geräte Where Standort ='Werkstatt' and Eigentümer ='Werkstatt'", $aResult, $iRows, $iColumns)

    [/autoit] [autoit][/autoit] [autoit]

    For $iR = 1 To $iRows
    $sItem = ""
    For $iC = 0 To $iColumns - 1
    $sItem &= $aResult[$iR][$iC] & "|"
    Next
    GUICtrlCreateListViewItem(StringTrimRight($sItem, 1), $ListView2)
    _SetItemColor(-1, 0x99FF33)
    Next
    $fSortSense2 = False
    _GUICtrlListView_SimpleSort($ListView2, $fSortSense2, 0)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    _SQLite_Exec(-1, "Create table if not exists Geräte (GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort);")
    _SQLite_GetTable2d(-1, "Select GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort From Geräte Where Not Eigentümer = 'Werkstatt' And Not Eigentümer = Standort And Standort ='Werkstatt'", $aResult, $iRows, $iColumns)
    _GUICtrlListView_DeleteAllItems($ListView3)
    For $iR = 1 To $iRows
    $sItem = ""
    For $iC = 0 To $iColumns - 1
    $sItem &= $aResult[$iR][$iC] & "|"
    Next
    GUICtrlCreateListViewItem(StringTrimRight($sItem, 1), $ListView3)
    Next
    $fSortSense3 = False
    _GUICtrlListView_SimpleSort($ListView3, $fSortSense3, 0)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    _SQLite_Exec(-1, "Create table if not exists Geräte (GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort);")
    _SQLite_GetTable2d(-1, "Select GID,Bezeichnung,Typ,Hersteller,SNr,Eigentümer,Standort From Geräte", $aResult, $iRows, $iColumns)
    _GUICtrlListView_DeleteAllItems($ListView4)
    For $iR = 1 To $iRows
    $sItem = ""
    For $iC = 0 To $iColumns - 1
    $sItem &= $aResult[$iR][$iC] & "|"
    Next
    GUICtrlCreateListViewItem(StringTrimRight($sItem, 1), $ListView4)
    Next
    $fSortSense4 = False
    _GUICtrlListView_SimpleSort($ListView4, $fSortSense4, 0)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    GUICtrlCreateTabItem("")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    GUICtrlSetState($ListView1, $GUI_SHOW)
    GUICtrlSetState($ListView2, $GUI_SHOW)
    GUICtrlSetState($ListView3, $GUI_SHOW)
    GUICtrlSetState($ListView4, $GUI_SHOW)
    EndFunc ;==>LV_update

    [/autoit]

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]

    Einmal editiert, zuletzt von Blubkuh (17. März 2014 um 00:25)

  • [autoit]

    _GUICtrlListView_BeginUpdate

    [/autoit]

    und

    [autoit]

    _GUICtrlListView_EndUpdate

    [/autoit]

    mal ausprobieren ;)

    Dann bräuchtest du dein HIDE/SHOW auch net mehr...

    Grüße Yaerox

    Grüne Hölle

  • Habe schon versucht mit _GUICtrlListView_BeginUpdate() zu arbeiten aber das hatte irgendwie garkeinen effekt.

    [autoit]

    _GUICtrlListView_BeginUpdate

    [/autoit]

    und

    [autoit]

    _GUICtrlListView_EndUpdate

    [/autoit]

    mal ausprobieren ;)

    Dann bräuchtest du dein HIDE/SHOW auch net mehr...

    Wie gesagt: Hatte 0 Effekt Listview hat trotzdem angezeigt wie daten in die Tabelle geschrieben wurden und auch geflackert.
    Kann es gerne nochmals probieren aber ich glaub nicht, dass ich da was falsche gemacht habe

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]
  • Habs grade nochmals mit dem BeginnUpdate probiert und das sieht im Prinzip gleich aus wie als wenn ich die ListView hide. Flackern bleibt leider vorhanden. Ich schätze das das einfach an der Großen Menge an Listvieweinträgen liegt und das das nicht schöner gemacht werden kann.

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]
  • Hi,

    ich habe es jetzt nicht getestet. Aber mein erster Versuch wäre, die Differenz aus dem ListViewInhalt und dem neuen Array zu ermitteln und anschließend nur diese Differenz hinzuzufügen oder aus der Liste zu entfernen. Am einfachsten ist es, wenn du das mit zwei Array's machst. Geht am schnellsten.

    Array1 = aktuelle Datensätze im Listview
    Array2 = wird durch _SQLite_GetTable2D gefüllt

  • Hi,

    ich habe es jetzt nicht getestet. Aber mein erster Versuch wäre, die Differenz aus dem ListViewInhalt und dem neuen Array zu ermitteln und anschließend nur diese Differenz hinzuzufügen oder aus der Liste zu entfernen. Am einfachsten ist es, wenn du das mit zwei Array's machst. Geht am schnellsten.

    Array1 = aktuelle Datensätze im Listview
    Array2 = wird durch _SQLite_GetTable2D gefüllt


    Hört sich nach einer guten Idee an.
    Aktuelle Datensätze einlesen ist kein Problem. das 2. Array mit aktuellen Daten auffüllen ist auch easy.
    Aber dann gehts los. Jeden Eintrag vergleichen und das wenn die Einträge evtl nicht in der gleichen Reihenfolge sind. Dann herausfinden welche Daten komplett neu sind diese zum Listview hinzufügen und die Daten die Sich geändert haben(z.B. nur die Telefonnummer eines Kunden) updaten.

    Hört sich nach verdammt viel Arbeit an wo ich noch nicht wirklich nen Plan habe ob sich das wirklich umzusetzen lohnt.


    Habe btw mal nen Video von dem Flackern gemacht. Im ersten Durchlauf benutze ich _GUICtrlListView_BeginUpdate() und danach sieht man wie ich das durch @GUI_hide austausche und lasse dann nochmal nen durchlauf machen.
    https://www.youtube.com/watch?v=EpGcYgujUBE&feature=youtu.be

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]
  • schon den ex-style: $LVS_EX_DOUBLEBUFFER ausprobiert??

    Danke den kannte ich nicht. hat aber leider garnichts geändert :)

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]
  • Moin!

    Ich hab mir dein Skript zwar jetzt nicht so genau angesehen, weil ich es in Ermangelung an Datenbanken auch nicht testen kann,
    aber ich habe mal ein kurzes Beispiel zu _GUICtrlListView_BeginUpdate und _GUICtrlListView_EndUpdate.

    Da Flackert zwar nichts, aber die Unterschiede sind emorm. Am Schluss hab ich noch ein Beispiel zu _GUICtrlListView_AddArray angefügt, was nochmal nen Tacken schneller ist, allerdings nicht so flexibel. Du kannst die Funktion aber nach deinen Vorlieben anpassen, was ich selbst schon getan habe.

    Skript

    Spoiler anzeigen
    [autoit]

    #include <GuiListView.au3>

    [/autoit] [autoit][/autoit] [autoit]

    GUICreate("ListView", 200, 600)
    $hListView = GUICtrlCreateListView("Spalte 1| Spalte 2", 0, 0, 200, 600)

    [/autoit] [autoit][/autoit] [autoit]

    $iEingabe = InputBox("", "Anzahl der Elemente eingeben:", "1000")
    If $iEingabe = "" Then Exit

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    _FillListView($iEingabe)

    [/autoit] [autoit][/autoit] [autoit]

    do
    Until GUIGetMsg() = -3

    [/autoit] [autoit][/autoit] [autoit]

    Func _FillListView($iItems)
    Local $aItem[$iItems][2]
    For $i = 0 To $iItems - 1
    $aItem[$i][0] = StringFormat("Zeile Nr. %04s", $i)
    $aItem[$i][1] = "Sinnloses Zeug"
    Next

    [/autoit] [autoit][/autoit] [autoit]

    $iBegin = TimerInit()
    For $i = 0 To $iItems - 1
    GUICtrlCreateListViewItem($aItem[$i][0] & "|" & $aItem[$i][1], $hListView)
    Next
    MsgBox(0, "", "Dauer zum Befüllen des ListViews mit " & $iItems & " Items: " & TimerDiff($iBegin) / 1000 & " Sekunden")

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlListView_BeginUpdate($hListView)
    _GUICtrlListView_DeleteAllItems($hListView)
    _GUICtrlListView_EndUpdate($hListView)

    [/autoit] [autoit][/autoit] [autoit]

    $iBegin = TimerInit()
    _GUICtrlListView_BeginUpdate($hListView)
    For $i = 0 To $iItems - 1
    GUICtrlCreateListViewItem($aItem[$i][0] & "|" & $aItem[$i][1], $hListView)
    Next
    _GUICtrlListView_EndUpdate($hListView)
    MsgBox(0, "", "Dauer zum Befüllen des ListViews mit " & $iItems & " Items: " & TimerDiff($iBegin) / 1000 & " Sekunden")

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlListView_BeginUpdate($hListView)
    _GUICtrlListView_DeleteAllItems($hListView)
    _GUICtrlListView_EndUpdate($hListView)

    [/autoit] [autoit][/autoit] [autoit]

    $iBegin = TimerInit()
    _GUICtrlListView_BeginUpdate($hListView)
    _GUICtrlListView_AddArray($hListView, $aItem)
    _GUICtrlListView_EndUpdate($hListView)
    _GUICtrlListView_SetColumnWidth($hListView, 0, $LVSCW_AUTOSIZE)
    _GUICtrlListView_SetColumnWidth($hListView, 1, $LVSCW_AUTOSIZE)

    [/autoit] [autoit][/autoit] [autoit]

    MsgBox(0, "", "Dauer zum Befüllen des ListViews mit " & $iItems & " Items: " & TimerDiff($iBegin) / 1000 & " Sekunden")
    EndFunc

    [/autoit]

    Sanfte Grüße :D


  • Hey super vielen Dank für die Beispiele. das scheint ja wirklich gut zu klappen in dem Fall.
    Ich war auch schon angefangen etwas in der Art zu scripten was deinem 3. Beispiel entspricht.

    Leider bin ich da jetzt auf ein Problem gestoßen was für mich keinen Sinn ergibt.
    Im ArrayDisplay() ist noch alles super ABER dann:
    _GUICtrlListView_AddArray($hListView, $aItem) liest die ersten 3 Zeilen richtig ein und dann bei der 4. Zeile ist die erste Spalte noch richtig(Kundennummer) aber dann folgt der Name eines total falschen Kunden der an die Stelle garnicht hingehört und dann werden plötzlich nurnoch die Kundennummern übernommen(1. Spalte) und die anderen 5 Spalten bleiben leer.
    Ganz am Ende ist dann plötzlich bei den letzten ~5 Kunden wieder alles in Ordnung :?:

    Soo... Wie könnt Ihr mir nun helfen ohne dass ich euch die Datenbank mit den ganzen Kundendaten posten muss? ^^


    BTW: In deinem Beispiel kannst du vor und nach _GUICtrlListView_AddArray() die _GUICtrlListView_BeginUpdate($hListView) bzw _GUICtrlListView_EndUpdate($hListView) wegmachen, weil die Funktion intern das Beginnupdate aufruft und beendet :)

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]
  • Leider bin ich da jetzt auf ein Problem gestoßen was für mich keinen Sinn ergibt.
    Im ArrayDisplay() ist noch alles super ABER dann:


    ArrayDisplay verursacht hin und wieder echt seltsame Effekte (Hab mir den Code allerdings nie näher angesehn, um das zu ergründen). Die benutze ich wirklich nur zum debuggen.
    Lass die Funktion einfach mal weg und schau, was passiert...


    BTW: In deinem Beispiel kannst du vor und nach _GUICtrlListView_AddArray() die _GUICtrlListView_BeginUpdate($hListView) bzw _GUICtrlListView_EndUpdate($hListView) wegmachen, weil die Funktion intern das Beginnupdate aufruft und beendet :)


    Vielen Dank, hatte ich übersehen... :thumbup:


  • ArrayDisplay verursacht hin und wieder echt seltsame Effekte (Hab mir den Code allerdings nie näher angesehn, um das zu ergründen). Die benutze ich wirklich nur zum debuggen.
    Lass die Funktion einfach mal weg und schau, was passiert...


    ArrayDisplay hatte ich auch nur zum debuggen genommen weil in meinem Listview halt leere Einträge vorhanden sind. Ich mach gleich mal nen kurzes Video um das mal zu zeigen.


    Edit: Video des Problems ist hier zu sehen: https://www.youtube.com/watch?v=1UwvgII9Xus&feature=youtu.be

    Wenn das Video ned geht: Paar minuten warten damit Youtube das eben rendern kann. Dann sollte auch bessere Quali verfügbar sein

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]

    Einmal editiert, zuletzt von Blubkuh (13. März 2014 um 21:52)

  • Vielen Dank schonmal im Voraus an Friesel dank seiner modifizierten Version der Funktion von _GUICtrlListView_AddArray() konnte ich nun etwas genauer beobachten wo die Funktion ins Stocken gerät.

    Hier erstmal die modifizierte Version: (Die Änderung gibt nach jedem Item was ins Listview geschrieben wird ne msg box und pausiert so die Funktion, sodass man sehen kan welche Daten geschrieben wurden und man überprüfen kann ob diese richtig sind)

    Spoiler anzeigen
    [autoit]

    Func _GUICtrlListView_AddArray_test($hWnd, ByRef $aItems)
    ;~ If $Debug_LV Then __UDF_ValidateClassName($hWnd, $__LISTVIEWCONSTANT_ClassName)

    [/autoit] [autoit][/autoit] [autoit]

    Local $fUnicode = _GUICtrlListView_GetUnicodeFormat($hWnd)

    [/autoit] [autoit][/autoit] [autoit]

    Local $tItem = DllStructCreate($tagLVITEM)
    Local $tBuffer
    If $fUnicode Then
    $tBuffer = DllStructCreate("wchar Text[4096]")
    Else
    $tBuffer = DllStructCreate("char Text[4096]")
    EndIf
    DllStructSetData($tItem, "Mask", $LVIF_TEXT)
    DllStructSetData($tItem, "Text", DllStructGetPtr($tBuffer))
    DllStructSetData($tItem, "TextMax", 4096)
    Local $iLastItem = _GUICtrlListView_GetItemCount($hWnd)
    ;~ _GUICtrlListView_BeginUpdate($hWnd)
    If IsHWnd($hWnd) Then
    MsgBox(0, "", "IsHWnd($hWnd) ist True!" & @CRLF & "Bitte nur eine ListView ID übergeben, kein Handle!")
    ;~ If _WinAPI_InProcess($hWnd, $_lv_ghLastWnd) Then
    ;~ For $iI = 0 To UBound($aItems) - 1
    ;~ DllStructSetData($tItem, "Item", $iI)
    ;~ DllStructSetData($tItem, "SubItem", 0)
    ;~ DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
    ;~ _SendMessage($hWnd, $LVM_INSERTITEMW, 0, $tItem, 0, "wparam", "struct*")
    ;~ For $iJ = 1 To UBound($aItems, 2) - 1
    ;~ DllStructSetData($tItem, "SubItem", $iJ)
    ;~ DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])
    ;~ _SendMessage($hWnd, $LVM_SETITEMW, 0, $tItem, 0, "wparam", "struct*")
    ;~ Next
    ;~ Next
    ;~ Else
    ;~ Local $iBuffer = DllStructGetSize($tBuffer)
    ;~ Local $iItem = DllStructGetSize($tItem)
    ;~ Local $tMemMap
    ;~ Local $pMemory = _MemInit($hWnd, $iItem + $iBuffer, $tMemMap)
    ;~ Local $pText = $pMemory + $iItem
    ;~ DllStructSetData($tItem, "Text", $pText)
    ;~ For $iI = 0 To UBound($aItems) - 1
    ;~ DllStructSetData($tItem, "Item", $iI + $iLastItem)
    ;~ DllStructSetData($tItem, "SubItem", 0)
    ;~ DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
    ;~ _MemWrite($tMemMap, $tItem, $pMemory, $iItem)
    ;~ _MemWrite($tMemMap, $tBuffer, $pText, $iBuffer)
    ;~ If $fUnicode Then
    ;~ _SendMessage($hWnd, $LVM_INSERTITEMW, 0, $pMemory, 0, "wparam", "ptr")
    ;~ Else
    ;~ _SendMessage($hWnd, $LVM_INSERTITEMA, 0, $pMemory, 0, "wparam", "ptr")
    ;~ EndIf
    ;~ For $iJ = 1 To UBound($aItems, 2) - 1
    ;~ DllStructSetData($tItem, "SubItem", $iJ)
    ;~ DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])
    ;~ _MemWrite($tMemMap, $tItem, $pMemory, $iItem)
    ;~ _MemWrite($tMemMap, $tBuffer, $pText, $iBuffer)
    ;~ If $fUnicode Then
    ;~ _SendMessage($hWnd, $LVM_SETITEMW, 0, $pMemory, 0, "wparam", "ptr")
    ;~ Else
    ;~ _SendMessage($hWnd, $LVM_SETITEMA, 0, $pMemory, 0, "wparam", "ptr")
    ;~ EndIf
    ;~ Next
    ;~ Next
    ;~ _MemFree($tMemMap)
    ;~ EndIf
    Else
    Local $pItem = DllStructGetPtr($tItem)
    For $iI = 0 To UBound($aItems) - 1
    MsgBox(0, "", "")
    DllStructSetData($tItem, "Item", $iI + $iLastItem)
    DllStructSetData($tItem, "SubItem", 0)
    DllStructSetData($tBuffer, "Text", $aItems[$iI][0])
    If $fUnicode Then
    GUICtrlSendMsg($hWnd, $LVM_INSERTITEMW, 0, $pItem)
    Else
    GUICtrlSendMsg($hWnd, $LVM_INSERTITEMA, 0, $pItem)
    EndIf
    For $iJ = 1 To UBound($aItems, 2) - 1
    MsgBox(0, "", "")
    DllStructSetData($tItem, "SubItem", $iJ)
    DllStructSetData($tBuffer, "Text", $aItems[$iI][$iJ])
    If $fUnicode Then
    GUICtrlSendMsg($hWnd, $LVM_SETITEMW, 0, $pItem)
    Else
    GUICtrlSendMsg($hWnd, $LVM_SETITEMA, 0, $pItem)
    EndIf
    Next
    Next
    EndIf
    ;~ _GUICtrlListView_EndUpdate($hWnd)
    EndFunc ;==>_GUICtrlListView_AddArray_test

    [/autoit]


    Un nun kommen wir zu dem Punkt an dem die Funktion scheitert:
    Mein Listview wurde wie folgt erstellt:

    Spoiler anzeigen
    [autoit]

    $ListView1 = GUICtrlCreateListView("KdNr|Name|Straße|PLZ|Ort|Telefon|", 5, 25, 802, 450, BitOR($LVS_SORTASCENDING, $LVS_SINGLESEL))

    [/autoit]

    Das Problem ist, dass die Daten einer nach dem anderen in das Listview eingetragen werden und zwar immer in der untersten Zeile des Listviews. Da ich aber $LVS_SORTASCENDING benutze und die Kundennummern(1. Spalte) nicht von niedrig -> hoch eingelesen werden sondern durcheinander wird automatisch eine niedrige Kundennummer im Listview nach oben geschoben, die Daten werden aber in der untersten Zeile des Listviews eingetragen(soll heißen die alten Daten in der Zeile werden überschrieben)

    nach dem entfernen von $LVS_SORTASCENDING funktioniert die Funktion wunderbar. Ich bin mir nicht sicher ob man das als Bug werten sollte. Es sollte aber auf jedenfall in die Hilfe der _GUICtrlListView_AddArray() Funktion hinzugefügt werden


    EDIT:
    Mit dieser Funktion tritt übrigends kein Flackern des Listviews mehr auf. Vielen Dank

    Dieser Beitrag wurde 9521 mal editiert, zum letzten Mal von Blubkuh: Morgen, 02:28.

    [autoit]

    If Not $Elephant Then $Irelephant = True

    [/autoit]

    Einmal editiert, zuletzt von Blubkuh (17. März 2014 um 00:25)