Eye Clock v1.3.1 build 2015-06-28

**UEZ**

Das u.a. mit den rollenden Augen ist geplant, aber nicht nach dem Aufwachen.

Je nach Timer werden momentan aus 4 Modi eine ausgeführt

normaler Modus, sprich Anzeige der Uhrzeit
rollende Augen
Augen folgen der Maus
große Pupillen

Bei dem Aufwachen wurde der Timer ausgelöst und zufällig der rollende Augen Modus gestartet, aber nichtsdestotrotz wäre das Cool nach dem "Aufwachen" einen der Effekte (2/4) zu starten.

Einen Effekt würde ich noch machen wollen und zwar das die Pupillen einfach quasi losgelassen werden, so dass sie sich in den Ruhezustand auf 6 Uhr schaukeln. Mal sehen...

Wenn's mit der alten Version lief und mit der Neuen nicht, dann hängt das nicht an der neuen Version, denn, soweit ich mich erinnern kann, habe ich nichts an den Grafiksachen herumgeschraubt.

Vielleicht stimmt was mit dem Grafiktreiber was nicht. Ich würde sagen Reboot tut gut.

**Mars**

Hier gibts ne LCD Uhr

Spoiler anzeigen

AutoIt

#include <GDIPlus.au3>


Opt('GUIOnEventMode', 1)


Global Const $iCol1 = 0xFF404A57 ; Pixelfarbe
Global Const $iCol2 = 0xFFA3B5A2 ; Hintergrundfarbe
Global Const $iSizePx = 16
Global Const $iSizeLine = 2


Global Const $iW = 33
Global Const $iH = 11
Global $bExit = False


_GDIPlus_Startup()


Global $vPX = DllStructCreate('int x[' & $iW * $iH & ']')
Global $aLCD = _LCD_New(DllStructGetPtr($vPX), $iW, $iH, $iSizePx, $iSizeLine, $iCol2)
Global $hGUI = GUICreate('LCD Uhr', $aLCD[0].WidthOutput, $aLCD[0].HeightOutput)
Global $hBmp = _GDIPlus_BitmapCreateFromScan0($aLCD[0].WidthOutput, $aLCD[0].HeightOutput, $GDIP_PXF32ARGB, $aLCD[0].WidthOutput * 4, $aLCD[0].pOutput)
Global $hGfx = _GDIPlus_GraphicsCreateFromHWND($hGUI)


For $x = 0 To $iW - 1 Step 1
	For $y = 0 To $iH - 1 Step 1
		If $x = 0 Or $x = $iW - 1 Or $y = 0 Or $y = $iH - 1 Then DllStructSetData($vPX, 1, $iCol1, $x + $y * $iW + 1)
	Next
Next


GUISetBkColor('0x' & StringRight(Hex($iCol2, 8), 6), $hGUI)
GUISetState(@SW_SHOW, $hGUI)
GUISetOnEvent(-3, 'x', $hGUI)
OnAutoItExitRegister('_Release')
GUIRegisterMsg(0xF, 'WM_PAINT')


While Sleep(20) And Not $bExit
	_Uhr()
WEnd


Func _Uhr()
	Local Static $iTimer = @SEC
	If $iTimer <> @SEC Then
		$iTimer = @SEC
		Local $s = @SEC, $m = @MIN, $h = @HOUR, $z = IsInt($s / 2)
		For $i = 0 To 3 Step 1
			DllStructSetData($vPX, 1, $z ? $iCol1 : 0, 144 + IsInt(($i + 1) / 2) * 66 + ($i > 1) * 10)
		Next
		_Ziffer(3, 3, Int($h/10))
		_Ziffer(7, 3, $h - Int($h/10)*10)
		_Ziffer(13, 3, Int($m/10))
		_Ziffer(17, 3, $m - Int($m/10)*10)
		_Ziffer(23, 3, Int($s/10))
		_Ziffer(27, 3, $s - Int($s/10)*10)
		_LCD_RenderASM($aLCD)
		WM_PAINT()
	EndIf
EndFunc


Func _Ziffer($x, $y, $n)
	Local Static $a[] = ['111101101101111','110010010010111','111001111100111','111001011001111','100101101111001','111100111001111','100100111101111','111001001001001','111101111101111','111101111001001']
	If IsString($a[0]) Then
		For $i = 0 To 9 Step 1
			$a[$i] = StringSplit($a[$i], '', 2)
		Next
	EndIf
	For $i = 0 To 14 Step 1
		DllStructSetData($vPX, 1, (($a[$n])[$i] = 1 ? $iCol1 : 0), $x + $y * $iW + 1 + Mod($i, 3) + Int($i/3)*$iW)
	Next
EndFunc


Func WM_PAINT()
	_GDIPlus_GraphicsDrawImage($hGfx, $hBmp, 0, 0)
EndFunc


Func x()
	$bExit = True
EndFunc


Func _Release()
	_GDIPlus_GraphicsDispose($hGfx)
	_GDIPlus_BitmapDispose($hBmp)
	_GDIPlus_Shutdown()
EndFunc


Func _LCD_RenderASM(ByRef $aLCD)
	Local Static $vOP = DllStructCreate('byte[229]'), $xTmp = DllStructSetData($vOP, 1, '0x8B4424048B388B70048B482889F28B5818891A83C2044977F88B48248B5814035810660F6EFB8B580C0FAF5808C1E30283EB0401DF51498B1F660F6EF383EF0481E3000000FF81FB000000FF0F85880000008B58085053BA0000000089C8F7F3660F6ECA660F6ED05B89D0BA00000000F7F30FAFC3660F7ED329C358660F7EFA0FAFDA035814660F6ED3660F7ECB0FAFDA035814660F6ECB518B50108B581C5089D1660F7ED001D029C80FAFC353660F7ECB01D8C1E00201F089C3515289D1C1E20201D0660F7EF283E80489104975F889D85A595B4975CA585959490F8553FFFFFFC20400'), $pOP = DllStructGetPtr($vOP)
	DllCallAddress('none', $pOP, 'ptr', $aLCD[2])
EndFunc


Func _LCD_New($pInput, $iWInput, $iHInput, $iSizePx, $iSizeLine, $iColBG)
	Local $vLCD = DllStructCreateEx('int pInput=' & $pInput & ';int pOutput;int WidthInput=' & $iWInput & ';int HeightInput=' & $iHInput & ';int SizePx=' & $iSizePx & ';int SizeLine=' & $iSizeLine & ';int ColBG=' & $iColBG & ';int WidthOutput;int HeightOutput;int PxInput=' & $iWInput * $iHInput & ';int PxOutput')
	$vLCD.WidthOutput = $vLCD.WidthInput * ($vLCD.SizePx + $vLCD.SizeLine) + $vLCD.SizeLine
	$vLCD.HeightOutput = $vLCD.HeightInput * ($vLCD.SizePx + $vLCD.SizeLine) + $vLCD.SizeLine
	$vLCD.PxOutput = $vLCD.WidthOutput * $vLCD.HeightOutput
	Local $aLCD[] = [$vLCD, DllStructCreate('int x[' & $vLCD.WidthOutput * $vLCD.HeightOutput & ']'), DllStructGetPtr($vLCD)]
	$vLCD.pOutput = DllStructGetPtr($aLCD[1])
	Return $aLCD
EndFunc


Func DllStructCreateEx($sStruct, $pPointer = Default) ; klappt nur OHNE Arrays, also kein int a[5]=[1,2,3,4,5] !
	Local $aSplit = StringSplit($sStruct, ';', 2), $u = UBound($aSplit), $sDef = '', $a[$u]
	For $i = 0 To $u - 1 Step 1
		$a[$i] = StringSplit($aSplit[$i], '=', 2)
		$sDef &= ($a[$i])[0] & (($i < $u - 1) ? ';' : '')
	Next
	Local $vStr = $pPointer = Default ? DllStructCreate($sDef) : DllStructCreate($sDef, $pPointer)
	For $i = 0 To $u - 1 Step 1
		If UBound($a[$i]) = 2 Then DllStructSetData($vStr, $i + 1, ($a[$i])[1])
	Next
	Return $vStr
EndFunc

Alles anzeigen

**UEZ**

Gleich mal die Assembler Keule ausgepackt. Wäre es mit reinem AutoIt Code zu langsam gewesen oder ist das nur die pure Lust an Autoaggression.

Wäre nett, wenn du den ASM Code posten würdest.

**Mars**

Das ist der dazugehörige Code. (Der war doch gestern auch in der SB^^)

AutoIt

Func __MyASM()
	_('use32')


	; ASM von Mars@AutoIt.de 27.Mai.2015
	; Im Code wird SSE ausschließlich zum Zwischenspeichern von Konstanten
	; oder Vairablen benutzt. Da der Input flexibel bleiben soll kann nicht
	; von Breite- oder Höhewerten die durch 2,4,8,usw teilbar sind aus-
	; gegangen werden. SSE würde den Programmieraufwand erhöhen und die
	; Funktion läuft ohnehin schnell genug.


	_('mov eax, [esp+4]')
	; 01 [00] - pInput
	; 02 [04] - pOutput
	; 03 [08] - WidthInput
	; 04 [12] - HeightInput
	; 05 [16] - SizePx
	; 06 [20] - SizeLine
	; 07 [24] - ColBG
	; 08 [28] - WidthOutput
	; 09 [32] - HeightOutput
	; 10 [36] - PxInput (Anzahl Pixel)
	; 11 [40] - PxOutput


	_('mov edi, [eax+00]')	; Pointer Input
	_('mov esi, [eax+04]')	; Pointer Output


	; Hintergrund färben
	; Der komplette Hintergrund wird
	_('mov ecx, [eax+40]')	; Anzahl Pixel Output
	_('mov edx, esi')		; Output Pointer
	_('mov ebx, [eax+24]')	; Hintergrundfarbe
	_('_ColBG:')			; Schleife zum Färben
	_('mov [edx], ebx')		; Farbe reinspachteln
	_('add edx, 4')			; 1 Px weiter
	_('dec ecx')			; Counter verringern
	_('ja _ColBG')			; Schleifenende


	; Hauptschleife Vorbereitungen
	_('mov ecx, [eax+36]')	; Anzahl Pixel Input
	_('mov ebx, [eax+20]')	; SizeLine
	_('add ebx, [eax+16]')	; SizeLine + SizePx
	_('movd xmm7, ebx')		; xmm7 = $_Const01 = SizePx + SizeLine


	; Input Pointer verschieben, weil wir Rückwärts laufen
	_('mov ebx, [eax+12]')	; WidthInput
	_('imul ebx, [eax+08]') ; HeightInput
	_('shl ebx, 2')			; BytesInput
	_('sub ebx, 4')			; UBound ist nicht gleich LBound !
	_('add edi, ebx')		; edi zeigt jetzt auf den letzten Pixel statt auf den Ersten


	; Hauptschleife
	_('_MainLoop:')			; Label der Hauptschleife
	_('push ecx')			; ecx sichern
	_('dec ecx')			; UBound Nummer 2
	_('mov ebx, [edi]')		; Inputfarbe
	_('movd xmm6, ebx')		; Farbe in xmm6 sichern
	_('sub edi, 4')			; Direkt 1 Px weiter (obwohl der aktuelle noch nichtmal gezeichnet wurde)
	_('and ebx, 0xFF000000'); Alphakanal abchecken
	_('cmp ebx, 0xFF000000'); Ist der Pixel vollständig undurchsichtig ?
	_('jne _PxIsTrans')		; Wenn nicht -> Pixel überspringen


	; Berechnung von x und y
	; $x = Mod($i, $vLCD.x(03))
	; $y = Int($i / $vLCD.x(03))
	_('mov ebx, [eax+08]')	; ebx = $vLCD.x(03)
	_('push eax')			; eax wird für div gebraucht -> eax auf den Stack
	_('push ebx')			; Den Wert brauchen wir gleich nochmal, so muss er nicht aus dem Ram geholt werden.
	_('mov edx, 0')			; edx bekommt den Modulo Wert, bei der Division stellt edx die ersten 32 Bit (die alle 0 sind)
	_('mov eax, ecx')		; eax = $i
	_('div ebx')			; wir Teilen edx:eax / ebx -> $i/$vLCD.x(03). Der Rest der Division liegt in edx, das Ergebnis in eax
	_('movd xmm1, edx') 	; xmm1 = $x = Mod($i, $vLCD.x(03))
	_('movd xmm2, eax')		; xmm2 = $y = Int($i / $vLCD.x(03))
	; $iTmp = Int($x / $vLCD.x(03)) * $vLCD.x(03)
	; $y -= $iTmp
	_('pop ebx')			; ebx = $vLCD.x(03)
	_('mov eax, edx')		; eax = $x
	_('mov edx, 0')			; Die ersten 32Bit bei div sind leer...
	_('div ebx')			; Gleiches wie Oben. Ergebnis -> eax, Rest -> edx
	_('imul eax, ebx')		; eax = Int($x / $vLCD.x(03)) * $vLCD.x(03)
	_('movd ebx, xmm2')		; Leider haben wir kein freies Register gehabt -> y aus xmm2 holen.
	_('sub ebx, eax')		; ebx = $y - Int($x / $vLCD.x(03)) * $vLCD.x(03)
	_('pop eax')			; eax kann endlich wieder als Pointer benutzt werden.
	_('movd edx, xmm7')		; edx = $_Const01
	_('imul ebx, edx')		; $y *= $_Const01
	_('add ebx, [eax+20]')  ; $y += $vLCD.x(06)
	_('movd xmm2, ebx')		; xmm2 = $y
	_('movd ebx, xmm1')		; Wiedermal fehlt ein zusätzliches Register -> x aus xmm1 holen
	_('imul ebx, edx')		; $x *= $_Const01
	_('add ebx, [eax+20]')	; $x += $vLCD.x(06)
	_('movd xmm1, ebx')		; xmm1 = $x


	; H Schleife Vorbereitungen
	_('push ecx')
	_('mov edx, [eax+16]')	; edx = SizePx = $vLCD.x(05)
	_('mov ebx, [eax+28]')	; edx = WidthOutput = $vLCD.x(08)
	_('push eax')			; eax -> Stack
	_('mov ecx, edx')		; ecx = $vLCD.x(05)


		_('_LoopH:')			; For $h = 0 To $vLCD.x(05) - 1 Step 1
		_('movd eax, xmm2')		; eax = $y
		_('add eax, edx')		; eax = $y + $vLCD.x(05)
		_('sub eax, ecx')		; eax = $y + $h, da $h = $vLCD.x(05) - ecx
		_('imul eax, ebx')		; eax = ($y + $h) * $vLCD.x(05)
		_('push ebx')			; $vLCD.x(08) wird erstmal nicht mehr gebraucht
		_('movd ebx, xmm1')		; ebx = x
		_('add eax, ebx')		; eax = Pixelnummer
		_('shl eax, 2') 		; Umrechnung in Bytes
		_('add eax, esi') 		; eax = Position der Vordersten Pixel in jedem zu zeichnenden Rechteck
		_('mov ebx, eax')		; ebx = Kopie von eax


		; W Schleife Vorbereitung
		_('push ecx')			; ecx wird wieder unser Counter
		_('push edx')			; Kuchen für alle !
		_('mov ecx, edx')		; Counter einstellen
		_('shl edx, 2')			; Umrechnung in Bytes
		_('add eax, edx')		; siehe oben
		_('movd edx, xmm6') 	; Wer weiß ob es besser ist aus einem 32er Register zu schreiben...


			_('_LoopW:')			; For $w = 0 To $vLCD.x(05) - 1 Step 1
			_('sub eax, 4')			; siehe oben
			_('mov [eax], edx')		; Hier wird der Pixel erst gezeichnet. Auf diese eine Zeile ist das komplette Gebilde ausgelegt.
			_('dec ecx')			;
			_('jnz _LoopW')			;


		_('mov eax, ebx')		; eax wieder herstellen
		_('pop edx')			;
		_('pop ecx')			;
		_('pop ebx')			;


		_('dec ecx')			;
		_('jnz _LoopH')			;


	_('pop eax')			;
	_('pop ecx')			;


	_('_PxIsTrans:')		;


	_('pop ecx')			;
	_('dec ecx')			;
	_('jnz _MainLoop')		;


	_('ret 4')				; Wir haben 4 Bytes gebraucht für unseren Datenpointer in [esp+4]
EndFunc

Alles anzeigen

Alles was er macht ist eine kleine Bitmap (in diesem Fall 33x11 px) in die Form zu bringen die man auf der Uhr sieht

Und das ist der AutoIt-Code der genau das gleiche macht:

Code

Func _LCD_Render(ByRef $aLCD) ; Extra schön einfach aufgebaut damit der


	Local $pLCD = DllStructGetPtr($aLCD[0])
	Local $vLCD = DllStructCreate('int x[11]', $pLCD)
	; 01 [00] - pInput
	; 02 [04] - pOutput
	; 03 [08] - WidthInput
	; 04 [12] - HeightInput
	; 05 [16] - SizePx
	; 06 [20] - SizeLine
	; 07 [24] - ColBG
	; 08 [28] - WidthOutput
	; 09 [32] - HeightOutput
	; 10 [36] - PxInput (Anzahl Pixel)
	; 11 [40] - PxOutput


	Local $vIn = DllStructCreate('int x[' & $vLCD.x(10) & ']', $vLCD.x(01))
	Local $vOut = DllStructCreate('int x[' & $vLCD.x(11) & ']', $vLCD.x(02))


	For $i = 0 To $vLCD.x(11) - 1 Step 1
		$vOut.x(($i + 1)) = $vLCD.x(07)
	Next


	Local $x, $y, $iTmp, $_Const01 = $vLCD.x(06) + $vLCD.x(05)


	For $i = 0 To $vLCD.x(10) - 1 Step 1
		If $vIn.x(($i + 1)) Then


			$x = Mod($i, $vLCD.x(03))
			$y = Int($i / $vLCD.x(03))


			$iTmp = Int($x / $vLCD.x(03)) * $vLCD.x(03)
			$y -= $iTmp


			$x *= $_Const01
			$x += $vLCD.x(06)
			$y *= $_Const01
			$y += $vLCD.x(06)


			For $h = 0 To $vLCD.x(05) - 1 Step 1
				For $w = 0 To $vLCD.x(05) - 1 Step 1


					$iTmp = $y
					$iTmp += $h
					$iTmp *= $vLCD.x(08)
					$iTmp += $x
					$iTmp += $w


					$vOut.x(($iTmp + 1)) = $vIn.x(($i + 1))


				Next
			Next


		EndIf
	Next


EndFunc

Alles anzeigen

Die Funktion ist in AutoIt (wenn man die Rechtecke via GDI+ zeichnet und mit einigen Tricks arbeitet) auch sehr schnell, der Code hier ist extra so umgemodelt das er 1:1 in ASM übernommen werden kann. Die ASM Version ist aber schneller, egal wie viele Tricks man mit AutoIt + GDI+ einsetzt

Den Sinn der Sache muss ich noch herausfinden, hab die Funktion geschrieben weil ich ein Nokiafeeling haben wollte...

**UEZ**

Die SB bzw. die 30 Tage aus Pastebin sind vergänglich. Den Code hatte ich bereits von Pastebin, aber die Anderen vielleicht noch nicht.

**UEZ**

Eigentlich wollte ich diese Projekt nicht mehr weiterführen, aber hatte ich noch Ideen, die ich umsetzen wollte.

Hinzugekommen sind

2 Brillen
Augenbrauen
weitere Pupillen Modis

bazii

UEZ:

Pupillen Modi, Brillen und Augenbrauen sind sind meiner Meinung nach richtig klasse geworden. Auch die Tranzparenzfähigkeit und die Einstellbarkeit des Hintergrundes sind einzigartig. Sehr gute Arbeit. Vielen Dank für die Bereitstellung.

PS: Ich fände es noch zusätzlich richtig klasse, wenn die Uhr mit all Ihren (oder den meisten) Einstellmöglichkeiten als .scr verwendbar (installierbar) wäre.

**UEZ**

Danke für dein Feedback bazii. Ich schaue mal, ob ich den SCR Modus hinzufügen kann. Einfach die Exe in SCR umbenennen geht zwar, ist aber so nicht gewollt.

**UEZ**

@bazii und die Anderen: könnt ihr bitte mal testen, ob der Bildschirmschoner funktioniert (siehe Anhang unten)?

Für x86 die SCR Datei nach C:\Windows\System32 und für x64 nach C:\Windows\SysWOW64 kopieren. Den Bildschirmschoner sollte man dann in der Combo Box sehen.

Die Exe ist einfach umbenannt, kann also wieder in Exe umbenannt werden und sollte dann wieder "normal" funktionieren.

bazii

UEZ:

Ich nutze Win7 Home premium x86:
Hab' die Eye Clock.scr von Deinem Anhang-Paket entpackt und nach c:\Windows\System32 kopiert.
Der Bildschirmschoner an sich lies sich bestens installieren und auch konfigurieren, allerdings ploppt die Eye Clock nur kurz auf und verschwindet wieder unsichtbar.

**UEZ**

Kannst du bitte diese Version testen?: https://autoit.de/index.php/Attachment/311-Eye-Clock-7z/ (Post 29)

Vielen DANK!

bazii

Hallo UEZ,

herzlichen Dank für die Änderungen. Jetzt bleibt der Bildschirmschoner bestehen und aktiviert sich auch nach gewählter Zeit sehr gut.
Eine Frage ist für mich jetzt noch offen. Wenn ich den transparenten Modus deaktiviere und stattdessen ein Hintergrundbild angebe, kann ich den Bildschirmschoner nicht mehr manuell mit Mausbewegung oder mit Esc beenden. Taskmanager erforderlich.

**UEZ**

Hmm, kann ich leider nicht nachstellen. Wenn ich eine Textur auswähle, die Einstellung übernehme und die SCR starte, wird der Bildschirmschoner beendet, wenn ich die Maus bewege oder eine Taste drücke.

Analog, wenn der Bildschirmschoner automatisch gestartet wird.

Kannst du die Schritte beschreiben, so dass ich sie analog nachstellen kann?

Danke.

PS: ich kann nur unter meinen VMs den Bildschirmschoner testen, da die GPO mir verbietet einen Bildschirmschoner auszusuchen.

bazii

Du, ich konnte das ganze jetzt noch ein wenig eingrenzen.
Stell mal den GUI-Scalierungsfaktor ganz hoch ein und teste nochmals. Bei mir friert dann der Bildschirmschoner ein. Anbei ein Bild zur Verdeutlichung, was ein Tester so treiben kann. Das hat dann mit dem manuellen Hintergrundbild weniger zu tun .

[Blockierte Grafik: http://www.top-pe.de/Temp/AutoIt/UEZ/2015-06-13%2018_49_18-Settings.png]

**UEZ**

In meiner Win7 x64 VM funktioniert es ohne Probleme. Auch auf meiner physikalien Win8 Maschine läuft's problemlos, wenn ich SCR starte.

bazii

Hmmm, ich teste real auf einem älteren Notebook i3 mit 3 GB RAM. Win7 x86 Host. Wenn ich Montag wieder bei der Arbeit bin, habe ich verschiedene Systeme zur Verfügung. Ich meld mich dann noch mal, sollte das einfrieren auf einem anderen Host nochmals vorkommen. Danke Dir vielmals für die Mühen.

**UEZ**

Ok, danke dir.

bazii

Hallo UEZ:

ich kann meinen zuvor geposteten Frost-Bildschirm mit maximaler Skalierung der Eye Clock.scr auf keinem anderen Test-PC egal ob XP, Win7, Win8, 8.1u1 rekonstruieren. Es bleibt mein Notebook als Einzelgerät, welches leider nur noch nach Beenden des Eye Clock-Tasks wieder zum Leben erweckt werden kann.

**UEZ**

Danke fürs Testen! Ich konnte auch dein Problem nicht nachstellen. Somit kann ich keine Fehlersuche durchführen. Sorry.