Read file -> return Zeilennummer

horphi

Hallo zusammen,

ein kurze Frage meinerseits. Ich kriege es nicht hin.

Ich möchte die Datei nach einem Begriff durchsuchen und mir dann die Zeilennummer ausgeben lassen, um dann zu sagen, "suche ab der Zeilennummer weiter".

mit _FileCountLines kann ich mir nur die komplette Anzahl ausgeben lassen..

Ich möchte aber:

AutoIt

$Wert
$Datei


Suche $Wert in $Datei und gib die Zeilennummer (nicht den Inhalt) zurück....

Geht das ?

VG

horphi

DasIch

So würde ich es wohl machen:

AutoIt

#include <file.au3>
#include <array.au3>


local $iLine, $aDatei, $sWert = "5Gehalt", $sFilePath = @ScriptDir & "\test.txt"


_FileReadToArray($sFilePath, $aDatei) ;Datei in Array einlesen


_ArrayDisplay($aDatei)


For $i = 1 To UBound($aDatei) - 1
	If $aDatei[$i] = $sWert Then $iLine = $i ;Wenn der aktuelle Eintrag des Arrays mit dem Suchwort übereinstimmt, wird die Zeile in $iLine gespeichert.
Next


MsgBox(0, "", $iLine)

Alles anzeigen

LG,
der Robert

teamnoobPDB

Probier es doch mal mit:

AutoIt

FileReadLine($sPath, $iLine)

oder soetwas hier:

AutoIt

#include <File.au3>


$iZeile = __DurchsucheDateiNach("test", @DesktopDir & "\test.txt")


Func __DurchsucheDateiNach($sWort, $sDateipfad)
	Local $hFile = FileOpen($sDateipfad)
	For $i = 1 To _FileCountLines($sDateipfad)
		If FileReadLine($hFile, $i) == $sWort Then
			FileClose($hFile)
			Return $i
		EndIf
	Next
	FileClose($hFile)
EndFunc

Alles anzeigen

EDIT: für größere Dateien hab ich es mal angepasst mit FIleOpn und FileClose!

teamnoobPDB

@DasIch Außerdem ist mir in deinem Skript ein Fehler aufgefallen... du überprüfst durch Ubound() - 1 nie das letzte Element deines Arrays etweder du nimmst nur Ubound oder das hier:

AutoIt

#include <File.au3>


$iZeile = __DurchsucheDateiNach("test", @DesktopDir & "\test.txt")


Func __DurchsucheDateiNach($sWort, $sDateipfad)
	Local $aRead
	_FileReadToArray($sDateipfad, $aRead)
	For $i = 1 To $aRead[0]
		If $aRead[$i] == $sWort Then Return $i
	Next
	Return -1
EndFunc

Alles anzeigen

Denn in $aDatei[0] befindet sich schon der Wert den Ubound($aDatei) zurückgeben würde

DasIch

Das letzte Element wird in meinem Beispiel auch geprüft. Der Code ist voll funktionial. Allerdings wird die schleife nicht abgebrochen, wenn der Eintrag gefunden wurde. Daher hier nochmal angepasst:

Ubound - 1 daher, dass das 0. Element im Array den Count des Arrays angibt und daher übersprungen wird. Du hast da wohl einen Denkfehler

AutoIt

#include <file.au3>
#include <array.au3>


local $iLine, $aDatei, $sWert = "5Gehalt", $sFilePath = @ScriptDir & "\test.txt"


_FileReadToArray($sFilePath, $aDatei) ;Datei in Array einlesen


_ArrayDisplay($aDatei)


For $i = 1 To UBound($aDatei) - 1
	ConsoleWrite($i)
	If $aDatei[$i] = $sWert Then
		$iLine = $i ;Wenn der aktuelle Eintrag des Arrays mit dem Suchwort übereinstimmt, wird die Zeile in $iLine gespeichert.
		ExitLoop
	EndIf
Next


MsgBox(0, "", $iLine)

Alles anzeigen

teamnoobPDB

Achja sorry hatte nen denkfehler ... es ist zu früh am morgen

aber wo ist es eine schande dass die Schleife abgebrochen wird? für größere dateien ist es doch viel sinnvoller weil, wenn ich den eintrag in zeile 10 gefunden habe brauche ich doch die anderen 20000 auch nicht überprüfen... das verhindert kurze hänger im Skript

DasIch

Und wieder bist du zu müde

Ich habe sie im ersten Post nicht abbrechen lassen, um aber das Skript schneller laufen lassen zu können habe ich im zweiten Post die Schleife abbrechen lassen

Micha_he

Meine Lösung:

AutoIt

$sFile = FileOpenDialog("Datei ?", @ScriptDir, "Alle (*.*)")
$sSearch = InputBox("Suchstring ?","Geben Sie den zu suchenden Text ein:")


$FileData = FileRead($sFile)
$sFound = StringLeft($FileData, StringInStr($FileData, $sSearch))
$sOut = StringReplace($sFound, @LF, "")


Msgbox(0,"",@extended + 1)

Edit: Zeilentrenner in @LF geändert. Ist dann auch Linux kompatibel.

teamnoobPDB

horphi

Hey ho, das klappt ja super.

Vielen DAnk.

Nur ich verstehe die Vorgehensweise mit @extended nicht....

Spoiler anzeigen

AutoIt

#include <Array.au3>


FileWrite(@ScriptDir & '\gefunden.txt', @CRLF & 'eins' & @CRLF & 'zwei' & @CRLF & 'drei')


$test = FileOpen(@ScriptDir & '\gefunden.txt')


$sSearch = InputBox("Suchstring ?","Geben Sie den zu suchenden Text ein:", "drei")


$FileData = FileRead($test) ; --> die Datei wird eingelesen


$sFound = StringLeft($FileData, StringInStr($FileData, $sSearch)) ; --> sucht in der Datei den Wert und gibt alles aus der Dtei bis zum 1 Wert des gefundenenen Suchbegriffs zurück


$sOut = StringReplace($sFound, @LF, "") ; --> nimm alle Zeilenumbrüche und ersetze sie mit ""


Msgbox(0,"",@extended + 1) ;--> was macht jetzt @extended????

Alles anzeigen

EIne Frage hab ich noch:

Kann ich auch festlegen, ab welcher Zeile gesucht werden soll?

VG

horphi

**chesstiger**

Also, Micha hat die mit Abstand effektivste Lösung gefunden.

Woher das @extended kommt, ist auch leicht zu beantworten. StringReplace ersetzt ja einen bestimmten Suchstring in einem Arbeitsstring durch einen Ersatzstring. Damit man danach noch nachvollziehen kann, wie viele Ersetzungen eigentlich durchgeführt worden sind, belegt StringReplace das @extended-Macro mit der Anzahl der Ersetzungen. Generell enthält dieses Makro immer gewisse Zusatzinformationen über den letzten Funktionsaufruf, die im Normalfall vernachlässigt werden können.
Micha wendet dann hier einen kleinen Trick an: Er ersetzt alle Zeilenumbrüche (@LF) durch einen Leerstring und verwirft dann schließlich das Ergebnis. Nun kann er aber über @extended nachschauen, wie viele @LFs überhaupt ersetzt worden sind. Und wenn man weiß, dass z.B. 4 @LFs ersetzt worden sind, so kann ich mir daraus zusammenreimen, dass insgesamt 5 Zeilen vorhanden gewesen sein müssen. 5, weil nach der letzten Zeile ja kein Zeilenumbruch mehr steht.

Das ist natürlich wesentlich effektiver und effizienter, als die Datei Zeile für Zeile durchzugehen.

horphi

Dank dir für die Erklärung Chesstiger.

Werde daran mal weiter basteln.

VG

horphi

Micha_he

Zitat von horphi

EIne Frage hab ich noch:

Kann ich auch festlegen, ab welcher Zeile gesucht werden soll?

Klar, mit etwas mehr Aufwand:

AutoIt

$sFile = FileOpenDialog("Datei ?", @ScriptDir, "Alle (*.*)")
$sSearch = InputBox("Suchstring ?","Geben Sie den zu suchenden Text ein:")
$iFromLine = InputBox("Ab Zeile ?","Geben Sie die Startzeile ein:", 1)
$FileData = FileRead($sFile)
$iStartPos = StringInStr($FileData, @LF, 0, $iFromLine - 1) + 1
$sFound = StringLeft($FileData, StringInStr($FileData, $sSearch, 0, 1, $iStartPos))
$sOut = StringReplace($sFound, @LF, "")
Msgbox(0,"Ausgabe", "Gefunden in Zeile: " & @extended + 1)

horphi

Zitat von Micha_he

Klar, mit etwas mehr Aufwand:

Micha du bist der Wahnsinn....vielen Dank.

VG

horphi

horphi

Tach zusammen,

Habe die Suche endlich mal ausgebaut.

Problem dabei: ich lasse mir jede Zeile vom Suchanfang bis zum SuchEnde einzeln ausgeben....das ist ein bisschen langsam.

Kennt jemand einen Weg, das zu beschleunigen?

Danke und Gruß,

horphi

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>


$sFile = FileOpenDialog("TXT öffnen",@ScriptDir & "\", "All (*.*)")
$sSearch = InputBox("Suchstring ?", "Geben Sie den zu suchenden Text ein:")




$FileData = FileRead($sFile)
$sStringset = StringInStr($FileData, $sSearch, 0)
$sFound = StringLeft($FileData, $sStringset)
$sOut = StringReplace($sFound, @LF, "")


$extendAnfang = @extended + 1
$extend = @extended + 1


MsgBox(0, "Ausgabe", "Start in Zeile: " & $extend)




Local $i = 0
While $i <= 2


	$extend = $extend + 1
	$sLineEnd = FileReadLine($sFile, $extend)
	$sLineEndLen = StringLen($sLineEnd) ;if Schleife sucht Zeile ohne Text


	If $sLineEndLen = 0 Then
		ProgressOn("Analyse", "Datei wird gelesen", "Working...")
		$i = $i + 1
		$extend = $extend + 1
		$extendDelta = $extend - $extendAnfang


		For $i = 0 To 100
			ProgressSet($i)
		Next
		ProgressSet(100, "Done!")
		Sleep(750)
		ProgressOff()
		MsgBox(0, '', "Zeile gefunden:" & $extend & " Differenz: " & $extendDelta)


		ExitLoop
	EndIf
WEnd

Alles anzeigen

**Oscar**

Das ist immer wieder der gleiche Fehler!
FileReadLine niemals mehrfach mit dem Dateinamen aufrufen. Das dauert ewig, weil intern die Datei geöffnet wird, es wird bis zu der Zeile "eingelesen" und dann wird erst die gesuchte Zeile zurückgegeben.
Wenn Du das mehrfach brauchst, dann immer mit dem Dateihandle arbeiten, also die Datei mit FileOpen öffnen und dann FileReadLine mit dem Dateihandle (Rückgabe von FileOpen) benutzen.
Am Ende nicht vergessen die Datei mit FileClose wieder zu schliessen, ansonsten liegt ein Lock auf der Datei.

Wenn Du sowieso jede Zeile durchgehst, brauchst Du dann auch $extend nicht, weil jedes folgende FileReadLine immer die jeweils nächste Zeile einliest.

horphi

Hallo Oscar,

ich rufe die Datei über FileOpenDialog auf und übergebe sie in FileRead.

Kann ich aus FileRead in FileReadLine übergeben und mit einer For/Next Schleife die Daten aus dem @extended Container (also die Zeilennummer) nutzen?

AutoIt

#include <Array.au3>
#include <Constants.au3>
#include <findinfile.au3>
#include <File.au3>
#include <Array.au3>
#include <MsgBoxConstants.au3>


_SearchLoop()


Func _SearchLoop()

$sFile = FileOpenDialog("TXT öffnen",@ScriptDir & "\", "All (*.txt*)")
$sSearch = InputBox("Suchstring ?", "Geben Sie den zu suchenden Text ein:")


;~ 	Global $sfile = @ScriptDir & "\00_test.txt",
	Global $search = GUICtrlRead($sSearch)
;~ 	GUICtrlSetData($Edit1, "")


	; find the line that has the search string


;~ 	$FileData = FileOpen($sFile)
	$FileData = FileRead($sFile)
	$sStringset = StringInStr($FileData, $search, 0)
	$sFound = StringLeft($FileData, $sStringset)
	$sOut = StringReplace($sFound, @LF, "")


	$extendAnfang = @extended + 1
	$extend = @extended + 1




	Local $i = 0
	While $i <= 9


		$extend = $extend + 1
		$sLineEnd = FileReadLine($sFile, $extend)
		$sLineEndLen = StringLen($sLineEnd)


		If $sLineEndLen = 0 Then ;if Schleife sucht Zeile ohne Text
			$i = $i + 1
			$extend = $extend + 1
			$extendDelta = $extend - $extendAnfang


			ExitLoop
		EndIf
	WEnd


	FileClose($sFile)


	While 1
		If @error = -1 Then ExitLoop


		$FileDataSearch = FileRead($sFile)
			For $i = $extendAnfang +1 To $extend -2
				ConsoleWrite($i & ':' & FileReadLine($FileDataSearch, $i) & @CRLF)
				GUICtrlSetData($Edit1, GUICtrlRead($Edit1) & FileReadLine($FileDataSearch, $i) & @CRLF);& $i & ':'
			Next
			ExitLoop


	WEnd
	WEnd
	FileClose($sFile)
EndFunc   ;==>SearchLoop

Alles anzeigen

VG

horphi

**BugFix**

Hier ein kurzes Bsp., wie man mit Dateihandle arbeitet:

AutoIt

; Datei öffnen per Handle
$hFileOpen = FileOpen($sFilePath, $FO_READ)


; Zeilenweise lesen bis Dateiende
While True
	$sLine = FileReadLine($hFileOpen)
	If @error Then ExitLoop
	ConsoleWrite($sLine & @CRLF)
WEnd


; Dateihandle schliessen
FileClose($hFileOpen)

Alles anzeigen

**AspirinJunkie**

Zitat von horphi

Kann ich aus FileRead in FileReadLine übergeben und mit einer For/Next Schleife die Daten aus dem @extended Container (also die Zeilennummer) nutzen?

Ich verstehe ehrlich gesagt nur Bahnhof.
Ich glaube das ist ein typischer Fall von XY-Problem.
Das bedeutet:

Ein User möchte X erreichen.
Er glaubt die Lösung des Problems wäre Y.
Da es dabei Probleme gibt stellt er eine Frage Y betreffend aber ohne X zu erwähnen.
Effektiver wäre für Ihn aber die Fragestellung: Ich möchte X erreichen dazu habe ich schon Y probiert aber noch immer nicht das gewünschte erreicht.

Ich weiß ehrlich gesagt noch nicht was du warum erreichen möchtest.
Sag uns mal den konkreten Anwendungsfall und dann finden wir sicherlich eine gute Lösung dafür.

Sonst können wir nur raten.
Hier daher mal mein Rateversuch: Alle Vorkommen eines Strings mit Angabe der Zeilennumer mit einem Zeilenoffset:

AutoIt

Global $s_FilePath = "Test.txt"
Global $s_Suchstring = "Test"
Global $h_File = FileOpen($s_FilePath)


Global $d_Counter = 1 ; Zähler für die aktuelle Zeilennummer


; Suche erst ab Zeile 25 starten
FileReadLine($h_File, 25)


; Datei zeilenweise von der aktuellen Position in der Datei aus durchsuchen
Do
	; nächste Zeile auslesen
	$s_Line = FileReadLine($h_File)
	If @error Then ExitLoop


; Zeile auf Suchstring hin untersuchen und Fund ausgeben:
	If StringInStr($s_Line, $s_Suchstring) Then MsgBox(0,"Gefunden", "Suchstring gefunden in Zeile " & $d_Counter)


	$d_Counter += 1 ; Zähler um 1 erhöhen
Until 0
FileClose($h_File)

Alles anzeigen

horphi

Hallo AspirinJunkie,

danke für deine Rückmeldung.

ENtschuldige, wenn ich mich nicht richtig ausgedrückt habe.

1.Ich möchte wie im 1. Post beschrieben TXT Files durchsuchen und mir die Zeilennummer (nicht den Inhalt) des Ergebnis wiedergeben lassen.
2. will ich dann von da weitersuchen bis zur nächsten Leerzeile. (also StringLen = 0)
3. Der gefundene Bereich von Ergebnis bis nächster Leerzeile soll in eine GUI geschrieben werden, damit ich es weiterverarbeiten kann.

Das habe ich hiermit auch hinbekommen, nur durchsucht die Schleife die Datei immer wieder von vorne, weil ich die Datei bei Jeder Schleife erneut einlesen....das ist bei 1000 Zeilen sehr viel...

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>


$sFile = FileOpenDialog("TXT öffnen",@ScriptDir & "\", "All (*.txt*)")




$FileData = FileOpen($sFile)
$FileDataLine = FileRead($FileData)
$sStringset = StringInStr($FileDataLine, "zwei", 0)
$sFound = StringLeft($FileDataLine, $sStringset)
$sOut = StringReplace($sFound, @LF, "")


$extendAnfang = @extended + 1
$extend = @extended + 1


MsgBox(0, "Ausgabe", "Start in Zeile: " & $sStringset)




Local $i = 0
While $i <= 2


	$extend = $extend + 1
	$sLineEnd = FileReadLine($FileData, $extend)
	$sLineEndLen = StringLen($sLineEnd)


	If $sLineEndLen = 0 Then ;if Schleife sucht Zeile ohne Text
		$i = $i + 1
		$extend = $extend + 1
		$extendDelta = $extend - $extendAnfang


		MsgBox(0, '', "Zeile gefunden:" & $extend & " Differenz: " & $extendDelta)


		ExitLoop
	EndIf
WEnd


FileClose($FileData)

Alles anzeigen

VG
horphi