Normalverteilung mit Random

**Mars**

Moin,
Es ist nur eine sehr kleine Funktion, aber ab und zu taucht die Frage wieder auf: Wie kann man mit der BuildIn Random-Funktion eine halbwegs anständige Normalverteilung zustandebringen ?

Der Trick ist, einfach mehrere (wir nehmen hier eine Gleichverteilung an) BuildIn-Randoms zu addieren und mit einem Korrekturfaktor (damit die Standardabweichung stimmt) zu versehen. In diesem Fall werden 6 float Zufallszahlen aus dem Bereich (-1, 1) verwendet, damit ist ein Maximalabstand zum Mittelwert von 6 Sigma möglich. (eine "echte" Normalverteilung hat selbstverständlich keine Beschränkung, allerdings kommen Ereignisse außerhalb von 6 Sigma nicht besonders häufig vor).

Als kleine Info: 1x Random -> Gleichverteilt, 2x Random -> "Dreieck", 3x Random -> Normalverteilung mit "Knicken", 6x Random -> Normalverteilung mit vielen, aber weniger ausgeprägten "Knicken".

AutoIt: Normvert.au3

#include <Array.au3>


Local $n = 100000, $aRnd[$n] ; 100.000 Testzahlen


For $i = 0 To $n - 1 Step 1
	$aRnd[$i] = RandomN(30, 20) ; Mittelwert 30, Standardabweichung 20
Next


Local $aStdAbw = StdABW($aRnd) ; Mittelwert und Standardabweichung berechnen


ConsoleWrite('Mid:    ' & $aStdAbw[0] & @CRLF & 'StdABW: ' & $aStdAbw[1] & @CRLF) ; Ausgabe


_ArrayDisplay($aRnd, 'Zufallszahlen', 25) ; Erste 25 Elemente anschauen


; #FUNCTION# ====================================================================================================================
; Author ........: Mars
; Description ...: Berechnet den Mittelwert und die Standardabweichung.
; ===============================================================================================================================
Func StdABW(ByRef $aArray)
	Local $n = UBound($aArray), $nMid = ArraySum($aArray)/$n, $nVar = 0
	For $i = 0 To $n - 1 Step 1
		$nVar += ($aArray[$i] - $nMid)^2
	Next
	Local $aRet = [$nMid, ($nVar / ($n - 1)) ^ 0.5]
	Return $aRet
EndFunc


; #FUNCTION# ====================================================================================================================
; Author ........: Mars
; Description ...: Ermittelt einen Zufallswert anhand eines gegebenen Mittelwertes und der Standardabweichung
; ...............: Obacht! Es handelt sich um KEINE richtige Normalverteilung, sondern nur um eine Näherung!
; ===============================================================================================================================
Func RandomN($nMid, $nSigma) ; Es können nur Ereignisse im 6 Sigma Bereich auftreten.
	Return $nMid + $nSigma * (Random(-1, 1) + Random(-1, 1) + Random(-1, 1) + Random(-1, 1) + Random(-1, 1) + Random(-1, 1)) / 1.414214
EndFunc


; #FUNCTION# ====================================================================================================================
; Author ........: Mars
; Description ...: Summiert alle Elemente eines Arrays
; ===============================================================================================================================
Func ArraySum($aArray)
	If Not IsArray($aArray) Then Return $aArray
	Local $iTmp = 0
	For $i = 0 To UBound($aArray) - 1 Step 1
		$iTmp += $aArray[$i]
	Next
	Return $iTmp
EndFunc

Alles anzeigen

Hier ist ein kleines Beispiel wie die Verteilung mit der Funktion aussehen könnte (so "glatt" ist sie nur, wenn man entsprechend viele Zufallszahlen generiert. Mittelwert = 50, Standardabweichung = 12.5)
Plot.png

Edit: In Post 3 gibt es noch eine Variante für die Erzeugung zweier Normalverteilter Zufallsvariablen, die eine echte Normalverteilung liefert.

lg
M

**autoBert**

Nice, aber Traue keiner ~~Statistik~~ Normalverteilung, wenn du sie nicht selbst gefakt hast.

**AspirinJunkie**

Zitat von Mars

ab und zu taucht die Frage wieder auf: Wie kann man mit der BuildIn Random-Funktion eine halbwegs anständige Normalverteilung zustandebringen ?

Ich biete dann meistens die Polarmethode an. Die ist auch mehr als halbwegs anständig:

AutoIt

; Parameter der Normalverteilung:
Global $f_Mittelwert = 4
Global $f_Standardabweichung = 2




For $i = 1 To 100
	$aRet = Random_Normal($f_Mittelwert, $f_Standardabweichung)
	ConsoleWrite($aRet[0] & @CRLF & $aRet[1]  & @CRLF)
Next




; #FUNCTION# ======================================================================================
; Name ..........: Random_Normal()
; Description ...: Gibt ein Array mit 2 normalverteilten Zufallsvariablen zurück
; Syntax ........: Random_Normal(Const $f_Mittelwert, Const $f_Standardabweichung)
; Parameters ....: Const $f_Mittelwert         - Mittelwert der Normalverteilung
;                  Const $f_Standardabweichung - Standardabweichung der Normalverteilung
; Return values .: Success: Array mit 2 normalverteilten Zufallsvariablen
;                  Failure: Ich mache keine Fehler!
; Author ........: AspirinJunkie
; =================================================================================================
Func Random_Normal(Const $f_Mittelwert, Const $f_Standardabweichung)
	Local $I, $f_H1, $f_H2, $f_QuadSum


	Do
		$f_H1 = (2* Random(0, 1) - 1)
		$f_H2 = (2* Random(0, 1) - 1)
		$f_QuadSum = ($f_H1*$f_H1 + $f_H2 * $f_H2)
	Until $f_QuadSum <= 1


	$f_I = Sqrt((-2*log($f_QuadSum )) / $f_QuadSum )


	Local $aZ[2] = [$f_Standardabweichung * $f_H1 * $f_I + $f_Mittelwert, $f_Standardabweichung * $f_H2 * $f_I + $f_Mittelwert]
	Return $aZ
EndFunc

Alles anzeigen

**Mars**

Jop. Mit der Polarmethode lassen sich "echt" Normalverteilte Zufallszahlen erzeugen. Meine Methode ist eine Variation der 12er Regel, die nur annähernd eine Normalverteilung liefert. Welche der Methoden man anwendet ist im Regelfall wahrscheinlich egal.

Damit können sich Leser des Threads direkt über 2 Lösungen freuen

lg
M