Warum blinken meinen Button ?

Lanealine

Hey,
ich habe ein paar radiobutton und möchte, wenn ein button geklickt ist, sollen andere versteckt werden.

AdlibRegister("lala", 500)
Func lala()
If GUICtrlRead($Radio5) = 1 Then

GUICtrlSetState($Radio14, $GUI_HIDE)
GUICtrlSetState($Radio15, $GUI_HIDE)
GUICtrlSetState($Radio16, $GUI_HIDE)
GUICtrlSetState($Radio17, $GUI_HIDE)
Else
GUICtrlSetState($Radio14, $GUI_SHOW)
GUICtrlSetState($Radio15, $GUI_SHOW)
GUICtrlSetState($Radio16, $GUI_SHOW)
GUICtrlSetState($Radio17, $GUI_SHOW)
EndIf
EndFunc ;==>lala

das funktioniert auch ganz gut, sobald ich $Radio5 klicke, werden die anderen button ausgeblendet.

jetzt zum problem:
wenn ich dann einen anderen button klicke, z.b. $Radio6, dann erscheinen die button $Radio14-17 wieder. allerdings "blinken" diese die ganze zeit.
wisst ihr woran das liegt, bzw. wie man das "aufblinken" umgehen kann ?

vielen dank

**Andy**

Hi,

Zitat von Lanealine

wenn ich dann einen anderen button klicke, z.b. $Radio6, dann erscheinen die button $Radio14-17 wieder. allerdings "blinken" diese die ganze zeit.
wisst ihr woran das liegt, bzw. wie man das "aufblinken" umgehen kann ?

Ich weiß, woran das blinken liegt, denn das hast du in deinem Script so programmiert!
Jede halbe Sekunde wird die lala()-Funktion aufgerufen, und dort steht im ELSE-Zweig eindeutig, dass die Buttons blinken sollen...

Um das zu ändern würde ich ggf. ein ELSEIF verwenden, ich weiß aber nicht wann du die Radiobuttons 14 bis 17 aktivieren willst...
//EDIT ich würde die Abfrage per select/case abwickeln, und dann auch eine Hilfsvariable fürs setzen bzw. rücksetzen verwenden, damit das "blinken" aufhört!

Lanealine

danke für die schnelle antwort,
bevor ich jetzt alle radiobutton einzeln eingeben muss welche abgefragt wird, frag ich lieber vorher.. was meinst du mit "hilfsvariable setzen" ? kannste mir da nen kurzes beispiel für geben ?

ich würd das jetzt so machen:
Case $lala
If GUICtrlRead($Radio5) = 1 Then
GUICtrlSetState($Radio14, $GUI_HIDE)
Endif

If GUICtrlRead($Radio5) = 1 Then
GUICtrlSetState($Radio15, $GUI_HIDE)
Endif

usw.

das muss ich allerdings sehr oft machen, gibts da eine möglichkeit das zuvereinfachen ?

**autoBert**

Erkläre doch einfach was du vor hast und stelle ein lauffähiges Skript ein, es über Adlibreister zu machen ist imho nicht nötig und einer der Gründe für deine Blinklichter.

Lanealine

AutoIt: test

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1_1 = GUICreate("Form1", 583, 716, 192, 124)
GUIStartGroup()
$Radio1 = GUICtrlCreateRadio("1", 24, 100, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio2 = GUICtrlCreateRadio("2", 24, 140, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio3 = GUICtrlCreateRadio("3", 24, 180, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio4 = GUICtrlCreateRadio("4", 24, 220, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio5 = GUICtrlCreateRadio("5", 24, 260, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio6 = GUICtrlCreateRadio("6", 24, 300, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio7 = GUICtrlCreateRadio("7", 24, 340, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
GUIStartGroup()
$Radio14 = GUICtrlCreateRadio("8", 72, 100, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio15 = GUICtrlCreateRadio("9", 72, 140, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio16 = GUICtrlCreateRadio("10", 72, 180, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio17 = GUICtrlCreateRadio("11", 72, 220, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio18 = GUICtrlCreateRadio("12", 72, 260, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio19 = GUICtrlCreateRadio("13", 72, 300, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio20 = GUICtrlCreateRadio("14", 72, 340, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio27 = GUICtrlCreateRadio("15", 120, 100, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio28 = GUICtrlCreateRadio("16", 120, 140, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio29 = GUICtrlCreateRadio("17", 120, 180, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio30 = GUICtrlCreateRadio("18", 120, 220, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio31 = GUICtrlCreateRadio("19", 120, 260, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio32 = GUICtrlCreateRadio("20", 120, 300, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
$Radio33 = GUICtrlCreateRadio("21", 120, 340, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
GUICtrlSetColor(-1, 0xFF0000)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Radio1


	EndSwitch
WEnd

Alles anzeigen

so soll das ganze aussehen.
wenn ich jetzt z.b. radio 3 klicke, dann soll er radio 10 und 17 ausblenden. wenn ich jetzt allerdings radio 5 anklicke, dann soll er radio 10 und 17 wieder einblenden und dafür dann 12 und 19 ausblenden.

**autoBert**

Also so, falls ich richtig schlussgefolgert habe:

C

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $idRadios[8][3]
$Form1_1 = GUICreate("Form1", 583, 716, 192, 124)
GUIStartGroup()
for $i= 0 to 6
	$idRadios[$i][0] = GUICtrlCreateRadio($i+1, 24, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next
GUIStartGroup()
for $i= 0 to 6
	$idRadios[$i][1] = GUICtrlCreateRadio($i+8, 72, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next
for $i= 0 to 6
	$idRadios[$i][2] = GUICtrlCreateRadio($i+15, 120, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next
GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $idRadios[0][0] to $idRadios[6][0]
			$iRadioGrp0 = $nMsg - $idRadios[0][0]
			GUICtrlSetState($idRadios[7][1],$GUI_SHOW)		;evtl. versteckes mittleres Radio zeigen
			GUICtrlSetState($idRadios[7][2],$GUI_SHOW)		;evtl. versteckes rechtes Radio zeigen
			If GUICtrlRead($idRadios[$iRadioGrp0][0]) Then
				$idRadios[7][1]=$idRadios[$iRadioGrp0][1]	;mittleres Radio merken
				$idRadios[7][2]=$idRadios[$iRadioGrp0][2]	;rechtes Radio merken
				GUICtrlSetState($idRadios[$iRadioGrp0][1],$GUI_HIDE)
				GUICtrlSetState($idRadios[$iRadioGrp0][2],$GUI_HIDE)
			EndIf
	EndSwitch
WEnd

Alles anzeigen

Lanealine

cool, genau das habe ich gesucht vielen dank für die hilfe.

finde cool, wie du die Radio´s erstellt hast.
geht das eigentlich auch wenn man zahlen und buchstaben in die radios schreiben möchte ? z.b. 1, 2, 3, a, b, c ?

ich habe gerade versucht einen multiarray zu erstellen, aber ich bekomme da einen fehler.
Global $aTest[6][2] = [[1, 2, 3, "a", "b", "c"], [1, 2, 3, "a", "b", "c"]]
: ==> Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
Global $aTest[6][2] = [[1, 2, 3, "a", "b", "c"], [1, 2, 3, "a", "b", "c"]]
Global $aTest[6][2] = [[1, 2, ^ ERROR
_ArrayDisplay($aTest)

kannst du sehen, warum ich einen fehler bei dem array bekomme ?

**Andy**

$aTest[2][6]
Da kommt man nach einigen Sekunden probieren selbst drauf...

Lanealine

@Andy, manchmal kann es so einfach sein danke

bevor die andere frage untergeht zu dem script von @autoBert:

Code

Global $idRadios[7][3]
_ArrayDisplay($idRadios)
$Form1_1 = GUICreate("Form1", 583, 716, 192, 124)
GUIStartGroup()
for $i= 0 to 6
	$idRadios[$i][0] = GUICtrlCreateRadio($i+1, 24, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next

ist es möglich, mehrere Radio´s mit dem "for..to.."-befehl zu erstellen, wenn buchstaben UND zahlen in dem "namen" von dem radio enthalten sind ?
z.b. die ersten drei heißen: 1,2,3,a,b,c

**autoBert**

Wenn eine abbildbare Logik dahintersteckt, ja.

**BugFix**

Zitat von Lanealine

ist es möglich, mehrere Radio´s mit dem "for..to.."-befehl zu erstellen, wenn buchstaben UND zahlen in dem "namen" von dem radio enthalten sind ?
z.b. die ersten drei heißen: 1,2,3,a,b,c

Wenn die Namen keiner Logik folgen, was eine automatische Generierung ausschließt:
Du kannst entweder das $idRadios[7][3] von 3 auf 4 Spalten erweitern und in der 4.ten Spalte die Namen vorab eintragen um sie dann beim Erstellen zu nutzen.
Bevorzugen würde ich jedoch ein separates Array für die Namen, läßt sich schneller erstellen:

AutoIt

Local $sNamen = 'Name1,Name2,Name3,Name4,Name5,Name6,Name7'
Local $aNamen = StringSplit($sNamen, ',', 2)

Jetzt kannst du in deiner Schleife das $aNamen mit dem selben Index benutzen und daraus die Namen verwenden.

**autoBert**

Hier mal mein erweitertes Skript, bei dem alle Buttons den Namen aus einem Array beziehen:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $idRadios[8][3]	;8 Zeilen (0..7) 3 Spalten (0..2)
;8. Zeile wird benutzt um derzeit versteckte ControlID's zwischenzuspeichern
Global $sRadioNames[7][3]
;8. Zeile wird hier nicht benutzt deshalb 1 Zeile weniger 
$sRadioNames[0][0]='Test0'
$sRadioNames[1][0]='aa0'
$sRadioNames[2][0]='vor0'
$sRadioNames[3][0]='nach0'
$sRadioNames[4][0]='all0'
$sRadioNames[5][0]='Null0'
$sRadioNames[6][0]='fertig?'
$sRadioNames[0][1]='Test1'
$sRadioNames[1][1]='aa1'
$sRadioNames[2][1]='vor1'
$sRadioNames[3][1]='nach1'
$sRadioNames[4][1]='normal'
$sRadioNames[5][1]='Null1'
$sRadioNames[6][1]='fast'
$sRadioNames[0][2]='Test2'
$sRadioNames[1][2]='aa2'
$sRadioNames[2][2]='vor2'
$sRadioNames[3][2]='nach2'
$sRadioNames[4][2]='komisch'
$sRadioNames[5][2]='Null2'
$sRadioNames[6][2]='fertig'


$Form1_1 = GUICreate("Form1", 583, 716, 192, 124)
GUIStartGroup()
for $i= 0 to 6
	$idRadios[$i][0] = GUICtrlCreateRadio($sRadioNames[$i][0], 24, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next
GUIStartGroup()
for $i= 0 to 6
	$idRadios[$i][1] = GUICtrlCreateRadio($sRadioNames[$i][1], 72, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next
for $i= 0 to 6
	$idRadios[$i][2] = GUICtrlCreateRadio($sRadioNames[$i][2], 120, 100+$i*40, 40, 40, BitOR($GUI_SS_DEFAULT_RADIO, $BS_PUSHLIKE))
Next
$idBtnOK=GUICtrlCreateButton('&OK',24,385,136,40)
GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $idRadios[0][0] to $idRadios[6][0]
			$iRadioGrp0 = $nMsg - $idRadios[0][0]
			ConsoleWrite($iRadioGrp0&' = ' &GUICtrlRead($idRadios[$iRadioGrp0][0],1)&@CRLF)
			GUICtrlSetState($idRadios[7][1],$GUI_SHOW)		;evtl. versteckes mittleres Radio zeigen
			GUICtrlSetState($idRadios[7][2],$GUI_SHOW)		;evtl. versteckes rechtes Radio zeigen
			If GUICtrlRead($idRadios[$iRadioGrp0][0]) Then
				$idRadios[7][1]=$idRadios[$iRadioGrp0][1]	;mittleres Radio merken
				$idRadios[7][2]=$idRadios[$iRadioGrp0][2]	;rechtes Radio merken
				GUICtrlSetState($idRadios[$iRadioGrp0][1],$GUI_UNCHECKED)	;verhindern von unsichtbar gecheckten Radios
				GUICtrlSetState($idRadios[$iRadioGrp0][2],$GUI_UNCHECKED)	;verhindern von unsichtbar gecheckten Radios
				;besser als Hide und Show wäre Disable und Enable ohne ist manuelles unckecken nötig
				GUICtrlSetState($idRadios[$iRadioGrp0][1],$GUI_HIDE)
				GUICtrlSetState($idRadios[$iRadioGrp0][2],$GUI_HIDE)
			EndIf
		Case $idRadios[0][1] to $idRadios[6][1]
			$iRadioGrp1 = $nMsg - $idRadios[0][1]
			ConsoleWrite($iRadioGrp1&' = ' &GUICtrlRead($idRadios[$iRadioGrp1][1],1)&@CRLF)
		Case $idRadios[0][2] to $idRadios[6][2]
			$iRadioGrp2 = $nMsg - $idRadios[0][2]
			ConsoleWrite($iRadioGrp2&' = ' &GUICtrlRead($idRadios[$iRadioGrp2][2],1)&@CRLF)
			;#cs
		Case $idBtnOK
			ConsoleWrite(@CRLF&'Checked Radios:'&@CRLF)
			For $i=0 to 6
				for $j=0 to 2
					If GUICtrlRead($idRadios[$i][$j])=$gui_Checked Then ConsoleWrite(GUICtrlRead($idRadios[$i][$j],1)&' = checked'&@CRLF)
				Next
			Next
			ConsoleWrite(@CRLF&'End Checked Radios End'&@CRLF)
			;#ce
		EndSwitch
WEnd

Alles anzeigen

Durch das Hinzufügen des OK-Buttons bin ich darauf gestoßen, daß versteckte Radios geCHECKed sein können, deshalb vor dem Verstecken ein manuelles unCHECKen eingefügt.

Lanealine

wow, respekt leute. genau das habe ich gesucht

allerbesten dank an euch !