Array aus Ini erstellen

ExoBiTe

Hallo.
Ich war gerade dabei einen Item-ersteller zu schreiben, und wollte diese Items nun in einem ini File speichern - was auch wunderbar funktioniert.
Die Ini ist so aufgebaut:

Code

[ID32]
ID=32
Type=32
Name=test
Price=32
[ID46]
ID=46
Type=4
Name=test2
Price=300

Nun möchte ich per Knopfdruck diese Datei in einen Array speichern, und diese somit auch auslesen können.
Ich hatte mir vorgestellt zu überprüfen wieviele sections die datei hat und dann mit einer for schleife alle daten auslesen lassen.
Das problem ist: Ich weiß nicht wie.
Perfekt wäre es wenn mehrere Arrays erstellt werden - also einer für ID, einer für Type einer für Name und einer für Price undzwar so angeordnet dass die ID von $arID[0] auf den Namen von $arName[0] passt.
Ich hoffe das ist verständlich und mir kann jemand helfen...

Mfg

**Kanashius**

Den IniWrite-Befehl hast du ja schon gefunden. Von dort ist es nicht mehr weit:
$arSections=IniReadSectionNames($file) gibt dir alle sections in einer datei.
Das Array kannst du dann durchlaufen und für jede section ein
$arSection=IniReadSection ($file,$arSections[$j]) aufrufen. Dort bekommst du ein 2D-Array mit den Key, value-paren.
Nun kannst du vor der Schleife einfach die Arrays erstellen
local $arIDs[UBound($arSections)],$arNames[UBound($arSections)],...
und in der Schleife, in der du die Sections durchgehst einfach entsprechend eintragen:
switch $arSection[$i][0]
case "ID":
$arIDs[$i]=$arSection[$i][1]
;...
Am Ende hast du deine Arrays mit den Werten

MfG Kanashius

ExoBiTe

Danke erstmal für die schnelle Antwort.

Ich habe aber trozdem noch zwei Fragen:
Ich habe jetzt folgendes geschrieben:

AutoIt

func _readIni()
	$arSections = IniReadSectionNames($itemList)
	Global $arIDs[UBound($arSections)], $arTypes[UBound($arSections)], $arNames[UBound($arSections)], $arPrices[UBound($arSections)]

Wie genau baue ich jetzt diesen zweiten Part ein, wo ich die arrays fülle..?
Ich glaube wenn du mir das als script schreiben würdest, könnte ich es villeicht besser verstehen.

Und das zweite:
Du hast geschrieben

Zitat

Das Array kannst du dann durchlaufen und für jede section ein
$arSection=IniReadSection ($file,$arSections[$j]) aufrufen.

Woher kommt das $j oder was ist $j?

Wäre cool wenn du mir da noch weiterhelfen könntest.

_mk_

AutoIt

Const $FILEPATH = 'test.ini'
Dim $Sections = IniReadSectionNames($FILEPATH)
Dim $IDs[$Sections[0] + 1]
Dim $Types[$Sections[0] + 1]
Dim $Names[$Sections[0] + 1]
Dim $Prices[$Sections[0] + 1]


$IDs[0] = 'IDs'
$Types[0] = 'Types'
$Names[0] = 'Names'
$Prices[0] = 'Prices'


ConsoleWrite('Ini-File: ' & $FILEPATH & @CRLF)
ConsoleWrite('Sectioncount: ' & $Sections[0] & @CRLF)


For $i = 1 To $Sections[0]
	ConsoleWrite('Section: ' & $Sections[$i] & @CRLF)
	Dim $Elements = IniReadSection($FILEPATH, $Sections[$i])


	; Die For-Schleife dient nur der Kontrolle. Die Schleife kann gelöscht werden.
	For $j = 1 To $Elements[0][0]
		ConsoleWrite('Key: ' & $Elements[$j][0] & '; Value: ' & $Elements[$j][1] & @CRLF)
	Next
	; ~~~~


	$IDs[$i] = $Elements[1][1]
	$Types[$i] = $Elements[2][1]
	$Names[$i] = $Elements[3][1]
	$Prices[$i] = $Elements[4][1]
Next




; Diese Zeilen dienen ebenfalls zur Kontrolle und können ebenfalls gelöscht werden.
_DumpArray($IDs)
_DumpArray($Types)
_DumpArray($Names)
_DumpArray($Prices)


Func _DumpArray($array)
	ConsoleWrite($array[0] & @CRLF)


	For $i = 1 To UBound($array) - 1
		ConsoleWrite($array[$i] & @CRLF)
	Next
EndFunc   ;==>_DumpArray

Alles anzeigen

**Mars**

Das sieht doch schon sehr gut aus. Damit es etwas Portabel einsetzbar ist sollte man das Gebilde noch in eine Funktion packen.

AutoIt

Local $aID = ['IDs'], $aType = ['Types'], $aName = ['Names'], $aPrice = ['Prices']


_IniToArray('Datei.ini', $aID, $aType, $aName, $aPrice)


_DumpArray($aID)
_DumpArray($aType)
_DumpArray($aName)
_DumpArray($aPrice)


Func _DumpArray($array)
	ConsoleWrite($array[0] & @CRLF)
	For $i = 1 To UBound($array) - 1
		ConsoleWrite($array[$i] & @CRLF)
	Next
EndFunc


Func _IniToArray($sPath, ByRef $aID, ByRef $aType, ByRef $aName, ByRef $aPrice)
	Local $aSections = IniReadSectionNames($sPath), $u = $aSections[0], $aKeys
	ReDim $aID[$u + 1], $aType[$u + 1], $aName[$u + 1], $aPrice[$u + 1]
	For $i = 1 To $u Step 1
		$aKeys = IniReadSection($sPath, $aSections[$i])
		$aID[$i] = $aKeys[1][1]
		$aType[$i] = $aKeys[2][1]
		$aName[$i] = $aKeys[3][1]
		$aPrice[$i] = $aKeys[4][1]
	Next
EndFunc

Alles anzeigen

lg
M