Hilfe bei Array !

NewProgger

Hallo zusammen,

könnte mir bitte jemand helfen ?
folgendes habe ich vor:

Ich habe an eine Funktion 21 Parameter übergeben die entweder "ok" oder "fehler" beinhalten.
jetzt möchte ich die, die "fehler" enthalten rausfiltern und in eine msgbox mit @CRLF ausgeben. Das Filtern habe ich schon per _Arrayfindall versucht, das hat auch geklappt aber eben nur über arraydisplay.

Ich bin mit Array's nicht so gut habe meist die komplexere variante genommen aber jetzt hört der Spaß langsam auf.
Der Weg ist mir halbwegs klar Array erstellen, sortieren, etc.. aber an der Ausführung hapert es.

Code

local $array[] = [$1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21]

Danke im voraus
Flo

**AspirinJunkie**

Zitat von NewProgger

Ich habe an eine Funktion 21 Parameter übergeben die entweder "ok" oder "fehler" beinhalten.

Gut bevor wir uns mit deiner konkreten Frage beschäftigen wäre es wohl sinnvoller erst einmal zu klären was du am Ende erreichen möchtest.
Was ist das Ziel des ganzen Vorhabens?

NewProgger

Das sind abfragen aus einem Formular (GUI) ob Checkboxen aktiviert sind. (Pflichtfelder) und die die nicht gewählt worden sind sollen später angezeigt werden.
Nach dem Motto Sie haben zu X, Y, Z keine Angaben gemacht...

Der Quellcode enthält teils brisante Daten, deshalb möchte ich den hier nicht Posten.

kurzfassung ist:

Code

Func _Status_din()
	For $i = 1 To UBound($din) - 1
		If $din[$i] <> @GUI_CtrlId Then GUICtrlSetState($din[$i], $GUI_UNCHECKED)


	Next


EndFunc


#######
GUI


#######


For $i = 1 To UBound($din) - 1
	GUICtrlSetOnEvent($din[$i], "_status_din")
Next


# Abfrage ob eine Din gesetzt ist
Func _check()


Select


	Case GUICtrlRead(44) = 1
		_check1("ok")
	Case GUICtrlRead(45) = 1
		_check1("ok")
	Case GUICtrlRead(46) = 1
		_check1("ok")
	Case GUICtrlRead(47) = 1
		_check1("ok")
	Case GUICtrlRead(48) = 1
		_check1("ok")
	Case GUICtrlRead(49) = 1
		_check1("ok")
	Case GUICtrlRead(50) = 1
		_check1("ok")
	Case GUICtrlRead(51) = 1
		_check1("ok")
	Case GUICtrlRead(53) = 1
		_check1("ok")
	Case Else
	     _check1("fehler")




EndSelect
EndFunc


# die Anzahl der zu übergebenden Parameter steigt mit jeder abfrage es geht bis _check21()

Alles anzeigen

**AspirinJunkie**

Sorry ich verstehe anhand des Beispieles nicht wirklich was passieren soll.
Schon gar nicht sehe ich die angesprochene Funktion mit 21 Parametern.

Wenn ich vom ersten Satz ausgehe und prüfen möchte welche Checkboxen gewählt wurden und welche nicht wäre folgendes ein Vorschlag um mal zu zeigen das man für sowas keine Funktion mit 21 Parameter benötigt:

AutoIt

#include <GUIConstantsEx.au3>


Opt("GUIOnEventMode", 1)


$h_GUI = GUICreate("Test", 150, 400)


$ctrl_Button_Start = GUICtrlCreateButton("Testen", 20, 5)
GUICtrlSetOnEvent(-1, check_Boxes)


; Checkboxen erstellen
For $i = 1 To 21
   GUICtrlCreateCheckbox("Checkbox " & $i, 20, 15+17*$i)
Next


GUISetOnEvent($GUI_EVENT_CLOSE, raus)
GUISetState(@SW_SHOW)


While Sleep(100)
WEnd


Func check_Boxes()
   ; Checkboxen abfragen (die Checkboxen sind direkt nach dem Button erstellt wurden - also wird ihre ID nahtlos weiter nummeriert)
   ; @GUI_CtrlId enthält die ID des Controls welches die Funktion ausgelöst hat - hier also der "Testen"-Button
   For $ID = @GUI_CtrlId + 1 To @GUI_CtrlId + 21
	  If GUICtrlRead($ID) <> 1 Then MsgBox(0,"", "Sie haben " & ControlGetText($h_GUI, "", $ID) & " nicht angeklickt!")
   Next
EndFunc




Func raus()
   Exit
EndFunc

Alles anzeigen

philipp

Also ich würde es so machen, erstmal die ganzen Checkboxen erstellen:

AutoIt

Local $aCheckbox[21], $aCbText[21] = ["1", "2", "3", "4", "5", "6", "7", "8", "9", "10", "11", "12", "13", "14", "15", "16", "17", "18", "19", "20", "21"]
For $i = 0 To 20
	$aCheckbox[$i] = GUICtrlCreateCheckbox($aCbText[$i], 10, 10+($i*25))
Next

Und dann zur Abfrage:

AutoIt

$sUnchecked = "Sie haben zu den Werten"
For $i = 0 To 20
	If GUICtrlRead($aCheckbox[$i]) = $GUI_UNCHECKED Then
		$sUnchecked &= " '" & GUICtrlRead($aCheckbox[$i], 1) & "',"
	EndIf
Next
If $sUnchecked <> "Sie haben zu den Werten" Then
	MsgBox(0, "Keine Angaben", StringTrimRight($sUnchecked, 1) & " keine Angaben gemacht!")
EndIf

ich kann den Code leider momentan nicht testen und es ist auch nur so heraus gecodet, kann also nichts versprechen.

NewProgger

Sorry das ich mich nicht so klar ausdrücken konnte,

viel einfacher:
Das Ganze läuft schon, die GUI nebst Checkboxen etc. ist bereits erstellt, alles was ich brauche ist der weg wie ich aus den 21 Variablen nach dem wort fehler suchen kann und diese entsprechend ausgeben kann.

in $1 steht das Ergebnis zu der folgenden Abfrage

Code

Case GUICtrlRead(44) = 1
     _check1("ok")
Case Else
     _check1("fehler")

ich will die 21 Variablen nur ausgewertet haben.

- Array auswerten
- msgbox ausgabe "es sind die folgenden Fehler aufgetreten

msgbox
- Fehler aus zum Beispiel $3
- Fehler aus zum Beispiel $8
- Fehler aus zum Beispiel $15

etc.

ich hoffe das bringt klarheit ?

Danke und Gruß

Flo

**autoBert**

Hat jetzt zwar nichts mit Checkboxen zu tun, aber bei einer Auftragsprogrammierung habe ich folgendes Schema verwendet:

AutoIt

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#comments-start
	verwendetes Schema für Variablen Namen:
	$a  = Arrays
	$h  = Handles z.B. hForm für GuiHandle
	$id	= für ControlID's gefolgt von 3 Buchstaben für den Controltyp
	Btn = Button
	Cbo = ComboBox
	Inp	= Input
	Lbl = Label
	$i			Integer
	$n			Number
	$s			String
#comments-end
#Region Hintergrundfarben für Eingabe
Const $iDichte = 7.850
Const $iNegativ = 0xFF0000
Const $iPositiv = 0x000000
Const $iFehler = 0xFFAA00
Const $iNormal = 0xFFFFFF
#EndRegion Hintergrundfarben für Eingabe
#Region GUI
Global $hForm = GUICreate("Infotool", 579, 456, 192, 124)
GUICtrlSetState(-1, $GUI_SHOW)
GUICtrlCreateGroup("Form&nestzahl", 32, 50, 250, 60)
Global $idInpFNZ_n = GUICtrlCreateInput("", 57, 72, 200, 21, $ES_Number)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("&Zykluszeit in Sek.", 32, 120, 250, 60)
Global $idInpZyklus_n = GUICtrlCreateInput("", 57, 142, 200, 21)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Tagesproduktion (24 Std.)", 32, 190, 250, 60)
Global $idLblProd24_n = GUICtrlCreateLabel("", 57, 212, 200, 21)
GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
;GUICtrlSetColor(-1, 0xFF0000)
GUICtrlCreateGroup("", -99, -99, 1, 1)
Global $idBtnCalcProd_n = GUICtrlCreateButton("Tagesproduktion &berrechnen", 32, 260, 250, 30, $BS_DEFPUSHBUTTON)
GUISetState(@SW_SHOW)
#EndRegion GUI
Global $iMsg
While 1
	$iMsg = GUIGetMsg()
	Switch $iMsg
		Case $GUI_EVENT_CLOSE
			Exit
			#comments-start
				Case $Tab1
				$iTab = GUICtrlRead($Tab1)
				Switch $iTab
				Case 0
				ControlFocus($hForm, '', $idInpFNZ_n)
				Case 1
				ControlFocus($hForm, '', $idInpFNZ_e)
				Case 2
				ControlFocus($hForm, '', $idCboMaschinen)
				Case 3
				ControlFocus($hForm, '', $idInpLaenge)
				EndSwitch
			#comments-end
		Case $idBtnCalcProd_n
			_ProdCalc()
	EndSwitch
WEnd
#Region Berechnungen
Func _ProdCalc()
	Local $iFNZ = Int(GUICtrlRead($idInpFNZ_n))
	;FormNestzahl ganzzahlig auslesen und zuweisen
	Local $nZyklus = _CommaToPeriod(GUICtrlRead($idInpZyklus_n))
	;Zykluszeit als Kommazahl (1 Nachkommastelle) auslesen und zuweisen
	Local $iError = 0
	;Fehlervariable initialisieren
	If $iFNZ <= 0 Then
		;Fehler
		$iError += 1
		;also Fehlervaraible um 1 erhöhen 2^(ntes Eingabecontrol-1) => 2^(1-1)
		GUICtrlSetBkColor($idInpFNZ_n, $iFehler)
	Else
		GUICtrlSetBkColor($idInpFNZ_n, $iNormal)
	EndIf
	If $nZyklus <= 0 Then
		$iError += 2
		;also Fehlervaraible um 2 erhöhen 2^(ntes Eingabecontrol-1) => 2^(2-1)
		GUICtrlSetBkColor($idInpZyklus_n, $iFehler)
	Else
		GUICtrlSetBkColor($idInpZyklus_n, $iNormal)
	EndIf
	Local $iProd24 = Int($iFNZ * 24 * 3600 / $nZyklus)
	;Tagesproduktion errechnen und auf ganze Zahl abrunden
	If Not $iError Then
		;Alle Eingabefelder sind ausgefüllt
		GUICtrlSetData($idLblProd24_n, $iProd24)
		;also Tagesproduktion anzeigen
	Else
		_MyErrorBox($iError, 'Formnestzahl|Zykluszeit', String($idInpFNZ_n & '|' & $idInpZyklus_n))
		;ansonsten auf fehlende Eingaben hinweisen
	EndIf
EndFunc   ;==>_ProdCalc
#EndRegion Berechnungen
#Region Hilfsfunktionen
Func _MyErrorBox($iErr, $sErr, $sCtrls = '')
	#comments-start
		Hiermit werden Eingaben überprüft
		Parameter:	$iErr Summe der Fehlerwerte
		1. Fehler (2^0)
		2. Fehler (2^1)
		...
		n. Fehler (2^(n-1))
		$sErr	String aller möglichen Meldungen mit "|" getrennt
		$sCtrls optionaler Parameter enthält alle möglichen Fehler auslösenden ControlIDs
		in einem String mit "|" als Trennzeichen
		gleiche Reihefolge wie bei $iErr einhalten
		Autor:		autoBert (autoit.de)
	#comments-end
	Local $iFocusCtrl, $bFirst = False
	Local $aCtrls = StringSplit($sCtrls, '|', 2)
	Local $aErr = StringSplit($sErr, '|', 2)
	Local $sMsg = 'Folgende(r) Wert(e): ' & @CRLF & @CRLF
	For $x = 0 To UBound($aErr) - 1
		If BitAND(2 ^ $x, $iErr) = 2 ^ $x Then
			$sMsg &= $aErr[$x] & @CRLF
			If Not $bFirst Then
				$bFirst = True
				$iFocusCtrl = Int($aCtrls[$x])
			EndIf
		EndIf
		;ConsoleWrite($x&': '&$bFirst&@TAB&$iFocusCtrl&@CRLF)
	Next
	$sMsg &= @CRLF & 'überprüfen!'
	MsgBox(16, "Eingabe", $sMsg, 0, $hForm)
	If $bFirst Then ControlFocus($hForm, '', $iFocusCtrl)
EndFunc   ;==>_MyErrorBox
Func _MyFormatedSetData($iCtrlID, $iWert)
	GUICtrlSetData($iCtrlID, $iWert)
	If $iWert < 0 Or Not (IsNumber($iWert)) Then
		GUICtrlSetColor($iCtrlID, $iNegativ)
	Else
		GUICtrlSetColor($iCtrlID, $iPositiv)
	EndIf
EndFunc   ;==>_MyFormatedSetData
Func _CommaToPeriod($Var, $iDecPlaces = 1)
	$Var = StringReplace($Var, ',', '.')
	Return Round(Number($Var), $iDecPlaces)
EndFunc   ;==>_CommaToPeriod
#EndRegion Hilfsfunktionen

Alles anzeigen

ist nur ein kleiner Ausschnitt, da auf weitere Tabs u.U. schützenswertes Interesse des Kunden.

philipp

Ich hoffe mal ich hab es jetzt kappiert. Ich würd es einfach so machen

AutoIt

$sUnchecked = "Es sind folgende Fehler aufgetreten:"
For $i = 1 To 21
	If Eval($i) = "fehler" Then
		$sUnchecked &= @CRLF & "Fehler in $" & $i & ","
	EndIf
Next
If $sUnchecked <> "Es sind folgende Fehler aufgetreten:" Then
	MsgBox(0, "Fehler aufgetreten", StringTrimRight($sUnchecked, 1) & ".")
EndIf

NewProgger

Zitat von Phil-IT

kappiert. Ich würd es einfach so machen

Zitat von Phil-IT

Ich hoffe mal ich hab es jetzt kappiert. Ich würd es einfach so machen

AutoIt

$sUnchecked = "Es sind folgende Fehler aufgetreten:"
For $i = 1 To 21
	If Eval($i) = "fehler" Then
		$sUnchecked &= @CRLF & "Fehler in $" & $i & ","
	EndIf
Next
If $sUnchecked <> "Es sind folgende Fehler aufgetreten:" Then
	MsgBox(0, "Fehler aufgetreten", StringTrimRight($sUnchecked, 1) & ".")
EndIf

also das funktioniert schon mal

Fragen: (Verständnis Probleme)
warum wird hier nicht der Inhalt von $i ausgegeben sondern die Nummer der Variable ?

Code

$sUnchecked &= @CRLF & "Fehler in $" & $i & ","

angenommen $1 würde so aussehen $1 = "Fehler, es wurde bei Feld 5 kein Wert gesetzt"

wie kann ich in dem Array trotzdem nach dem Wort Fehler sortieren und den Teil nach dem "," ausgeben ?

geht das iwie mit StringLeft ?

Code

If StringLeft($i,6) = "fehler" Then # so scheinbar nicht

NewProgger

Code

# Prüfen ob alle checkboxen ausgefüllt wurden


func _check21($1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21)


local $array[] = [$1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21], $a
Local $result1
Local $result[21]


For $i = UBound($array, 1) -1 to 0 Step -1
	$result[$i] = StringLeft($array[$i], 2)
	if $result[$i] <> "fe" Then _ArrayDelete($result,$i)


#ConsoleWrite($result[$i])
Next
For $x = 0 To UBound($result, 1) -1
	$result1 &= @CRLF & $result[$x]
	#ConsoleWrite($result[$x])
Next
MsgBox(0, "", $result1)

Alles anzeigen

Damit bekomme ich zumindest schon mal die angezeigt das Felder nicht ausgefüllt wurden, aber die Ausgabe ist logischweise "fe" da Stringleft...
wie bekomme ich das denn nun hin das der ganze Text aus der Variable angezeigt wird ? auch an der richtigen pos. im array ? (nicht das Apfel fehlt und Banane angezeigt wird )

NewProgger

Habe es selber hin bekommen so funktioniert es wie ich will.

Danke für die Tipps, ohne die hätte es noch länger gedauert.

Code

# Prüfen ob alle checkboxen ausgefüllt wurden


func _check21($1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21)


local $array[] = [$1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21], $a
Local $result1
Local $result[21]


For $i = UBound($array, 1) -1 to 0 Step -1
	if  StringLeft($array[$i], 2) <> "Fe" Then
		_ArrayDelete($result,$i)
	Else
		$result[$i] = $array[$i]
	EndIf


#ConsoleWrite($result[$i])
Next


if 


For $x = 0 To UBound($result, 1) -1
	$result1 &= @CRLF & $result[$x]


Next
ConsoleWrite($result1)
MsgBox(0, "", $result1)

Alles anzeigen

NewProgger

Code

# Prüfen ob alle checkboxen ausgefüllt wurden


Func _check21($1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21)


local $array[] = [$1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21]
Local $result1
Local $result[21]


For $i = UBound($array, 1) -1 to 0 Step -1
	if  StringLeft($array[$i], 2) <> "Fe" Then
		_ArrayDelete($result,$i)
	Else
		$result[$i] = $array[$i]
	EndIf




Next




For $x = 0 To UBound($result, 1) -1
	$result1 &= @CRLF & $result[$x]


Next
if $result1 = "" Then
	ConsoleWrite($result1)
	MsgBox(0, "", " Es fehlt was")
Else
	MsgBox(0, "", "alles ausgefüllt ")
EndIf

Alles anzeigen

leider doch noch nicht fertig

Auch wenn keine Fehler mehr da sind geht er unten nicht in den else zweig...
ich habe es schon mit isArray versucht und mit in einer schleife prüfen ob leere Felder da sind und dann mit arraydelet löschen lassen, hat alles nichts gebracht.

kann mir das jemand erklären ?

**Andy**

Ich habe keine Ahnung, wie du bei dieser Problematik auf die Verwendung eines Arrays kommst, wenn du doch letztendlich einen String haben willst....
Du erstellst ein Array, beschreibst die Array-Items mit Strings, durchsuchst die Array-Items nach Strings, löschst diese Array-Items und schreibst letztendlich alle übriggebliebenen Arrayitems in einen String. Viel komplizierter geht es garnicht....von einer Funktion mit 21 Parametern ganz zu schweigen...

AutoIt

#include <Array.au3>
;~ # Prüfen ob alle checkboxen ausgefüllt wurden




Local $1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21


$vorher = ""
;Variablen füllen und als string ausgeben
For $i = 1 To 21
    Assign($i, Random(0, 1, 1) = 1 ? "OK" : "Fehler")
    $vorher &= $i & "  " & Eval($i) & @CRLF
Next
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $vorher = ' & $vorher & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
MsgBox(262144, 'Debug line ~' & @ScriptLineNumber, 'Selection:' & @CRLF & '$vorher' & @CRLF & @CRLF & 'Return:' & @CRLF & $vorher) ;### Debug MSGBOX




;die "komplizierte Lösung"
$nachher1 = _check21($1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21)
MsgBox(262144, 'Debug line ~' & @ScriptLineNumber, 'Selection:' & @CRLF & '$nachher1' & @CRLF & @CRLF & 'Return:' & @CRLF & $nachher1) ;### Debug MSGBOX


;so geht das als Einzeiler, ohne Funktion
$nachher2=stringregexpreplace($vorher,"(?m)(^\d+  OK\s+)","")
MsgBox(262144, 'Debug line ~' & @ScriptLineNumber, 'Selection:' & @CRLF & '$nachher2' & @CRLF & @CRLF & 'Return:' & @CRLF & $nachher2) ;### Debug MSGBOX








Func _check21($1, $2, $3, $4, $5, $6, $7, $8, $9, $10, $11, $12, $13, $14, $15, $16, $17, $18, $19, $20, $21)


    $nachher = ""
    For $i = 1 To 21
        If StringInStr(Eval($i), "Fehler") Then $nachher &= $i & "  Fehler" & @CRLF
    Next
    Return $nachher
EndFunc                                                                                                       ;==>_check21

Alles anzeigen

NewProgger

was wäre denn die bessere Lösung?

die Var 1-21 stammen aus abfragen ob Checkboxen gechecked sind oder nicht.
das heisst eine Var enthält entweder "ok" oder "Fehler: zum Thema xy wurden keine Angaben gemacht"

wenn nun PflichtCheckboxen nicht ausgefüllt worden sind sollen diese aufgelistet werden welche es sind und dann Return zur GUI
wenn alle auf OK stehen soll eine weiter Funktion ausgeführt werden. ( die beinhaltet den Datenimport in Excel etc.)

es ist halt eine Fehlerabfrage.

**BugFix**

Zitat von NewProgger

die Var 1-21 stammen aus abfragen ob Checkboxen gechecked sind oder nicht.

Für dieses Ergebnis reicht ein einziger Parameter. Du kannst den Checkboxen Werte zuordnen (2-er Potenzen), dadurch ist jeder Wert eineindeutig in einer Gesamtsumme identifizierbar. Hier mal ein Bsp. aus meinen Musterskripten, kannst es dann anpassen:

AutoIt

; Muster Checkbox-Bearbeitung
; Ziel: einfache Abfrage, welche CB aktiviert sind


#include <GUIConstants.au3>
Opt('GUIOnEventMode', 1)
Opt("MustDeclareVars", 1)
Global $bCheckAll, $bUnCheckAll, $GUI, $i, $str
Global $arCB[20][2]             ; Array für Handle und Dual-Wert der CB
For $i = 0 To UBound($arCB) -1
	$arCB[$i][1] = 2^$i         ; Zuweisung eindeutiger Wert
Next
Global $Checked = 0             ; Variable nimmt Status ALLER Checkboxen in einem Wert auf,
                                ; Startstatus für alle: UNCHECKED
Global $w = 500, $h = 20*30+40, $l = (@DesktopWidth-$w)/2, $t = (@DesktopHeight-$h)/2
Global $top = -10
$GUI = GUICreate('Test Checkbox', $w, $h, $l, $t)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Ende')
For $i = 0 To UBound($arCB) -1
	$top += 30
	$arCB[$i][0] = GUICtrlCreateCheckbox('CheckBox_' & $i+1, 40, $top, 120)
	GUICtrlSetOnEvent(-1, '_ClickCB')
Next
$bCheckAll = GUICtrlCreateButton('Alle markieren', 250, 20, 150, 21)
GUICtrlSetOnEvent(-1, '_CheckAll')
$bUnCheckAll = GUICtrlCreateButton('Markierung aufheben', 250, 50, 150, 21)
GUICtrlSetOnEvent(-1, '_UnCheckAll')
GUISetState()


While 1
	Sleep(100)
WEnd


Func _Ende()
	Exit
EndFunc


Func _ClickCB()
	For $i = 0 To UBound($arCB) -1
		If $arCB[$i][0] = @GUI_CtrlId Then
			$Checked = BitXOR($Checked, $arCB[$i][1])
			_ReadCB()
			ExitLoop
		EndIf
	Next
EndFunc


Func _CheckAll()
	For $i = 0 To UBound($arCB) -1
		If Not BitAND($Checked, $arCB[$i][1]) Then
;~ 			GUICtrlSetState($arCB[$i][0], $GUI_CHECKED)
			GUICtrlSetState($arCB[$i][0], BitOR($GUI_CHECKED, $GUI_DISABLE)) ; markieren und disablen
			$Checked = BitXOR($Checked, $arCB[$i][1])
		EndIf
	Next
	_ReadCB()
EndFunc


Func _UnCheckAll()
	For $i = 0 To UBound($arCB) -1
		If BitAND($Checked, $arCB[$i][1]) Then
;~ 			GUICtrlSetState($arCB[$i][0], $GUI_UNCHECKED)
			GUICtrlSetState($arCB[$i][0], BitOR($GUI_UNCHECKED, $GUI_ENABLE)) ; Markierung aufheben und enablen
			$Checked = BitXOR($Checked, $arCB[$i][1])
		EndIf
	Next
	_ReadCB()
EndFunc


Func _ReadCB() ; Fkt. dient nur zur Ausgabe, welche CB markiert sind
	Local $str = 'Markiert:  '
	For $i = 0 To UBound($arCB) -1
		If BitAND($Checked, $arCB[$i][1]) Then $str &= $i+1 & ', '
	Next
	WinSetTitle($GUI, '', StringTrimRight($str, 2))
EndFunc

Alles anzeigen

**autoBert**

Zitat von NewProgger

wenn nun PflichtCheckboxen nicht ausgefüllt worden sind sollen diese aufgelistet werden welche es sind und dann Return zur GUI

könnte alles so einfach sein, hierfür nimmt man Radio's und belegt einen der Werte vor. Dies habe ich so ähnlich schon ein paar Mal in deinem anderen Thema bemerkt:

Zitat von autoBert

Scheiß auf das Layout, die Funktionalität zählt und mit deinem (für dich) Superlayout kommen nur dumme Fragen, denn

Checkbox=Mehfachauswahl möglich, Radio=nur eine Antwort möglich. Man sollte Windowscontrols so verwenden wie sie vorgesehen sind, alles andere verunsichert nur den Anwender.

und wie man sieht, nicht nur den Anwernder. Der Programmierer ist sicher auch nicht sicher hat er oder hat er nicht?:

Zitat von NewProgger

Habe es selber hin bekommen

Zitat von NewProgger

leider doch noch nicht fertig

BugFix : bezweifle, daß er das liest ich habe ihm in meinem vorhergehenden Post etwas ähnliches demostriert, allerdings nicht mit Checkboxen.

NewProgger

autoBert, Dich mögen bestimmt ganz viele Menschen oder ? kleiner Stinkstiefel ! wie ich bereits schrieb möchte ich keine Radiobutton. Wenn es Dir nicht passt was ich möchte ja dann lies doch meinen Post nicht geschweige denn schreib hier rein!

Oder hast DU meine Posts nicht gelesen ?

**autoBert**

Zitat von NewProgger

Oder hast DU meine Posts nicht gelesen ?

ich deine schon, du aber hast mind. 1 überlesen: https://autoit.de/index.php/Thre…5503#post675503 geschweige denn getestet was ich als Demo eingestellt habe. Von daher halte ich

Zitat von autoBert

BugFix : bezweifle, daß er das liest ich habe ihm in meinem vorhergehenden Post etwas ähnliches demostriert, allerdings nicht mit Checkboxen.

diese Bemerkung für gerechtfertigt, im Gegensatz zu:

Zitat von NewProgger

autoBert, Dich mögen bestimmt ganz viele Menschen oder ? kleiner Stinkstiefel !

damit macht man sich hier sicher Freunde.