Funktion "_RecursiveFileListToArray" auf mehere Laufwerke ausweiten - aber wie? (ANFÄNGER)

kilo

Liebe AutoIt-Profis,
ich möchte mit der tollen Suchfunktion "_RecursiveFileListToArray" (von Oscar) alle Dateien mit einer bestimmten Dateiendung auf meheren Laufwerken suchen. Mir fehlt aber schlichtweg das nötige Tiefenverständnis, um die Suchfunktion richtig mit z.B. "DriveGetDrive("Fixed")" zu kombinieren.

Mir ist wichtig, dass

die Suchfunktion mit Platzhalter * erhalten bleibt, damit auch wirklich alle Dateien mit der von mir gesuchten Dateiendung gefunden werden
als Ergebnis ein Array ausgegeben wird (mit [0] = Anzahl)

Vielen Dank im Vorraus für Eure Mühen und Eure Rücksichtnahme für jene, die leider noch keine Profis sind!
Michael

**alpines**

Ich versteh dein Problem nicht so ganz, DriveGetDrive("Fixed") gibt dir doch die Laufwerksbezeichnungen zurück und das Array kannst du doch einfach mit ner For-Schleife iterieren und _RecursiveFileListToArray darauf anwenden.

kilo

Zitat von alpines

Ich versteh dein Problem nicht so ganz, DriveGetDrive("Fixed") gibt dir doch die Laufwerksbezeichnungen zurück und das Array kannst du doch einfach mit ner For-Schleife iterieren und _RecursiveFileListToArray darauf anwenden.

Ich weiß leider nicht, wo/wie ich die For-Schleife in diese Funktion integrieren soll. Alle meine Versuche haben entweder einen Stack-Overflow oder einen 8-stelligen Fehlercode ausgelöst. Deshalb schreibe ich immer "Anfänger" dazu.

PS: Derzeit frage ich mit einer einer For-Next-Schleife die Laufwerke nacheinander ab und bekomme so bis zu 5 Arrays, die ich dann zusammenführe, aber wirklich sauber, oder gar elegant ist das nicht ...
Ich bin guter Hoffnung, dass das auch so zu lösen ist, dass nur wirklich nur ein Array herauskommt. Ein Beispiel wäre toll.

**autoBert**

Zitat von kilo

PS: Derzeit frage ich mit einer einer For-Next-Schleife die Laufwerke nacheinander ab und bekomme so bis zu 5 Arrays, die ich dann zusammenführe, aber wirklich sauber, oder gar elegant ist das nicht ...

Genau so würde ich es auch lösen.

**Oscar**

Naja, es geht schon einfacher, weil meine Funktion auch die Rückgabe als String zulässt und man so erstmal alles in einen String einlesen und am Schluß dann das Array erstellen lassen kann.
Hier mal als Beispiel:

AutoIt

#include <Array.au3>
Global $sFiles = '', $aFiles
Global $iTimer = TimerInit()
Global $aDrives = DriveGetDrive('FIXED')
If Not @error Then
	For $i = 1 To $aDrives[0]
		ToolTip('Lese Laufwerk: "' & $aDrives[$i] & '" - Bitte warten...')
		$sFiles &= _RecursiveFileListToArray($aDrives[$i], '.*', 1, 0)
	Next
	$aFiles = StringSplit(StringTrimRight($sFiles, 2), @CRLF, 1)
EndIf
ConsoleWrite('Zeit (ms): ' & TimerDiff($iTimer) & @CR)
ToolTip('')
_ArrayDisplay($aFiles)




;===============================================================================
; Function Name:   _RecursiveFileListToArray($sPath[, $sPattern][, $iFlag][, $iFormat][, $fRecursion][, $sDelim])
; Description::    gibt Verzeichnisse (rekursiv) und/oder Dateien zurück, die einem RegExp-Pattern entsprechen
; Parameter(s):    $sPath = Startverzeichnis
;                  $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
;                  $iFlag = Auswahl
;                           0 = Dateien & Verzeichnisse
;                           1 = nur Dateien
;                           2 = nur Verzeichnisse
;                  $iFormat = Rückgabeformat
;                             0 = String
;                             1 = Array mit [0] = Anzahl
;                             2 = Nullbasiertes Array
;                  $fRecursion = Verzeichnisse rekursiv durchsuchen
;                                False = Nein
;                                True = Ja
;                  $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s):  AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s):       Oscar (www.autoit.de)
;                  Anregungen von: bernd670 (www.autoit.de)
;                             und: AspirinJunkie (www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArray($sPath, $sPattern = '.*', $iFlag = 0, $iFormat = 1, $fRecursion = True, $sDelim = @CRLF, $fOpenDLL = True)
	Local $hSearch, $sFile, $sReturn = '', $aD
	Local Static $hDll
	If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
	$hSearch = FileFindFirstFile($sPath & '*')
	If Not @error And $hSearch <> -1 Then
		If $fOpenDLL Then $hDll = DllOpen('kernel32.dll')
		While True
			$sFile = FileFindNextFile($hSearch)
			If @error Then ExitLoop
			If @extended Then
				$aD = DllCall($hDll, 'dword', 'GetFileAttributesW', 'wstr', $sPath & $sFile)
				If @error Or BitAND($aD[0], 0x400) Then ContinueLoop
				If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
				If $fRecursion Then $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0, True, $sDelim, False)
				ContinueLoop
			EndIf
			If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
		WEnd
		FileClose($hSearch)
		If $fOpenDLL Then DllClose($hDll)
	EndIf
	If $iFormat = 2 Then $iFormat = 3
	If $iFormat And $sReturn = '' Then Return StringSplit($sReturn, '', $iFormat)
	If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
	Return $sReturn
EndFunc

Alles anzeigen

Wichtiger Hinweis: _ArrayDisplay zeigt nur die ersten 65525 Einträge an. Es sind aber alle Dateien im Array enthalten!

kilo

2 Mal ganz dickes Dankeschön!

@ Oscar: Das sich der Entwickler der Funktion meiner Frage persönlich annimmt und (wie selbstverständlich) auch noch eine Lösung parat hat, ist schon wirklich ganz große Klasse! - Herzlichen Dank!

@ autoBert: Da bin ich ja fast ein bißchen stolz auf mich, dass auch ein Profi wie Sie so an die Sache herangegangen wäre. Insofern Danke für Ihre Bestätigung meiner bsiherigen Versuche.

MfG
Michael

**AspirinJunkie**

Hatte mal ne entsprechende Funktion geschrieben, welche direkt mehrere Pfadangaben schluckt.
Könnte dann z.B. so aussehen:

AutoIt

#include <Array.au3>


$s_Dirs = ""
For $x = 67 To 90
	$s_Dirs &= Chr($x) & ":|"
Next


$a_Test = _listFilesFlexibleRec(StringTrimRight($s_Dirs, 1))
_ArrayDisplay($a_Test)






; #FUNCTION# ====================================================================================================================
; Name...........: _listFilesFlexibleRec
; Description ...: Gibt ein Array mit Dateien bzw. Unterordnern im gesamten Verzeichnisbaum zurück
; Syntax.........: _listFilesFlexibleRec($sSD, [$sPat = '*', [$iF = 0, [$flgSS = 2]])
; Parameters ....: $sSD   - Startverzeichnis (mehrere Verzeichnisse durch | trennen)
;                  $sPat  - Optional: Pattern zur Filterung mit regulären Ausdrücken oder Verweis auf Funktion für komplexeres Matching
;                  $iF    - Optional: Flag ob nur Dateien, Ordner oder beides gesucht werden sollen
;                  		|$iF=3(Default) Gibt beides zurück
;                  		|$iF=1 Gibt nur Dateien zurück
;                  		|$iF=2 Gibt nur Ordner zurück
;                  $flgSS - Art der Rückgabe (Siehe StringSplit()-Funktion)
;                  $bS    - interner Rekursionsparameter - nicht verändern!
; Return values .: @Error: 1 = Startverzeichnis existiert nicht.
;                  		|2 = ungültiger Wert für $iF
; Author ........: AspirinJunkie
; Modified.......: 05.07.2016
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; Note ..........: basiert auf einem rekursiven Ansatz
; ===============================================================================================================================
Func _listFilesFlexibleRec($sSD, Const $sPat = '', Const $iF = 3, Const $flgSS = 2, Const $bS = True)
	; By AspirinJunkie
	Local $FFFF, $FFNF, $aD
	Local Static $sRet, $hDLL, $p_F
	If $bS Then
		$hDLL = DllOpen("kernel32.dll")
		$p_F = DllCall($hDLL, "ptr", "GetProcAddress", "handle", DllCall($hDLL, "handle", "GetModuleHandleW", "wstr", "kernel32.dll")[0], "str", "GetFileAttributesW")[0] ; get the function address of GetModuleHandleW
		If Not ($iF = 3 Or $iF = 1 Or $iF = 2) Then Return SetError(1, DllClose($hDLL), "")
	EndIf
	For $i In StringSplit($sSD, "|", 2)
		If Not (StringRight($i, 1) == '\') Then $i &= "\"
		If Not FileExists($i) Then ContinueLoop
		$FFFF = FileFindFirstFile($i & '*')
		If $FFFF <> -1 Then
			If $sPat = "" Then
				Do
					$FFNF = FileFindNextFile($FFFF)
					If @error Then ExitLoop
					If @extended Then
						If BitAND($iF, 2) Then $sRet &= $i & $FFNF & "|"
						If Not BitAND(DllCallAddress('dword', $p_F, 'wstr', $i & $FFNF)[0], 0x400) Then _listFilesFlexibleRec($i & $FFNF, $sPat, $iF, $flgSS, False)
					ElseIf BitAND($iF, 1) Then
						$sRet &= $i & $FFNF & '|'
					EndIf
				Until 0
			Else
				Do
					$FFNF = FileFindNextFile($FFFF)
					If @error Then ExitLoop
					If @extended Then
						If BitAND($iF, 2) Then
							If IsFunc($sPat) Then
								If $sPat($i & $FFNF) Then $sRet &= $i & $FFNF & "|"
							ElseIf StringRegExp($FFNF, $sPat) Then
								$sRet &= $i & $FFNF & "|"
							EndIf
						EndIf
						If BitAND(DllCallAddress('dword', $p_F, 'wstr', $i & $FFNF)[0], 0x400) Then ContinueLoop
						_listFilesFlexibleRec($i & $FFNF, $sPat, $iF, $flgSS, False)
					ElseIf BitAND($iF, 1) Then
						If IsFunc($sPat) Then
							If $sPat($i & $FFNF) Then $sRet &= $i & $FFNF & '|'
						ElseIf StringRegExp($FFNF, $sPat) Then
							$sRet &= $i & $FFNF & '|'
						EndIf
					EndIf
				Until 0
			EndIf
			FileClose($FFFF)
		EndIf
	Next
	If $bS Then
		DllClose($hDLL)
		Local $aRet = StringSplit(StringTrimRight($sRet, 1), "|", $flgSS)
		$sRet = ""
		Return $aRet
	EndIf
EndFunc   ;==>_listFilesFlexibleRec

Alles anzeigen