Daten von einer Webseite auslesen

Muecke

hallo miteinander,

ich möchte auf in einem Webshop Preise und Artikelbezeichnung auslesen.
Da ich jedoch recht viele Artikel habe bei denen ich dies immer wider machen möchte ist der Zeitaufwand schon recht hoch.
Daher war meine Überlegung anstelle alles vom Monitor abzuschreiben die Daten in eine CSV Datei schreiben lassen.

so würde ich gerne vorgehen.

1. ich melde mich im Webshop an
2. ich suche den Artikel den ich meine
3. ich rufe den Artikel auf
4. ich Starte ein kleines Tool das die offene Webseite an bestimmten Stellen ausliest
das Tool schreibt die Daten in eine CSV Datei
5. dann springe ich wider zu Punkt 2

Ich möchte das nicht von einem Bot machen lassen sondern ich möchte die Artikel suchen und auswählen, das abschreiben vom Monitor sollte jedoch automatisiert sein.

Im Netz habe ich für solche aufgaben das Add-ons für Firefox "iMacros" gefunden, leider ist hier immer alles auf Englisch und das Forum für iMacros lässt nur Englisch zu
leier kann ich kein Englisch, so bin ich dann auf dieses Forum gestoßen jetzt bin ich mir nur nicht sicher ob das hier auch ein Tool in der Richtung zum iMacro ist oder ob Ihr ein extra Unterforum für iMacros habt, bzw. wo ich denn mit meinen Fragen hin kann, bisher habe ich noch kein richtig laufendes iMacro hin bekommen stehe also noch ganz am Anfang. und bin für fast alles offen

Wenn Ihr mir weiter helfen könnt würde ich mich sehr freuen.

Gruß Mücke

BinDannMalWeg

Du könntest die Internet Explorer UDF (IE.au3) verwenden. Mit ihr kannst du eine ganz normale Instanz des IE erzeugen in der du dann wie gewohnt in deinem Webshop surfen kannst. Zusätzlich könntest du mit der Funktion HotkeySet() darauf warten, dass du zu einem gewünschten Artikel gesurft bist. (Wenn du einen gefunden hast drückst du eben die Tastenkombination) In der zur Tastenkombination gehörenden Funktion kannst du dann mit den Funktionen der IE-UDF den Text/Quelltext der gerade im Browser geöffneten Seite auslesen und daraus mit Funktionen wie StringBetween, StringRegExp, usw. die benötigten Daten extrahieren.
Das Abspeichern der Daten ist dann ganz einfach mit den File-Funktionen möglich.

Spoiler anzeigen

AutoIt: Kleines Beispiel

#include <IE.au3>
OnAutoItExitRegister("onExit")


$oIE = _IECreate()
_IENavigate($oIE, "http://www.autoit.de/")
MsgBox(0, "", "Surfe eine beliebige Seite an und drücke Strg+Leertaste.")
HotKeySet("^{SPACE}", "hotkeyPressed")


While True
	Sleep(1000)
WEnd


Func hotkeyPressed()
	$sSource = _IEDocReadHTML($oIE)
	$aTitel = StringRegExp($sSource, "<title>(.+)</title>", 3)
	If Not @error And IsArray($aTitel) Then
		MsgBox(0, "", "Der Titel der aktuellen Seite ist '" & $aTitel[0] & "'")
	Else
		MsgBox(16, "", "Fehler beim Auslesen!")
	EndIf
EndFunc   ;==>hotkeyPressed


Func onExit()
	_IEQuit($oIE)
EndFunc   ;==>onExit

Alles anzeigen

**chip**

Zitat

jetzt bin ich mir nur nicht sicher ob das hier auch ein Tool in der Richtung zum iMacro ist oder ob Ihr ein extra Unterforum für iMacros habt, bzw. wo ich denn mit meinen Fragen hin kann, bisher habe ich noch kein richtig laufendes iMacro hin bekommen stehe also noch ganz am Anfang. und bin für fast alles offen

Hi Muecke,

nein Autoit geht nicht in die Richtung iMacro. iMacro generiert dir den Code ja komplett selbstständig, bei Autoit müsstest du dir alles selbst Programmieren. Für iMacro bist du hier eigentlich komplett falsch. Allerdings verstehe ich nicht wie darauf kommst, da im iMacro-Forum nur englisch zulässt. Schau mal hier, ist zwar ein alter Thread aber hier hat selbst ein Supporter dann auch deutsch geantwortet: http://forum.imacros.net/viewtopic.php?f=2&t=12371

Muecke

Hallo Christoph,

das hört sich doch schon nicht so schlecht an, und sehr User freundlich.

Jetzt muss ich aber doch doof fragen das ist ein Code der dann im Autoit laufen würde?

ich habe noch nicht so richtig verstanden was das für ein Programm ist und wo ich das bekomme.

Was kostet das Programm?

Da ich noch am Anfang bin es es mir ziemlich Jacke wie Hose mit welchen Programm ich arbeite, solange ich das richtige Ergebnis so User freundlich wie möglich bekomme

Gruß Mücke

Hey Chip,

iMacro für Firefox ist scheinbar eine etwas abgespeckte Version von iMacro glaube ich zumindest, denn auf der webseite von iMacro kommt etwas von 30 Tagen testen und das iMacro für Firefox sagt so etwas nicht.

Was ich damit sagen möchte auch hier muss ich den Größten teil des Codes Selber schreiben, da ich die befehle etc. nicht kenne tue ich mich damit sehr schwer

Wie ich darauf komme das in den Forum von forum.imacros.net/ nur Englisch gesprochen wird, da ich mich dort registriert habe und einen Beitrag in Deutsch verfasst habe jedoch habe ich den Beitrag auch gleich mit Google übersetzen lassen und im Beitrag auch die Englische Version mit drin stehen gehabt, und ich habe mich für mein Schlechtes Englisch entschuldigt da ich das nur übersetzen lassen habe Online.

Naja ich bin neu dort und ein Admin muss erst meinen Beitrag freigeben kam dann , und einen tag später bekomme ich eine Mail mit der Ablehnung meines Beitrages, Begründung es ist ausschließlich Englisch im Forum gestattet.

Das hat mich sehr verwundert da mein Beitrag in deutsch und Englisch verfasst war.

und aus dem Grund bin ich auf der suche nach einem Alternativen Forum. oder Software

Gruß Mücke

**autoBert**

Es gibt viele Lösungsmöglichkeiten, sehr einfach wäre:

gewünschten Text der Webseite markieren und auf eine Dropbox ziehen

AutoIt: RicheditAsDropBox

;https://autoit.de/index.php/Thread/22579-Dropbox-f%C3%BCr-Links-aus-Browsern/?postID=185846#post185846
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


Local $hGui, $iMsg
$hGui = GUICreate("Dropbox", 150, 150, -1, -1, BitOR($WS_SIZEBOX, $WS_BORDER), BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
GUICtrlSetState(-1, $GUI_ONTOP)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 0, 0, 150, 150, -1)
GUISetState()
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
_GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_SELCHANGE)
While True
	$iMsg = GUIGetMsg()
	Select
		Case $iMsg = $GUI_EVENT_CLOSE
			_GUICtrlRichEdit_Destroy($hRichEdit)
			GUIDelete()
			Exit
	EndSelect
WEnd


Func WM_NOTIFY($hWnd, $iMsg, $iWparam, $iLparam)
	#forceref $hWnd, $iMsg, $iWparam
	Local $hWndFrom, $iCode, $tNMHDR, $tEnLink, $cpMin, $cpMax, $tMsgFilter
	$tNMHDR = DllStructCreate($tagNMHDR, $iLparam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iCode = DllStructGetData($tNMHDR, "Code")
	Switch $hWndFrom
		Case $hRichEdit
			Select
				Case $iCode = $EN_SELCHANGE
					_Check()
			EndSelect
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY




Func _Check()
	$sText = _GUICtrlRichEdit_GetText($hRichEdit)
	MsgBox(64,'Text',$sText)
EndFunc   ;==>Checklink

Alles anzeigen

das Beispiel zu _ClipBoard_ChangeChain

AutoIt: _ClipBoard_ChangeChain

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>


Global $g_idMemo, $g_hNext = 0


Example()


Func Example()
	Local $hGUI


	; Create GUI
	$hGUI = GUICreate("Clipboard", 600, 400)
	$g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
	GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
	GUISetState(@SW_SHOW)


	; Initialize clipboard viewer
	$g_hNext = _ClipBoard_SetViewer($hGUI)


	GUIRegisterMsg($WM_CHANGECBCHAIN, "WM_CHANGECBCHAIN")
	GUIRegisterMsg($WM_DRAWCLIPBOARD, "WM_DRAWCLIPBOARD")


	; Loop until the user exits.
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE


	; Shut down clipboard viewer
	_ClipBoard_ChangeChain($hGUI, $g_hNext)
EndFunc   ;==>Example


; Write message to memo
Func MemoWrite($sMessage = "")
	GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite


; Handle $WM_CHANGECBCHAIN messages
Func WM_CHANGECBCHAIN($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	; Show that message was received
	MemoWrite("***** $WM_CHANGECBCHAIN *****")


	; If the next window is closing, repair the chain
	If $wParam = $g_hNext Then
		$g_hNext = $lParam
		; Otherwise pass the message to the next viewer
	ElseIf $g_hNext <> 0 Then
		_SendMessage($g_hNext, $WM_CHANGECBCHAIN, $wParam, $lParam, 0, "hwnd", "hwnd")
	EndIf
EndFunc   ;==>WM_CHANGECBCHAIN


; Handle $WM_DRAWCLIPBOARD messages
Func WM_DRAWCLIPBOARD($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg
	; Display any text on clipboard
	MemoWrite(_ClipBoard_GetData())


	; Pass the message to the next viewer
	If $g_hNext <> 0 Then _SendMessage($g_hNext, $WM_DRAWCLIPBOARD, $wParam, $lParam)
EndFunc   ;==>WM_DRAWCLIPBOARD

Alles anzeigen

beides mußt du natürlich nach deinen Bedürfnissen erweitern/abändern.

Zitat von Muecke

Hallo Christoph,

das hört sich doch schon nicht so schlecht an, und sehr User freundlich.

Jetzt muss ich aber doch doof fragen das ist ein Code der dann im Autoit laufen würde?

ich habe noch nicht so richtig verstanden was das für ein Programm ist und wo ich das bekomme.

Was kostet das Programm?

Die IE.au3 ist eine Standard Datei die man in eigene Skripte inkludieren kann. Die IE.au3 ermöglich das automatisieren des Internetexplorers. Kosten = 0 für das include, Arbeitsaufwand je nach Kenntnissen und Ansprüchen 5 Min. bis unendlich. Schau dir einfach einmal die Beispiele zu _IECreate bzw. _IECreateEmbedded an.

mfg (auto)Bert

Muecke

Wow das ist viel Code und viel Möglichkeiten, das Problem zu lösen.

ich glaube irgend wie fehlt mir der Anfang.

Wo kommt der Code denn rein? in eine Text Datei?
mit was muss ich das Skripte ausführen?

Mir fehlen glaube ich die Grundbausteine gerade was da wie wo ist.

**chip**

Zitat von Muecke

iMacro für Firefox ist scheinbar eine etwas abgespeckte Version von iMacro glaube ich zumindest, denn auf der webseite von iMacro kommt etwas von 30 Tagen testen und das iMacro für Firefox sagt so etwas nicht.

Genau von der Beschreibung der Erweiterung für den Firefox habe ich das aber ;). https://addons.mozilla.org/de/firefox/add…os-for-firefox/

"Sie können die sogenannten Makros selbst aufnehmen. Den benötigten Code zum Ausführen generiert die Browser-Erweiterung dabei selbst."

Das Problem ist scheinbar eher, wenn man die Kommentare ließt, das das ganze nicht mehr geupdatet wird auf die aktuelle Firefox-Version.

**Gun-Food**

Hallo Muecke,

vielleicht magst du dir für den Einstieg in AutoIt zumindest den Anfang unseres Tutorials anschauen? Du findest es auf der Startseite auf der rechten Seite.
Hier wird dir erklärt, was AutoIt ist, wie du es installierst und die ersten Schritte. Im zweiten Teil dann auch die erweiterten Datenstrukturen.

Grüße

Gun-Food

Muecke

hallo Gun-Food,

das werde ich machen, denn irgend wie fehlt mir noch einiges bevor ich wirklich mit meiner Aufgabe anfangen kann.
Das auf der Startseite auch Tutorials sind habe ich noch nicht gesehen gehabt werde ich aber gleich in angriff nehmen.

DANKE.

ich melde mich dann wider wenn ich wies was Sache ist und ich auch etwas davon verstehe.

Bis demnächst

Gruß Mücke

Hey Chip,

ob das an den Update liegt für den Neuen FF kann ich dir nicht sagen, ich weis nur das ich auch alleine aus den Tutoriels der Webseite entnehmen kann das einige Funktionen gar nicht vorhanden sind die dort in Bildern gezeigt werden.

Wenn ich den Code jedoch von Hand hinein schreibe dann funktioniert das schon, ich komme nur mit dem Code nicht so richtig zurecht dort.
Daher benötige ich Hilfe.

ich werde mich in das AutoIt etwas einlesen und schauen ob das nicht eine echte Alternative sein würde, hier sind zumindest schon mal ein Paar von euch die wie ich Deutsch verstehen
Danke dir.
Gruß Mücke

Muecke

Hallo Gun-Food,

ich bin nun dabei die Tut durch zuarbeiten danke noch mal dafür.

ich wies jetzt auch warum ich die nicht gefunden habe, ich habe immer mit dem iPad auf der Webseite geschaut, und wenn man mit dem iPad auf das "Portal" Startseite geht, kommen die Kleien Fenster rechts nicht und man kann auch die TuT nicht finden.

Wollte das nur kurz als Hinweis da lassen.

Bis demnächst.

Und allen einen schönen Feiertag.

Gruß Mücke

Muecke

Wie versprochen melden ich mich wider ;-).

habe mir jetzt einen Kleinen über blich verschlaft und wollte mit dem Code aus Post #2 von @Christoph54 anfangen.

Damit ich verstehe was genau Passiert habe ich mir als erstes Kommentare hinter jede ziele geschrieben dann sehe ich schneller was wie passiert
Da ich mit dem HTML Codieren nicht so viel anfangen kann dachte ich mir das ich als Nächstes mir den HTML Code anzeigen lassen,
das habe ich dann in einer MsgBox gemacht, das ist jedoch etwas unpraktisch denn die ist dann zu lange, also habe ich mir den Code in eine

Text Datei auf dem Desktop schreiben lassen, das ist auch nicht gerade Praktisch denn hier gibt es keine Zeilenumbrüche mehr

Daher meine Erste Frage:

Wie kann ich die Zeilenumbrüche für den HTML Code beim Schreiben in eine Datei wider Aktiviren? bzw. mit übergeben?

Dann habe ich noch eine Frage zum Beenden des AutoIT Programms, wenn ich den Browser wider schlisse dachte ich das auch das
AutoIT Script beendet wird, ist bei mir nicht der Fall, das Script wird weiterhin in der Windows leiste ganz unten am Monitor in dem Rechten Bereich
bei der Uhr angezeigt, das muss ich immer mit Rechtsklick und Exit beenden von Hand.
ist da nicht der teil "OnAutoItExitRegister("onExit")"* für zuständig?

oder mache ich da was Falsch?

Wenn ich die Zeilenumbrüche habe und das Script richtig beendet wird würde ich gerne anfangen bestimmte teile auf einer Webseite zu
finden und auszugeben, doch immer eins nach dem anderen.

Gruß Mücke

Spoiler anzeigen

AutoIt: Web-test.au3

#cs ----------------------------------------------------------------------------
 AutoIt Version:     3.3.14.2
 Author:             
 Quelle:             
 Dateiname:          Web-test.au3
 Script Function:    Webseite auslesen
 Beschreibung:       Öffnet den Internet Explorer, ....
#ce ----------------------------------------------------------------------------
#include <IE.au3>                                                           ; Funkzionen für den Internet Explorer
$file = FileOpen(@DesktopDir & "\test.txt", 1)                              ; Datei Test.txt auf dem Desktop Öffnen oder anlegen


If $file = -1 Then                                                          ; Überprüfen Sie, ob die Datei für das Schreiben von OK geöffnet
    MsgBox(0, "Fehler", "Datei kann nicht geöffnet werden.")                ;    Wenn Fehler Felder ausgeben
    Exit                                                                    ;    Programm abbrechen
EndIf                                                                       ; Ende der Überprüfung der Datei


OnAutoItExitRegister("onExit")                                              ; keine Ahnung


$oIE = _IECreate()                                                          ; Öffnet den Internet Explorer


_IENavigate($oIE, "http://www.autoit.de/")                                  ; Öffnet im Browser die Webseite


MsgBox(0, "", "Surfe eine beliebige Seite an und drücke Strg + Leertaste.") ; Gibt eine Info Box aus


HotKeySet("^{SPACE}", "hotkeyPressed")                                      ; Tastendruck "STRG + Leertaste" => Func hotkeyPressed()




While True                                                                  ; Endlosschleife
    Sleep(1000)                                                             ;    Warten für 1.000 Sekunden
WEnd                                                                        ; Endlosschleife Ende




Func hotkeyPressed()                                                        ; Funktion Start
    $sSource = _IEDocReadHTML($oIE)                                         ; Aktuellen Quelltext aus dem Internet Explorer Lesen
    MsgBox(0, "Quelltext", $sSource)                                        ; Quelltext in Info Box ausgeben
    FileWrite($file, $sSource)                                              ; Quelltext in Datei Exportiren


    $aTitel = StringRegExp($sSource, "<title>(.+)</title>", 3)                  ; Titel der Seite auslesen
    If Not @error And IsArray($aTitel) Then                                     ;    Wenn kein Fehler und $aTitel ein Array ist dann mache
        MsgBox(0, "", "Der Titel der aktuellen Seite ist '" & $aTitel[0] & "'") ;        Ausgabe des Array[0] was den Titel enspricht
    Else                                                                        ;    Wenn Bedingung nicht zutrift dann
        MsgBox(16, "", "Fehler beim Auslesen!")                                 ;       Fehlermeldung ausgeben
    EndIf                                                                       ;    Ende der Wenn prüfung
EndFunc   ;==>hotkeyPressed                                                     ; Funktion Ende




Func onExit()                                                               ; Funktion Start
    _IEQuit($oIE)                                                           ;     Internet Explorer Schlißen
    FileClose($file)                                                        ;     Datei wider schlißen
    MsgBox (0,"onExit", "Das ist die onExit Func ;-)")                      ;     Info Box, als Debug damit cih weis wann die Func ausgefürt wird
    Exit                                                                    ;     AutoIt programm beenden
EndFunc   ;==>onExit                                                        ; Funktion Ende

Alles anzeigen

**autoiter**

Hi @Muecke

- die Ausgabe in eine Datei mit Zeilenumbrüchen funktioniert. Versuch es vllt. mal mit Notepad++ oder jedenfalls einem anderen Editor.

- das Schließen des Browsers beendet dein Skript nicht, weil "OnAutoItExitRegister("onExit")" allgemein die Ausführung einer Funktion registriert, die ausgeführt wird, wenn das Skript per Exit verlassen wird. Bei dir fehlt einfach der Teil, der abfragt, ob der Browser noch läuft und evtl. dann deine Endlosschleife verlässt.
Hier unten habe ich einfach mal eine Prüfung in die Endlosschleife eingefügt, ob der IE-Prozess noch läuft (Nur diese eine Zeile If not ProcessExists...). Wenn nicht, wird per ExitLoop die Endlosschleife verlassen und danach wird beim Beenden des Skripts auch deine onExit-Funktion aufgerufen.

AutoIt

While True                                                                  ; Endlosschleife
    Sleep(1000)                                                             ;    Warten für 1.000 Sekunden
    If Not ProcessExists("iexplore.exe") Then ExitLoop
WEnd

**Kanashius**

Ich hab mal ein kleines Script geschrieben. Vielleicht magst du die Idee auch lieber als das mit dem extra Browserfenster.
Ich hab alles Kommentiert.
Die Lösung zu den Zeilenumbrüchen ist in Zeile 36-39. Das Problem ist, dass Linux/Mac als Zeilenumbruch das unsichtbare Zeichen @LF nutzt, Windows aber die beiden Zeichen @CRLF. Deshalb sind die Zeilenumbrüche unter Windows dann nicht sichtbar. Spezielle Programme, wie das von autoiter genannte Notepad++ (sehr zu empfehlen) zeigen auch @LF als Zeilenumbruch an.

OnAutoitExitRegister sorgt nur dafür, dass wenn dein Programm beendet wird, vorher noch die genannte Funktion aufgerufen wird.
Wird eigentlich nur genutzt, wenn man noch irgendwas unbedingt machen muss, bevor das Programm beendet. Zum Beispiel Speicherfreigeben, Dateihandle schließen,...
Das FileOpen/FileClose kannst du hier auch weglassen. Das ist eigentlich nur dann wichtig, wenn man die Parameter von Fileopen braucht, oder sehr oft in eine Datei schreibt.
Du hast ja nur einen einzigen Schreibvorgang, deshalb kann es hier weggelassen werden.

AutoIt

#include <ie.au3>
#include <WindowsConstants.au3>


Global $iWidth=800,$iHeight=600 ;Fensterhöhe/Breite, damit die Controls bei Änderungen noch passend liegen, hier die Variable ändern
Global $startUrl="www.google.de"
Global $startMaximized=true
Global $file=@DesktopDir & "\test.txt";Die Datei, wo der quelltext gespeichert werden soll


GUICreate("",$iWidth,$iHeight,-1,-1,BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU,$WS_MAXIMIZEBOX ));Fenster erstellen (Die Parameter sind nur dafür, dass es maximiert werden kann. Der Rest ist standartmäßig dabei.
$oIE=_IECreateEmbedded();Eine Instanz vom IE öffnen, die im eigenen Fenster angezeigt wird (Kein eigener IE-Prozess)
$cIE=GUICtrlCreateObj($oIE,5,35,$iWidth-10,$iHeight-45);Den Browser in diesem Control darstellen lassen. (Eigentlich nur zum ändern der Größe wichtig, und zum darstellen lassen^^)
GUICtrlSetResizing(-1,BitOR(2,4,32,64));Damit bei einer Größenänderung des Fensters alles passend liegt: 2 steht für Dock-Left->Das Control soll am linken Rand den gleichen Abstand behalten, das selbe für die anderen (siehe Hilfe)
$cUrl=GUICtrlCreateInput($startUrl,5,5,$iWidth-60,25);Input, falls eine andere URL aufgerufen werden soll
GUICtrlSetResizing(-1,BitOR(2,4,512,32))
$cGO=GUICtrlCreateButton("GO",$iWidth-55,5,50,25);Die im Inputfeldbefindene Url aufrufen
GUICtrlSetResizing(-1,BitOR(4,512,32,256))
GUISetState(@SW_SHOW);Fenster anzeigen


HotKeySet("^{SPACE}", "saveData");Bei Tastendruck die FUnktion saveData aufrufen


if $startMaximized then GUISetState(@SW_MAXIMIZE);Wenns maximiert werden soll, hier maximieren
_IENavigate($oIE,$startUrl);Zur Standart URL navigieren


while 1
	$msg=GUIGetMsg();Abfragen, ob in dem Fenster was passiert ist
	switch $msg
		case -3;Wenn schließen geklickt wurde: Programm beenden
			exit
		case $cGO;Wenn G= gedrückt wurde: URL aufrufen
			_IENavigate($oIE,GUICtrlRead($cUrl));guictrlread ließt den Inhalt des Inputfeldes aus
	EndSwitch
WEnd


Func saveData()
	$sSource = _IEDocReadHTML($oIE)                                          	 ; Aktuellen Quelltext aus dem Internet Explorer Lesen
	if NOT StringInStr($sSource,@CRLF) then ;Wenn keine Zeilenumbrüche in Windows sichtbar
		$sSource=StringReplace($sSource,@LF,@CRLF);Ersetze Linux/Mac Zeilenumbrüche durch die von Windows
		$sSource=StringReplace($sSource,@CR,@CRLF);Keine Ahnung, warum jemand cr nutzen sollte, aber man weiß ja nie^^
	endif
    MsgBox(0, "Quelltext", $sSource)                                             ; Quelltext in Info Box ausgeben


    ;FileWrite($file, $sSource)                                                   ; Quelltext in Datei Exportiren
    $aTitel = StringRegExp($sSource, "<title>(.+)</title>", 3)                   ; Titel der Seite auslesen
    If Not @error And IsArray($aTitel) Then                                      ;    Wenn kein Fehler und $aTitel ein Array ist dann mache
        MsgBox(0, "", "Der Titel der aktuellen Seite ist '" & $aTitel[0] & "'")  ;        Ausgabe des Array[0] was den Titel enspricht
    Else                                                                         ;    Wenn Bedingung nicht zutrift dann
        MsgBox(16, "", "Fehler beim Auslesen!")                                  ;       Fehlermeldung ausgeben
    EndIf
EndFunc

Alles anzeigen

Am besten erst einmal ausführen und dann alles durchlesen, dann sind die Kommentare verständlicher schätze ich
Ich hoffe das hilft dir weiter

MfG Kanashius

misterspeed

Deine @LF bzw. @CR Ersetzung ist übrigens fehlerhaft und führt zu doppelten Zeilenumbrüchen, da das @CR vom zuvor eingefügten @CRLF erneut durch @CRLF ersetzt wird. Das Ergebnis ist dann ein @CRLFLF

Hier eine korrekte Lösung:

AutoIt

if NOT StringInStr($sSource,@CRLF) then ;Wenn keine Zeilenumbrüche in Windows sichtbar
		$sSource=StringReplace($sSource,@LF,@CR);Ersetze Linux/Mac Zeilenumbrüche durch die von Windows
		$sSource=StringReplace($sSource,@CR,@CRLF);Keine Ahnung, warum jemand cr nutzen sollte, aber man weiß ja nie^^
	endif

Muecke

Hey @autoiter,

Danke für die Codezeile, da klappt prima so.
hier wir geprüft ob die Datei "iexplore.exe" noch ausgeführt wird oder nicht, wenn nicht wird der Loop verlasen und das AutoIT-Script beendet.
das ist perfekt. Danke.

Hey @Kanashius,

ich wollte jetzt nicht den gesamten Rechner umstellen müssen und mir das "Notepad" als Standarteditor Verlinken. wäre schön wenn man nicht alles immer ändern muss ;-).

Ich hoffe das du den Code nicht extra für mich geschrieben hast, es sind viele Dinge drin die mehr als neu sind.
Jedoch gefällt mir das "Normale" Browser Fenster vom IE besser.

auch wenn ich in Script aus Post #2 die URL ändere von Hand bekommt das Script diese mit.

Deine Zeilenumbrüche habe ich jedoch bei mir auch mit eingefügt und klapt prima Danke dafür .

Hey @misterspeed,

Cool danke, bei mir gab es bis jetzt zwar keinen doppelten Zeilenumbrüche, habe jedoch eine Änderung mit aufgenommen und Funktioniert einwandfrei.
Danke dafür.

@alle:
Habe das Script noch beim Öffnen der Datei auf Modus 2 gestellt das jeder Alter Inhalt erst ein mal gelöscht wird, jetzt kann ich anfangen bestimmte teile auszulesen.
Hoffe das geht einfach ich werde ein wenig Experimentieren.

Danke schon mal für die erste Hilfe von euch.

ich melde mich wider.

Gruß Mücke

EDIT: ich könnte auch den neuen Script -code einstellen ,-)

AutoIt: Web-test.au3

#cs ----------------------------------------------------------------------------
 AutoIt Version:     3.3.14.2
 Author:
 Quelle:
 Dateiname:          Web-test.au3
 Script Function:    Webseite auslesen
 Beschreibung:       Öffnet den Internet Explorer, ....
#ce ----------------------------------------------------------------------------
#include <IE.au3>                                                           ; Funkzionen für den Internet Explorer
$file = FileOpen(@DesktopDir & "\test.txt", 2)                              ; Datei Test.txt auf dem Desktop Öffnen oder anlegen


If $file = -1 Then                                                          ; Überprüfen Sie, ob die Datei für das Schreiben von OK geöffnet
    MsgBox(0, "Fehler", "Datei kann nicht geöffnet werden.")                ;    Wenn Fehler Felder ausgeben
    Exit                                                                    ;    Programm abbrechen
EndIf                                                                       ; Ende der Überprüfung der Datei


OnAutoItExitRegister("onExit")                                              ; keine Ahnung


$oIE = _IECreate()                                                          ; Öffnet den Internet Explorer


_IENavigate($oIE, "http://www.autoit.de/")                                  ; Öffnet im Browser die Webseite


MsgBox(0, "", "Surfe eine beliebige Seite an und drücke Strg + Leertaste.") ; Gibt eine Info Box aus


HotKeySet("^{SPACE}", "hotkeyPressed")                                      ; Tastendruck "STRG + Leertaste" => Func hotkeyPressed()


While True                                                                  ; Endlosschleife
    Sleep(1000)                                                             ;    Warten für 1.000 Sekunden
    If Not ProcessExists("iexplore.exe") Then ExitLoop                      ;    Prüfen ob die Datei "iexplore.exe" noch ausgefürt wird wenn nicht AutoIT Script beenden
WEnd                                                                        ; Endlosschleife Ende


Func hotkeyPressed()                                                        ; Funktion Start
    $sSource = _IEDocReadHTML($oIE)                                         ; Aktuellen Quelltext aus dem Internet Explorer Lesen


; Zeilenumbrüche für die Datei erstellen
    if NOT StringInStr($sSource,@CRLF) then                                 ; Wenn keine Zeilenumbrüche in Windows sichtbar
        $sSource=StringReplace($sSource,@LF,@CR)                            ; Ersetze Linux/Mac Zeilenumbrüche durch die von Windows
        $sSource=StringReplace($sSource,@CR,@CRLF)                          ; Keine Ahnung, warum jemand cr nutzen sollte, aber man weiß ja nie^^
    endif


    MsgBox(0, "Quelltext", $sSource)                                        ; Quelltext in Info Box ausgeben
    FileWrite($file, $sSource & @CRLF )                                     ; Quelltext in Datei Exportiren


    $aTitel = StringRegExp($sSource, "<title>(.+)</title>", 3)                  ; Titel der Seite auslesen
    If Not @error And IsArray($aTitel) Then                                     ;    Wenn kein Fehler und $aTitel ein Array ist dann mache
        MsgBox(0, "", "Der Titel der aktuellen Seite ist '" & $aTitel[0] & "'") ;        Ausgabe des Array[0] was den Titel enspricht
    Else                                                                        ;    Wenn Bedingung nicht zutrift dann
        MsgBox(16, "", "Fehler beim Auslesen!")                                 ;       Fehlermeldung ausgeben
    EndIf                                                                       ;    Ende der Wenn prüfung
EndFunc   ;==>hotkeyPressed                                                     ; Funktion Ende




Func onExit()                                                               ; Funktion Start
    _IEQuit($oIE)                                                           ;     Internet Explorer Schlißen
    FileClose($file)                                                        ;     Datei wider schlißen
    MsgBox (0,"onExit", "Das ist die onExit Func ;-)")                      ;     Info Box, als Debug damit cih weis wann die Func ausgefürt wird
    Exit                                                                    ;     AutoIt programm beenden
EndFunc   ;==>onExit                                                        ; Funktion Ende

Alles anzeigen

misterspeed

Hab das Script zwar nicht getestet, aber so auf anhieb würde ich dir davon abraten eine 1000ms Pause in deine Endlosschleife zu packen. Sleep() ist blockierend und deine Hotkeys werden erst ausgeführt wenn die Sleep() Funktion beendet wird. 100ms sollten mehr als ausreichend sein und sorgen für ein deutlich rekationsfähigeres Script. Dürfte in deinem Fall zwar nicht allzu relevant sein, aber für die Zukunft ist es vielleicht hilfreich zu wissen, dass zu lange "Sleeps" negative Auswirkungen haben können.

**AspirinJunkie**

Zitat von misterspeed

Sleep() ist blockierend und deine Hotkeys werden erst ausgeführt wenn die Sleep() Funktion beendet wird.

Sicher?:

AutoIt

HotKeySet("+Q", Test) ; Shift-Q


Sleep(1e7)


Func Test()
	MsgBox(0,"", "Test")
	Exit
EndFunc

misterspeed

Zitat von AspirinJunkie

Sicher?:

Da lag ich wohl falsch, zumindestens beim Einsatz von Hotkeys und Adlibregister wird die Ausführung von sleep() tatsächlich unterbrochen.

Muecke

Irgend wie mag ich das Forum, daher möchte ich euch meinen Neuen Strukturierten Code auch nicht vorenthalten.

Ja ich bin noch immer dabei den Befehl "StringRegExp" besser zu verstehen, warum etwas ins Arrea kommt oder nicht, jedoch habe ich mir ein paar Hilfen eingebaut.

1. Funktion Quelltext in eine Datei Speichern
2. Ergebnis in eine Datei Speichern
3. Dateien Öffnen und Schließen in eine Funktion gepackt

jetzt kann ich mir das Ergebnis immer in den Dateien anscheinen und scheuen ob ich auch das richtige der Webseite auslese oder nicht.
noch klappt das nicht mal ansatzweise, doch ich bin zuversichtlich das ich das irgend wann hin bekomme.

so das ist der Aktuelle Code von mir:

AutoIt: Web-test_12_10_16.au3

#cs ----------------------------------------------------------------------------
 AutoIt Version:     3.3.14.2
 Author:
 Quelle:
 Dateiname:          Web-test_12_10_16.au3
 Script Function:    Webseite auslesen
 Beschreibung:       Öffnet den Internet Explorer, ....
#ce ----------------------------------------------------------------------------


#include <IE.au3>                                                           ; Funkzionen für den Internet Explorer laden


OnAutoItExitRegister("onExit")                                              ; keine Ahnung


$oIE = _IECreate()                                                          ; Öffnet den Internet Explorer


 _IENavigate($oIE, "http://www.autoit.de/")                                  ; Öffnet im Browser die Webseite


; MsgBox(0, "", "Surfe eine beliebige Seite an und drücke Strg + Leertaste.") ; Gibt eine Info Box aus


HotKeySet("^{SPACE}", "hotkeyPressed")                                      ; Tastendruck "STRG + Leertaste" => Func hotkeyPressed()


While True                                                                  ; Endlosschleife
    Sleep(1000)                                                             ;    Warten für 1.000 Sekunden
    If Not ProcessExists("iexplore.exe") Then ExitLoop                      ;    Prüfen ob die Datei "iexplore.exe" noch ausgefürt wird wenn nicht AutoIT Script beenden
WEnd                                                                        ; Endlosschleife Ende


Func hotkeyPressed()                                                        ; Funktion Start


$sSource = _IEDocReadHTML($oIE)                                             ; Aktuellen Quelltext aus dem Internet Explorer Lesen


Datei_Speichern (@DesktopDir & "/", "Quellcode.txt", 2, $sSource)           ; Daten in Daten in Datei Speichern


;$aTitel = StringRegExp($sSource, "<title>(.+)</title>", 3)                  ; Titel der Seite auslesen
;Datei_Array_Speichern(@DesktopDir & "/", "aTitel.txt", 2, $aTitel)


$aDIV = StringRegExp($sSource, "<head>(.+)</head>", 3)
Datei_Array_Speichern(@DesktopDir & "/", "aHead.txt", 2, $aDIV)


EndFunc   ; ==> hotkeyPressed                                                ; Funktion Ende




Func Datei_Array_Speichern ($das_Pfad, $das_Datei, $das_Modus, $das_Array)


$das_Text = ""


; Datei Öffnen
  $das_File = FileOpen($das_Pfad & $das_Datei, $das_Modus)                      ; Datei Öffnen
  If $das_File = -1 Then                                                        ; Überprüft ob die Datei richtig geöffnet wurde
    MsgBox(0, "Fehler", "Datei '"&$das_Datei&"' kann nicht geöffnet werden.")   ;    Wenn Fehler, Felder ausgeben
	Exit                                                                        ;    Programm abbrechen
  EndIf


; Array bearbeiten (Zeilenumbrüche)
  $das_Array_Groesse = UBound ($das_Array)
  MsgBox (0,"Info","das Array ist Groß = "&$das_Array_Groesse)
  For $das_i = 0 To $das_Array_Groesse - 1 Step 1
    $das_Text = $das_Text & @CRLF & "Array [" & $das_i & "] = " & $das_Array[$das_i]
  Next


; Text in Datei Speichern
  FileWrite($das_File, $das_Text)                                                ; Quelltext in Datei Exportiren


; Datei Schlißen
  FileClose($das_File)                                                          ;     Datei wider schlißen
EndFunc   ; ==> Datei_Array_Speichern


Func Datei_Speichern ($ds_Pfad, $ds_Datei, $ds_Modus, $ds_Text)
; Datei Öffnen
  $ds_File = FileOpen($ds_Pfad & $ds_Datei, $ds_Modus)                         ; Datei Öffnen
  If $ds_File = -1 Then                                                        ; Überprüft ob die Datei richtig geöffnet wurde
    MsgBox(0, "Fehler", "Datei '"&$ds_Datei&"' kann nicht geöffnet werden.")   ;    Wenn Fehler, Felder ausgeben
	Exit                                                                       ;    Programm abbrechen
  EndIf


; Text bearbeiten (Zeilenumbrüche)
  if NOT StringInStr($ds_Text,@CRLF) then                                      ; Wenn keine Zeilenumbrüche in Windows sichtbar
    $ds_Text=StringReplace($ds_Text,@LF,@CR)                                   ;   Ersetze Linux/Mac Zeilenumbrüche durch die von Windows
    $ds_Text=StringReplace($ds_Text,@CR,@CRLF)                                 ;   Keine Ahnung, warum jemand cr nutzen sollte, aber man weiß ja nie^^
  endif


; Text in Datei Speichern
  FileWrite($ds_File, $ds_Text)                                                ; Quelltext in Datei Exportiren


; Datei Schlißen
  FileClose($ds_File)                                                          ;     Datei wider schlißen
EndFunc	; ==> Datei_Speichern


Func onExit()                                                               ; Funktion Start
    _IEQuit($oIE)                                                           ;     Internet Explorer Schlißen
    MsgBox (0,"onExit", "Danke, AutoIT-Script ist beendet!")                ;     Info Box, als Debug damit cih weis wann die Func ausgefürt wird
    Exit                                                                    ;     AutoIt programm beenden
EndFunc   ; ==> onExit                                                      ; Funktion Ende

Alles anzeigen

Muecke

So da bin ich wider, habe mein Script weiter ausgebaut und kann nun alle Daten auslesen die ich Lesen möchte, jedoch habe ich ein Großes Problem.

Mein Script beendet sich nach einer gewissen zeit von alleine. .-(

was mache ich.

1. Script aufrufen im Editor
2. Script starten mit F5
3. Auf der Webseite Servern bis ich einen interessanten Artikel gefunden habe. (sorry es ist nicht E-bay jedoch möchte ich die eigentliche Seite nicht nennen müssen da es sich um einen Passwort geschützten Shop handelt)
4. beim Artikel der mir gefällt drücke ich "STRG + Leertaste"
5. dann suche ich weiter.

Und jetzt kommt es vor das mein Browserfenster geschlossen wird und mein Script sich bedankt und alles ist zu, jedoch kommt nicht die Meldung das das Fenster von Hand geschlossen worden wäre.

Ich bin am verzweifeln denn ich finde die Stelle nicht an der es sich selbst beendet, ich gehe davon aus das ich irgend wo einen Fehler drin habe so das irgend was Überlaufen tut und daher das Script sich selbst beendet.
könnte von euch jemand mal drüber schauen? und mir ein Tipp geben, an was das liegen könnte.

Gruß Mücke

das ist mein Code:

C: Web-test_20_10_16.au3

#cs ----------------------------------------------------------------------------
 AutoIt Version:     3.3.14.2
 Author:
 Quelle:
 Dateiname:          Web-test_20_10_16.au3
 Script Function:    Webseite auslesen
 Beschreibung:       Öffnet den Internet Explorer, ....
#ce ----------------------------------------------------------------------------


#include <IE.au3>                                                           ; Funkzionen für den Internet Explorer laden
#include<Date.au3>															; Funkzionen füs Datum laden
OnAutoItExitRegister("onExit")                                              ; Was alles gemacht werden muss wenn das Script beendet wurde
$oIE = _IECreate()                                                          ; Öffnet den Internet Explorer


  $sURL      = "http://www.e-bay.de/"
  $File_name = "/Datei_Name.txt"




_IENavigate($oIE, $sURL)


HotKeySet("^{SPACE}", "hotkeyPressed")                                      ; Tastendruck "STRG + Leertaste" => Func hotkeyPressed()


While True                                                                  ; Endlosschleife
    Sleep(1000)                                                             ;    Warten für 1.000 milli sekunden
    If Not ProcessExists("iexplore.exe") Then
		MsgBox (64, "Ende", "Browser Fenster wurde geschloßen")
		ExitLoop                   										   ;    Prüfen ob die Datei "iexplore.exe" noch ausgefürt wird wenn nicht AutoIT Script beenden
	Endif
WEnd                                                                        ; Endlosschleife Ende


Func hotkeyPressed()                                                        ; Funktion Start


$sSource = _IEDocReadHTML($oIE)                                             ; Aktuellen Quelltext aus dem Internet Explorer Lesen


#cs ----------------------------------------------------------------------------
    1) Datum lesen
    2) Herstellernummer lesen
    3) EAN lesen
    4) WebLink lesen
    5) Liferanten lessen
    6) EK lesen
    7) Daten Suchen und ersätzen in gelesenen Werten
    8) Datei Öffnen
	9) Daten Schreiben
	10) Datei Schlißen
	11) Ausgabe
#ce ----------------------------------------------------------------------------


;  1) bis 6)
	$aDatum            = _NowDate()
	$aURL              = _IEPropertyGet($oIE, "locationurl")
    $aHerstellernummer = StringRegExp($sSource, "(?s)<td><strong>Herstellernummer</strong></td>\s*<td>(\d+)</td>", 3)
	$aEAN              = StringRegExp($sSource, "(?s)<td><strong>EAN</strong></td>\s*<td>(\d+)</td>", 3)
	$aLiName           = StringRegExp($sSource, "<input name=""name"" type=""hidden"" value=""(.+)"">", 3)
	$aEK               = StringRegExp($sSource, "<td class=""align-right"">(.+)€</td>", 3)


; 7)
    For $i = 0 to UBound($aEK)-1
		$aEK[$i] = StringReplace ($aEK[$i], ".", ",")
	Next
    For $i = 0 to UBound($aLiName)-1
		$aLiName[$i] = StringReplace ($aLiName[$i], "&", "&")
	Next


; 8)
	If Not FileExists(@DesktopDir & $File_name)  then
		$File = FileOpen(@DesktopDir & $File_name, 2)		; Datei Erstellen und öffnen
		FileWrite($File, "Datum; Herstellernummer; EAN; Lieferantenname; EK; URL"& @CRLF)
	Else
		$File = FileOpen(@DesktopDir & $File_name, 1)		; Datei Existirtbereits, Öffnen und ans Ende schreiben
	EndIf


	If $File = -1 Then												; Pfüfen ob die Datei richtig geöffnet wurde
	 MsgBox(0, "Fehler", "Datei kann nicht geöffnet werden.")
	 Exit
	EndIf


; 9)
	; Daten Schreiben
	For $i = 0 To UBound ($aEK)-1
	 FileWrite($File, $aDatum & "-" & @hour & ":" & @min & ":" & @sec & ";" & $aHerstellernummer[0] & ";" & $aEAN[0] & ";" & $aLiName[$i] & ";" & $aEK[$i] & ";" & $aURL & @CRLF)
	Next


; 10)
    FileClose($File)


; 11)
	; Arrey Löschen
	Dim $aHerstellernummer[UBound($aHerstellernummer,1)]
	Dim $aEAN[UBound($aEAN,1)]
	Dim $aLiName[UBound($aLiName,1)]
	Dim $aEK[UBound($aEK,1)]




	MsgBox (64, "Perfekt", "Lesen und Speichern", 0.5)
;	_IENavigate($oIE, $sURL)


EndFunc   ; ==> hotkeyPressed


Func onExit()                                                               ; Funktion Start
    _IEQuit($oIE)                                                           ;     Internet Explorer Schlißen
    MsgBox (0,"onExit", "Danke, AutoIT-Script ist beendet!")                ;     Info Box, als Debug damit cih weis wann die Func ausgefürt wird
    Exit                                                                    ;     AutoIt programm beenden
EndFunc   ; ==> onExit                                                      ; Funktion Ende

Alles anzeigen