Auslosung Script (Wichteln)

shakoon

Hallo,

Ich bin gerade dabei mir ein Script zu schreiben um Auslosungen zum wicheteln du erstellen.
Ich dachte mir ich erzeuge mit der Funktion "Random" Zufallszahlen von 1-10. und den Zahlen ordne ich dann die namen zu mit "if".
Jetzt habe ich aber das problem, ich habe z.B. 10 Namen, und zu jedem Namen soll eine anderer name zugeordnet werden, so dass man sich nicht selbst ziehen kann.

Könnt ihr mir verraten wie ich das umsetzen kann?

**Alina**

OHNE WORTE !

**Kanashius**

Kurz und knapp wäre das eine Lösung:

AutoIt

#include <array.au3>
;Array (Liste) mit den Namen anlegen
global $arNames=[["Name1",-1],["Name2",-1],["Name3",-1],["Name4",-1]]


;Zahlen von 0 bis zur Anzahl der Namen in der Liste durchgehen (nur noch Anzahl genannt)
for $i=0 to UBound($arNames)-1 step 1
	;Zufallszahl zwischen 0 und Anzahl
	$iNr=Random(0,UBound($arNames)-1,1)
	;Solange erhöhen, bis der Eintrag an der Stelle noch nicht zugewiesen wurde, bei überschreiten von Anzahl wieder vorne Anfangen
	while $arNames[$iNr][1]<>-1
		$iNr+=1
		if $iNr>UBound($arNames)-1 then
			$iNr=0
		endif
	WEnd
	;Zahl zuweisen
	$arNames[$iNr][1]=$i
next
_ArrayDisplay($arNames)


;Alle Zahlen durch die Namen ersetzen
for $i=0 to UBound($arNames)-1 step 1
	$arNames[$i][1]=$arNames[$arNames[$i][1]][0]
next


_ArrayDisplay($arNames)

Alles anzeigen

Ich wähle zufällig einen Arrayeintrag aus und Zähle immer weiter, bis der nchste nach dem zufällig ausgewählten frei ist. Ist nicht komplett zufällig, aber fast
Sonst könnte man noch die UDF von Oscar nutzen: Random-Number-Generator

Du musst somit nurnoch die Namen in die Liste oben eintragen und das Programm läuft durch und gibt dir das Ergebnis

MfG Kanashius

shakoon

Vielen dank schonmal das ist denke ich das was ich brauche
Allerdings habe ich jetzt mit der Datenausgabe von dem Script so meine Problemchen xD

Ich habe dein Script jetzt als Function.

Und ich habe mir eine GUi erstellt. Durch Klicken auf den Button Wichteln, möchte ich ganz gerne, das in meinem GUI bei "Zufallsname1-8" dann ein Zufälliger Name Auftaucht.
Aber Name 1 und Zufallsname 1 darf z.B. nicht hintereinander stehen. Also so das man sich nicht selber zieht
ist das irgendwie umsetzbar mit einfachen mitteln?

AutoIt

Func Example2()
    Local $msg


    GUICreate("Wichtelgenerator") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird
    GUISetState(@SW_SHOW) ; Zeigt das leere GUI-Fenster




	GUICtrlCreateLabel ( "Name1", 10, 20 , 100 , 15 )
	GUICtrlCreateLabel ( "Name2", 10, 40 , 100 , 15 )
	GUICtrlCreateLabel ( "Name3", 10, 60 , 100 , 15 )
	GUICtrlCreateLabel ( "Name4", 10, 80 , 100 , 15 )
	GUICtrlCreateLabel ( "Name5", 10, 100 , 100 , 15 )
	GUICtrlCreateLabel ( "Name6", 10, 120 , 100 , 15 )
	GUICtrlCreateLabel ( "Name7", 10, 140 , 100 , 15 )
	GUICtrlCreateLabel ( "Name8", 10, 160 , 100 , 15 )




	GUICtrlCreateLabel ( Zufallsname1, 150, 20 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname2, 150, 40 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname3, 150, 60 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname4, 150, 80 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname5, 150, 100 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname6, 150, 120 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname7, 150, 140 , 100 , 15 )
	GUICtrlCreateLabel ( Zufallsname8, 150, 160 , 100 , 15 )










	$Button1 = GUICtrlCreateButton ( "WICHTELN", 10, 200 , 100 , 20)
	$Button2 = GUICtrlCreateButton ( "SCHLIEßEN", 150, 200 , 100 , 20)




    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst
    While 1
        $msg = GUIGetMsg()
		Select
			Case $msg = $GUI_EVENT_CLOSE
			ExitLoop
			Case $msg = $Button1
			Example1()
			Case $msg = $Button2
			Exit
		EndSelect
    WEnd
    GUIDelete()
EndFunc   ;==>Example1

Alles anzeigen

**Kanashius**

Hab das ganze mal mit nem Script kombiniert, was ich noch hier liegen hatte. Ne Listview mit editierbaren Feldern hätte es vermutlich auch getan

AutoIt

#include <array.au3>
#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>
#include <GuiConstantsEx.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiComboBoxEx.au3>


Global Const $SIF_DISABLENOSCROLL = 0x8
Global $iWidth = 800, $iHeight = 600, $iScrollControlHeight = 25, $iEntryColWidth = 150, $iEntryOperWidth = 40,$iScrollControllHeightSpace=5,$iScrollControllWidthSpace=5
Global $iLastItemWidth,$iLastItemHeigt,$iLastHorizontalScrolled,$iLastVerticalScrolled
Global $arCols = [["Name", "col"], ["Name2", "col2"]],$arOper=["+","-","*","/"],$arScrollControls[0],$sNoSelection="- -"


$hMainGui = GUICreate("Export", $iWidth, $iHeight,-1,-1,BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU,$WS_MAXIMIZEBOX,$WS_SIZEBOX))
$hAddRow = GUICtrlCreateButton("Add Col", 5, $iHeight - 30, 60, 25)
$hReady = GUICtrlCreateButton("Ready", $iWidth-65, $iHeight - 30, 60, 25)




$hScrollGui=GUICreate("",$iWidth-15,$iHeight-40,5,5,$WS_CHILD,$WS_EX_CLIENTEDGE,$hMainGui)
GUISetState(@SW_SHOW,$hScrollGui)


GUIRegisterMsg($WM_SIZE, "WM_SIZE")
GUIRegisterMsg($WM_VSCROLL, "WM_VSCROLL")
GUIRegisterMsg($WM_HSCROLL, "WM_HSCROLL")


GUISetState(@SW_SHOW,$hMainGui)
_GUIScrollBars_Init($hScrollGui)
_GUIScrollBars_ShowScrollBar($hScrollGui,$SB_BOTH,true)


While 1
	$msg = GUIGetMsg(1)
	if $msg[1]=$hMainGui then
		Switch $msg[0]
			case -3
				exit
			case $hAddRow
				_addScrollControl()
			case $hReady
				_calculatePartners()
				_getResult()
		EndSwitch
	else
		for $i=0 to UBound($arScrollControls)-1 step 1
			local $tmp=$arScrollControls[$i]
			for $j=0 to UBound($tmp)-1 step 1
				if $msg[0]=$tmp[$j] then
					if $j=0 then
						;exit
						_removeControl($i)
					elseif $j=1 then
						;top
						_switchControl($i,$i-1)
					elseif $j=2 then
						;down
						_switchControl($i,$i+1)
					endif
					ExitLoop 2
				endif
			next
		next
	endif
WEnd


Func _calculatePartners()
	for $i=0 to UBound($arScrollControls)-1 step 1
		$iNr=Random(0,UBound($arScrollControls)-1,1)
		local $arTmp=$arScrollControls[$iNr]
		while GUICtrlRead($arTmp[4])<>""
			$iNr+=1
			if $iNr>UBound($arScrollControls)-1 then
				$iNr=0
			endif
			$arTmp=$arScrollControls[$iNr]
		WEnd
		local $arTmp2=$arScrollControls[$i]
		GUICtrlSetData($arTmp[4],GUICtrlRead($arTmp2[3]))
	next
	for $i=0 to UBound($arScrollControls)-1 step 1
		local $arTmp=$arScrollControls[$i]
		if GUICtrlRead($arTmp[3])=GUICtrlRead($arTmp[4]) then
			if $i<UBound($arScrollControls)-1 then
				local $tmp=GUICtrlRead($arTmp[4])
				local $arTmp2=$arScrollControls[$i+1]
				GUICtrlSetData($arTmp[4],$arTmp2[4])
				GUICtrlSetData($arTmp2[4],$tmp)
			else
				local $tmp=GUICtrlRead($arTmp[4])
				local $arTmp2=$arScrollControls[0]
				GUICtrlSetData($arTmp[4],$arTmp2[4])
				GUICtrlSetData($arTmp2[4],$tmp)
			endif
			$i+=1
			if $i>UBound($arScrollControls)-1 then
				$i=0
			endif
		endif
	next
EndFunc


Func _getResult()
	local $string=""
	for $i=0 to UBound($arScrollControls)-1 step 1
		local $arTmp=$arScrollControls[$i]
		$string&=GUICtrlRead($arTmp[3])&" wichtelt für "&GUICtrlRead($arTmp[4])
		if $i<>UBound($arScrollControls)-1 then
			$string&=@crlf
		endif
	next
	msgbox(48,"",$string)
EndFunc


Func _removeAllControlsBehind($index,$j)
	local $tmp=$arScrollControls[$index]
	for $i=$j+1 to UBound($tmp)-1 step 1
		GUICtrlDelete($tmp[$i])
	next
	ReDim $tmp[$j+1]
	$arScrollControls[$index]=$tmp
EndFunc


Func _addScrollControl()
	GUISwitch($hScrollGui)
	if UBound($arScrollControls)>0 then
		local $arControlsLast=$arScrollControls[UBound($arScrollControls)-1]
		GUICtrlSetState($arControlsLast[2],$GUI_ENABLE)
	endif
	ReDim $arScrollControls[UBound($arScrollControls)+1]
	local $arControls[5],$iActEntry=UBound($arScrollControls)-1,$iTopSpace=5+$iScrollControllHeightSpace+($iActEntry*($iScrollControlHeight+$iScrollControllHeightSpace))
	$arControls[0]=GUICtrlCreateButton("X",5+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,20,$iScrollControlHeight)
	$arControls[1]=GUICtrlCreateButton(ChrW(8679),30+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,20,$iScrollControlHeight)
	if UBound($arScrollControls)=1 then GUICtrlSetState(-1,$GUI_DISABLE)
	GUICtrlSetFont(-1,20)
	$arControls[2]=GUICtrlCreateButton(ChrW(8681),55+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,20,$iScrollControlHeight)
	GUICtrlSetFont(-1,20)
	GUICtrlSetState(-1,$GUI_DISABLE)
	$arControls[3]=GUICtrlCreateInput("",80+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,$iEntryColWidth,$iScrollControlHeight)
	GUICtrlSendMsg(-1, 0x1501, 0, "Name")
	GUICtrlSetFont(-1,$iScrollControlHeight-15)
	$arControls[4]=GUICtrlCreateInput("",80+$iEntryColWidth+$iScrollControllWidthSpace+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled,$iEntryColWidth,$iScrollControlHeight)
	GUICtrlSendMsg(-1, 0x1501, 0, "Nicht zugeordnet")
	GUICtrlSetFont(-1,$iScrollControlHeight-15)
	GUICtrlSetState(-1,$GUI_DISABLE)
	$arScrollControls[$iActEntry]=$arControls
	_setVertScroll()
	_setHoriScroll()
EndFunc


Func _switchControl($i,$j)
	local $tmpI=$arScrollControls[$i]
	local $tmpJ=$arScrollControls[$j]
	$arScrollControls[$i]=$tmpJ
	$arScrollControls[$j]=$tmpI
	$iTopSpaceJ=5+$iScrollControllHeightSpace+($i*($iScrollControlHeight+$iScrollControllHeightSpace))
	for $k=0 to UBound($tmpJ)-1 step 1
		ControlMove($hScrollGui,"",$tmpJ[$k],ControlGetPos($hScrollGui,"",$tmpJ[$k])[0]-7+$iLastHorizontalScrolled,$iTopSpaceJ+$iLastVerticalScrolled)
	next
	$iTopSpaceI=5+$iScrollControllHeightSpace+($j*($iScrollControlHeight+$iScrollControllHeightSpace))
	for $k=0 to UBound($tmpI)-1 step 1
		ControlMove($hScrollGui,"",$tmpI[$k],ControlGetPos($hScrollGui,"",$tmpI[$k])[0]-7+$iLastHorizontalScrolled,$iTopSpaceI+$iLastVerticalScrolled)
	next
	if $i=0 then
		GUICtrlSetState($tmpI[1],$GUI_ENABLE)
		GUICtrlSetState($tmpJ[1],$GUI_DISABLE)
	endif
	if $j=0 then
		GUICtrlSetState($tmpJ[1],$GUI_ENABLE)
		GUICtrlSetState($tmpI[1],$GUI_DISABLE)
	endif
	if $i=UBound($arScrollControls)-1 then
		GUICtrlSetState($tmpI[2],$GUI_ENABLE)
		GUICtrlSetState($tmpJ[2],$GUI_DISABLE)
	endif
	if $j=UBound($arScrollControls)-1 then
		GUICtrlSetState($tmpJ[2],$GUI_ENABLE)
		GUICtrlSetState($tmpI[2],$GUI_DISABLE)
	endif
	_WinAPI_RedrawWindow($hScrollGui)
EndFunc


Func _removeControl($i)
	local $tmp=$arScrollControls[$i]
	for $j=0 to UBound($tmp)-1 step 1
		GUICtrlDelete($tmp[$j])
	next
	for $j=$i+1 to UBound($arScrollControls)-1 step 1
		$arScrollControls[$j-1]=$arScrollControls[$j]
		local $tmp=$arScrollControls[$j-1]
		$iTopSpace=5+$iScrollControllHeightSpace+(($j-1)*($iScrollControlHeight+$iScrollControllHeightSpace))
		for $k=0 to UBound($tmp)-1 step 1
			ControlMove($hScrollGui,"",$tmp[$k],ControlGetPos($hScrollGui,"",$tmp[$k])[0]-7+$iLastHorizontalScrolled,$iTopSpace+$iLastVerticalScrolled)
		next
	next
	ReDim $arScrollControls[UBound($arScrollControls)-1]
	_setVertScroll()
	_WinAPI_RedrawWindow($hScrollGui)
EndFunc


Func _setVertScroll()
	local $elements=UBound($arScrollControls)
	local $clientHeight=WinGetPos($hScrollGui)[3]
	local $itemHeight=($iScrollControlHeight+$iScrollControllHeightSpace)
	$iLastItemHeigt=$itemHeight
	Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE,$SIF_DISABLENOSCROLL))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", $elements)
    DllStructSetData($tSCROLLINFO, "nPage", int($clientHeight/$itemHeight))
    _GUIScrollBars_SetScrollInfo(HWnd($hScrollGui), $SB_VERT, $tSCROLLINFO)
EndFunc


Func _setHoriScroll()
	local $elements=0
	for $i=0 to UBound($arScrollControls)-1 step 1
		if $elements<UBound($arScrollControls[$i]) then
			$elements=UBound($arScrollControls[$i])
		endif
	next
	local $clientWidth=WinGetPos($hScrollGui)[2]
	local $spaces=$iScrollControllWidthSpace*($elements-3)
	local $combos=$iEntryColWidth*Int(($elements-4)/2+0.5)
	local $opers=$iEntryOperWidth*(Int(($elements-4)/2))
	local $itemWidth=(80+$iEntryColWidth+$spaces+$combos+$opers)/$elements
	$iLastItemWidth=$itemWidth
	Local $tSCROLLINFO = DllStructCreate($tagSCROLLINFO)
    DllStructSetData($tSCROLLINFO, "fMask", BitOR($SIF_RANGE, $SIF_PAGE,$SIF_DISABLENOSCROLL))
    DllStructSetData($tSCROLLINFO, "nMin", 0)
    DllStructSetData($tSCROLLINFO, "nMax", $elements)
    DllStructSetData($tSCROLLINFO, "nPage", int($clientWidth/$itemWidth))
    _GUIScrollBars_SetScrollInfo(HWnd($hScrollGui), $SB_HORZ, $tSCROLLINFO)
EndFunc


Func _getColString()
	local $string=""
	for $i=0 to UBound($arCols)-1 step 1
		$string&=$arCols[$i][0]
		if $i<>UBound($arCols)-1 then
			$string&="|"
		endif
	next
	return $string
EndFunc


Func _getOperString()
	local $string=""
	for $i=0 to UBound($arOper)-1 step 1
		$string&=$arOper[$i]
		if $i<>UBound($arOper)-1 then
			$string&="|"
		endif
	next
	return $string
EndFunc


Func WM_SIZE($hWnd, $Msg, $wParam, $lParam)
	_setVertScroll()
	_setHoriScroll()
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_SIZE


Func WM_HSCROLL($hWnd, $Msg, $wParam, $lParam)
	Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
	local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_HORZ)
    $iMin = DllStructGetData($tSCROLLINFO, "nMin")
    $iMax = DllStructGetData($tSCROLLINFO, "nMax")
    $iPage = DllStructGetData($tSCROLLINFO, "nPage")
    $iPosX = DllStructGetData($tSCROLLINFO, "nPos")
    $iPos = $iPosX
    $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    #forceref $iMin, $iMax
    Switch $iScrollCode
        Case $SB_LINELEFT ; user clicked left arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)
        Case $SB_LINERIGHT ; user clicked right arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)
        Case $SB_PAGELEFT ; user clicked the scroll bar shaft left of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)
        Case $SB_PAGERIGHT ; user clicked the scroll bar shaft right of the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)
        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
    EndSwitch
    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_HORZ, $tSCROLLINFO)
    $iPos = DllStructGetData($tSCROLLINFO, "nPos")
	If ($iPos <> $iPosX) Then
		_GUIScrollBars_ScrollWindow($hWnd, $iLastItemWidth * ($iPosX - $iPos), 0)
		$iLastHorizontalScrolled+=$iLastItemWidth * ($iPosX - $iPos)
	endif
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_HSCROLL


Func WM_VSCROLL($hWnd, $Msg, $wParam, $lParam)
	Local $iScrollCode = BitAND($wParam, 0x0000FFFF)
	Local $tSCROLLINFO = _GUIScrollBars_GetScrollInfoEx($hWnd, $SB_VERT)
    $iMin = DllStructGetData($tSCROLLINFO, "nMin")
    $iMax = DllStructGetData($tSCROLLINFO, "nMax")
    $iPage = DllStructGetData($tSCROLLINFO, "nPage")
    $iPosY = DllStructGetData($tSCROLLINFO, "nPos")
    $iPos = $iPosY
    $iTrackPos = DllStructGetData($tSCROLLINFO, "nTrackPos")
    Switch $iScrollCode
        Case $SB_TOP ; user clicked the HOME keyboard key
            DllStructSetData($tSCROLLINFO, "nPos", $iMin)
        Case $SB_BOTTOM ; user clicked the END keyboard key
			DllStructSetData($tSCROLLINFO, "nPos", $iMax)
        Case $SB_LINEUP ; user clicked the top arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - 1)
        Case $SB_LINEDOWN ; user clicked the bottom arrow
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + 1)
        Case $SB_PAGEUP ; user clicked the scroll bar shaft above the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos - $iPage)
        Case $SB_PAGEDOWN ; user clicked the scroll bar shaft below the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iPos + $iPage)
        Case $SB_THUMBTRACK ; user dragged the scroll box
            DllStructSetData($tSCROLLINFO, "nPos", $iTrackPos)
    EndSwitch
    DllStructSetData($tSCROLLINFO, "fMask", $SIF_POS)
    _GUIScrollBars_SetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    _GUIScrollBars_GetScrollInfo($hWnd, $SB_VERT, $tSCROLLINFO)
    $iPos = DllStructGetData($tSCROLLINFO, "nPos")
    If ($iPos <> $iPosY) Then
        _GUIScrollBars_ScrollWindow($hWnd, 0, $iLastItemHeigt * ($iPosY - $iPos))
		$iLastVerticalScrolled+=$iLastItemHeigt * ($iPosY - $iPos)
        $iPosY = $iPos
    EndIf
	Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_VSCROLL

Alles anzeigen

MfG Kanashius

shakoon

Ok xD da blick ich jetzt garnichtmehr durch
Habe es mal ausprobiert sieht schon ganz gut aus Aber z.B. Name 2 wichtelt für Name 2. Das darf ja eigentlich nicht sein Das man sich selbst wichtelt

**Kanashius**

Ah ja, war noch ein Fehler in der Schleife. Habs oben korrigiert.

Hier auch noch ein Beispiel mit der Listview (erfordert meine ListView UDF (ist im Anhang)):

AutoIt

#include <GuiListView.au3>
#include "ListViewEditInput.au3"
Opt("GuiOnEventMode",1)


global $iWidth=800,$iHeight=600
$hGui=GUICreate("ListviewEditExample",$iWidth,$iHeight,-1,-1)
$hListView=GUICtrlCreateListView("Person|wichtelt für",5,5,$iWidth-20,$iHeight-45)
GUICtrlCreateButton("Zuteilen",$iWidth-100,$iHeight-30,80,25)
GUICtrlSetOnEvent(-1,"_calculatePartners")
GUICtrlCreateButton("Neue Person",5,$iHeight-30,100,25)
GUICtrlSetOnEvent(-1,"_addRow")
GUICtrlCreateButton("Lösche ausgewählte Person",110,$iHeight-30,200,25)
GUICtrlSetOnEvent(-1,"_delRow")
;Starten des Editierens (Label erstellen und die MessageFunktionen aktivieren
;Startup Editing
__ListViewEditInput_StartUp($hGui)
;Listview hinzufügen (Nur Spalte 0 darf bearbeitet werden) (Doppelklick)
__ListViewEditInput_AddListview($hGui,$hListView,"0")
;ESC zum abbrechen und ENTER zum abschicken initialisieren
__ListViewEditInput_InitializeKeys($hGui)
GUISetOnEvent($GUI_EVENT_CLOSE,"_close")
GUISetState(@SW_SHOW)


while 1
WEnd


Func _close()
	exit
EndFunc


Func _addRow()
	GUICtrlCreateListViewItem("",$hListView)
	GUICtrlSetBkColor(-1,0xDDDDDD)
EndFunc


Func _delRow()
	_GUICtrlListView_DeleteItemsSelected($hListView)
EndFunc


Func _calculatePartners()
	for $i=0 to _GUICtrlListView_GetItemCount($hListView)-1 step 1
		_GUICtrlListView_SetItemText($hListView,$i,"",1)
	next
	for $i=0 to _GUICtrlListView_GetItemCount($hListView)-1 step 1
		$iNr=Random(0,_GUICtrlListView_GetItemCount($hListView)-1,1)
		while _GUICtrlListView_GetItemText($hListView,$iNr,1)<>""
			$iNr+=1
			if $iNr>_GUICtrlListView_GetItemCount($hListView)-1 then
				$iNr=0
			endif
		WEnd
		_GUICtrlListView_SetItemText($hListView,$iNr,_GUICtrlListView_GetItemText($hListView,$i,0),1)
	next
	for $i=0 to _GUICtrlListView_GetItemCount($hListView)-1 step 1
		if _GUICtrlListView_GetItemText($hListView,$i,0)=_GUICtrlListView_GetItemText($hListView,$i,1) then
			if $i<_GUICtrlListView_GetItemCount($hListView)-1 then
				local $tmp=_GUICtrlListView_GetItemText($hListView,$i,0)
				_GUICtrlListView_SetItemText($hListView,$i,_GUICtrlListView_GetItemText($hListView,$i+1,1),1)
				_GUICtrlListView_SetItemText($hListView,$i+1,$tmp,1)
			else
				local $tmp=_GUICtrlListView_GetItemText($hListView,$i,0)
				_GUICtrlListView_SetItemText($hListView,$i,_GUICtrlListView_GetItemText($hListView,0,1),1)
				_GUICtrlListView_SetItemText($hListView,0,$tmp,1)
			endif
		endif
	next
EndFunc

Alles anzeigen

MfG Kanashius

shakoon

Vielen vielen dank Noch klingt das alles Spanisch für mich aber ich versuche jetzt mal den Code zu verstehen
Danke danke danke

**Oscar**

Dann kann es ja nicht schaden, wenn Du noch eine Lösung bekommst.
Hier mal meine Variante:

AutoIt

#include <GUIConstantsEx.au3>
Global $aWichtelnamen = ['Andreas', 'Barbara', 'Cornelia', 'Doris', 'Ernst', 'Fred', 'Gustav', 'Hilde']


Global $iCount = UBound($aWichtelnamen), $aidWichtellabel[$iCount][2]


Opt('GUIOnEventMode', 1)


Global $hGui = GUICreate('Wichtelgenerator', 420, 70 + $iCount * 30)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')


For $i = 0 To $iCount - 1
	$aidWichtellabel[$i][0] = GUICtrlCreateLabel($aWichtelnamen[$i], 20, 20 + $i * 30, 160, 25)
	GUICtrlSetFont(-1, 16, 400, 0, 'Times New Roman')
	GUICtrlSetBkColor(-1, 0xAAAAFF)
	GUICtrlCreateLabel('->', 190, 20 + $i * 30, 160, 25)
	GUICtrlSetFont(-1, 16, 800, 0, 'Courier New')
	$aidWichtellabel[$i][1] = GUICtrlCreateLabel('', 235, 20 + $i * 30, 160, 25)
	GUICtrlSetFont(-1, 16, 400, 0, 'Times New Roman')
	GUICtrlSetBkColor(-1, 0xFFDDAA)
Next
GUICtrlCreateButton('Wichteln', 150, 30 + $iCount * 30, 120, 25)
GUICtrlSetOnEvent(-1, '_Wichteln')


GUISetState(@SW_SHOW, $hGui)
WinWaitClose($hGui)
Exit


Func _Wichteln()
	Local $aTmp = $aWichtelnamen, $iRnd = 0, $iErr = 0, $iRepeat = 0
	SRandom(@MSEC)
	For $i = 0 To $iCount - 1
		GUICtrlSetData($aidWichtellabel[$i][1], '')
	Next
	Do
		$iRepeat = 0
		For $i = 0 To $iCount - 1
			$iErr = 0
			While True
				$iRnd = Random(0, $iCount - 1 - $i, 1)
				If $aWichtelnamen[$i] <> $aTmp[$iRnd] Then ExitLoop
				$iErr += 1
				If $iErr > $iCount - $i Then
					$iRepeat = 1
					ExitLoop
				EndIf
			WEnd
			GUICtrlSetData($aidWichtellabel[$i][1], $aTmp[$iRnd])
			_Switch($aTmp[$iRnd], $aTmp[$iCount - 1 - $i])
		Next
	Until Not $iRepeat
EndFunc   ;==>_Wichteln


Func _Switch(ByRef $a, ByRef $b)
	Local $c = $a
	$a = $b
	$b = $c
EndFunc   ;==>_Switch


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui

Alles anzeigen

**Andy**

Ihr seid ja gemein!
Bei jeder eurer Lösungen wird vermieden, dass man sein eigenes Geschenk wichtelt! Dabei ist das doch das eigentlich Interessante an der Sache!

http://www.wichteln.de/WichtelnBeschreibung.php

**Oscar**

Das eigentlich programmiertechnisch Interessante war dabei, dass es nicht immer aufgeht, wenn man die Namen der Reihe nach zuweist. Jetzt (im Nachhinein) ist mir klar, warum. Aber erstmal wunderte ich mich.
Wenn (in meinem Beispiel) für den letzten Namen (Hilde) nur noch Hilde im Auslosungs-"Topf" ist. Deshalb habe ich um das Ganze noch eine Repeat-Schleife gelegt, um in dem Fall eine neue Auslosung zu starten.
Wenn man sich auch selbst "bewichteln" kann, dann ist die Lösung viel einfacher.
Aber so hatte das Script für mich etwas Interessantes als Nebenprodukt gebracht.

**autoBert**

Und noch eine einfache Lösung:

AutoIt

#include <GUIConstantsEx.au3>
#include <Array.au3>


Global $aWichtelnamen = ['Andreas', 'Barbara', 'Cornelia', 'Doris', 'Ernst', 'Fred', 'Gustav', 'Hilde']


Global $iCount = UBound($aWichtelnamen), $aidWichtellabel[$iCount][2]


Opt('GUIOnEventMode', 1)


Global $hGui = GUICreate('Wichtelgenerator', 420, 70 + $iCount * 30)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')


For $i = 0 To $iCount - 1
	$aidWichtellabel[$i][0] = GUICtrlCreateLabel($aWichtelnamen[$i], 20, 20 + $i * 30, 160, 25)
	GUICtrlSetFont(-1, 16, 400, 0, 'Times New Roman')
	GUICtrlSetBkColor(-1, 0xAAAAFF)
	GUICtrlCreateLabel('->', 190, 20 + $i * 30, 160, 25)
	GUICtrlSetFont(-1, 16, 800, 0, 'Courier New')
	$aidWichtellabel[$i][1] = GUICtrlCreateLabel('', 235, 20 + $i * 30, 160, 25)
	GUICtrlSetFont(-1, 16, 400, 0, 'Times New Roman')
	GUICtrlSetBkColor(-1, 0xFFDDAA)
Next
GUICtrlCreateButton('Wichteln', 150, 30 + $iCount * 30, 120, 25)
GUICtrlSetOnEvent(-1, '_Wichteln')


GUISetState(@SW_SHOW, $hGui)
WinWaitClose($hGui)
Exit


Func _Wichteln()
	Local $aTmp = $aWichtelnamen, $bOK
	For $i = 0 To $iCount - 1
		GUICtrlSetData($aidWichtellabel[$i][1], '')
	Next
	Do
		_ArrayShuffle($aTmp)	;mischen
		$bOK=True
		For $i=0 To UBound($aTmp) -1
			If $aTmp[$i]=$aWichtelnamen[$i] Then	
				;shit jemand wichtelt sich selbst
				$bOK=False
				ExitLoop
			EndIf
		Next
	Until $bOK
	For $i=0 To UBound($aTmp) -1
		GUICtrlSetData($aidWichtellabel[$i][1], $aTmp[$i])
	Next
EndFunc   ;==>_Wichteln


Func _Switch(ByRef $a, ByRef $b)
	Local $c = $a
	$a = $b
	$b = $c
EndFunc   ;==>_Switch


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui

Alles anzeigen

ist Oscars Skript mit einer anderen Wichtelroutine. Die Duplikate ($aTmp) werden solange gemischt, bis sich niemand selbst gezogen hat.