Button Farbe Ändern wenn ein Prozess läuft

SCCSSF

Hallo,

stehe gerade mal wieder auf dem Schlauch um ein Problem zu lösen.

Ich muss ein kleines Programm schreiben was Anzeigt ob ein Prozess läuft.

Basis ist ein altes Programm, was ich mal geschrieben habe.

Was soll passieren der Button "PN4000" soll Grün sein wenn der Prozess läuft.

Läuft er nicht soll er Rot sein.

Es ist mir Klar das es mit if ProcessExists("blablaexe") geht.

Allerdings wie baue ich das ganze in meine GUI sinnvoll ein.

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)


$Form1 = GUICreate("PN4000", 307, 150, 192, 124)
$Setting_Menu = GUICtrlCreateMenu("Menü")
$Setting_exit = GUICtrlCreateMenuItem("Ende", $Setting_Menu)
GUICtrlSetOnEvent(-1,"_Exit")
$helpmenu = GUICtrlCreateMenu("?")
GUICtrlSetOnEvent(-1,"_Help")
$Info = GUICtrlCreateMenuItem("Info",$helpmenu)
GUICtrlSetOnEvent(-1,"_showInfo")
$Kommen = GUICtrlCreateButton("PN4000", 32, 8, 113, 113)
GUICtrlSetFont(-1, 18, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x00FF00)
$Gehen = GUICtrlCreateButton("Reset", 171, 8, 113, 113)
GUICtrlSetFont(-1, 18, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x4452F0)
GUICtrlSetOnEvent(-1,"_RESET")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')
TraySetOnEvent( -7, '_Restore')




While sleep(100)
WEnd


Func _showInfo()
            MsgBox (0,"Info","Version 0.1 "&@CRLF&"Stand 31.10.2016")
EndFunc


Func _Exit()
    Exit
EndFunc


Func _Minimize()
    TraySetState(1)
    GUISetState(@SW_HIDE)
EndFunc


Func _Restore()
    TraySetState(2)
    GUISetState(@SW_SHOW)
EndFunc


Func _RESET() ;Hier passiert was wenn der Button gedrückt wird
Run('Notepad.exe')
;ProcessClose("pn4.exe")
;RunAsWait("abc","neu","12346",0,@ComSpec  &  " /c " &'net stop "Autostart"',"",@SW_HIDE);Sleep (1000)
;RunAsWait("abc","neu","123456",0,@ComSpec  &  " /c " &'net start "Autostart"',"",@SW_HIDE) 
EndFunc

Alles anzeigen

Danke für die Tipps.

Gruß

Steffen

**Andy**

hi,
du musst doch nur die Abfrage in die Schleife packen

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)


$Form1 = GUICreate("PN4000", 307, 150, 192, 124)
$Setting_Menu = GUICtrlCreateMenu("Menü")
$Setting_exit = GUICtrlCreateMenuItem("Ende", $Setting_Menu)
GUICtrlSetOnEvent(-1, "_Exit")
$helpmenu = GUICtrlCreateMenu("?")
;GUICtrlSetOnEvent(-1,"_Help")
$Info = GUICtrlCreateMenuItem("Info", $helpmenu)
GUICtrlSetOnEvent(-1, "_showInfo")
$Kommen = GUICtrlCreateButton("AUS", 32, 8, 113, 113)
GUICtrlSetFont(-1, 18, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x0000FF)
$Gehen = GUICtrlCreateButton("Reset", 171, 8, 113, 113)
GUICtrlSetFont(-1, 18, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x4452F0)
GUICtrlSetOnEvent(-1, "_RESET")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')
TraySetOnEvent(-7, '_Restore')




While Sleep(100)


    If ProcessExists("notepad.exe") Then
        GUICtrlSetData($Kommen, "läuft")
        GUICtrlSetBkColor($Kommen, 0x00FF00)
    Else
        GUICtrlSetData($Kommen, "läuft" & @CRLF & "nicht")
        GUICtrlSetBkColor($Kommen, 0xFF0000)
    EndIf




WEnd


Func _showInfo()
    MsgBox(0, "Info", "Version 0.1 " & @CRLF & "Stand 31.10.2016")
EndFunc                                ;==>_showInfo


Func _Exit()
    Exit
EndFunc                                ;==>_Exit


Func _Minimize()
    TraySetState(1)
    GUISetState(@SW_HIDE)
EndFunc                                ;==>_Minimize


Func _Restore()
    TraySetState(2)
    GUISetState(@SW_SHOW)
EndFunc                                ;==>_Restore


Func _RESET()                          ;Hier passiert was wenn der Button gedrückt wird
    Run('Notepad.exe')
    ;ProcessClose("pn4.exe")
    ;RunAsWait("abc","neu","12346",0,@ComSpec  &  " /c " &'net stop "Autostart"',"",@SW_HIDE);Sleep (1000)
    ;RunAsWait("abc","neu","123456",0,@ComSpec  &  " /c " &'net start "Autostart"',"",@SW_HIDE)
EndFunc                                ;==>_RESET

Alles anzeigen

SCCSSF

Danke manchmal ist man blöd.

AutoMit

Das ist ein interessantes Skript.

Mir ist aufgefallen, dass der Button (wahrscheinlich durch die Aktualisierung) flackert (die Schrift springt), unabhängig davon, ob der Button grün oder rot ist.

Wie sieht eine Lösung aus, bei der der Button (die Schrift) nicht flackert?

Zeitriss

Hi,

Einfach nur dann aktualisieren, wenn sich der Wert seit der letzten überprüfung geändert hat.
Dazu muss man nur den letzten Wert von ProcessExists nehmen und diesen mit dem aktuellen vergleichen.

z.B. so:

AutoIt

Global $bProcessExists, $bLastProcessExists = True
While Sleep(100)
   $bProcessExists = ProcessExists("notepad.exe")


   If Not ($bProcessExists = $bLastProcessExists) Then
	  If $bProcessExists Then
		 GUICtrlSetData($Kommen, "läuft")
		 GUICtrlSetBkColor($Kommen, 0x00FF00)
	  Else
		 GUICtrlSetData($Kommen, "läuft" & @CRLF & "nicht")
		 GUICtrlSetBkColor($Kommen, 0xFF0000)
	  EndIf
	  $bLastProcessExists = True
   EndIf
WEnd

Alles anzeigen

oder so:

AutoIt

While sleep(100)
   CheckProcess()
WEnd
Func CheckProcess()
   Local $bExist = ProcessExists("notepad.exe")
   Local Static $bLast = Not $bExist
   If Not ($bExist = $bLast) Then
	  If $bExist Then
		GUICtrlSetData($Kommen, "läuft")
		GUICtrlSetBkColor($Kommen, 0x00FF00)
	  Else
		GUICtrlSetData($Kommen, "läuft" & @CRLF & "nicht")
		GUICtrlSetBkColor($Kommen, 0xFF0000)
	  EndIf
	  $bLast = $bExist
   EndIf
EndFunc

Alles anzeigen

mfg
Zeitriss

**Bitnugger**

So in etwa...

ButtonColor

AutoIt

;-- TIME_STAMP   2016-11-07 19:36:59


#Region    ;************ Includes ************
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
;~ #include <GuiStatusBar.au3>;~~~
;~ #include <StaticConstants.au3>;~~~
;~ #include <EditConstants.au3>;~~~
#include <Array.au3>
#EndRegion ;************ Includes ************


Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)


Global $g_aPIDs[0]	; NotePad PIDs


Global $hGUI = GUICreate("PN4000", 670, 140, 192, 124)


Global $idSetting_Menu = GUICtrlCreateMenu("Menü")


Global $idSetting_Exit = GUICtrlCreateMenuItem("Ende", $idSetting_Menu)
GUICtrlSetOnEvent(-1, "_Exit")


Global $idHelpMenu = GUICtrlCreateMenu("?")
;GUICtrlSetOnEvent(-1,"_Help")


Global $idInfo = GUICtrlCreateMenuItem("Info", $idhelpmenu)
GUICtrlSetOnEvent(-1, "_ShowInfo")


Global $idAccelKeys = GUICtrlCreateLabel('ESC = Exit    F2 = Start NotePad    F3 = Kill NotePad', 90, 5, 600, 26)
GUICtrlSetFont(-1, 14, 800, 0, "@Arial Unicode MS")


Global $idNotRunning = GUICtrlCreateButton("Not Running", 32, 50, 300, 42, -1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 14, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0xFF0000)


Global $idIsRunning  = GUICtrlCreateButton("Is Running (" & UBound($g_aPIDs) & ")", 32, 50, 300, 42, -1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 14, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x00FF00)
GUICtrlSetState(-1, BitOR($GUI_HIDE, $GUI_DISABLE))


Global $idStart = GUICtrlCreateButton("Reset", 340, 50, 300, 42, -1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 14, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x4452F0)
GUICtrlSetOnEvent(-1, "_RESET")


Global $id_Kill = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "_Kill")


Global $aAccelKeys[3][2] = [["{ESC}", $idSetting_Exit], ["{F2}", $idStart], ["{F3}", $id_Kill]]
GUISetAccelerators($aAccelKeys)


GUISetState(@SW_SHOW)


GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')
TraySetOnEvent(-7, '_Restore')


Global $iPID = -1
While Sleep(100)
	$iPID = ProcessWait("notepad.exe", 1)
	Switch $iPID
		Case  -1
			ContinueLoop
		Case Else
			GUICtrlSetState($idNotRunning, BitOR($GUI_HIDE, $GUI_DISABLE))
			GUICtrlSetState($idIsRunning, BitOR($GUI_SHOW, $GUI_ENABLE))
			ProcessWaitClose("notepad.exe")
			$iPID = -1
			GUICtrlSetState($idIsRunning, BitOR($GUI_HIDE, $GUI_DISABLE))
			GUICtrlSetState($idNotRunning, BitOR($GUI_SHOW, $GUI_ENABLE))
	EndSwitch
WEnd


Func _ShowInfo()
    MsgBox(0, "Info", "Version 0.1 " & @CRLF & "Stand 31.10.2016")
EndFunc  ;==>_ShowInfo


Func _Exit()
	For $i = 0 To UBound($g_aPIDs) -1 Step 1
		ProcessClose($g_aPIDs[$i])
    Next
	Exit
EndFunc  ;==>_Exit


Func _Minimize()
    TraySetState(1)
    GUISetState(@SW_HIDE)
EndFunc  ;==>_Minimize


Func _Restore()
    TraySetState(2)
    GUISetState(@SW_SHOW)
EndFunc  ;==>_Restore


Func _RESET()                          ;Hier passiert was wenn der Button gedrückt wird
    _ArrayAdd($g_aPIDs, Run('Notepad.exe'))
	GUICtrlSetData($idIsRunning, "Is Running (" & UBound($g_aPIDs) & ")")
	WinActivate($hGUI)
    ;ProcessClose("pn4.exe")
    ;RunAsWait("abc","neu","12346",0,@ComSpec  &  " /c " &'net stop "Autostart"',"",@SW_HIDE);Sleep (1000)
    ;RunAsWait("abc","neu","123456",0,@ComSpec  &  " /c " &'net start "Autostart"',"",@SW_HIDE)
EndFunc  ;==>_RESET


Func _Kill()                          ;Hier passiert was wenn F3 gedrückt wird
    ProcessClose('Notepad.exe')
EndFunc  ;==>_Kill

Alles anzeigen

SCCSSF

Zitat von Bitnugger

So in etwa..

Das Flackert bei mir richtig viel! Auch das Hochzählen ist nicht in Ordnung oder wolltest du wirklich die einzeln Starts zählen?

Natürlich sehen deine Buttons schöner aus

Und ja ich hatte noch in meinem Skript Fehler

Zitat von Zeitriss

Hi,

Einfach nur dann aktualisieren, wenn sich der Wert seit der letzten überprüfung geändert hat.
Dazu muss man nur den letzten Wert von ProcessExists nehmen und diesen mit dem aktuellen vergleichen.

mfg
Zeitriss

Dei Skript habe ich heute auch getestet.
Oberes geht flackert aber auch.
Unteres geht nicht zeigt nicht das richtige an.

Was mir noch aufgefallen ist @Andy

AutoIt

GUICtrlSetData($Kommen, "läuft" & @CRLF & "nicht")

Leider wird @CRLF wird nicht beachtet. Habe auch noch nicht raus gefunden wie ich es hin bekomme.

Ich habe in meine Schleife noch eine Pause von 1000 eingefügt, dann ist das Flackern nicht so schlimm. Programm läuft bei mir auf einem Rechner den ich nur per VNC Aufrufe.

Hier noch meine Aktuelle Version.

Spoiler anzeigen

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <MsgBoxConstants.au3>


Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)


$Form1 = GUICreate("Serverüberwachung", 348, 155, 192, 124)
$Setting_Menu = GUICtrlCreateMenu("Menü")
$Setting_exit = GUICtrlCreateMenuItem("Ende", $Setting_Menu)
GUICtrlSetOnEvent(-1,"_Exit")
$helpmenu = GUICtrlCreateMenu("?")
$Info = GUICtrlCreateMenuItem("Version",$helpmenu)
GUICtrlSetOnEvent(-1,"_showInfo")
$wachen = GUICtrlCreateButton("", 8, 16, 100, 100)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x00FF00)
$reset = GUICtrlCreateButton("Reset-Start", 124, 16, 100, 100)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x4452F0)
GUICtrlSetOnEvent(-1,"_RESET")
$stopen = GUICtrlCreateButton("STOP", 240, 16, 100, 100)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0xe9f01a)
GUICtrlSetOnEvent(-1,"_STOP")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')
TraySetOnEvent( -7, '_Restore')




While sleep(100)
	If ProcessExists("notepad.exe") Then
        GUICtrlSetData($wachen, "läuft")
        GUICtrlSetBkColor($wachen, 0x00FF00)
    Else
        GUICtrlSetData($wachen, "läuft nicht")
        GUICtrlSetBkColor($wachen, 0xFF0000)
    EndIf
sleep(1000)
WEnd


Func _showInfo()
            MsgBox (0,"Info","Version 1.3 "&@CRLF&"09.11.2016 SCCSSF")
EndFunc


Func _Exit()
    Exit
EndFunc


Func _Minimize()
    TraySetState(1)
    GUISetState(@SW_HIDE)
EndFunc


Func _Restore()
    TraySetState(2)
    GUISetState(@SW_SHOW)
EndFunc


Func _RESET() ;Hier passiert was wenn der Button gedrückt wird
ProcessClose("notepad.exe")
RunAsWait("Benutzer","Domain","Passwort",0,@ComSpec  &  " /c " &'net stop "Test_Autostart"',"",@SW_HIDE)
RunAsWait("Benutzer","Domain","Passwort",0,@ComSpec  &  " /c " &'net start "Test_Autostart"',"",@SW_HIDE) 
EndFunc


Func _STOP() ;Hier passiert was wenn der Button gedrückt wird
ProcessClose("notepad.exe")
RunAsWait("Benutzer","Domain","Passwort",0,@ComSpec  &  " /c " &'net stop "Test_Autostart"',"",@SW_HIDE)
EndFunc

Alles anzeigen

Vielleicht will noch jemand die Lösung finden.

**Oscar**

Wenn Du das flackern verhindern willst, dann benutze einfach eine zusätzliche Variable, um abzufragen, ob der Status bereits geändert wurde:

AutoIt

Global $iExistCheck = True
While Sleep(10)
	If ProcessExists("notepad.exe") Then
		If Not $iExistCheck Then
			$iExistCheck = True
			GUICtrlSetData($wachen, "läuft")
			GUICtrlSetBkColor($wachen, 0x00FF00)
		EndIf
	Else
		If $iExistCheck Then
			$iExistCheck = False
			GUICtrlSetData($wachen, "läuft nicht")
			GUICtrlSetBkColor($wachen, 0xFF0000)
		EndIf
	EndIf
WEnd

Alles anzeigen

Dann brauchst Du den zusätzlichen Sekunden-Sleep nicht und kannst sogar den Sleep in der Endlosschleife verringern (falls da noch mehr passieren soll).

SCCSSF

Zitat von Oscar

Wenn Du das flackern verhindern willst, dann benutze einfach eine zusätzliche Variable, um abzufragen, ob der Status bereits geändert wurde:

Dann brauchst Du den zusätzlichen Sekunden-Sleep nicht und kannst sogar den Sleep in der Endlosschleife verringern (falls da noch mehr passieren soll).

Hallo Oskar,

brauche zwar nicht mehr in meiner Schleife aber man kann ja nie wissen.

Spoiler anzeigen

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <MsgBoxConstants.au3>


Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)
Global $iExistCheck = True


$Form1 = GUICreate("Serverüberwachung", 348, 155, 192, 124)
$Setting_Menu = GUICtrlCreateMenu("Menü")
$Setting_exit = GUICtrlCreateMenuItem("Ende", $Setting_Menu)
GUICtrlSetOnEvent(-1,"_Exit")
$helpmenu = GUICtrlCreateMenu("?")
$Info = GUICtrlCreateMenuItem("Version",$helpmenu)
GUICtrlSetOnEvent(-1,"_showInfo")
$wachen = GUICtrlCreateButton("", 8, 16, 100, 100)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x00FF00)
$reset = GUICtrlCreateButton("Reset-Start", 124, 16, 105, 100,1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x4452F0)
GUICtrlSetOnEvent(-1,"_RESET")
$stopen = GUICtrlCreateButton("STOP", 240, 16, 100, 100,1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0xe9f01a)
GUICtrlSetOnEvent(-1,"_STOP")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')
TraySetOnEvent( -7, '_Restore')




While Sleep(10)
	If ProcessExists("notepad.exe") Then
		If Not $iExistCheck Then
			$iExistCheck = True
			GUICtrlSetData($wachen, "läuft")
			GUICtrlSetBkColor($wachen, 0x00FF00)
		EndIf
	Else
		If $iExistCheck Then
			$iExistCheck = False
			GUICtrlSetData($wachen, "läuft nicht")
			GUICtrlSetBkColor($wachen, 0xFF0000)
		EndIf
	EndIf
WEnd


Func _showInfo()
            MsgBox (0,"Info","Version 1.3 "&@CRLF&"Stand 09.11.2016"&@CRLF& "SCCSSF",5)
EndFunc


Func _Exit()
    Exit
EndFunc


Func _Minimize()
    TraySetState(1)
    GUISetState(@SW_HIDE)
EndFunc


Func _Restore()
    TraySetState(2)
    GUISetState(@SW_SHOW)
EndFunc


Func _RESET() ;Hier passiert was wenn der Button gedrückt wird
ProcessClose("notepad.exe")
RunAsWait("user","domain","passwort",0,@ComSpec  &  " /c " &'net stop "Autostart"',"",@SW_HIDE)
RunAsWait(""user","domain","passwort",0,@ComSpec  &  " /c " &'net start "Autostart"',"",@SW_HIDE) 
EndFunc


Func _STOP() ;Hier passiert was wenn der Button gedrückt wird
ProcessClose("notepad.exe")
RunAsWait("user","domain","passwort",0,@ComSpec  &  " /c " &'net stop "Autostart"',"",@SW_HIDE)
EndFunc

Alles anzeigen

Jetzt nur noch die Frage Zweizeiliges Button Beschriftung.

SCCSSF

Hallo,

habe heute noch etwas an meinem Programm geändert.

Jetzt habe ich aber das Problem, dass der Prozess nur überwacht wird, wenn ich nach dem Programmstart die Exe setzte in den Einstellungen.

Was mache ich falsch?
Man erkennt es schön wenn der Button türkis ist.

Habt ihr eine Lösung wie ich das Passwort Verschlüsseln kann in der INI. Klar ist mir das jeder das Programm, rückübersetzten kann und damit die Verschlüsselung rückgängig machen kann.

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>




Opt('GUIOnEventMode', 1)
Opt('TrayOnEventMode', 1)
Opt('TrayMenuMode', 1)
Global $iExistCheck = True
global $Form2,$BNspeichern,$PWspeichern,$DOspeichern,$EXEspeichern,$PRspeichern
DirCreate(@AppDataDir & '\PN\')


$name =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Benutzer", "")
$pw =IniRead(@AppDataDir & "\PN\pn.ini", "User", "PW", "")
$do =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Domaene", "")
$pr =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Prozess", "")
$exe =IniRead(@AppDataDir & "\PN\pn.ini", "User", "EXE", "")
$name =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Benutzer", "")


$Form1 = GUICreate("Serverüberwachung", 348, 155, 192, 124)
$Setting_Menu = GUICtrlCreateMenu("Menü")
$Setting_exit = GUICtrlCreateMenuItem("Ende", $Setting_Menu)
GUICtrlSetOnEvent(-1,"_Exit")
$helpmenu = GUICtrlCreateMenu("?")
$Einstellung = GUICtrlCreateMenuItem("Einstellungen",$helpmenu)
GUICtrlSetOnEvent(-1,"_settings")
$Info = GUICtrlCreateMenuItem("Version",$helpmenu)
GUICtrlSetOnEvent(-1,"_showInfo")
$wachen = GUICtrlCreateButton("", 8, 16, 100, 100)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x00FFFF)
$reset = GUICtrlCreateButton("Reset-Start", 124, 16, 105, 100,1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0x4452F0)
GUICtrlSetOnEvent(-1,"_RESET")
$stopen = GUICtrlCreateButton("STOP", 240, 16, 100, 100,1, $WS_EX_DLGMODALFRAME)
GUICtrlSetFont(-1, 12, 800, 0, "@Arial Unicode MS")
GUICtrlSetBkColor(-1, 0xe9f01a)
GUICtrlSetOnEvent(-1,"_STOP")
GUISetState(@SW_SHOW)
GUISetOnEvent($GUI_EVENT_CLOSE, '_Exit')
GUISetOnEvent($GUI_EVENT_MINIMIZE, '_Minimize')
TraySetOnEvent( -7, '_Restore')






While Sleep(10)
	If ProcessExists($exe) Then
		If Not $iExistCheck Then
			$iExistCheck = True
			GUICtrlSetData($wachen, "läuft")
			GUICtrlSetBkColor($wachen, 0x00FF00)
		EndIf
	Else
		If $iExistCheck Then
			$iExistCheck = False
			GUICtrlSetData($wachen, "läuft nicht")
			GUICtrlSetBkColor($wachen, 0xFF0000)
		EndIf
	EndIf
WEnd


Func _settings()
                GuiSETState(@SW_HIDE, $Form1)
                $name =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Benutzer", "")
                $pw =IniRead(@AppDataDir & "\PN\pn.ini", "User", "PW", "")
				$do =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Domaene", "")
				$pr =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Prozess", "")
				$exe =IniRead(@AppDataDir & "\PN\pn.ini", "User", "EXE", "")
                $Form2 = GUICreate("Einstellungen", 293, 232, 192, 124)
                $Benutzername = GUICtrlCreateLabel("Benutzername", 8, 16, 100, 22)
                GUICtrlSetFont(-1, 10, 800, 0, "@Arial Unicode MS")
				$Passwort = GUICtrlCreateLabel("Passwort", 8, 52, 66, 22)
                GUICtrlSetFont(-1, 10, 800, 0, "@Arial Unicode MS")
				$Domaene = GUICtrlCreateLabel("Domäne", 8, 90, 100, 22)
                GUICtrlSetFont(-1, 10, 800, 0, "@Arial Unicode MS")                
				$Prozess = GUICtrlCreateLabel("Prozess", 8, 128, 100, 22)
                GUICtrlSetFont(-1, 10, 800, 0, "@Arial Unicode MS")                
				$_EXE = GUICtrlCreateLabel("Exe", 8, 164, 100, 22)
                GUICtrlSetFont(-1, 10, 800, 0, "@Arial Unicode MS")                
                $BNspeichern = GUICtrlCreateInput($name, 128, 16, 145, 21)
				$PWspeichern = GUICtrlCreateInput("", 128, 52, 145, 21,$ES_PASSWORD)
				$DOspeichern = GUICtrlCreateInput($do, 128, 90, 145, 21)
				$PRspeichern = GUICtrlCreateInput($pr, 128, 128, 145, 21)
                $EXEspeichern = GUICtrlCreateInput($exe, 128, 164, 145, 21)
				$Speichern1 = GUICtrlCreateButton("Speichern", 128, 202, 65, 25)
                GUICtrlSetOnEvent(-1,"_settings_save")
                $Abbrechen = GUICtrlCreateButton("Abbrechen", 208, 202, 65, 25)
                GUICtrlSetOnEvent(-1,"_settings_end")
                GUISetState(@SW_SHOW)
                GUISetOnEvent($GUI_EVENT_CLOSE, '_settings_end')
EndFunc


Func _settings_save()
                    IniWrite (@AppDataDir & "\PN\pn.ini","User", "Benutzer", GUICtrlRead ($BNspeichern))
                    IniWrite (@AppDataDir & "\PN\pn.ini","User", "Domaene", GUICtrlRead ($DOspeichern))
                    IniWrite (@AppDataDir & "\PN\pn.ini","User", "Prozess", GUICtrlRead ($PRspeichern ))
                    IniWrite (@AppDataDir & "\PN\pn.ini","User", "EXE", GUICtrlRead ($EXEspeichern))
                    if GUICtrlRead ($PWspeichern) <> "" Then
					IniWrite (@AppDataDir & "\PN\pn.ini","User", "PW", GUICtrlRead ($PWspeichern))
					Endif
                    $name =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Benutzer", "")
                    $pw =IniRead(@AppDataDir & "\PN\pn.ini", "User", "PW", "")
                    $do =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Domaene", "")
					$pr =IniRead(@AppDataDir & "\PN\pn.ini", "User", "Prozess", "")
					$exe =IniRead(@AppDataDir & "\PN\pn.ini", "User", "EXE", "")
					GUIDelete($Form2)
                    GUISetState(@SW_SHOW, $Form1)
EndFunc


Func _settings_end()
                    GUIDelete($Form2)
                    GUISetState(@SW_SHOW, $Form1)
EndFunc


Func _showInfo()
            MsgBox (0,"Info","Version 1.4 "&@CRLF&"Stand 10.11.2016"&@CRLF& "Steffen Förster",5)
EndFunc


Func _Exit()
    Exit
EndFunc


Func _Minimize()
    TraySetState(1)
    GUISetState(@SW_HIDE)
EndFunc


Func _Restore()
    TraySetState(2)
    GUISetState(@SW_SHOW)
EndFunc


Func _RESET() ;Hier passiert was wenn der Button gedrückt wird
ProcessClose($exe)
RunAsWait($name,$do,$pw,0,@ComSpec  &  " /c " &"net stop "& $pr,"",@SW_HIDE)
RunAsWait($name,$do,$pw,0,@ComSpec  &  " /c " &"net start "& $pr,"",@SW_HIDE) 
EndFunc


Func _STOP() ;Hier passiert was wenn der Button gedrückt wird
ProcessClose($exe)
RunAsWait($name,$do,$pw,0,@ComSpec  &  " /c " &"net stop " & $pr,"",@SW_HIDE)
EndFunc

Alles anzeigen