Hallo,
evetuell kannst du mit der Outlook-UDF da etwas machen.
_OL_ItemSave sollte helfen
Es gibt kein Drag & Drop. Die UDF automatisiert nicht die GUI sondern über COM wird Outlook direkt angesprochen.
Du solltest daher vorher den Benutzer nach dem Zielverzeichnis fragen und dies dann als Parameter an _OL_ItemSave übergeben.
Du kannst dir dazu ja mal die Funktion _WinAPI_DragAcceptFiles() anschauen und die _FileDragDrop UDF...
Zitat von BitnuggerDu kannst dir dazu ja mal die Funktion _WinAPI_DragAcceptFiles()
Vielen Dank!
Wo finde ich diese Funktion? 
Wo finde ich diese Funktion?
In der AutoIt-Hilfe natürlich... und wenn nicht dort, dann bei MSDN.
Und schau mal hier... vielleicht bringt dich dieses Beispiel ja auf eine Idee, wie du dass umsetzen kannst.
Hier habe ich ein paar Mails aus Thunderbird in meine GUI gezogen und bekomme dann die Namen der Files im Memo angezeigt.
Nachtrag: Du kannst auch gleich mehrere oder alle Mails aus einem Postfach in einem Rutsch auf deine GUI ziehen...
;-- TIME_STAMP 2016-12-04 17:46:26
#include <GUIConstantsEx.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
OnAutoItExitRegister('OnAutoItExit')
; Create GUI
Local $hForm = GUICreate('Test ' & StringReplace(@ScriptName, '.au3', '()'), 400, 422, -1, -1, -1, $WS_EX_TOPMOST)
Local $idCheck = GUICtrlCreateCheckbox('Enable Drag && Drop', 100, 240, 120, 19)
Local $idLabel = GUICtrlCreateLabel('', 100, 25, 200, 200)
Global $g_hLabel = GUICtrlGetHandle($idLabel)
GUICtrlSetBkColor(-1, 0xD3D8EF)
; Create memo control
$g_idMemo = GUICtrlCreateEdit("", 2, 270, 396, 150, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUICtrlSendMsg($g_idMemo, $EM_SETREADONLY, True, 0)
GUICtrlSetBkColor($g_idMemo, 0xFFFFFF)
GUICtrlCreateLabel('Drop here', 175, 193, 50, 14)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
; Allow WM_DROPFILES to be received from lower privileged processes (Windows Vista or later)
#cs
If IsAdmin() Then
_WinAPI_ChangeWindowMessageFilterEx($g_hLabel, $WM_COPYGLOBALDATA, $MSGFLT_ALLOW)
_WinAPI_ChangeWindowMessageFilterEx($g_hLabel, $WM_DROPFILES, $MSGFLT_ALLOW)
EndIf
#ce
; Register label window proc
Global $g_hDll = DllCallbackRegister('_WinProc', 'ptr', 'hwnd;uint;wparam;lparam')
Global $g_pDll = DllCallbackGetPtr($g_hDll)
Global $g_hProc = _WinAPI_SetWindowLong($g_hLabel, $GWL_WNDPROC, $g_pDll)
GUISetState(@SW_SHOW)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $idCheck
_WinAPI_DragAcceptFiles($g_hLabel, GUICtrlRead($idCheck) = $GUI_CHECKED)
EndSwitch
WEnd
Func _WinProc($hWnd, $iMsg, $wParam, $lParam)
Switch $iMsg
Case $WM_DROPFILES
Local $sFileList = _WinAPI_DragQueryFileEx($wParam)
If Not @error Then
MemoWrite('--------------------------------------------------')
For $i = 1 To $sFileList[0]
MemoWrite($sFileList[$i])
Next
EndIf
_WinAPI_DragFinish($wParam)
Return 0
EndSwitch
Return _WinAPI_CallWindowProc($g_hProc, $hWnd, $iMsg, $wParam, $lParam)
EndFunc ;==>_WinProc
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite
Func OnAutoItExit()
_WinAPI_SetWindowLong($g_hLabel, $GWL_WNDPROC, $g_hProc)
DllCallbackFree($g_hDll)
EndFunc ;==>OnAutoItExit