While schleife probleme

BlackHornetttt

Oscar hat mir schon geholfen mit einem script, nur das problem ist ich weiß nicht wie ich es schaffe das 1.exe nur 1 mal geöffnet wird und dann die schleife wieder von neu begonnen wird ?

AutoIt

#include <GUIConstantsEx.au3>
#include <WinAPISys.au3>
Global $hGui = GUICreate('Idle-Time', 300, 200)
Global $idMSec = GUICtrlCreateLabel('0', 10, 10, 280, 20)
GUISetState()
While True
	If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
	$iIdleTime = _WinAPI_GetIdleTime()
	If $iIdleTime > 3000 Then Run("1.exe")
	GUICtrlSetData($idMSec, $iIdleTime)
WEnd

Alles anzeigen

**alpines**

Ganz einfach, du setzt den Idle Timer zurück in dem du am PC interagierst (Maus bewegen) oder du prüfst ob die Letzte erfolgreiche Ausführung von Run("1.exe") mehr als 3000 Sekunden(?) zurückliegt und Idle-Time >= 3000 ist.

BlackHornetttt

ja das schreiben mir schon ur viele aber ich weiß nicht wie ich das schreiben soll kannst du mir das bitte zeigen

**alpines**

Genau so wie ich es gesagt habe, mehr nicht. Wenn du das Script schon hinbekommen hast dann wirst du das auch schaffen.
Mach einfach genau das was ich gesagt habe.

hunterla

Ich glaub er hat es nicht gemacht sondern "oscar"

**autoiter**

Hallo @BlackHornetttt,

Wenn du einen neuen Timer setzt:
Schau dir doch einmal die Hilfe zu dem Befehl TimerInit an. Dort gibt es ein Beispiel. Schau doch mal, ob du das sinnvoll einbauen kannst.

Ansonsten eben die Maus benutzen. Das sollte mit AutoIt doch möglich sein

**Oscar**

Du musst eine Abfrage einbauen, ob der Browser überhaupt läuft und nur dann die Idletime auswerten.
Im übrigen ist es völlig unsinnig, noch ein externes Programm dafür zu verwenden. Einfach alles in einem Script:

AutoIt

#include <GUIConstantsEx.au3>
#include <Process.au3>
#include <StaticConstants.au3>
#include <WinAPISys.au3>


Global $hGui = GUICreate('Idle-Time', 300, 200)
Global $idFirefox = GUICtrlCreateLabel('Firefox: beendet', 10, 10, 200, 20)
GUICtrlSetFont(-1, 14, 400, 0, 'Times New Roman')
Global $idMSec = GUICtrlCreateLabel('0', 210, 10, 80, 20)
GUICtrlSetFont(-1, 14, 400, 0, 'Times New Roman')
Global $idMsg = GUICtrlCreateLabel('Firefox wird in 10 sek. beendet!', 10, 100, 280, 20, $SS_CENTER)
GUICtrlSetFont(-1, 16, 400, 0, 'Times New Roman')
GUICtrlSetState(-1, $GUI_HIDE)
GUISetState()
Global $fExist = False, $iResttime, $iLasttime
Global $sProcess = 'firefox.exe' ; Prozessname dessen Fenster geschlossen werden sollen
Global $iWaitTime = 3000 ; Wartezeit bis Meldung (Zeit in Millisekunden)
Global $iTime2Close = 10000 ; Zeit bis zum beenden der Fenster (Zeit in Millisekunden)
While True
	If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
	If ProcessExists($sProcess) Then
		If Not $fExist Then
			$fExist = True
			GUICtrlSetData($idFirefox, 'Firefox: aktiv')
		EndIf
		$iIdleTime = _WinAPI_GetIdleTime()
		If $iIdleTime > $iWaitTime Then
			If BitAND(GUICtrlGetState($idMsg), $GUI_HIDE) Then GUICtrlSetState($idMsg, $GUI_SHOW)
			$iResttime = Int(($iTime2Close + $iWaitTime - $iIdleTime) / 1000)
			If $iResttime <> $iLasttime Then
				$iLasttime = $iResttime
				GUICtrlSetData($idMsg, 'Firefox wird in ' & $iResttime & ' sek. beendet.')
			EndIf
			If $iIdleTime > $iTime2Close + $iWaitTime Then _WinCloseByProcessname($sProcess)
		Else
			If BitAND(GUICtrlGetState($idMsg), $GUI_SHOW) Then GUICtrlSetState($idMsg, $GUI_HIDE)
		EndIf
		GUICtrlSetData($idMSec, $iIdleTime)
	Else
		If $fExist Then
			$fExist = False
			GUICtrlSetData($idFirefox, 'Firefox: beendet')
			GUICtrlSetState($idMsg, $GUI_HIDE)
		EndIf
	EndIf
WEnd


Func _WinCloseByProcessname($sProcess)
	Local $aList = WinList()
	For $i = 1 To $aList[0][0]
		If _ProcessGetName(WinGetProcess($aList[$i][1])) = $sProcess Then WinClose($aList[$i][1])
	Next
EndFunc

Alles anzeigen