_GDIPlus_ImageCalcDif

Reinhard

Die letzten Zeilen in Post #19 (Ach ja, mit den Befehlszeilen...) habe ich nur deshalb hinzugefügt, weil Mars in Post #12 meinte: "Ich vermute, dass du die 64Bit Version verwendest und der ASM Code ist für 32Bit zusammengesetzt worden". Ich möchte nur zeigen, dass ich dann keine falschen, sondern gar keine Werte erhalte.
Unter Autoit 3.3.18.0 habe ich die neue UDF genutzt, also die, wo es in Zeile 47 'int' statt 'none' heißt.
Unter Autoit 3.3.16.1 habe ich die alte UDF genutzt. Jetzt auch noch mal die neue. Ergebnis: Wie in Post #7.
Welche Werte bekommst du denn angezeigt? Mit der modifizierten 'Test.au3' aus Post #19 ist das schnell getestet.

Gruß

Reinhard

**Mars**

Ich habs jetzt auch nochmal bei mir angeschaut (mit deiner modifizierten Test.au3) -> Ergebnisse sind meines Erachtens nach richtig.

Ansonsten kann ich nur empfehlen ein bisschen selbst zu debuggen. Da der Code vorher funktioniert hat kann es maximal ein "Minifehler" irgendwo sein. Also zumindest eingrenzen was schiefgeht. Weil wenn ich es nicht reproduzieren kann muss ich im Dunkeln stochern...

Bitte probiere es mal komplett ohne ASM aus mit dem nativen AutoIt-Code aus Post #12. Reinhard
Falls das Ergebnis dann deinen Erwartungen entspricht liegt es am ASM Teil, falls nicht, dann nicht.

**Mars**

Hier ist noch ein Anhang mit der EasyASM.au3 zusammen, damit man im ASM herumfummeln kann, falls erforderlich.
(Den 2x Startup & Shutdown bitte ignorieren, das hatte ich mal automatisch in die EasyASM.au3 eingebaut. Genauso wie anderer Kram wie z.B. _ASM_Call(...) wo ich das Interface geändert habe sodass nur noch ein einziger pointer verwendet wird und cdecl verwendet wird statt stdcall. Also bitte bei DllCallAdress bleiben)

Reinhard

Wenn ich die Funktion aus Post #12 in die UDF einbaue, erhalte ich korrekte Ergebnisse.
Was ich gerade noch herausgefunden habe: Mit Autoit 3.3.14.5, das ich vermutlich unter Windows 7 genutzt habe, erhalte ich auch auf meinem Rechner korrekte Ergebnisse (mit der ursprünglichen Original-UDF).

**UEZ**

Passt gut hier rein - Differenz als Graustufe, wobei weiß = keine Differenz, je dunkler, desto größer die Differenz:

AutoIt

;Coded by UEZ build 2025-11-05
#include <Array.au3>
#include <GDIPlus.au3>
#include <MsgBoxConstants.au3>

_GDIPlus_Startup()
Global $hImage1, $hImage2
Global $sImages = FileOpenDialog("Select 2 images", "", "Image (*.bmp;*.jpg;*.png;*.gif)", $FD_MULTISELECT)
If @error Then _Exit("Nothing selected")
Global $aFiles = StringSplit($sImages, "|", 2)
If (UBound($aFiles) < 3) Then _Exit("Select at least 2 images")
$hImage1 = _GDIPlus_ImageLoadFromFile($aFiles[1])
If @error Then _Exit("Unable to load " & $aFiles[1])
$hImage2 = _GDIPlus_ImageLoadFromFile($aFiles[2])
If @error Then _Exit("Unable to load " & $aFiles[2])
If (_GDIPlus_ImageGetWidth($hImage1) <> _GDIPlus_ImageGetWidth($hImage2)) Then _Exit("Width of both images are different")
If (_GDIPlus_ImageGetHeight($hImage1) <> _GDIPlus_ImageGetHeight($hImage2)) Then _Exit("Height of both images are different")

Global $iMode = 4
Global $aDiff = _GDIPlus_ImageCompare($hImage1, $hImage2, $iMode)

If $iMode = 1 Then Exit MsgBox($MB_SYSTEMMODAL, "Compared", "Equal: " & $aDiff & " / " & @extended & " ms")

If $iMode = 2 Then
	Global $iChk = MsgBox(BitOR($MB_SYSTEMMODAL, $MB_YESNO), "Information", "Found " & Round((UBound($aDiff) - 1) / ($aDiff[0][1] * $aDiff[0][2]) * 100, 2) & " % differences in " & Round($aDiff[0][0], 2) & " ms." & _
							@CRLF & @CRLF & _
							"Display the array with information")
	If ($iChk = 6) Then _ArrayDisplay($aDiff, "Differences", Default, Default, Default, "Runtime / Coordinate (x,y)|Image1 Color|Image2 Color")
	_Exit()
	Exit
EndIf
ConsoleWrite($aDiff & " ms" & @CRLF)
_Exit()

Func _GDIPlus_ImageCompare($hImage1, $hImage2, $iMode = 1)
	Local Const $iW = _GDIPlus_ImageGetWidth($hImage1), $iH = _GDIPlus_ImageGetHeight($hImage1)
	If ($iW <> _GDIPlus_ImageGetWidth($hImage2)) Then Return SetError(1, 0, 0)
	If ($iH <> _GDIPlus_ImageGetHeight($hImage2)) Then Return SetError(2, 0, 0)
	Local $t = TimerInit()
	Local $tBitmapData1 = _GDIPlus_BitmapLockBits($hImage1, 0, 0, $iW, $iH, $GDIP_ILMREAD, $GDIP_PXF32ARGB)
	Local $tBitmapData2 = _GDIPlus_BitmapLockBits($hImage2, 0, 0, $iW, $iH, $GDIP_ILMREAD, $GDIP_PXF32ARGB)

    Local $pScan1 = DllStructGetData($tBitmapData1, "Scan0")
    Local $tPixel1 = DllStructCreate("uint[" & $iW * $iH & "];", $pScan1)
	Local $iStride = Abs(DllStructGetData($tBitmapData1, "Stride"))

    Local $pScan2 = DllStructGetData($tBitmapData2, "Scan0")
    Local $tPixel2 = DllStructCreate("uint[" & $iW * $iH & "];", $pScan2)

	Switch $iMode
		Case 1
			$iResult = DllCall("msvcrt.dll", "int:cdecl", "memcmp", "ptr", $pScan1, "ptr", $pScan2, "uint", DllStructGetSize($tPixel1))[0]
			_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
			_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
			Return SetError(0, Int(TimerDiff($t)), $iResult = 0)
		Case 2
			If ($iW * $iH + 1) * 3 > 16 * 1024 ^ 2 Then Return SetError(3, 0, 0)
			Local $iX, $iY, $iRowOffset, $iPixel1, $iPixel2, $c = 1, $aDiff[$iW * $iH + 1][3]
			For $iY = 0 To $iH - 1
				$iRowOffset = $iY * $iW + 1
				For $iX = 0 To $iW - 1
					$iPixel1 = DllStructGetData($tPixel1, 1, $iRowOffset + $iX) ;get pixel color
					$iPixel2 = DllStructGetData($tPixel2, 1, $iRowOffset + $iX) ;get pixel color
					If $iPixel1 <> $iPixel2 Then
						$aDiff[$c][0] = $iX & ", " & $iY
						$aDiff[$c][1] = "0x" & Hex($iPixel1, 8)
						$aDiff[$c][2] = "0x" & Hex($iPixel2, 8)
						$c += 1
					EndIf
				Next
			Next
			_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
			_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
			$aDiff[0][0] = TimerDiff($t)
			$aDiff[0][1] = $iW
			$aDiff[0][2] = $iH
			ReDim $aDiff[$c][3]
			Return $aDiff
		Case 3 ;Graustufen
			If ($iW * $iH + 1) * 3 > 16 * 1024 ^ 2 Then Return SetError(4, 0, 0)
			Local $stride = $iW * 4
			Local $tDestBmp = DllStructCreate("uint color[" & $stride * $iH & "];")
			Local $hBitmapDiff = _GDIPlus_BitmapCreateFromScan0($iW, $iH, $GDIP_PXF32ARGB, $stride, DllStructGetPtr($tDestBmp))
			If @error Or Not $hBitmapDiff Then
				_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
				_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
				Return SetError(5, @error, 0)
			EndIf
			Local $iX, $iY, $iRowOffset, $iPixel1, $iPixel2, $c = 1, $aDiff[$iW * $iH + 1][3], $a1, $a2, $r1, $r2, $g1, $g2, $b1, $b2, $dist3D, $dist4D, $alpha, $gamma = 0.1
			For $iY = 0 To $iH - 1
				$iRowOffset = $iY * $iW + 1
				For $iX = 0 To $iW - 1
					$iPixel1 = DllStructGetData($tPixel1, 1, $iRowOffset + $iX) ;get pixel color
					$iPixel2 = DllStructGetData($tPixel2, 1, $iRowOffset + $iX) ;get pixel color
					$a1 = BitShift(BitAND($iPixel1, 0xFF000000), 24)
					$a2 = BitShift(BitAND($iPixel2, 0xFF000000), 24)
					$r1 = BitShift(BitAND($iPixel1, 0x00FF0000), 16)
					$r2 = BitShift(BitAND($iPixel2, 0x00FF0000), 16)
					$g1 = BitShift(BitAND($iPixel1, 0x0000FF00), 8)
					$g2 = BitShift(BitAND($iPixel2, 0x0000FF00), 8)
					$b1 = BitAND($iPixel1, 0x000000FF)
					$b2 = BitAND($iPixel2, 0x000000FF)

					;euklidische Distanz in 4D
;~ 					$dist4D = Sqrt(($a1 - $a2) * ($a1 - $a2) + ($r1 - $r2) * ($r1 - $r2) + ($g1 - $g2) * ($g1 - $g2) + ($b1 - $b2) * ($b1 - $b2))
;~ 					$tDestBmp.color($iRowOffset + $iX) = BitOR(0xFF000000, BitXOR(BitShift($dist4D, -16), BitShift($dist4D, -8), $dist4D, 0xFFFFFF))

					;Alpha als Gewichtung der RGB-Distanz
					$dist3D = Sqrt(($r1 - $r2) * ($r1 - $r2) + ($g1 - $g2) * ($g1 - $g2) + ($b1 - $b2) * ($b1 - $b2))

					$alpha = Int(($a1 + $a2) / 2)
					$dist3D = 255 - Int($dist3D / 441.67295593 * 255) ;Sqr(3 * 255^2) = 441.67295593

					$tDestBmp.color($iRowOffset + $iX) = BitOR(BitShift($alpha, -24), BitShift($dist3D, -16), BitShift($dist3D, -8), $dist3D)

;~ 					$alpha = ($a1 + $a2) / 510 ;
;~ 					$dist3D = Int(($dist3D / 441.67295593) * 255 * $alpha)
;~ 					$tDestBmp.color($iRowOffset + $iX) = BitOR(0xFF000000, BitShift($dist3D, -16), BitShift($dist3D, -8), $dist3D)

				Next
			Next
			_GDIPlus_ImageSaveToFile($hBitmapDiff, @ScriptDir & "\ImageDiff.png")
			_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
			_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
			_GDIPlus_ImageDispose($hBitmapDiff)
			Return TimerDiff($t)
		Case 4 ;Graustufen mit Auto-Kontrast
			If ($iW * $iH + 1) * 3 > 16 * 1024 ^ 2 Then Return SetError(6, 0, 0)
			Local $stride = $iW * 4
			Local $tDestBmp = DllStructCreate("uint color[" & $stride * $iH & "];")
			Local $hBitmapDiff = _GDIPlus_BitmapCreateFromScan0($iW, $iH, $GDIP_PXF32ARGB, $stride, DllStructGetPtr($tDestBmp))
			If @error Or Not $hBitmapDiff Then
				_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
				_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
				Return SetError(6, @error, 0)
			EndIf

			Local $iX, $iY, $iRowOffset, $iPixel1, $iPixel2, $r1, $r2, $g1, $g2, $b1, $b2, $dist3D
			Local $minDist = 999999, $maxDist = 0
			Local $aDist[$iW * $iH + 1]

			;Distanzen berechnen und Min/Max finden
			For $iY = 0 To $iH - 1
				$iRowOffset = $iY * $iW + 1
				For $iX = 0 To $iW - 1
					$iPixel1 = DllStructGetData($tPixel1, 1, $iRowOffset + $iX)
					$iPixel2 = DllStructGetData($tPixel2, 1, $iRowOffset + $iX)
					$r1 = BitShift(BitAND($iPixel1, 0x00FF0000), 16)
					$r2 = BitShift(BitAND($iPixel2, 0x00FF0000), 16)
					$g1 = BitShift(BitAND($iPixel1, 0x0000FF00), 8)
					$g2 = BitShift(BitAND($iPixel2, 0x0000FF00), 8)
					$b1 = BitAND($iPixel1, 0x000000FF)
					$b2 = BitAND($iPixel2, 0x000000FF)

					$dist3D = Sqrt(($r1 - $r2) * ($r1 - $r2) + ($g1 - $g2) * ($g1 - $g2) + ($b1 - $b2) * ($b1 - $b2))
					$aDist[$iRowOffset + $iX] = $dist3D

					If $dist3D < $minDist Then $minDist = $dist3D
					If $dist3D > $maxDist Then $maxDist = $dist3D
				Next
			Next

			Local $range = $maxDist - $minDist
			If $range < 0.001 Then $range = 1  ;Division durch 0 verhindern (Bilder identisch)

			;Normalisieren
			Local $a1, $a2, $alpha
			For $iY = 0 To $iH - 1
				$iRowOffset = $iY * $iW + 1
				For $iX = 0 To $iW - 1
					$iPixel1 = DllStructGetData($tPixel1, 1, $iRowOffset + $iX)
					$iPixel2 = DllStructGetData($tPixel2, 1, $iRowOffset + $iX)
					$a1 = BitShift(BitAND($iPixel1, 0xFF000000), 24)
					$a2 = BitShift(BitAND($iPixel2, 0xFF000000), 24)
					$alpha = Int(($a1 + $a2) / 2)

					; Kontrast-Stretch: voller Bereich 0-255
					$dist3D = 255 - Int((($aDist[$iRowOffset + $iX] - $minDist) / $range) * 255)

					$tDestBmp.color($iRowOffset + $iX) = BitOR(BitShift($alpha, -24), BitShift($dist3D, -16), BitShift($dist3D, -8), $dist3D)
				Next
			Next

			_GDIPlus_ImageSaveToFile($hBitmapDiff, @ScriptDir & "\ImageDiff.png")
			_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
			_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
			_GDIPlus_ImageDispose($hBitmapDiff)
			Return TimerDiff($t)

		Case 5 ;direkte Differenz RGBA
			If ($iW * $iH + 1) * 3 > 16 * 1024 ^ 2 Then Return SetError(7, 0, 0)
			Local $stride = $iW * 4
			Local $tDestBmp = DllStructCreate("uint color[" & $stride * $iH & "];")
			Local $hBitmapDiff = _GDIPlus_BitmapCreateFromScan0($iW, $iH, $GDIP_PXF32ARGB, $stride, DllStructGetPtr($tDestBmp))
			If @error Or Not $hBitmapDiff Then
				_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
				_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
				Return SetError(8, @error, 0)
			EndIf
			Local $iX, $iY, $iRowOffset, $iPixel1, $iPixel2, $c = 1, $aDiff[$iW * $iH + 1][3], $a1, $a2, $r1, $r2, $g1, $g2, $b1, $b2, $dr, $dg, $db, $rDiff, $gDiff, $bDiff, $alpha
			For $iY = 0 To $iH - 1
				$iRowOffset = $iY * $iW + 1
				For $iX = 0 To $iW - 1
					$iPixel1 = DllStructGetData($tPixel1, 1, $iRowOffset + $iX) ;get pixel color
					$iPixel2 = DllStructGetData($tPixel2, 1, $iRowOffset + $iX) ;get pixel color
					$a1 = BitShift(BitAND($iPixel1, 0xFF000000), 24)
					$a2 = BitShift(BitAND($iPixel2, 0xFF000000), 24)
					$r1 = BitShift(BitAND($iPixel1, 0x00FF0000), 16)
					$r2 = BitShift(BitAND($iPixel2, 0x00FF0000), 16)
					$g1 = BitShift(BitAND($iPixel1, 0x0000FF00), 8)
					$g2 = BitShift(BitAND($iPixel2, 0x0000FF00), 8)
					$b1 = BitAND($iPixel1, 0x000000FF)
					$b2 = BitAND($iPixel2, 0x000000FF)

					$dr = Abs($r1 - $r2)
					$dg = Abs($g1 - $g2)
					$db = Abs($b1 - $b2)
					$alpha = Int(($a1 + $a2) / 2)
					$tDestBmp.color($iRowOffset + $iX) = BitOR(BitShift($alpha, -24), BitShift($dr, -16), BitShift($dg, -8), $db)
				Next
			Next
			_GDIPlus_ImageSaveToFile($hBitmapDiff, @ScriptDir & "\ImageDiff.png")
			_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
			_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
			_GDIPlus_ImageDispose($hBitmapDiff)
			Return TimerDiff($t)

		Case 6 ;Heatmap
			If ($iW * $iH + 1) * 3 > 16 * 1024 ^ 2 Then Return SetError(9, 0, 0)
			Local $stride = $iW * 4
			Local $tDestBmp = DllStructCreate("uint color[" & $stride * $iH & "];")
			Local $hBitmapDiff = _GDIPlus_BitmapCreateFromScan0($iW, $iH, $GDIP_PXF32ARGB, $stride, DllStructGetPtr($tDestBmp))
			If @error Or Not $hBitmapDiff Then
				_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
				_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
				Return SetError(10, @error, 0)
			EndIf
			Local $iX, $iY, $iRowOffset, $iPixel1, $iPixel2, $a1, $a2, $r1, $r2, $g1, $g2, $b1, $b2, $dr, $dg, $db, $alpha, $totalDiff, $heatR, $heatG, $heatB
			For $iY = 0 To $iH - 1
				$iRowOffset = $iY * $iW + 1
				For $iX = 0 To $iW - 1
					$iPixel1 = DllStructGetData($tPixel1, 1, $iRowOffset + $iX)
					$iPixel2 = DllStructGetData($tPixel2, 1, $iRowOffset + $iX)
					$a1 = BitShift(BitAND($iPixel1, 0xFF000000), 24)
					$a2 = BitShift(BitAND($iPixel2, 0xFF000000), 24)
					$r1 = BitShift(BitAND($iPixel1, 0x00FF0000), 16)
					$r2 = BitShift(BitAND($iPixel2, 0x00FF0000), 16)
					$g1 = BitShift(BitAND($iPixel1, 0x0000FF00), 8)
					$g2 = BitShift(BitAND($iPixel2, 0x0000FF00), 8)
					$b1 = BitAND($iPixel1, 0x000000FF)
					$b2 = BitAND($iPixel2, 0x000000FF)

					$dr = Abs($r1 - $r2)
					$dg = Abs($g1 - $g2)
					$db = Abs($b1 - $b2)
					$alpha = Int(($a1 + $a2) / 2)

					$totalDiff = ($dr + $dg + $db) / 3
					If $totalDiff < 64 Then ;Blau -> Cyan (0-63)
						$heatR = 0
						$heatG = Int($totalDiff * 4)
						$heatB = 255
					ElseIf $totalDiff < 128 Then ;Cyan -> Grün (64-127)
						$heatR = 0
						$heatG = 255
						$heatB = Int(255 - ($totalDiff - 64) * 4)
					ElseIf $totalDiff < 192 Then ;Grün -> Gelb (128-191)
						$heatR = Int(($totalDiff - 128) * 4)
						$heatG = 255
						$heatB = 0
					Else ;Gelb -> Rot (192-255)
						$heatR = 255
						$heatG = Int(255 - ($totalDiff - 192) * 4)
						$heatB = 0
					EndIf

					$tDestBmp.color($iRowOffset + $iX) = BitOR(BitShift($alpha, -24), BitShift($heatR, -16), BitShift($heatG, -8), $heatB)
				Next
			Next
			_GDIPlus_ImageSaveToFile($hBitmapDiff, @ScriptDir & "\ImageDiff.png")
			_GDIPlus_BitmapUnlockBits($hImage1, $tBitmapData1)
			_GDIPlus_BitmapUnlockBits($hImage2, $tBitmapData2)
			_GDIPlus_ImageDispose($hBitmapDiff)
			Return TimerDiff($t)

	EndSwitch
EndFunc


Func _Exit($sError = "")
	If $sError <> "" Then MsgBox($MB_ICONERROR, "ERROR", $sError)
	If ($hImage1 <> 0) Then _GDIPlus_ImageDispose($hImage1)
	If ($hImage2 <> 0) Then _GDIPlus_ImageDispose($hImage2)
	_GDIPlus_Shutdown()
	Exit
EndFunc

Alles anzeigen

Sorry fürs Hijacken...

Reinhard

Zitat von UEZ

Sorry fürs Hijacken...

Ist jedenfalls interessant: In der Freeware meines Vertrauens einmal Auto-Farbe über 'ImageDiff.png' laufen lassen und schon werden feinste Unterschiede sichtbar. Kommt in die Bastelkiste

**UEZ**

Kannst du mal ein Beispiel posten, wie es mit Farbe aussieht?

Reinhard

Hallo,
mir ist ein bisschen unbehaglich dabei, hier vom ursprünglichen Thema abzuschweifen. Vielleicht hast du Nerv, das schöne Skript in einem eigenen Thema vorzustellen.
Aber jedenfalls: Der Befehl 'Auto Farbe' im Faststone-Image-Viewer erzeugt aus einem Graustufenbild keine Farben. Es wird nach meinem Eindruck lediglich eine Tonwertspreizung ausgeführt, die dazu führt, dass die (u. U. wenigen) vorhandenen Farben über die gesamte Breite des Histogramms verteilt werden. Bei Farbbildern werden die Farbkanäle einzeln behandelt. Vielleicht werden auch noch weitere clevere Algorithmen bemüht. Unabhängig davon kann auch die Anwendung des Befehls 'Auto-Farbe' auf ein Graustufenbild verblüffen. Ich habe in die hier angehängte Datei 'ImageDiff.zip' vier Bilder gepackt:
- Fahrrad.png (das Original)
- Fahrrad.jpg (eine verlustarme Kompression des Originals)
- ImageDiff.png (vom Skript im Modus '3' erzeugt)
- ImageDiff_AutoFarbe.png
Man sieht also schön, wie der Befehl 'Auto Farbe' die in 'ImageDiff.png' kaum wahrnehmbaren Differenzen sichtbar macht.

**UEZ**

Ich habe den Code oben aktualisiert. Mode 4 sollte auch so ähnliche Resultate liefern.

Um diesen Thread nicht weiter zu missbrauchen, kann jemand einen neue Thread eröffnen, um den Code weiter zu behandeln, falls erwünscht, ansonsten mache ich jetzt einen Punkt zu meinem Code.

**Mars**

Zitat von Reinhard

mir ist ein bisschen unbehaglich dabei, hier vom ursprünglichen Thema abzuschweifen.

Ach das passt schon
Im Endeffekt geht es ja um eine sehr ähnliche (bzw. fast die selbe) Sache, von daher ist das hier thematisch eigentlich ganz gut aufgehoben. Wäre nur praktisch das was am Ende herauskommt ggf. nochmal kurz in einem eigenen Post zu erklären. Den verlinke ich (oder auch UEZ, wir sind ja PUs, da kann man überall editieren) dann im Startpost entsprechend damit er sichtbarer wird, falls andere Leute das auch gebrauchen können.

lg
M