Gitternetz (edit: gelöst)

**Alina**

Moin Moin und ein gesundes Jahr 2017.

Ich habe ein Problem. Was auch sonst.

Kann man über ein Bild ein Gitter setzen. Klare Linien. Bild ist in der Anlage und das Gitter soll waagerecht 22 / senkrecht 14 Felder haben.

Bildvorlage:
jpg2_stp.jpg

Und so stell ich es mir vor:
jpg2_stp_soll.jpg
(ist mit Excel zurechtgemacht)

Jetzt heißt es wieder einmal ALLTAG !!!

Bis dann und bleibt so wie ihr 2016 wart, reicht wenn ich immer schlimmer werde.

**Oscar**

Ich habe Dir mal ein Beispiel mit GDI+ erstellt (inkl. Kommentaren):

AutoIt

#include <GDIPlus.au3>
#include <GDIPlusConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()
Global $hBackgr = _GDIPlus_BitmapCreateFromFile(@ScriptDir & '\jpg2_stp.jpg') ; das Hintergrundbild laden
Global $iWidth = _GDIPlus_ImageGetWidth($hBackgr) ; die Breite
Global $iHeight = _GDIPlus_ImageGetHeight($hBackgr) ; und die Höhe des Bildes ermitteln
ConsoleWrite(StringFormat('Bildauflösung: %i x %i Pixel\n', $iWidth, $iHeight)) ; Debug-Info
Global $hGui = GUICreate('', $iWidth, $iHeight) ; ein entsprechendes Fenster erstellen
Global $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui) ; eine Graphic des Fensters erstellen
_GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Smoothing aktivieren
Global $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic) ; eine Bitmap von der Graphic erstellen (zum separaten Zeichnen der Linien)
Global $hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; den GraphicContext der Bitmap holen
Global $iGridX = Int($iWidth / 22), $iGridY = Int($iHeight / 14) ; die Gitter-Breite und -Höhe errechnen
ConsoleWrite(StringFormat('Gitternetz: %i x %i Pixel\n', $iGridX, $iGridY)) ; Debug-Info
For $iX = 0 To $iWidth Step $iGridX ; eine Schleife für die vertikalen Linien
	_GDIPlus_GraphicsDrawLine($hGfxCtxt, $iX, 0, $iX, $iHeight) ; die Linie zeichnen
Next
For $iY = 0 To $iHeight Step $iGridY ; eine Schleife für die horizontalen Linien
	_GDIPlus_GraphicsDrawLine($hGfxCtxt, 0, $iY, $iWidth, $iY) ; die Linie zeichnen
Next
GUIRegisterMsg($WM_PAINT, '_WM_PAINT') ; WM_PAINT registrieren, damit das Fenster bei Bedarf neu gezeichnet wird
GUISetState() ; das Fenster anzeigen
Global $aInfo, $sMsg
While True
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE ; wenn das Fenster geschlossen wird
			; Wichtig! Das "aufräumen" nicht vergessen!
			_GDIPlus_BitmapDispose($hBackgr)
			_GDIPlus_BitmapDispose($hBitmap)
			_GDIPlus_GraphicsDispose($hGfxCtxt)
			_GDIPlus_GraphicsDispose($hGraphic)
			_GDIPlus_Shutdown()
			; und hier dann erst das Programm beenden
			Exit
		Case $GUI_EVENT_RESTORE ; beim Wiederherstellen des Fensters (aus dem minimierten Status)
			_RedrawBitmap() ; die Fenster-Graphic neuzeichnen
		Case $GUI_EVENT_PRIMARYDOWN ; wenn die linke Maustaste gedrückt wird
			$aInfo = GUIGetCursorInfo($hGui) ; die Koordinaten der Maus ermitteln (relativ zum Fenster)
			$sMsg = StringFormat('Maus:\n x = %3i\n y = %3i\n\nGitternetz:\n x = %2i\n y = %2i', $aInfo[0], $aInfo[1], Int($aInfo[0] / $iGridX), Int($aInfo[1] / $iGridY)) ; für die Anzeige die Maus- in Gitternetz-Koordinaten umrechnen
			ToolTip($sMsg, Default, Default, 'Koordinaten', 1) ; und im ToolTip anzeigen
		Case $GUI_EVENT_MOUSEMOVE ; wenn die Maus bewegt wird
			ToolTip('') ; ToolTip wieder ausblenden
		Case $GUI_EVENT_SECONDARYDOWN ; wenn die rechte Maustaste gedrückt wird
			_GDIPlus_GraphicsDrawImage($hGraphic, $hBackgr, 0, 0) ; nur die Hintergrund-Bitmap (ohne das Gitter) auf die Fenster-Graphic zeichnen
		Case $GUI_EVENT_SECONDARYUP ; beim loslassen der rechten Maustaste
			_RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	EndSwitch
WEnd
Func _RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBackgr, 0, 0) ; die Hintergrund-Bitmap auf die Fenster-Graphic zeichnen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0) ; die Linien-Bitmap auf die Fenster-Graphic zeichnen
EndFunc   ;==>_RedrawBitmap
Func _WM_PAINT($hWnd, $iMsg, $wParam, $lParam)
	#forceref $iMsg, $wParam, $lParam
	If $hWnd = $hGui Then _RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_PAINT

Alles anzeigen

Edit: Das Script nochmal überarbeitet. Da kann man so schön mit rumspielen.
Beim linken Mausklick werden die Maus- und Gitternetz-Koordinaten angezeigt und beim rechten Mausklick wird das Gitternetz ausgeblendet.

**Bitnugger**

Sehr schön!

Zitat von Oscar

Da kann man so schön mit rumspielen.

Hihi... jeep... habe noch einen paar Zeilen hinzugefügt, damit man die Linien transparent zeichen kann...

AutoIt

;-- TIME_STAMP   2017-01-02 16:14:39


#include <GDIPlus.au3>
#include <GDIPlusConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()
Global $hBackgr = _GDIPlus_BitmapCreateFromFile(@ScriptDir & '\jpg2_stp.jpg') ; das Hintergrundbild laden
Global $iWidth = _GDIPlus_ImageGetWidth($hBackgr) ; die Breite
Global $iHeight = _GDIPlus_ImageGetHeight($hBackgr) ; und die Höhe des Bildes ermitteln
ConsoleWrite(StringFormat('Bildauflösung: %i x %i Pixel\n', $iWidth, $iHeight)) ; Debug-Info
Global $hGui = GUICreate('', $iWidth, $iHeight) ; ein entsprechendes Fenster erstellen
Global $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui) ; eine Graphic des Fensters erstellen
_GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Smoothing aktivieren
Global $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic) ; eine Bitmap von der Graphic erstellen (zum separaten Zeichnen der Linien)
Global $hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; den GraphicContext der Bitmap holen
Global $iGridX = Int($iWidth / 22), $iGridY = Int($iHeight / 14) ; die Gitter-Breite und -Höhe errechnen
ConsoleWrite(StringFormat('Gitternetz: %i x %i Pixel\n', $iGridX, $iGridY)) ; Debug-Info


; Damit wir die Linien transparent zeichnen können
Global $iARGB = 0x11000000	; Alpha, Red, Green and Blue components of pen color
Global $hPen = _GDIPlus_PenCreate($iARGB)


For $iX = 0 To $iWidth Step $iGridX ; eine Schleife für die vertikalen Linien
	_GDIPlus_GraphicsDrawLine($hGfxCtxt, $iX, 0, $iX, $iHeight, $hPen) ; die Linie zeichnen
Next


For $iY = 0 To $iHeight Step $iGridY ; eine Schleife für die horizontalen Linien
	_GDIPlus_GraphicsDrawLine($hGfxCtxt, 0, $iY, $iWidth, $iY, $hPen) ; die Linie zeichnen
Next
GUIRegisterMsg($WM_PAINT, '_WM_PAINT') ; WM_PAINT registrieren, damit das Fenster bei Bedarf neu gezeichnet wird
GUISetState() ; das Fenster anzeigen
Global $aInfo, $sMsg
While True
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE ; wenn das Fenster geschlossen wird
			; Wichtig! Das "aufräumen" nicht vergessen!
			_GDIPlus_PenDispose($hPen)
			_GDIPlus_BitmapDispose($hBackgr)
			_GDIPlus_BitmapDispose($hBitmap)
			_GDIPlus_GraphicsDispose($hGfxCtxt)
			_GDIPlus_GraphicsDispose($hGraphic)
			_GDIPlus_Shutdown()
			; und hier dann erst das Programm beenden
			Exit
		Case $GUI_EVENT_RESTORE ; beim Wiederherstellen des Fensters (aus dem minimierten Status)
			_RedrawBitmap() ; die Fenster-Graphic neuzeichnen
		Case $GUI_EVENT_PRIMARYDOWN ; wenn die linke Maustaste gedrückt wird
			$aInfo = GUIGetCursorInfo($hGui) ; die Koordinaten der Maus ermitteln (relativ zum Fenster)
			$sMsg = StringFormat('Maus:\n x = %3i\n y = %3i\n\nGitternetz:\n x = %2i\n y = %2i', $aInfo[0], $aInfo[1], Int($aInfo[0] / $iGridX), Int($aInfo[1] / $iGridY)) ; für die Anzeige die Maus- in Gitternetz-Koordinaten umrechnen
			ToolTip($sMsg, Default, Default, 'Koordinaten', 1) ; und im ToolTip anzeigen
		Case $GUI_EVENT_MOUSEMOVE ; wenn die Maus bewegt wird
			ToolTip('') ; ToolTip wieder ausblenden
		Case $GUI_EVENT_SECONDARYDOWN ; wenn die rechte Maustaste gedrückt wird
			_GDIPlus_GraphicsDrawImage($hGraphic, $hBackgr, 0, 0) ; nur die Hintergrund-Bitmap (ohne das Gitter) auf die Fenster-Graphic zeichnen
		Case $GUI_EVENT_SECONDARYUP ; beim loslassen der rechten Maustaste
			_RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	EndSwitch
WEnd
Func _RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBackgr, 0, 0) ; die Hintergrund-Bitmap auf die Fenster-Graphic zeichnen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0) ; die Linien-Bitmap auf die Fenster-Graphic zeichnen
EndFunc   ;==>_RedrawBitmap
Func _WM_PAINT($hWnd, $iMsg, $wParam, $lParam)
	#forceref $iMsg, $wParam, $lParam
	If $hWnd = $hGui Then _RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_PAINT

Alles anzeigen

**Andy**

Ohne Gedöns!

Code

#include <GDIPlus.au3>


_GDIPlus_Startup()


;$datei = "fullscreen.bmp"


$datei = FileOpenDialog("Bilder", @ScriptDir, "Bilder (*.jpg;*.bmp;*.png)")


$bitmap = _GDIPlus_BitmapCreateFromFile($datei)


$hbmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($bitmap)


$hImage = _GDIPlus_BitmapCreateFromHBITMAP($hbmp)


$iX = _GDIPlus_ImageGetWidth($hImage)
$iY = _GDIPlus_ImageGetHeight($hImage)


$xstep = $iX / 22
$ystep = $iY / 14


$hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage)


$hPen = _GDIPlus_PenCreate()


For $x = 0 To $iX Step $xstep
    _GDIPlus_GraphicsDrawLine($hGraphic, $x, 0, $x, $iY, $hPen)
Next
For $y = 0 To $iY Step $ystep
    _GDIPlus_GraphicsDrawLine($hGraphic, 0, $y, $iX, $y, $hPen) ;x
Next




_GDIPlus_ImageSaveToFile($hImage, "GDIPlus_Image_test.bmp")
ShellExecute("GDIPlus_Image_test.bmp")

Alles anzeigen

@Oscar, ich würde in der Zeile Global $iGridX = Int($iWidth / 22), $iGridY = Int($iHeight / 14) [i]; die Gitter-Breite und -Höhe errechnen[/i] die INT weglassen, da sonst bei "ungeraden" Breiten/Höhen hässliche Reste rechts und unten am Rand übrigbleiben.
GDI rundet idR Floatzahlen zum passenden Integer.

**Oscar**

Andy: Stimmt! Ohne die INT sieht es besser aus!
Außerdem die halbtransparenten Linien von Bitnugger und ein Menü zum speichern des Bildes.
Hier also die aktuelle Version:

AutoIt

#include <GDIPlus.au3>
#include <GDIPlusConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
_GDIPlus_Startup()
Global $hBackgr = _GDIPlus_BitmapCreateFromFile(@ScriptDir & '\jpg2_stp.jpg') ; das Hintergrundbild laden
Global $iWidth = _GDIPlus_ImageGetWidth($hBackgr) ; die Breite
Global $iHeight = _GDIPlus_ImageGetHeight($hBackgr) ; und die Höhe des Bildes ermitteln
ConsoleWrite(StringFormat('Bildauflösung: %i x %i Pixel\n', $iWidth, $iHeight)) ; Debug-Info
Global $iMenuHeight = _WinAPI_GetSystemMetrics($SM_CYMENU) ; die Höhe (in Pixel) für das Menü holen
Global $hGui = GUICreate('Koordinaten-Gitter', $iWidth, $iHeight + $iMenuHeight) ; ein entsprechendes Fenster erstellen
Global $idMenu = GUICtrlCreateMenu('Datei') ; das Dateimenü erstellen
Global $idSaveAs = GUICtrlCreateMenuItem('Bild speichern', $idMenu) ; Menüeintrag zum speichern erstellen
GUICtrlCreateMenuItem('', $idMenu) ; Menüeintrag Leerzeile erstellen
Global $idExit = GUICtrlCreateMenuItem('Programm beenden', $idMenu) ; Menüeintrag zum beenden erstellen
Global $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui) ; eine Graphic des Fensters erstellen
_GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ; Smoothing aktivieren
Global $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic) ; eine Bitmap von der Graphic erstellen (zum separaten Zeichnen der Linien)
Global $hGfxCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; den GraphicContext der Bitmap holen
Global $iGridX = $iWidth / 22, $iGridY = $iHeight / 14 ; die Gitter-Breite und -Höhe errechnen
ConsoleWrite(StringFormat('Gitternetz: %f x %f Pixel\n', $iGridX, $iGridY)) ; Debug-Info
; Damit wir die Linien transparent zeichnen können
Global $iARGB = 0x22000000	; Alpha, Red, Green and Blue components of pen color
Global $hPen = _GDIPlus_PenCreate($iARGB)
For $iX = 0 To $iWidth Step $iGridX ; eine Schleife für die vertikalen Linien
	_GDIPlus_GraphicsDrawLine($hGfxCtxt, $iX, 0, $iX, $iHeight, $hPen) ; die Linie zeichnen
Next
For $iY = 0 To $iHeight Step $iGridY ; eine Schleife für die horizontalen Linien
	_GDIPlus_GraphicsDrawLine($hGfxCtxt, 0, $iY, $iWidth, $iY, $hPen) ; die Linie zeichnen
Next
GUIRegisterMsg($WM_PAINT, '_WM_PAINT') ; WM_PAINT registrieren, damit das Fenster bei Bedarf neu gezeichnet wird
GUISetState() ; das Fenster anzeigen
Global $aInfo, $sMsg, $hSaveImg, $hSaveGfx
While True
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE, $idExit ; wenn das Fenster geschlossen wird
			; Wichtig! Das "aufräumen" nicht vergessen!
			_GDIPlus_PenDispose($hPen)
			_GDIPlus_BitmapDispose($hBackgr)
			_GDIPlus_BitmapDispose($hBitmap)
			_GDIPlus_GraphicsDispose($hGfxCtxt)
			_GDIPlus_GraphicsDispose($hGraphic)
			_GDIPlus_Shutdown()
			; und hier dann erst das Programm beenden
			Exit
		Case $GUI_EVENT_RESTORE ; beim Wiederherstellen des Fensters (aus dem minimierten Status)
			_RedrawBitmap() ; die Fenster-Graphic neuzeichnen
		Case $GUI_EVENT_PRIMARYDOWN ; wenn die linke Maustaste gedrückt wird
			$aInfo = GUIGetCursorInfo($hGui) ; die Koordinaten der Maus ermitteln (relativ zum Fenster)
			$sMsg = StringFormat('Maus:\n x = %3i\n y = %3i\n\nGitternetz:\n x = %2i\n y = %2i', $aInfo[0], $aInfo[1], Int($aInfo[0] / $iGridX), Int($aInfo[1] / $iGridY)) ; für die Anzeige die Maus- in Gitternetz-Koordinaten umrechnen
			ToolTip($sMsg, Default, Default, 'Koordinaten', 1) ; und im ToolTip anzeigen
		Case $GUI_EVENT_MOUSEMOVE ; wenn die Maus bewegt wird
			ToolTip('') ; ToolTip wieder ausblenden
		Case $GUI_EVENT_SECONDARYDOWN ; wenn die rechte Maustaste gedrückt wird
			_GDIPlus_GraphicsDrawImage($hGraphic, $hBackgr, 0, 0) ; nur die Hintergrund-Bitmap (ohne das Gitter) auf die Fenster-Graphic zeichnen
		Case $GUI_EVENT_SECONDARYUP ; beim loslassen der rechten Maustaste
			_RedrawBitmap() ; die Fenster-Graphic neuzeichnen
		Case $idSaveAs ; wenn der Menüpukt "Bild speichern" ausgewählt wurde
			$hSaveImg = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic) ; Bitmap zum speichern erstellen
			$hSaveGfx = _GDIPlus_ImageGetGraphicsContext($hSaveImg) ; den GraphicContext holen
			_GDIPlus_GraphicsDrawImage($hSaveGfx, $hBackgr, 0, 0) ; den Hintergrund in die Graphic zeichnen
			_GDIPlus_GraphicsDrawImage($hSaveGfx, $hBitmap, 0, 0) ; das Gitternetz in die Graphic zeichnen
			_GDIPlus_ImageSaveToFile($hSaveImg, @ScriptDir & '\ImageWithGrid.png') ; die Bitmap als PNG speichern
			_GDIPlus_BitmapDispose($hSaveImg) ; und aufräumen
			_GDIPlus_GraphicsDispose($hSaveGfx) ; und aufräumen
	EndSwitch
WEnd
Func _RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBackgr, 0, 0) ; die Hintergrund-Bitmap auf die Fenster-Graphic zeichnen
	_GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0) ; die Linien-Bitmap auf die Fenster-Graphic zeichnen
EndFunc   ;==>_RedrawBitmap
Func _WM_PAINT($hWnd, $iMsg, $wParam, $lParam)
	#forceref $iMsg, $wParam, $lParam
	If $hWnd = $hGui Then _RedrawBitmap() ; die Fenster-Graphic neuzeichnen
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_PAINT

Alles anzeigen

**Alina**

DANKE !!!
PERFEKT !!!