Kindern etwas spielerisch beibringen - Schritt für Schritt Anleitungen

AutoMit

Hallo,

alle gut im Jahr 2017 angekommen?, dann auf in gutes 2017

Ich bin auf der Suche nach Anregungen, wie man Schritt für Schritt Anleitungen mit AutoIt auf eine Oberfläche bringen kann,
die Kinder spielerisch mit der Maus in die richtige Reihenfolge bringen können.

Kurz gefasst: Objekte (Button, Icons, Label, Bilder) per Drag / Drop in die richtige Reihenfolge verschieben + Auswertung der Reihenfolge.

Beispiel

1 Spielsachen wegräumen
2 Händewaschen
3 Teller holen
4 an den Tisch setzen
5 essen

Diese Punkte sind auf einer Oberfläche durcheinandergewürfelt zu lesen oder als Bild dargestellt.
(sowie zusätzlich zwei Begriffe, die nicht dazugehören)

essen
Traumlandreise
an den Tisch setzen
Händewaschen
Spielsachen wegräumen
Teller holen
Hund ausführen

Die "Begriffe" sind wie Spielkarten frei auf der Oberfläche ausgebreitet.

Mit der Maus sollen die Elemente in die richtige Reihenfolge verschoben werden.

Wenn die richtige Reihenfolge erreicht wurde, erscheint eine Meldung.

Auf der Oberfläche gibt es einen "Papierkorb", so dass die Elemente, die nicht zum Thema gehören, vom Kind erkannt, mit der Maus in den
„Papierkorb später“ geschoben werden können.
(Aus obigen Beispiel wären das die Begriffe: „Traumlandreise“ und „Hund ausführen“.)

Das ist eine erste Idee.

Wie würdet ihr so eine Schritt für Schritt Anleitung für Kinder aufbauen?
(inklusive Laden unterschiedlicher Themen, vielleich ini-Datei?)

Gibt es hier im Forum bereits vergleichbare Beispiele, bei denen es darum geht, Elemente auf einer Oberfläche mit der Maus und Drag and Drop zu sortieren und die Reihenfolge zu prüfen?

Danke

**chesstiger**

Hi,

ich würde das ganze auf Basis von Child Windows realisieren. Dann nimmt dir Windows das Verschieben und Neuzeichnen direkt ab. Ich hab mal ein kleines (fehlerhaftes) Minimalbeispiel geschrieben. Bei mir gibt es da den ein oder anderen Darstellungsfehler, ich bin mir aber nicht sicher, was davon am Betriebssystem liegt (Debian 8 mit Wine). Daher, sieh es einfach mal als Proof-Of-Concept.

[autoit]

#include <StaticConstants.au3>
#include <GUIConstants.au3>

[/autoit][autoit][/autoit][autoit]

$hMainWnd = GUICreate("Child Window Sort", 600, 400)
$cSlotA = GUICtrlCreateLabel("Example Slot", 250, 150, 100, 100, $SS_CENTER + $SS_CENTERIMAGE)
GUICtrlSetBkColor(-1, 0x00ff00)
GUISetBkColor(0xffffff)

[/autoit][autoit][/autoit][autoit]

Global $ahChildWnd[3]
For $i = 0 To UBound($ahChildWnd) - 1
$ahChildWnd[$i] = GUICreate("", 100, 100, 0, 0, $WS_CHILD, Default, $hMainWnd)
GUICtrlCreateLabel("Drag Me " & ($i + 1), 0, 0, 100, 100, $SS_CENTER + $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
GUISetBkColor(0xff00ff)
GUISetState()
Next

[/autoit][autoit][/autoit][autoit]

GUISetState(@SW_SHOW, $hMainWnd) ;parent window auf sichtbar stellen

[/autoit][autoit][/autoit][autoit]

While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $GUI_EVENT_PRIMARYUP
;Linke Maustaste losgelassen
CheckPositions()
EndSwitch
WEnd

[/autoit][autoit][/autoit][autoit]

Func CheckPositions()
;Alle Child-Windows durchgehen und schauen,
;ob eines teilweise auf dem Slot liegt
;(Stichwort: Kollisionsabfrage)
$aSlotPos = WinGetPos(GUICtrlGetHandle($cSlotA))
$aMainPos = WinGetPos($hMainWnd)
For $i = 0 To UBound($ahChildWnd) - 1
$aChildPos = WinGetPos($ahChildWnd[$i])
If IsRectCollision($aChildPos, $aSlotPos) Then
ConsoleWrite("Kollision erkannt. Richte ChildWnd " & ($i + 1) & " neu aus..." & @CRLF)
WinMove($ahChildWnd[$i], "", $aSlotPos[0] - $aMainPos[0], $aSlotPos[1] - $aMainPos[1])
EndIf
Next
EndFunc

[/autoit][autoit][/autoit][autoit]

Func IsRectCollision($aPosA, $aPosB)
Local Enum $X, $Y, $W, $H
If $aPosA[$X] > ($aPosB[$X] + $aPosB[$W]) Then Return False
If ($aPosA[$X] + $aPosA[$W]) < $aPosB[$X] Then Return False
If $aPosA[$Y] > ($aPosB[$Y] + $aPosB[$H]) Then Return False
If ($aPosA[$Y] + $aPosA[$H]) < $aPosB[$Y] Then Return False
Return True
EndFunc

[/autoit]

AutoMit

Danke @chesstiger

Unter Windows 8 funktioniert das hier ohne Grafikfehler - das ist die gute Nachricht

"Child Windows" in AutoIt sind Neuland für mich.

(1)

Wenn ich „ISN Autoit Studio“ nutze, müsste ich den Controls folgende Parameter mitgeben:
$WS_CHILD
$GUI_WS_EX_PARENTDRAG

Habe ich das soweit richtig verstanden?
Kann ich so jedes Control (Button, Image, Icon) zu einem "Child Window" machen?

(2)

Verschiebe ich ein violettes "Drag-Me-Feld" auf das grüne "Ziel", so erscheint das violette Feld hinter dem grünen Feld.

Ich habe noch nicht die "Schraube" im Script finden können, an der ich "drehen" muss, um das "Drag-Me-Feld" über das "Ziel" zu legen - welche "Schraube" ist es?

@all

Drag an Drop scheint ein sehr interessantes Feld. Wer dazu weitere Script-Beispiele beitragen kann, die für obiges Thema geeignet sind, bitte hier einfügen.

**alpines**

Zitat von AutoMit

Wenn ich „ISN Autoit Studio“ nutze, müsste ich den Controls folgende Parameter mitgeben:

$WS_CHILD
$GUI_WS_EX_PARENTDRAG

Habe ich das soweit richtig verstanden?

$WS_CHILD musst du als ChildWindow Style setzen, $GUI_WS_EX_PARENTDRAG beim Label.

Zitat von AutoMit

Kann ich so jedes Control (Button, Image, Icon) zu einem "Child Window" machen?

Du erstellst kleine Fenster wo du die Controls platzierst, du machst die Controls selbst nicht zu einem Child Window!
Du kannst nur Elemente verschieben die den Extended Style $GUI_WS_EX_PARENTDRAG unterstützten.

Schau einfach mal im Form Designer welche Controls das sind.

**chesstiger**

Zu zwei: Man platziere die Slots ebenfalls auf Child-Windows und erstelle sie nach den verschiebbaren Feldern (im Skript Tiles). Dann passt das.

PARENTDRAG können nur Label und Pic, soweit ich mich erinnere. Ich habe das ganze mal ein wenig ausgebaut, mit Positionsüberprüfung. Die richtige Reihenfolge ist 1, 2, 3. Dann wird der Hintergrund grün.

[autoit]

#include <StaticConstants.au3>
#include <GUIConstants.au3>

[/autoit][autoit][/autoit][autoit]

;Main Window
$hMainWnd = GUICreate("Child Window Sort", 600, 400)
GUISetBkColor(0xffffff)

[/autoit][autoit][/autoit][autoit]

;Tile Windows
Global $ahTileWnd[3]
For $i = 0 To UBound($ahTileWnd) - 1
$ahTileWnd[$i] = GUICreate("", 100, 100, 0, 0, $WS_CHILD, $WS_EX_TOPMOST, $hMainWnd)
GUICtrlCreateLabel("Drag Me " & ($i + 1), 0, 0, 100, 100, $SS_CENTER + $SS_CENTERIMAGE, $GUI_WS_EX_PARENTDRAG)
GUISetBkColor(0xff00ff)
GUISetState()
Next

[/autoit][autoit][/autoit][autoit]

;Slot Windows
Global $ahSlotWnd[3]
For $i = 0 To UBound($ahSlotWnd) - 1
$ahSlotWnd[$i] = GUICreate("", 100, 100, 100 * ((1.5 * $i) + 1), 150, $WS_CHILD, Default, $hMainWnd)
GUICtrlCreateLabel("Slot " & ($i + 1), 0, 0, 100, 100, $SS_CENTER + $SS_CENTERIMAGE)
GUICtrlSetBkColor(-1, 0x0000ff)
GUISetState()
Next

[/autoit][autoit][/autoit][autoit]

GUISetState(@SW_SHOW, $hMainWnd) ;parent window auf sichtbar stellen

[/autoit][autoit][/autoit][autoit]

While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $GUI_EVENT_PRIMARYUP
;Linke Maustaste losgelassen
$aTilePos = AlignTiles($ahTileWnd, $ahSlotWnd)
CheckPositions($aTilePos)
EndSwitch
WEnd

[/autoit][autoit][/autoit][autoit]

Func CheckPositions($aTilePos)
;Diese Funktion entscheidet,
;ob ein Tile auf dem richtigen Slot
;liegt (bzw. ob alle richtig liegen)

[/autoit][autoit][/autoit][autoit]

;Das folgende kann man auch in eine
;Schleife packen, so ist der Sinn
;aber deutlicher
If ($aTilePos[0] = 0) And ($aTilePos[1] = 1) And ($aTilePos[2] = 2) Then
GUISetBkColor(0x00ff00, $hMainWnd)
Else
GUISetBkColor(0xff0000, $hMainWnd)
EndIf
EndFunc

[/autoit][autoit][/autoit][autoit]

Func AlignTiles($ahTileWnd, $ahSlotWnd)
;Alle Child-Windows durchgehen und schauen,
;ob eines teilweise auf dem Slot liegt
;(Stichwort: Kollisionsabfrage
Local $aReturn[UBound($ahSlotWnd)]
For $i = 0 To UBound($aReturn) - 1
$aReturn[$i] = -1
Next
;Außerdem gibt diese Funktion ein
;Array zur Bestimmung der Positionen
;zurück. Aufbau: $aReturn[n] = m
; n: Tile-Nummer
; m: Slot-Nummer
$aMainPos = WinGetPos($hMainWnd)
$aMainClientSize = WinGetClientSize($hMainWnd)
$aMainPos[0] += $aMainPos[2] - $aMainClientSize[0] - 3
$aMainPos[1] += $aMainPos[3] - $aMainClientSize[1] - 3
For $iSlot = 0 To UBound($ahSlotWnd) - 1
$aSlotPos = WinGetPos($ahSlotWnd[$iSlot])
For $iTile = 0 To UBound($ahTileWnd) - 1
$aTilePos = WinGetPos($ahTileWnd[$iTile])
If IsRectCollision($aTilePos, $aSlotPos) Then
ConsoleWrite("+DEBUG> Kollision erkannt. Richte ChildWnd " & ($iTile + 1) & " neu aus..." & @CRLF)
WinMove($ahTileWnd[$iTile], "", $aSlotPos[0] - $aMainPos[0], $aSlotPos[1] - $aMainPos[1])
$aReturn[$iTile] = $iSlot
EndIf
Next
Next
Return $aReturn
EndFunc ;==>AlignTiles

[/autoit][autoit][/autoit][autoit]

Func IsRectCollision($aPosA, $aPosB)
Local Enum $X, $Y, $W, $H
If $aPosA[$X] > ($aPosB[$X] + $aPosB[$W]) Then Return False
If ($aPosA[$X] + $aPosA[$W]) < $aPosB[$X] Then Return False
If $aPosA[$Y] > ($aPosB[$Y] + $aPosB[$H]) Then Return False
If ($aPosA[$Y] + $aPosA[$H]) < $aPosB[$Y] Then Return False
Return True
EndFunc ;==>IsRectCollision

[/autoit]

P.S.: Das ist nicht violett, das ist pink!

Edit: Hatte vergessen, das Return-Array von AlignTiles() vorher auf unplausible Werte zu setzen.

AutoMit

Zitat von chesstiger

P.S.: Das ist nicht violett, das ist pink!

Ich gebe zu, ich habe die Farbe von pink in violett geändert ... und das, obowhl ein pinker Tiger in der Nähe ist

Deine neue Umsetzung sieht interessant aus. Ich zerlege das gerade, um es zu verstehen. Danke Euch beide!

AutoMit

Zitat von chesstiger

Die richtige Reihenfolge ist 1, 2, 3. Dann wird der Hintergrund grün.

Wirf bitte noch mal einen Blick drauf. Als Codeknacker funktioniert auch die Lösung
leer - 2 - 3
(also wenn Feld 1 frei bleibt, schaltet der Hintergrund auf grün um)

(edit)

... schmunzel, Du hast es ist der Zwischenzeit schon selbst gemerkt. Du bist um einiges schneller als ich.
Lösung 1 - 2 - 3

Danke

**Oscar**

Statt mit mehreren Fenstern, würde ich einfach nur die Control-Elemente verschieben. Das läßt sich IMHO einfacher handhaben:

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


Opt('GUIOnEventMode', 1)
Global $hGui = GUICreate('Test', 800, 600)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, '_PrimaryDown')
GUISetOnEvent($GUI_EVENT_PRIMARYUP, '_PrimaryUp')
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, '_MouseMove')
Global $iCount = 10, $idMove = -1, $iIconSize = 64, $iSpace = $iIconSize + 16
Global $aidLabel[$iCount]
For $i = 0 To $iCount - 1
	$aidLabel[$i] = GUICtrlCreateIcon('shell32.dll', $i+1, 10 + Int($i / 2) * $iSpace, 10 + Mod($i, 2) * $iSpace, $iIconSize, $iIconSize, Default, $WS_EX_DLGMODALFRAME)
;~ 	$aidLabel[$i] = GUICtrlCreateLabel($i+1, 10 + Int($i / 2) * 80, 10 + Mod($i, 2) * 80, 64, 64, Default, $WS_EX_DLGMODALFRAME)
Next
GUISetState()
WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc


Func _PrimaryDown()
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	$idMove = $aInfo[4]
	GuiCtrlSetOnTop($idMove)
EndFunc


Func _PrimaryUp()
	$idMove = -1
EndFunc


Func _MouseMove()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui)
	GUICtrlSetPos($idMove, $aInfo[0] - $iIconSize / 2, $aInfo[1] - $iIconSize / 2)
EndFunc


Func GuiCtrlSetOnTop($iCtrlID)
    ;Need to include <WinAPI.au3> and <APIConstants.au3>
    Local $hWnd = $iCtrlID
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($iCtrlID)
    Return _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $SWP_NOMOVE + $SWP_NOSIZE + $SWP_NOCOPYBITS)
EndFunc

Alles anzeigen

**Oscar**

Hier mal ein erster Versuch mit Text-Label:

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>


Opt('GUIOnEventMode', 1)
Global $hGui = GUICreate('Test', 800, 600)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, '_PrimaryDown')
GUISetOnEvent($GUI_EVENT_PRIMARYUP, '_PrimaryUp')
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, '_MouseMove')
GUISetBkColor(0xCCCCFF)
Global $idMove = -1
Global $aText[] = ['Traumlandreise', 'essen', 'Hände waschen', 'an den Tisch setzen', 'Hund ausführen', 'Spielsachen wegräumen', 'Teller holen']
Global $iCount = UBound($aText)
Global $aResolving[5] = [5, 2, 6, 3, 1] ; Lösung
Global $aidLabel[$iCount]
For $i = 0 To $iCount - 1
	$aidLabel[$i] = GUICtrlCreateLabel($aText[$i], 10 + Int($i / 2) * 195, 10 + Mod($i, 2) * 40, 190, 28, $SS_CENTER, $WS_EX_DLGMODALFRAME)
	GUICtrlSetFont(-1, 12, 400, 0, 'Tahoma')
	GUICtrlSetBkColor(-1, 0xEEEEEE)
Next
Global $aidSlot[5], $aidLED[5]
For $i = 0 To 4
	GUICtrlCreateLabel($i + 1 & '.', 180, 145 + $i * 48, 20, 32)
	GUICtrlSetFont(-1, 12, 400, 0, 'Tahoma')
	$aidSlot[$i] = GUICtrlCreateLabel('', 206, 140 + $i * 48, 194, 32, Default, $WS_EX_CLIENTEDGE)
	GUICtrlSetBkColor(-1, 0xEEEEEE)
	$aidLED[$i] = GUICtrlCreateLabel('', 410, 148 + $i * 48, 16, 16, Default, $WS_EX_CLIENTEDGE)
	GUICtrlSetBkColor(-1, 0xFF0000)
Next
GUISetState()
WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc


Func _PrimaryDown()
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	$idMove = $aInfo[4]
	GuiCtrlSetOnTop($idMove)
EndFunc


Func _PrimaryUp()
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	For $i = 0 To 4
		If _WinAPI_PtInRectEx($aInfo[0], $aInfo[1], 206, 140 + $i * 48, 400, 172 + $i * 48) Then
			GUICtrlSetPos($idMove, 208, 142 + $i * 48)
			Beep(600, 40)
			If $aText[$aResolving[$i]] = GUICtrlRead($idMove) Then
				GUICtrlSetBkColor($aidLED[$i], 0x00FF00)
			Else
				GUICtrlSetBkColor($aidLED[$i], 0xFF0000)
			EndIf
		EndIf
	Next
	$idMove = -1
EndFunc


Func _MouseMove()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui)
	GUICtrlSetPos($idMove, $aInfo[0] - 85, $aInfo[1] - 12)
EndFunc


Func GuiCtrlSetOnTop($iCtrlID)
    ;Need to include <WinAPI.au3> and <APIConstants.au3>
    Local $hWnd = $iCtrlID
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($iCtrlID)
    Return _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $SWP_NOMOVE + $SWP_NOSIZE + $SWP_NOCOPYBITS)
EndFunc

Alles anzeigen

AutoMit

Zitat von Oscar

Hier mal ein erster Versuch mit Text-Label:

Vielen Dank Oscar. Dein Entwurf in Post 9 sieht optisch einfach (und) gut aus!

Kannst Du bitte an zwei Stellen noch ewtas ergänzen (sind 2 kleine optische Sachen)?

(a)
Derzeit kann man pro Ziel-Feld mehrere Text-Labels raufsetzen.
Was muss im Code ergänzt werden, dass Text-Labels im Ziel nicht übereinander gestapelt werden können? Bzw. wenn ein neues Text-Label reingezogen wird, dass ein bisheriges dort vorhandenes wieder auf die Oberfläche gelegt wird?

(b)
Wenn man ein Text-Label richtig in ein Ziel gezogen hat, wird auf grün umschaltet.
Zieht man es wieder heraus, also wenn das Ziel wieder leer ist, bleibt der Status auf grün und schaltet nicht auf rot um.

Übrigens - Deine Idee, eine Teillösung als richtig (grün) zu makieren, ist für Kinder eine gute Motivation, um schneller Erfolge zu erzielen.

Als zusätzliche Motivation werde ich versuchen, einen Counter zu ingegrieren, wieviele Versuche notwendig waren, um alle Text-Labels richtig zu plazieren.
Einmal für das Einzel-Feld rechts neben dem Ziel.
Und einmal als Summe für alle Felder.

Gute Nacht - und vielen Dank an alle helfenden Hände

**Oscar**

Hier mal die korrigierte Version:

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>


Opt('GUIOnEventMode', 1)
Global $hGui = GUICreate('Test', 800, 600)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, '_PrimaryDown')
GUISetOnEvent($GUI_EVENT_PRIMARYUP, '_PrimaryUp')
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, '_MouseMove')
GUISetBkColor(0xCCCCFF)
Global $idMove = -1
Global $aText[] = ['Traumlandreise', 'essen', 'Hände waschen', 'an den Tisch setzen', 'Hund ausführen', 'Spielsachen wegräumen', 'Teller holen']
Global $iCount = UBound($aText)
Global $aResolving[5] = [5, 2, 6, 3, 1] ; Lösung
Global $aidLabel[$iCount][3], $aPos
For $i = 0 To $iCount - 1
	$aidLabel[$i][0] = GUICtrlCreateLabel($aText[$i], 10 + Int($i / 2) * 195, 10 + Mod($i, 2) * 40, 190, 28, $SS_CENTER, $WS_EX_DLGMODALFRAME)
	GUICtrlSetFont(-1, 14, 400, 2, 'Times New Roman', 5)
	GUICtrlSetBkColor(-1, 0xEEEEEE)
	$aPos = ControlGetPos($hGui, '', $aidLabel[$i][0])
	$aidLabel[$i][1] = $aPos[0]
	$aidLabel[$i][2] = $aPos[1]
Next
Global $aidSlot[5][2], $aidLED[5]
For $i = 0 To 4
	GUICtrlCreateLabel($i + 1 & '.', 180, 145 + $i * 48, 20, 32)
	GUICtrlSetFont(-1, 12, 400, 0, 'Tahoma')
	$aidSlot[$i][0] = GUICtrlCreateLabel('', 206, 140 + $i * 48, 194, 32, Default, $WS_EX_CLIENTEDGE)
	GUICtrlSetBkColor(-1, 0xEEEEEE)
	$aidSlot[$i][1] = -1
	$aidLED[$i] = GUICtrlCreateLabel('', 410, 148 + $i * 48, 16, 16, Default, $WS_EX_CLIENTEDGE)
	GUICtrlSetBkColor(-1, 0xFF0000)
Next
GUISetState()
WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui


Func _PrimaryDown()
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	If $aInfo[4] < $aidLabel[0][0] Or $aInfo[4] > $aidLabel[$iCount - 1][0] Then Return
	$idMove = $aInfo[4]
	GuiCtrlSetOnTop($idMove)
	For $i = 0 To 4
		If $aidSlot[$i][1] = $idMove Then $aidSlot[$i][1] = -1
	Next
EndFunc   ;==>_PrimaryDown


Func _PrimaryUp()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui), $iIndex
	If @error Then Return
	For $i = 0 To 4
		If _WinAPI_PtInRectEx($aInfo[0], $aInfo[1], 206, 140 + $i * 48, 400, 172 + $i * 48) Then
			If $aidSlot[$i][1] <> -1 Then
				$iIndex = -1
				For $j = 0 To $iCount - 1
					If $aidSlot[$i][1] = $aidLabel[$j][0] Then $iIndex = $j
				Next
				GUICtrlSetPos($aidSlot[$i][1], $aidLabel[$iIndex][1], $aidLabel[$iIndex][2])
			EndIf
			GUICtrlSetPos($idMove, 208, 142 + $i * 48)
			$aidSlot[$i][1] = $idMove
			Beep(600, 40)
		EndIf
		$aPos = ControlGetPos($hGui, '', $aidLabel[$aResolving[$i]][0])
		If _WinAPI_PtInRectEx($aPos[0], $aPos[1], 206, 140 + $i * 48, 400, 172 + $i * 48) Then
			GUICtrlSetPos($aidLabel[$aResolving[$i]][0], 208, 142 + $i * 48)
			GUICtrlSetBkColor($aidLED[$i], 0x00FF00)
		Else
			GUICtrlSetBkColor($aidLED[$i], 0xFF0000)
		EndIf
	Next
	$idMove = -1
EndFunc   ;==>_PrimaryUp


Func _MouseMove()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui)
	GUICtrlSetPos($idMove, $aInfo[0] - 85, $aInfo[1] - 12)
EndFunc   ;==>_MouseMove


Func GuiCtrlSetOnTop($iCtrlID)
	;Need to include <WinAPI.au3> and <APIConstants.au3>
	Local $hWnd = $iCtrlID
	If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($iCtrlID)
	Return _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $SWP_NOMOVE + $SWP_NOSIZE + $SWP_NOCOPYBITS)
EndFunc   ;==>GuiCtrlSetOnTop

Alles anzeigen

Das ist jetzt aber ziemlich kompliziert geworden.
Ich denke, dass man das auch einfacher hinbekommt, aber dazu muss man das ganze Konzept nochmal überdenken.
Aber das sollte ja auch nur als Grundgerüst dienen, damit Du siehst, wie man die Control-Elemente verschieben/auswerten kann.

**Kanashius**

Muss man nur aufpassen, dass man die Fenster nicht aus dem Sichtfeld schiebt
Achja... die Lösung steht zum Glück ja im Quellcode

(Nicht, dass da jemand versucht das durch denken zu lösen )

**Kanashius**

So, wie man mich mittlerweile kennt mag ich Flexibilität
Also hier das ganze flexibler:

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <Array.au3>
Opt('GUIOnEventMode', 1)


Global $idMove = -1,$iControlHeight=30,$iWidth=800,$iHeight=600,$iSpace=5
Global $iSlotInfoCount=10,$arSlotInfos[0][$iSlotInfoCount],$iItemInfoCount=3,$arItemInfos[0][$iItemInfoCount],$sFunction=""


Global $hGui = GUICreate('Sequences', $iWidth, $iHeight)
GUISetBkColor(0xCCCCFF)
GUISetFont($iControlHeight/2,400,2, 'Times New Roman',$hGui,5)
GUISetOnEvent($GUI_EVENT_CLOSE, '_close',$hGui)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, '_PrimaryDown',$hGui)
GUISetOnEvent($GUI_EVENT_PRIMARYUP, '_PrimaryUp',$hGui)
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, '_MouseMove',$hGui)
GUISetState()


local $arTask1Items=["TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4", _
					"TestItem 1","TestItem 2","TestItem 3","TestItem 4" _
					]
local $arTask1Seq=[0,2,1]
_loadTask($arTask1Items,$arTask1Seq,"_ItemMoved")
If @error Then MsgBox(16,"Error","Something went wrong: "&@error)


While Sleep(10)
WEnd


Func _close()
	exit
EndFunc


Func _ItemMoved()
	If _checkAllIsRight() Then
		msgbox(48,"","Alles richtig! :)")
		_clearTask()
	EndIf
EndFunc


Func _checkAllIsRight()
	for $i=0 to UBound($arSlotInfos)-1 step 1
		If NOT $arSlotInfos[$i][9] Then return false
	next
	return true
EndFunc


Func _clearTask()
	for $i=0 to UBound($arItemInfos)-1 step 1
		GUICtrlDelete($arItemInfos[$i][0])
	next
	for $i=0 to UBound($arSlotInfos)-1 step 1
		GUICtrlDelete($arSlotInfos[$i][0])
		GUICtrlDelete($arSlotInfos[$i][1])
		GUICtrlDelete($arSlotInfos[$i][2])
	next
EndFunc


Func _loadTask( ByRef $arItems, ByRef $arSequence, $sCallback="")
	$sFunction=$sCallback
	_clearTask()
	if UBound($arItems)<1 then
		SetError(1,0,-1)
		return
	endif
	if UBound($arSequence)>UBound($arItems) then
		SetError(2,0,-1)
		return
	endif
	For $i=0 to UBound($arSequence)-1 step 1
		If $arSequence[$i]<0 or $arSequence[$i]>UBound($arItems)-1 Then
			SetError(3,0,-1)
			return
		endif
		If $i<UBound($arSequence)-1 and _ArraySearch($arSequence,$arSequence[$i],$i+1)<>-1 Then
			SetError(4,0,-1)
			return
		endif
	Next
	ReDim $arItemInfos[UBound($arItems)][$iItemInfoCount]
	ReDim $arSlotInfos[UBound($arSequence)][$iSlotInfoCount]
	local $iMaxWidthItem=0,$iMaxWidthSlot,$iActWidth=0
	for $i=0 to UBound($arItems)-1 step 1
		$arItemInfos[$i][0]=GUICtrlCreateLabel($arItems[$i],0,-50,Default,$iControlHeight-4,$SS_CENTER,$WS_EX_DLGMODALFRAME)
		GUICtrlSetBkColor(-1, 0xEEEEEE)
		$iActWidth=ControlGetPos($hGui,"",$arItemInfos[$i][0])[2]
		$iMaxWidthItem=$iActWidth>$iMaxWidthItem?$iActWidth:$iMaxWidthItem
	next
	for $i=0 to UBound($arSequence)-1 step 1
		$arSlotInfos[$i][0]=GUICtrlCreateLabel($i&".",0,-50,Default,$iControlHeight-4,$SS_CENTER,$WS_EX_DLGMODALFRAME)
		$iActWidth=ControlGetPos($hGui,"",$arSlotInfos[$i][0])[2]
		$iMaxWidthSlot=$iActWidth>$iMaxWidthSlot?$iActWidth:$iMaxWidthSlot
	next
	$iMaxHeightItems=Int($iHeight/($iControlHeight+$iSpace))-1
	$iMinColsItems=Int((UBound($arItems)/$iMaxHeightItems))+1
	$iMinColsSlots=Int((UBound($arSequence)/$iMaxHeightItems))+1
	if (($iMinColsItems*$iMaxWidthItem)+(($iMinColsItems-1)*$iSpace)+($iMinColsSlots*($iMaxWidthItem+$iMaxWidthSlot+$iSpace+4+$iSpace+16)) _
		+(($iMinColsSlots-1)*$iSpace))>($iWidth-($iSpace*2)) Then
		_clearTask()
		SetError(5,0,-1)
		return
	endif
	local $iStart=0,$iCount=0
	for $i=0 to UBound($arItems)-1 step $iMaxHeightItems
		if $i+$iMaxHeightItems>UBound($arItems) Then
			$iStart=Int(($iMaxHeightItems-Mod(UBound($arItems),$iMaxHeightItems))/2)*($iControlHeight+$iSpace)
		endif
		for $j=0 to $iMaxHeightItems-1 step 1
			if $i+$j>UBound($arItems)-1 then ExitLoop 2
			GUICtrlSetPos($arItemInfos[$i+$j][0],$iSpace+($iMaxWidthItem+$iSpace)*$iCount,$iSpace+$iStart+($j*($iControlHeight+5)),$iMaxWidthItem)
			$arItemInfos[$i+$j][1]=$iSpace+($iMaxWidthItem+$iSpace)*$iCount
			$arItemInfos[$i+$j][2]=$iSpace+$iStart+($j*($iControlHeight+5))
		next
		$iCount+=1
	next
	$iStart=0
	$iCount=0
	for $i=0 to UBound($arSequence)-1 step $iMaxHeightItems
		if $i+$iMaxHeightItems>UBound($arSequence) Then
			$iStart=Int(($iMaxHeightItems-Mod(UBound($arSequence),$iMaxHeightItems))/2)*($iControlHeight+$iSpace)
		endif
		for $j=0 to $iMaxHeightItems-1 step 1
			if $i+$j>UBound($arSequence)-1 then ExitLoop 2
			local $iLeft=($iSpace+($iMaxWidthItem+$iSpace)*$iMinColsItems)+$iSpace+(($iMaxWidthItem+$iMaxWidthSlot+$iSpace+4+$iSpace+16)+$iSpace)*$iCount
			GUICtrlSetPos($arSlotInfos[$i+$j][0],$iLeft,2+$iSpace+$iStart+($j*($iControlHeight+5)),$iMaxWidthSlot)
			$arSlotInfos[$i+$j][1]=GUICtrlCreateLabel("",$iLeft+$iMaxWidthSlot+$iSpace,$iSpace+$iStart+($j*($iControlHeight+5)),$iMaxWidthItem+4,$iControlHeight,Default,$WS_EX_CLIENTEDGE)
			GUICtrlSetBkColor(-1, 0xEEEEEE)
			$arSlotInfos[$i+$j][2]=GUICtrlCreateLabel("",$iLeft+$iMaxWidthItem+$iMaxWidthSlot+$iSpace*2+4,$iSpace+$iStart+($j*($iControlHeight+5))+(($iControlHeight-16)/2),16,16,Default,$WS_EX_CLIENTEDGE)
			GUICtrlSetBkColor(-1, 0xFF0000)
			$arSlotInfos[$i+$j][3]=$arSequence[$i+$j]
			$arSlotInfos[$i+$j][4]=-1
			$arSlotInfos[$i+$j][5]=$iLeft+$iMaxWidthSlot+$iSpace
			$arSlotInfos[$i+$j][6]=$iSpace+$iStart+($j*($iControlHeight+5))
			$arSlotInfos[$i+$j][7]=$iLeft+$iMaxWidthSlot+$iSpace+$iMaxWidthItem+4
			$arSlotInfos[$i+$j][8]=$iSpace+$iStart+($j*($iControlHeight+5))+$iControlHeight
		next
		$iCount+=1
	next
EndFunc


Func _PrimaryDown()
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	$index=_ArraySearch($arItemInfos,$aInfo[4],0,0,0,0,1,0)
	If $index=-1 Then return
	$idMove = $index
	GuiCtrlSetOnTop($arItemInfos[$index][0])
	For $i = 0 To UBound($arSlotInfos)-1
		If $arSlotInfos[$i][4] = $index Then
			$arSlotInfos[$i][4] = -1
			GUICtrlSetBkColor($arSlotInfos[$i][2], 0xFF0000)
			$arSlotInfos[$i][9]=false
		endif
	Next
EndFunc   ;==>_PrimaryDown


Func _PrimaryUp()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	For $i = 0 To UBound($arSlotInfos)-1 step 1
		If _WinAPI_PtInRectEx($aInfo[0], $aInfo[1], $arSlotInfos[$i][5],$arSlotInfos[$i][6],$arSlotInfos[$i][7],$arSlotInfos[$i][8]) Then
			If $arSlotInfos[$i][4] <> -1 Then
				GUICtrlSetPos($arItemInfos[$arSlotInfos[$i][4]][0],$arItemInfos[$arSlotInfos[$i][4]][1],$arItemInfos[$arSlotInfos[$i][4]][2])
				GUICtrlSetBkColor($arSlotInfos[$i][2], 0xFF0000)
				$arSlotInfos[$i][9]=false
			EndIf
			GUICtrlSetPos($arItemInfos[$idMove][0], $arSlotInfos[$i][5]+2,$arSlotInfos[$i][6]+2)
			$arSlotInfos[$i][4] = $idMove
			if $arSlotInfos[$i][3]=$idMove Then
				GUICtrlSetBkColor($arSlotInfos[$i][2], 0x00FF00)
				$arSlotInfos[$i][9]=true
			EndIf
			Beep(600, 40)
			if $sFunction<>"" then Call($sFunction)
		EndIf
	Next
	$idMove = -1
EndFunc   ;==>_PrimaryUp


Func _MouseMove()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui)
	local $arSize=ControlGetPos($hGui,"",$arItemInfos[$idMove][0])
	GUICtrlSetPos($arItemInfos[$idMove][0], $aInfo[0] - Int($arSize[2]/2), $aInfo[1] - Int($arSize[3]/2))
EndFunc   ;==>_MouseMove


Func GuiCtrlSetOnTop($iCtrlID)
	;Need to include <WinAPI.au3> and <APIConstants.au3>
	Local $hWnd = $iCtrlID
	If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($iCtrlID)
	Return _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $SWP_NOMOVE + $SWP_NOSIZE + $SWP_NOCOPYBITS)
EndFunc   ;==>GuiCtrlSetOnTop

Alles anzeigen

Es kann einfach die Funktion _loadTask mit den beiden Arrays aufgerufen werden und schon kanns losgehen.
Die Felder und Slots werden automatisch ausgerichtet. Ist nicht genug Platz kommt eine Fehlermeldung
Ebenfalls, wenn die Parameter nicht stimmen.
Man kann ne Funktion angeben, die aufgerufen wird, wenn ein Item gesetzt wurde und eine Funktion, die prüft ob alles richtig ist

Viel Spaß, Kanashius.

PS: Weniger Komplex ist es dadurch nicht geworden. Eher im Gegenteil

**Oscar**

Ich habe mein Script mal noch etwas erweitert (Kommentare, Spielende plus Auswertung, Neustart):

AutoIt

#include <AutoItConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>


Opt('GUIOnEventMode', 1)
Global $hGui = GUICreate('Kinderspiel', 800, 560)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, '_PrimaryDown')
GUISetOnEvent($GUI_EVENT_PRIMARYUP, '_PrimaryUp')
GUISetOnEvent($GUI_EVENT_MOUSEMOVE, '_MouseMove')
GUISetBkColor(0xCCCCFF)
Global $aText[] = ['Traumlandreise', 'essen', 'Hände waschen', 'an den Tisch setzen', 'Hund ausführen', 'Spielsachen wegräumen', 'Teller holen', 'Blumen gießen'] ; die Texte für die Label
Global $iCount = UBound($aText) ; Anzahl der Text-Label ermitteln
Global $aResolving[5] = [5, 2, 6, 3, 1] ; Lösungs-Reihenfolge
Global $idMove = -1 ; dient als Speicher für das gerade verschobene Label
Global $iMoveCount = 0 ; Variable zum zählen der Spielzüge
Global $idMenu = GUICtrlCreateMenu('Spiel')
GUICtrlCreateMenuItem('Neu starten', $idMenu)
GUICtrlSetOnEvent(-1, '_Replay')
GUICtrlCreateMenuItem('', $idMenu)
GUICtrlCreateMenuItem('Beenden', $idMenu)
GUICtrlSetOnEvent(-1, '_CloseGui')
Global $aidLabel[$iCount][3], $aPos
For $i = 0 To $iCount - 1 ; hier werden die Text-Label erstellt
	$aidLabel[$i][0] = GUICtrlCreateLabel($aText[$i], 10 + Int($i / 2) * 195, 30 + Mod($i, 2) * 40, 190, 28, $SS_CENTER, $WS_EX_DLGMODALFRAME)
	GUICtrlSetFont(-1, 14, 400, 2, 'Times New Roman', 5)
	GUICtrlSetBkColor(-1, 0xEEEEEE)
	$aPos = ControlGetPos($hGui, '', $aidLabel[$i][0]) ; Ausgangsposition des Labels holen (zum zurücksetzen)
	$aidLabel[$i][1] = $aPos[0] ; X-Position speichern
	$aidLabel[$i][2] = $aPos[1] ; Y-Position speichern
Next
Global $aidSlot[5][2], $aidLED[5], $aSlotPos[5][4]
For $i = 0 To 4 ; hier werden die Ziel-Slots erstellt
	GUICtrlCreateLabel($i + 1 & '.', 260, 185 + $i * 48, 20, 32)
	GUICtrlSetFont(-1, 12, 400, 0, 'Tahoma')
	$aidSlot[$i][0] = GUICtrlCreateLabel('', 286, 180 + $i * 48, 194, 32, Default, $WS_EX_CLIENTEDGE)
	GUICtrlSetBkColor(-1, 0xEEEEEE)
	$aidSlot[$i][1] = -1 ; wird benutzt, um zu speichern, welches Textlabel auf dem Slot liegt (-1 = leer)
	$aidLED[$i] = GUICtrlCreateLabel('', 490, 188 + $i * 48, 16, 16, Default, $WS_EX_CLIENTEDGE)
	GUICtrlSetBkColor(-1, 0xFF0000)
	$aPos = ControlGetPos($hGui, '', $aidSlot[$i][0]) ; Position des Slots ermitteln (wird für _WinAPI_PtInRectEx benötigt)
	$aSlotPos[$i][0] = $aPos[0] ; X-Position
	$aSlotPos[$i][1] = $aPos[1] ; Y-Position
	$aSlotPos[$i][2] = $aPos[0] + $aPos[2] ; X + Width = Right
	$aSlotPos[$i][3] = $aPos[1] + $aPos[3] ; Y + Height = Bottom
Next
; die folgenden Texte werden angezeigt, wenn alle Label richtig positioniert wurden
Global $idWin = GUICtrlCreateLabel('Alles richtig! Das hast Du gut gemacht!', 30, 440, 730, 40, $SS_CENTER)
GUICtrlSetFont(-1, 24, 400, 2, 'Times New Roman')
GUICtrlSetState(-1, $GUI_HIDE)
; das folgende Label wird mit der Anzahl der Spielzüge gefüllt
Global $idMoveCount = GUICtrlCreateLabel('', 30, 490, 730, 40, $SS_CENTER)
GUICtrlSetFont(-1, 18, 400, 2, 'Times New Roman')
GUICtrlSetState(-1, $GUI_HIDE)
GUISetState()
WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui


Func _Replay()
	For $i = 0 To $iCount - 1
		GUICtrlSetPos($aidLabel[$i][0], $aidLabel[$i][1], $aidLabel[$i][2])
	Next
	For $i = 0 To 4
		$aidSlot[$i][1] = -1
		GUICtrlSetBkColor($aidLED[$i], 0xFF0000)
	Next
	$iMoveCount = 0
	GUICtrlSetState($idWin, $GUI_HIDE)
	GUICtrlSetState($idMoveCount, $GUI_HIDE)
EndFunc   ;==>_Replay


Func _PrimaryDown()
	Local $aInfo = GUIGetCursorInfo($hGui)
	If @error Then Return
	If $aInfo[4] < $aidLabel[0][0] Or $aInfo[4] > $aidLabel[$iCount - 1][0] Then Return
	$idMove = $aInfo[4]
	GuiCtrlSetOnTop($idMove)
	For $i = 0 To 4
		If $aidSlot[$i][1] = $idMove Then $aidSlot[$i][1] = -1
	Next
EndFunc   ;==>_PrimaryDown


Func _PrimaryUp()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui), $iIndex
	If @error Then Return
	$iMoveCount += 1
	Local $iWin = 0
	For $i = 0 To 4
		If _WinAPI_PtInRectEx($aInfo[0], $aInfo[1], $aSlotPos[$i][0], $aSlotPos[$i][1], $aSlotPos[$i][2], $aSlotPos[$i][3]) Then
			If $aidSlot[$i][1] <> -1 Then
				$iIndex = -1
				For $j = 0 To $iCount - 1
					If $aidSlot[$i][1] = $aidLabel[$j][0] Then $iIndex = $j
				Next
				GUICtrlSetPos($aidSlot[$i][1], $aidLabel[$iIndex][1], $aidLabel[$iIndex][2])
			EndIf
			GUICtrlSetPos($idMove, $aSlotPos[$i][0] + 2, $aSlotPos[$i][1] + 2)
			$aidSlot[$i][1] = $idMove
			Beep(600, 40)
		EndIf
		$aPos = ControlGetPos($hGui, '', $aidLabel[$aResolving[$i]][0])
		If _WinAPI_PtInRectEx($aPos[0], $aPos[1], $aSlotPos[$i][0], $aSlotPos[$i][1], $aSlotPos[$i][0] + 4, $aSlotPos[$i][1] + 4) Then
			$iWin += 1
			GUICtrlSetBkColor($aidLED[$i], 0x00FF00)
		Else
			GUICtrlSetBkColor($aidLED[$i], 0xFF0000)
		EndIf
	Next
	If $iWin = 5 Then
		GUICtrlSetData($idMoveCount, StringFormat('Du hast %s%s Spielzüge benötigt.', $iMoveCount = 5 ? 'nur ' : '', $iMoveCount))
	EndIf
	GUICtrlSetState($idWin, $iWin = 5 ? $GUI_SHOW : $GUI_HIDE)
	GUICtrlSetState($idMoveCount, $iWin = 5 ? $GUI_SHOW : $GUI_HIDE)
	$idMove = -1
EndFunc   ;==>_PrimaryUp


Func _MouseMove()
	If $idMove = -1 Then Return
	Local $aInfo = GUIGetCursorInfo($hGui)
	GUICtrlSetPos($idMove, $aInfo[0] - 85, $aInfo[1] - 12)
EndFunc   ;==>_MouseMove


Func GuiCtrlSetOnTop($iCtrlID)
	;Need to include <WinAPI.au3> and <APIConstants.au3>
	Local $hWnd = $iCtrlID
	If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($iCtrlID)
	Return _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $SWP_NOMOVE + $SWP_NOSIZE + $SWP_NOCOPYBITS)
EndFunc   ;==>GuiCtrlSetOnTop

Alles anzeigen

AutoMit

Ich danke Euch allen für die sehr gute Hilfe!

Auf in ein erfolgreiches 2017

Am Wochenende schaue ich mir in Ruhe die Codezeilen an, um etwas daraus zu zaubern. Ich hoffe, meine kleinen Geister lassen mir die Zeit

Grünen Haken gesetzt