reguläre Suche - Verzeichnisnamen

AutoMit

Hallo,

vorab nebenbei gefragt: Gibt es bei AutoIt eine Funktion, um aus einem Pfad z.B. das letzte Unterverzeichnis (das erste Unterverzeichnis, das xte Unterverzeichnis) auszulesen oder würde man das mit StringRegExp (auslesen) bzw. StringRegExpReplace (entfernen) machen müssen?

Wer mag beim Thema reguläre Suche helfen?

StringRegExp($Verzeichnis_mit_den_Daten, regulärer Suchausdruck)

Wie schreibt man, dass man das erste Vorkommen von "\ beliebige Zeichen \" bzw. das letzte Vorkommen von "\ beliebige Zeichen \" bzw. das xte Vorkommen von "\ beliebige Zeichen \ in dem String sucht?

(1)

Wie kann ich den letzten Ordner "01" aus dem Pfad mit StringRegExp (reguläre Suche) oder anderweitig (a) entfernen bzw. (b) in einer Variablen speichern?

$Verzeichnis_mit_den_Daten = "d:\test\01\05\01\01\test.txt"

(2)

Wie kann ich den letzten Ordner "01" aus dem Pfad mit StringRegExp (reguläre Suche) oder anderweitig (a) entfernen bzw. (b) in einer Variablen speichern?

$Verzeichnis_mit_den_Daten = "d:\test\01\05\01\01"

(3)

Wie kann ich das dritte Unterverzeichn (hier: "05") aus dem Pfad mit StringRegExp (reguläre Suche) oder anderweitig (a) entfernen bzw. (b) in einer Variablen speichern?

$Verzeichnis_mit_den_Daten = "d:\test\01\05\01\test.txt"
$Verzeichnis_mit_den_Daten = ""d:\test\01\05\01"

Danke - und einen gelungenen Wochenstart

**Oscar**

Ich würde den Pfad aufsplitten und wieder neu zusammensetzen:

AutoIt

#include <Array.au3>
#include <WinAPIShPath.au3>


$sPath = "d:\test\01\05\01\test.txt"


$sNewPath = _RemoveFolderNr($sPath, 3) ; das 3. Verzeichnis entfernen
MsgBox(0, 'Test', 'Neuer Pfad: "' & $sNewPath & '"')


Func _RemoveFolderNr($sPath, $iFolderNr)
	Local $sFile = _WinAPI_PathStripPath($sPath) ; Dateinamen sichern
	$sPath = _WinAPI_PathRemoveFileSpec($sPath) ; Dateinamen entfernen
	Local $aFolder = StringSplit($sPath, '\', 2) ; Pfad aufteilen
	If $iFolderNr > UBound($aFolder) - 1 Then $iFolderNr = UBound($aFolder) - 1
	Local $sNewPath = ''
	For $i = 0 To UBound($aFolder) - 1
		If $i <> $iFolderNr Then $sNewPath &= $aFolder[$i] & '\'
	Next
	Return $sNewPath & $sFile
EndFunc

Alles anzeigen

AutoMit

Danke Oscar, das ist eine gute Idee.

Kannst Du das auch als reguläre Suche (siehe Beispiele 1 bis 3) formulieren?

Ich würde gerne beim Thema reguläre Suche voran kommen, weil die Fragestelle "erste Fundstelle", "xte Fundstelle" und "letzte Fundstelle" in einer Zeichenkette häufiger vorkommt.

Aus der Hilfe konnte ich bisher entnehmen:

Falls "\" in dem ersetzen String vorkommt, so muss dieser gedoppelt werden.
-> also \\ -> Findet alle tatsächlichen Backslashs (\)

^ für Zeilenanfang (ggf. nutzbar als "beginne am Zeilenanfang"?)

$ fü Zeilenende (ggf. nutzbar als "beginne am Zeilenende"?)

Über das offset könnte ich die xte Fundstelle festlegen.

StringRegExp ( "test", "pattern" [, flag [, offset]] )
offset = Die Position des Strings, wo die Funktion beginnen soll (startet bei 1). Der Standard ist 1.

Finde beginnende vom Zeilenende $ das erste Vorkommen, welchen zwichen / und / steht.

Weiter komme ich leider nicht.

**BugFix**

AutoIt

; == Wie schreibt man, dass man das erste Vorkommen von "\ beliebige Zeichen \" bzw. das letzte Vorkommen von "\ beliebige Zeichen \" bzw. das xte Vorkommen von "\ beliebige Zeichen \ in dem String sucht?
; StringInString - suchen von vorn mit positiver Zahl oder von hinten mit negativer Zahl für occurence


Local $Verzeichnis_mit_den_Daten = "d:\test\01\05\01\01\test.txt"


; Bsp.: 2. '\'´von hinten
$iPos = StringInStr($Verzeichnis_mit_den_Daten, '\', 0, -2)

**chesstiger**

Das geht auch mit RegExp, ist aber ein längeres Pattern:

Code

; #FUNCTION# ====================================================================================================================
; Name ..........: GetNthPartOfPath
; Description ...:
; Syntax ........: GetNthPartOfPath($sPath, $n)
; Parameters ....: $sPath               - Eingabepfad.
;                  $n                   - 0-basierte Nummer des Pfadteiles, der gelesen werden soll.
; Return values .: n-ter Teil des Pfades.
; Author ........: chesstiger
; Modified ......:
; Remarks .......: Achtung! Der Laufwerksbuchstabe wird nicht mitgezählt.
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func GetNthPartOfPath($sPath, $n)
$sPattern = "^[a-zA-Z]:(?:\\.+?){" & $n & "}\\(.+?)(?:\\|$)"
$aMatch = StringRegExp($sPath, $sPattern, 3)
If Not IsArray($aMatch) Then Return SetError(1, 0, 0)
Return $aMatch[0]
EndFunc   ;==>GetNthPartOfPath


; #FUNCTION# ====================================================================================================================
; Name ..........: RemoveNthPartOfPath
; Description ...:
; Syntax ........: RemoveNthPartOfPath($sPath, $n)
; Parameters ....: $sPath               - Eingabepfad.
;                  $n                   - 0-basierte Nummer des Pfadteiles, der entfernt werden soll.
; Return values .: Pfad ohne n-ten Teil.
; Author ........: chesstiger
; Modified ......:
; Remarks .......: Achtung! Der Laufwerksbuchstabe wird nicht mitgezählt.
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func RemoveNthPartOfPath($sPath, $n)
$sPattern = "^([a-zA-Z]):((?:\\.+?){" & $n & "})(\\.+?)((?:\\.+?)+|$)"
$sReplace = "$1:$2$4"
$sReturn = StringRegExpReplace($sPath, $sPattern, $sReplace)
If @extended = 0 Then Return SetError(1, 0, 0)
Return $sReturn
EndFunc   ;==>RemoveNthPartOfPath

Alles anzeigen

Müsste eigentlich so gehen.

AutoMit

Vielen Dank Euch zwei

Da gibts was zum Ausprobieren am Wochenende.

(liege noch krank danieder, es wird langsam)

grünen Haken gesetzt

**Bitnugger**

Zitat von chesstiger

Müsste eigentlich so gehen.

Im Prinzip schon... allerdings wird hier gar nicht überprüft, ob es sich wirklich um ein Verzeichnis handelt... und ob der letzte Part auch ein Verzeichnis ist, oder doch eine Datei ohne Extension. Verlässlich damit hantieren kann man also nicht. Deshalb habe ich mir die Mühe gemacht und das Ganze ein wenig überarbeitet und auch ein paar alternative Funktionen mit reingepackt, die ich euch nicht vorenthalten wollte.

PathEx

AutoIt

#include <Array.au3>
#include <String.au3>
#include <WinAPIShPath.au3>


;-- TIME_STAMP   2017-02-10 16:33:14   v 1.0


; #FUNCTION# ====================================================================================================================
; Name ..........: _GetPartsOfPath
; Description ...: Formats a path to the fully qualified path
; Syntax ........: _GetPartsOfPath($sPath[, $bExits = False])
; Parameters ....: $sPath               - Eingabepfad.
;                  $bExits              - [optional] Specifies whether the path should be existing, valid values:
;                                           True - The path must be an existing path, otherwise, the function fails.
;                                           False - The path may not exist (Default).
; Return values .: Success:             - The formated path.
;                  Failure:             - Empty string and sets the @error flag to non-zero.
; Author ........: Bitnugger
; Modified ......:
; Remarks .......: To make sure that $sPath is a fully qualified path, you should first call this function before using another
;                  function from this UDF!
; Related .......: FileExists()
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _GetPartsOfPath(ByRef $sPath, $bExists = False, $bShowParts = False)
	Local $sShow = $sPath, $aSplit
	$sPath = _WinAPI_PathSearchAndQualify($sPath, $bExists)
	If @error Then Return SetError(1, 0, ConsoleWrite('> ' & $sShow & @CRLF))
	If $bShowParts Then _PrintParts($sPath, $aSplit)
	StringReplace($sPath, '\', '')
	Return (@extended = 0) ? SetError(1, 0, '') : SetError(0, @extended -1, $aSplit)
EndFunc


; #FUNCTION# ====================================================================================================================
; Name ..........: _GetNthPartOfPath
; Description ...:
; Syntax ........: _GetNthPartOfPath($sPath, $n)
; Parameters ....: $sPath               - Eingabepfad.
;                  $n                   - 0-basierte Nummer des Pfadteiles, der gelesen werden soll.
; Return values .: n-ter Teil des Pfades.
; Author ........: chesstiger
; Modified ......: Bitnugger
; Remarks .......: Achtung! Der Laufwerksbuchstabe wird nicht mitgezählt.
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _GetNthPartOfPath($sPath, $n)
	Local $sPattern = "^[a-zA-Z]:(?:\\.+?){" & $n -1 & "}\\(.+?)(?:\\|$)", $aMatch = StringRegExp($sPath, $sPattern, 3)
	If Not IsArray($aMatch) Then Return SetError(1, 0, 0)
	StringReplace($sPath, '\', '')
	Return SetError(0, (@extended = 0) ? 0 : @extended -1, _WinAPI_PathSearchAndQualify($aMatch[0] & '\', False))
EndFunc   ;==>_GetNthPartOfPath


; #FUNCTION# ====================================================================================================================
; Name ..........: _GetNthPartOfPath2
; Author ........: Bitnugger
; Remarks .......: Alternative function for _GetNthPartOfPath
; ===============================================================================================================================
Func _GetNthPartOfPath2($sPath, $n)
	Local $x = StringReplace($sPath, '\', ''), $iExt = @extended -1, $iPos1 = StringInStr($sPath, '\', 0, $n), $iPos2 = StringInStr($sPath, '\', 0, $n +1) - $iPos1
	Return ($iExt < $n Or $iPos1 = 0 Or $iPos2 = 0) ? SetError(1, 0, '') : SetError(0, $iExt, _WinAPI_PathSearchAndQualify(StringMid($sPath, $iPos1 +1, $iPos2 -1) & '\', False))
EndFunc   ;==>_GetNthPartOfPath2


; #FUNCTION# ====================================================================================================================
; Name ..........: _GetNthPartOfPath3
; Author ........: Bitnugger
; Remarks .......: Alternative function for _GetNthPartOfPath
; ===============================================================================================================================
Func _GetNthPartOfPath3($sPath, $n)
	Local $aString = _StringBetween($sPath, '\', '\'),	$ub = UBound($aString)
	Return ($ub = 0 Or $ub +1 < $n) ? SetError(1, $n, '') : SetError(0, $ub, _WinAPI_PathSearchAndQualify($aString[$n -1] & '\', False))
EndFunc   ;==>_GetNthPartOfPath3




; #FUNCTION# ====================================================================================================================
; Name ..........: _RemoveNthPartOfPath
; Description ...:
; Syntax ........: _RemoveNthPartOfPath($sPath, $n)
; Parameters ....: $sPath               - Eingabepfad.
;                  $n                   - 0-basierte Nummer des Pfadteiles, der entfernt werden soll.
; Return values .: Pfad ohne n-ten Teil.
; Author ........: chesstiger
; Modified ......: Bitnugger
; Remarks .......: Achtung! Der Laufwerksbuchstabe wird nicht mitgezählt.
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _RemoveNthPartOfPath($sPath, $n)
	Local $sPattern = "^([a-zA-Z]):((?:\\.+?){" & $n -1 & "})(\\.+?)((?:\\.+?)+|$)", $sReplace = "$1:$2$4"
	$sReturn = StringRegExpReplace($sPath, $sPattern, $sReplace)
	Return (@error <> 0 Or @extended = 0) ? SetError(@error, 0, '') : SetError(0, @extended +1, _WinAPI_PathSearchAndQualify($sReturn & '\', False))
EndFunc   ;==>_RemoveNthPartOfPath


; #FUNCTION# ====================================================================================================================
; Name ..........: _RemoveNthPartOfPath2
; Author ........: Bitnugger
; Remarks .......: Alternative function for _RemoveNthPartOfPath
; ===============================================================================================================================
Func _RemoveNthPartOfPath2($sPath, $n)
	Local $x = StringReplace($sPath, '\', ''), $iExt = @extended, $iPos1 = StringInStr($sPath, '\', 0, $n), $iPos2 = StringInStr($sPath, '\', 0, $n +1)
	Return ($iExt = 0 Or $iPos2 = 0) ? SetError(1, 0, '') : SetError(0, $iExt -2, _WinAPI_PathSearchAndQualify(StringLeft($sPath, $iPos1 -1) & StringMid($sPath, $iPos2) & '\', False))
EndFunc   ;==>_RemoveNthPartOfPath2


; #FUNCTION# ====================================================================================================================
; Name ..........: _RemoveNthPartOfPath3
; Author ........: Bitnugger
; Remarks .......: Alternative function for _RemoveNthPartOfPath
; ===============================================================================================================================
Func _RemoveNthPartOfPath3($sPath, $n)
	Local $aString = StringSplit($sPath, '\', 2), $ub = UBound($aString), _
		$vRange = ($aString[$ub -1] = '') ? StringFormat('%s;%s', $ub -1, $n) : $n
	$ub = _ArrayDelete($aString, $vRange)
	Return ($ub < 0) ? SetError(1, 0, '') : SetError(0, $ub -1, _WinAPI_PathSearchAndQualify(_ArrayToString($aString, '\') & '\', False))
EndFunc   ;==>_RemoveNthPartOfPath3


; #FUNCTION# ====================================================================================================================
; Name ..........: _PrintParts
; Author ........: Bitnugger
; Remarks .......: Only for debugging...
; ===============================================================================================================================
Func _PrintParts($sPath, ByRef $aSplit)
	$aSplit = StringSplit($sPath, '\')
	If $aSplit[$aSplit[0]] = '' Then $aSplit[0] = -1 + _ArrayDelete($aSplit, $aSplit[0] )
	For $i = 1 To $aSplit[0] Step 1
		If $i = 1 Then ConsoleWrite(@CRLF & '>   ' & $aSplit[0] & ' Count of splits' & @CRLF)
		ConsoleWrite(StringFormat('+ %3i %s\n', $i, $aSplit[$i]))
	Next
EndFunc   ;==>

Alles anzeigen

PathEx_Demo

AutoIt

;-- TIME_STAMP   2017-02-10 16:38:20


#include <PathEx.au3>


Example(1)
Example(2)
Example(3)
Example(4)
Example(5)


Func Example($n = 1)
	Local Static $bLoop = False
	If $bLoop = False Then
		_SPC()
		Local $sPath = 'c:Program Files (x86)\AutoIt32SciTE\Properties\\\\properties.hide\\\', $aSplit = _GetPartsOfPath($sPath, True, True) 	; Pfad muss existieren!
		If @error Then ConsoleWrite($sPath & '! $sPath ist kein gültiger Pfad!' & @CRLF)	; <-- genau hingucken!
		_SPC()
	EndIf
	; Dieser Pfad ist auch nicht korrekt, kann aber repariert werden...
	Local $iDepth, $sPath = 'c:Program Files (x86)\AutoIt3\SciTE\Properties\\\\properties.hide\\\', $aSplit = _GetPartsOfPath($sPath, True, False) ; $bExists = True, $bShowParts = True
	If @error Then Exit 1	; kein gültiger Pfad!
	$iDepth = @extended	; Pfad muss existieren!
	If $bLoop = False Then
		ConsoleWrite(StringFormat('> $sPath  = %s\n> $sParts = %s\n+ %s\n', $sPath, $iDepth, '$sPath ist ein gültiger Pfad!'))
		$bLoop = True
		_SPC()
	EndIf
	_ArrayDisplay($aSplit, '$aSplit')
	_Print('-', '_GetNthPartOfPath    ', _GetNthPartOfPath($sPath,  $n), $n, $iDepth, @error, @extended, 'chesstiger', 'StringRegExp()')
	_Print('!', '_GetNthPartOfPath2   ', _GetNthPartOfPath2($sPath, $n), $n, $iDepth, @error, @extended, 'Bitnugger', 'StringReplace() & StringInStr()')
	_Print('!', '_GetNthPartOfPath3   ', _GetNthPartOfPath3($sPath, $n), $n, $iDepth, @error, @extended, 'Bitnugger', '_StringBetween()')
	_SPC()
	; Anzahl der verbliebenen Parts in @extended
	_Print('+', '_RemoveNthPartOfPath ', _RemoveNthPartOfPath($sPath,  $n), $n, $iDepth, @error, @extended, 'chesstiger', 'StringRegExpReplace')
	_Print('>', '_RemoveNthPartOfPath2', _RemoveNthPartOfPath2($sPath, $n), $n, $iDepth, @error, @extended, 'Bitnugger', 'StringReplace() & StringInStr()')
	_Print('>', '_RemoveNthPartOfPath3', _RemoveNthPartOfPath3($sPath, $n), $n, $iDepth, @error, @extended, 'Bitnugger', 'StringSplit()')
	_SPC()
EndFunc


Func _Print($sColor, $sFunc, $sString, $n, $iDepth, $iError, $iExtended, $sAuthor, $sComment)
	If $iError Then Return ConsoleWrite('! ' & $sFunc & @TAB & @TAB & 'Ops, der Pfad hat ' & $iDepth & ' Parts, aber $n ist !' & ' ' & $n & @CRLF & '! #Error: ' & $iError & @TAB & '#Extended:' & $iExtended & @CRLF)
	ConsoleWrite(StringFormat('%s %s|$n = %2i|$iDepth = %2i|Returned Parts in $iExtended = %2i|$sString = %-62s|%-16s|%-36s\r\n', $sColor, $sFunc, $n, $iDepth, $iExtended, $sString, $sAuthor, $sComment))
EndFunc


Func _SPC()
	ConsoleWrite('------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------' & @CRLF)
EndFunc

Alles anzeigen

AutoMit

Vielen Dank Bitnugger für die Ergänzung