_LogFile - Einfach LogFiles erstellen und schreiben

n00b-it

Guten Morgen zusammen,
ich hatte Ende 2015 mal eine kleine UDF für mich geschrieben mit der ich leichter LogFiles erstellen und schreiben kann.
Nachdem ich meine Festplatten mal aufgeräumt habe, habe ich die UDF endlich wiedergefunden.

Spoiler anzeigen

AutoIt: _LogFile.au3

#include <File.au3>
Global $h_LOG_FILE = Null
Global $s_LOG_FILE = @ScriptDir & "\" & @YEAR & "_" & @MON & "_" & @MDAY & "-logfile.log"
; #FUNCTION# ====================================================================================================================
; Name ..........: _WriteLogMessage
; Description ...:
; Syntax ........: _WriteLogMessage($i_LOG_LEVEL, $s_LOG_MESSAGE)
; Parameters ....: $i_LOG_LEVEL         - an integer value. Can be a value from 0 to 4. Each value is specifying a certain string in $a_LOG_LEVEL
;                  $s_LOG_MESSAGE       - a string value. The message to be written in the logfile
; Return values .: None
; Author ........: Philip G.
; Modified ......: 2015-10-01
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: _WriteLogMessage(1, "Das ist eine Information")
; ===============================================================================================================================
Func _WriteLogMessage($i_LOG_LEVEL, $s_LOG_MESSAGE)
	Local $a_LOG_LEVEL[] = ["Nichts ----------------", "Information -----------", "Warnung ---------------", "Fehler ----------------", "Kritischer Fehler -----"]
	__OpenLogFile()
	FileWriteLine($h_LOG_FILE, "[" & @YEAR & "-" & @MON & "-" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC & "] -> " & $a_LOG_LEVEL[$i_LOG_LEVEL] & " -> " & $s_LOG_MESSAGE)
	__CloseLogFile()
EndFunc


; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __OpenLogFile
; Description ...: Opens a logfile and returns the handle to the file
; Syntax ........: __OpenLogFile()
; Parameters ....: None
; Return values .: None
; Author ........: Philip G.
; Modified ......: 2015-10-01
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __OpenLogFile()
	If (Not FileExists($s_LOG_FILE)) Then _FileCreate($s_LOG_FILE)
	$h_LOG_FILE = FileOpen($s_LOG_FILE, 1)
	If (Not @error) Then Return $h_LOG_FILE
EndFunc


; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name ..........: __CloseLogFile
; Description ...: Closes the logfile
; Syntax ........: __CloseLogFile()
; Parameters ....: None
; Return values .: None
; Author ........: Philip G.
; Modified ......: 2015-10-01
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func __CloseLogFile(  )
	FileClose($h_LOG_FILE)
	If (Not @error) Then $h_LOG_FILE = Null
EndFunc

Alles anzeigen

Spoiler anzeigen

AutoIt: ExampleScript.au3

#include "_LogFile.au3"
_WriteLogMessage(0, "Nichts")
_WriteLogMessage(1, "Information")
_WriteLogMessage(2, "Warnung")
_WriteLogMessage(3, "Fehler")
_WriteLogMessage(4, "Kritischer Fehler")

Es ist nichts großartiges, aber vielleicht kann es mal jemand gebrauchen.

Für Tipps und Anregungen bin ich jederzeit offen

**autoiter**

Hi @n00b-it,
Ich würde die UDF um die Möglichkeit von _FileWriteLog erweitern, dass man bestimmen kann, ob die neuen Einträge immer an die Liste angehängt werden, oder als erste Zeile in der Logdatei erscheinen. Ich persönlich sehe jedenfalls die letzten Einträge gerne zuerst.

n00b-it

Hallo @autoiter,
danke für Deine Rückmeldung.
Aus diesem Blickwinkel habe ich das noch nie betrachtet. Macht eigentlich mehr Sinn, da man ja direkt den Eintrag sieht der einen Eventuellen Fehler verursacht hat.
Ich werde mal versuchen das mit einzubauen.

**Kanashius**

Da du das als UDF veröffentlichst:

AutoIt

Global $h_LOG_FILE = Null
Global $s_LOG_FILE = @ScriptDir & "\" & @YEAR & "_" & @MON & "_" & @MDAY & "-logfile.log"

Sowas schreibt man nicht, da dann die UDF editiert werden muss, wenn der Pfad geändert werden soll.

Man würde einen _Init Befehl schreiben, bei dem der Pfad übergeben werden kann(, evtl. auch mit dem Pfad als Optionalen Parameter, falls du denkst, dass viele den Aktuellen Namen nutzen würden), oder den Open/Close Befehl öffentlich machen, sodass man dort den Pfad angibt. Das würde ich auch bevorzugen, da dann auch mehrere Log-Dateien genutzt werden können, wenn die _write Funktion auch einen Parameter für den Handle bekommt. Auch macht das nutzen der open und close-funktion bei jedem write momentan keinen wirklichen sinn, da filewrite das auch intern macht. Man könnte einfach den pfad angeben

Außerdem benennt man UDF funktionen normalerweise __UDFNAME_Function, wobei UDFNAME auch ein kürzel sein kann. Bei Globalen Variablen kommt dann auch $__UDFNAME_Variable, damit kein Nutzer ausversehen die gleiche Variable anlegt und dadurch Konflikte entstehen

Dann würde man bei den Kommentaren:
;Parameters ....: $i_LOG_LEVEL - an integer value. Can be a value from 0 to 4. Each value is specifying a certain string in $a_LOG_LEVEL
Dabei noch die 5 Möglichkeiten auflisten, also sowas:

AutoIt

;Parameters ....: $i_LOG_LEVEL - an integer value. Can be a value from 0 to 4. Each value is specifying a certain string in $a_LOG_LEVEL
;                            0 - Nichts
;                            1 - Information
;...

Dann muss man als Nutzer nicht im Quellcode nachsehen, was es dort für Möglichkeiten gibt. Solche genaueren Infos kann man auch in die REMARKS schreiben

Bei größeren UDFs kann man daraus dann auch automatisch Hilfe-Dateien generieren.

Nur mal als Tipps für UDFs genannt

MfG Kanashius

**BugFix**

Logdaten werden u.U. in hoher Frequenz geschrieben. Insofern ist es nicht sinnvoll bei jedem Schreibvorgang die Datei zu öffnen, dann zu schreiben und die Datei zu schliessen.
Besser:
- globale Variable für das File-Handle $_g_fHwndLog
- eine Funktion z.B. _Log_Init(optionaler_Dateiname), die das $_g_fHwndLog für FileOpen verwendet
- Logfunktion _Log_Write(Msg), die das offene Handle nutzt
- Shutdown-Funktion _Log_ShutDown(), die mit OnAutoItExitRegister() $_g_fHwndLog schliesst.

Falls verschieden Logdateien gleichzeitig bedient werden sollen, kann kein globales HWnd verwendet werden, sondern muß beim Init als Return aufgefangen und bei jedem Schreibvorgang übergeben werden, ebenso beim Shutdown.

n00b-it

Hallo @Kanashius und @BugFix,

vielen Dank für eure Kommentare. Werde mir das alles noch mal in Ruhe zu Gemüte führen und dann alles neu umsetzten.
Eure Beiträge tragen viel zum Verständnis von UDFs bei
Hab grade auch noch diesen Link gefunden. Weiß jemand ob der aktuell ist oder ob es was aktuelleres gibt?

n00b-it

Nochmal eine Frage.
Bin ich so auf einem besseren Weg oder habe ich irgendwas falsch verstanden?

Spoiler anzeigen

AutoIt: _LogFile.au3

#include-once


#include <File.au3>
#include <FileConstants.au3>


; #INDEX# =======================================================================================================================
; Title .........: LogFile
; AutoIt Version : 3.3.14.2
; Language ......: English
; Author(s) .....: Philip G.
; Modifiers .....:
; Forum link ....: https://autoit.de/index.php/Thread/84955-LogFile-Einfach-LogFiles-erstellen-und-schreiben
; Description ...: -
; ===============================================================================================================================


; #CURRENT# =====================================================================================================================
;__LogFile_Init
;__LogFile_ShutDown
;__LogFile_Write
; ===============================================================================================================================


; #VARIABLES# ===================================================================================================================
Global $__g_fHwndLog
; ===============================================================================================================================


Func __LogFile_Init($s_LOG_FILE = @ScriptDir & "\" & @YEAR & "_" & @MON & "_" & @MDAY & "-logfile.log")
	$__g_fHwndLog = FileOpen($s_LOG_FILE, $FO_APPEND)
	If (Not @error) Then Return $__g_fHwndLog
EndFunc   ;==>__LogFile_Init


Func __LogFile_ShutDown()
	FileClose($__g_fHwndLog)
EndFunc   ;==>__LogFile_ShutDown


Func __LogFile_Write($i_LOG_LEVEL, $s_LOG_MESSAGE)
	Local $a_LOG_LEVEL[] = ["Nichts ----------------", "Information -----------", "Warnung ---------------", "Fehler ----------------", "Kritischer Fehler -----"]
	FileWriteLine($__g_fHwndLog, "[" & @YEAR & "-" & @MON & "-" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC & "] -> " & $a_LOG_LEVEL[$i_LOG_LEVEL] & " -> " & $s_LOG_MESSAGE)
EndFunc   ;==>

Alles anzeigen

Spoiler anzeigen

AutoIt: Example.au3

#include "_LogFile.au3"


OnAutoItExitRegister("__LogFile_ShutDown")


MsgBox(0, "ANFANG", "ANFANG")


__LogFile_Init()


__LogFile_Write(0, "Nichts")
__LogFile_Write(1, "Information")
__LogFile_Write(2, "Warnung")
__LogFile_Write(3, "Fehler")
__LogFile_Write(4, "Kritischer Fehler")


MsgBox(0, "ENDE", "ENDE")

Alles anzeigen

**Kanashius**

Jo, das ist schon der richtige Weg. Ob man mehrere Logfiles möchte ist natürlich persönliche Meinung, ansonsten höchstens noch $__g_fHwndLog mit LogFile benennen (mach ich zumindest immer ).
Schaut aber sehr gut aus jetzt

**BugFix**

Zitat von Kanashius

Ob man mehrere Logfiles möchte ist natürlich persönliche Meinung

Das ist eher konzeptabhängig. Wenn jedes Event geloggt wird ist es durchaus auch sinnvoll, im Interesse der besseren Auswertbarkeit, Logs für allgemeine Events und Events für Fehler zu trennen.

**Bitnugger**

AutoIt

Func __LogFile_Write($i_LOG_LEVEL, $s_LOG_MESSAGE)
	Local $a_LOG_LEVEL[] = ["Nichts ----------------", "Information -----------", "Warnung ---------------", "Fehler ----------------", "Kritischer Fehler -----"]
	FileWriteLine($__g_fHwndLog, "[" & @YEAR & "-" & @MON & "-" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC & "] -> " & $a_LOG_LEVEL[$i_LOG_LEVEL] & " -> " & $s_LOG_MESSAGE)
EndFunc   ;==>

Zu Zeile 2:
Local $a_LOG_LEVEL[] = [...] ; wenn du keinen Wert angibst, kannst du die [] auch weglassen.
Local $a_LOG_LEVEL = [...]

"Nichts ----------------"; Hust... da kann ich geistig nicht folgen, wofür das gut sein soll.

Zu Zeile 3:
FileWriteLine($__g_fHwndLog, ... ; Kann bitte mal jemand diesen Variablennamen aufschlüsseln?
FileWriteLine($__g_hLog, ... ; wäre doch treffender?!

Ansonsten würde ich die Funktion eher so schreiben...

AutoIt

Func __LogFile_Write($hLOG, $iLOG_LEVEL, $sLOG_MESSAGE)
	; Static Variablen existieren nur innerhalb der Funktion in der sie deklariert wurden, aber sie existieren weiter und behalten ihren letzten Wert, nachdem die Ausführung der Funktion beendet ist.
	Local Static $_FO_LOG = '[%s/%s/%s %s:%s:%s] -> %s -> %s', _
		$_aLOG_LEVEL = ["Nichts ----------------", _
				"Information -----------", _
				"Warnung ---------------", _
				"Fehler ----------------", _
				"Kritischer Fehler -----"]


;~ 	ConsoleWrite(StringFormat($_FO_LOG, @YEAR, @MON, @MDAY, @HOUR, @MIN, @SEC, $_aLOG_LEVEL[$iLOG_LEVEL], $sLOG_MESSAGE) & @CRLF)
	FileWriteLine($hLOG, StringFormat($_FO_LOG, @YEAR, @MON, @MDAY, @HOUR, @MIN, @SEC, $_aLOG_LEVEL[$iLOG_LEVEL], $sLOG_MESSAGE))
EndFunc   ;==>__LogFile_Write

Alles anzeigen