Passwortgeschützte Dateien öffnen

Kinemod

Hallo zusammen,

ich habe eine Frage bezüglich passwortgeschützte Dateien. Ich habe in der Autoit-Hilfe gelesen, dass man Word- bzw. Excelldateien öffnen kann auch wenn diese mit Passwort geschützt sind.
Meine Frage nun:
Kann man auch andere passwortgeschützte Dateien via Autoitskript öffnen, z.B. pdf's, zip's oder sonst was? Wenn ja, wie geht das? Muss man dafür "spezielle" UDF's (nach-)laden?

**water**

Passwortgeschützte Word und Excel-Dateien kannst Du nur öffnen, wenn Du das Passwort mitgibst.
Es gibt UDFs um passwortgeschützte ZIP Dateien zu entpacken bzw. neue Inhalte hinzuzufügen.
Die Lösung hängt also immer vom Dateityp ab.
Was hast Du genau vor?

Kinemod

Nun ich habe eigentlich nichts bestimmtes vor...
Ich habe mir lediglich überlegt, ob ich eben aus einem Autoitskript auch eine pdf oder andere passwortgeschützte Datei öffnen könnte.
Ich habe dann in der Hilfe nachgelesen was z.B. bei fileOpen steht und konnte nirgends (ausser Word und Excell eben) eine Funktion finden, die eine passwortgeschützte Datei öffnet. Also habe ich mich weiter gefragt, ob Autoit das überhaupt kann?

Also angenommen ich bekommen eine passwortgeschützte pdf und möchte diese mit einem Autoitskript öffnen (Passwort wäre natürlich vorhanden), wäre dies überhaupt möglich? (Ich weiss das Beispiel ist sehr an den Haaren herbei gezogen. Ich könnte ja das Passwort einfach eingeben, aber so auf die Schnelle ist mir jetzt nichts Schlaues in den Sinn gekommen)

Es könnte auch eine Libre-Office Datei sein. Bei der könnte ich wahrscheinlich auch nicht auf die Word- bzw. Excellfunktionen von Autoit zurückgreifen, oder?

**Bitnugger**

Hier hast du mal einen groben Ansatz wie man das angehen könnte... der ist allerdings schon stark angestaubt und auch extrem verbesserungsbedürftig.

Automatische PDF-Passworteingabe

Wie @water schon sagte, die Lösung hängt immer vom Dateityp und der dafür verwendeten Software ab, mit dem dieser geöffnet werden soll.

Ich habe mir z. B. ein Script geschrieben, mit dem ich den PAGEANT von Putty beim Systemstart aufrufe und ihm die Passphrasen für meine RSA-Keys übergebe. Denn das sind mal ein paar und die sind ätzend lang... mindestens 64 Zeichen! Die speichere ich dann 2x verschlüsselt in ein IniFile ab und kann sie dann wahlweise mit oder ohne Masterpasswort entschlüsseln und an PAGEANT übergeben.

Hier mal eine abgespeckte und leicht zu verstehende Version ohne Verschlüsselung... vom Prinzip her auch auf PDF bzw. Adobe Reader usw. anwendbar.

PAGENTX

AutoIt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseUpx=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


;-- TIME_STAMP   2016-09-28 12:08:38


#include <Array.au3>
#include <WinAPI.au3>


_Main()


Func _Main()
	Local $aKey = ['rsa-key-20161201-gast.ppk', 'rsa-key-20161201-batch.ppk', 'rsa-key-20161201-root.ppk', 'rsa-key-20161201-User.ppk', 'rsa-key-20161210-VM.ppk']
	Local $sKey = _ArrayToString($aKey, ' ')
	Local $hPAGEANT, $sWinText, $sKeyName, $bIsKey
	Local $sPageantWinTitle = 'Pageant: Enter Passphrase'
	Local $idPageantEdit1 = 102


	Local $iPID = Run('"c:\Program Files (x86)\TC UP\Plugins\Tools\Putty\PAGEANT.EXE" ' & $sKey, _WinAPI_ExpandEnvironmentStrings('%MPK%'), @SW_SHOW)
	$aKey = ''


	Local $aPP = [	['rsa-key-20161210-VM',		'xAx7dJOkgtrO&dsUzrHM4AZwwOvvOd%wOEbwOrzes3$RGNs&&wOJXwXE5NxkJPzg'], _
			['rsa-key-20161201-User',	'8UICcb$7Ed4#o#RW2RF9AG$ipJrb2$Px#S##n8gb8Mj9tKSdMXGdzK6hgscXhD%T'], _
			['rsa-key-20161201-root',	'i9%2ebEAGMJdGDeu8Qr7fL82OikALmHGNs&&QPn$RwOJXwXE5N4JPz9jANbb84O4'], _
			['rsa-key-20161201-batch',	'Y8GtPubzrHM4AM89dsUZvOd%q5L8&h77wMgAGQl2qbcUWNSzSjIP9oUC4&z#pKdK'], _
			['rsa-key-20161201-gast',	'CDHUoZJtd$Cil26IrItreJKqMF$9CfzwG4JLLhncRdkt9%XtoEq4Q7NneRDCr4ZI']]


	For $i = UBound($aPP) -1 To 0 Step -1
		$hPAGEANT = WinWaitActive($sPageantWinTitle, '', 3)
		If $hPAGEANT = 0 Then Exit 1
		$sWinText = WinGetText($sPageantWinTitle)
		$sKeyName = StringSplit($sWinText, @LF)[2]
		If $sKeyName = "" Then Exit 2
		$bIsKey = ($sKeyName = $aPP[$i][0])
		If $bIsKey = False Then _CW(StringFormat('! "%-30s" "%-30s" = %-5s', $sKeyName & '.ppk', $aPP[$i][0], ($sKeyName & '.ppk' = $aPP[$i][0] & '.ppk')) & @CRLF)
		If $bIsKey = True Then
			_CW(StringFormat('+ %-30s %-30s = %-5s', '"' & $sKeyName & '.ppk', $aPP[$i][0], ($sKeyName & '.ppk' = $aPP[$i][0] & '.ppk')) & @CRLF)
			_CW('ControlSetText ' & $aPP[$i][1] & ' = ' & ControlSetText($sPageantWinTitle, '', $idPageantEdit1, $aPP[$i][1], $SEND_RAW) & @CRLF)
			Send('{Enter}')
			_ArrayDelete($aPP, $i)
		EndIf
	Next
EndFunc


Func _CW($sString)
	If @Compiled = 0 Then ConsoleWrite($sString)
EndFunc

Alles anzeigen

Kinemod

Ich hab mir ein weiteres Szenario ausgedacht:

Sagen wir ich habe eine Eingabemaske mit Autoit erstellt und die Eingaben werden in eine kleine passwortgeschützte Datenbank (Access oder so) geschrieben.

Wenn ich die Beispiele richtig gelesen habe, habe ich eigentlich nur die Möglichkeit das Passwort mittels Send() zu übergeben?

**Bitnugger**

Zitat von Kinemod

Sagen wir ich habe eine Eingabemaske mit Autoit erstellt und die Eingaben werden in eine kleine passwortgeschützte Datenbank (Access oder so) geschrieben.

Ja und dann? Soll Access die Passwörter schützen? Das kannst du mit AutoIt auch sehr gut machen. Dafür gibt es z. B. die Funktionen _Crypt_EncryptData() und _Crypt_DecryptData()

Die essentielle Frage ist jedoch, welches Programm und welchen Datentyp du am Ende benutzt, wodurch sich mehrere Lösungsansätze ergeben, wie man das dann bewerkstelligen kann.

Send() ist eine dieser Möglichkeiten... es geht je nach Fall sicher auch mit ControlSetText() oder _SendMessage()... bzw. mit _FileDragDrop()... oder man kann das Programm mit speziellen Parametern starten... doch ohne einen konkreten Fall führt das hier ins Nirwana! Im Prinzip sind es lediglich 'sensible' Informationen, die du von A nach B bekommen musst... dies geht allerdings nur dann, wenn B dafür eine Möglichkeit bietet.

Kinemod

Zitat von Bitnugger

Ja und dann? Soll Access die Passwörter schützen? Das kannst du mit AutoIt auch sehr gut machen. Dafür gibt es z. B. die Funktionen _Crypt_EncryptData() und _Crypt_DecryptData()

Nein! Die Accessdatei soll die passwortgeschützte Datei sein (Was drin steht ist Wurscht!) und die soll geöffnet werden um die Eingaben "aufzunehmen".

Zitat von Bitnugger

... doch ohne einen konkreten Fall führt das hier ins Nirwana!

Stimme dir zu, hab aber trotzdem keinen konkreteren Fall...Sorry!

**Bitnugger**

Hier mal ein Beispiel wie es mit Access geht...

Access_SetPW

AutoIt

;-- TIME_STAMP   2017-02-06 13:04:57


#include <WinAPISys.au3>
#include <Array.au3>


; ******************************************************************************
; DB mit ShellEcecute() oder ... öffnen - Access fragt dann nach dem Passwort...
; ******************************************************************************


; Einfache Verschlüsselung ;-)
Global $sPW = BitXOR('435', 456)	; PW = 123
ConsoleWrite($sPW & @CRLF)


Global $hAccess = WinGetHandle('[TITLE:Access; CLASS:OMain]')
If Not IsHWnd($hAccess) Then Exit MsgBox(0, @ScriptName, 'Access-Handle nicht gefunden!') +1
ConsoleWrite('$hAccess = '  & $hAccess & @CRLF)


;_ShowChildWindows()	; Brauchen wir doch nicht...


Global $hStatic2 = ControlGetHandle('Kennwort erforderlich', 'Datenbankkennwort eingeben', '[CLASS:Static; INSTANCE:2]')	; Label
If Not IsHWnd($hStatic2) Then Exit MsgBox(0, @ScriptName, 'Access - "Static2" nicht gefunden!') +3
ConsoleWrite('$hStatic2 = ' & $hStatic2 & @CRLF)


Global $hRichEdit20W1 = ControlGetHandle('Kennwort erforderlich', '', '[CLASS:RichEdit20W; INSTANCE:1]')	; hier musss das Passwort rein!
If Not IsHWnd($hRichEdit20W1) Then Exit MsgBox(0, @ScriptName, 'Access - "RichEdit20W1" nicht gefunden!') +3
ConsoleWrite('$hRichEdit20W1 = ' & $hRichEdit20W1 & @CRLF)


Global $iSend = ControlSend($hRichEdit20W1, '', '', '123' & '{ENTER}')
If $iSend = 0 Then Exit MsgBox(0, @ScriptName, 'Access - Senden an "RichEdit20W1" hat nicht geklappt!') +4


ConsoleWrite('Das Passwort sollte angekommen sein und die DB nun editierbar sein' & @CRLF)


Func _ShowChildWindows()
	Local $aChildWindows = _WinAPI_EnumChildWindows($hAccess)
	If $aChildWindows[0][0] = 0 Then Exit MsgBox(0, @ScriptName, 'Access-ChildWindows nicht gefunden!') +2
	ConsoleWrite('$aChildWindows[0][0] = ' & $aChildWindows[0][0] & @CRLF & @CRLF)
	For $i = 1 To $aChildWindows[0][0] Step 1
		Local $hCtrl = $aChildWindows[$i][0]
		Local $sClassName = $aChildWindows[$i][1]
		Local $sCtrlText = StringStripWS(ControlGetText('', '', $hCtrl), 8)
		Local $sWinText = StringStripWS(StringLeft(WinGetText($hCtrl), 26) & '...', 8)
		Local $sTitle = StringStripWS(StringLeft(WinGetTitle($hCtrl), 26) & '...', 8)
		ConsoleWrite(StringFormat('$hCtrl: %10s    $sClassName: %-28s    $sCtrlText: %-28s    $sWinText: %-28s    $sTitle: %-28s', $hCtrl, $sClassName, $sCtrlText, $sWinText, $sTitle) & @CRLF)
	Next
EndFunc

Alles anzeigen

Kinemod

Vielen Dank für die Bemühungen. Meinen Frage wurde grundsätzlich beantwortet aber ich merke ich muss noch viiiiiiiiiiiiiiiiiiiiiiiel lernen und üben...

**alpines**

Super das alles geklappt hat. Es wäre schön wenn du den grünen Haken für erledigt / gelöst setzen könntest, damit andere Nutzer in der Zukunft ebenfalls eine Lösung parat haben.
Das ganze kannst du bewerkstelligen indem du den 1. Beitrag in diesem Thread editierst und den Threadstatus anpasst.