Variable in Dateiname

Hingo

Moin,
mein Problem ist Folgendes.
Mein Skript generiert eine PDF Datei, die BPCS Checkliste heißt, jetzt soll hinter dem Namen noch die MacAdresse des Computers stehen.
Die MacAdresse wird im Programm selber schon ausgewertet.

AutoIt

#include <Date.au3>
#include <MPDF_UDF.au3>
#include <File.au3>


$dir    = "C:\logs\"
$file1  = "C:\logs\BPCS Checkliste__.txt"
$file2  = "C:\logs\BPCS Checkliste_.txt"
$getmac = "C:\logs\BPCS Checkliste.txt"


If Not FileExists($dir) Then DirCreate ($dir)


FileOpen($file1, 2)
FileWrite($file1,"                                                                          BPCS Checkliste"&@CRLF)
FileWrite($file1,"                     ================================================================"&@CRLF)
FileWrite($file1, "                      Current Date:                                                                                            " & _NowDate()&@CRLF)
FileWrite($file1, "                      Current Time:				                                                                                           " & _NowTime()&@CRLF)
FileWrite($file1, ""&@CRLF)
FileWrite($file1, "                      **************************************Computer Data***************************************"&@CRLF)
FileWrite($file1, "                      Serial number:"&@CRLF)






Global $objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Global $colAdapters = $objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration")


$str  = ""


For $objAdapter in $colAdapters
	If $objAdapter.MacAddress = Null Then
	Else
		FileWrite($file1, "                      Physicaladdress:                                                                        " & $objAdapter.MacAddress &@CRLF)
	EndIf
Next




FileOpen($getmac, 2)
FileWrite($getmac, FileRead($file1) & @CRLF & FileRead($file2))
FileClose($file2)
FileClose($getmac)


#cs
======================================================================================================================================================================================================
;Einstellungen für die PDF Erstellung
======================================================================================================================================================================================================
#ce
_SetTitle("BPCS Checkliste")
_SetSubject("BPCS Checkliste to pdf")
_SetKeywords("pdf, AutoIt")
_OpenAfter(True);PDF nach Erstellung öffnen
_SetUnit($PDF_UNIT_CM)
_SetPaperSize("A4")
_SetZoomMode($PDF_ZOOM_CUSTOM, 70)
_SetOrientation($PDF_ORIENTATION_PORTRAIT)
_SetLayoutMode($PDF_LAYOUT_CONTINOUS)


;initialize the pdf
_InitPDF("C:\logs\BPCS Checkliste.pdf")
_LoadFontTT("F1", $PDF_FONT_NORMAL)
_Txt2PDF($getmac, "F1")


;write the buffer to disk
_ClosePDFFile()


#cs
#FUNCTION# ===========================================================================================================================================================================================
Name ..........: _Txt2PDF
Description ...: Convert a text file to pdf
======================================================================================================================================================================================================
#ce


Func _Txt2PDF($sFile, $sFontAlias)
	Local $hFile = FileOpen($sFile)
	Local $sText = FileRead($hFile)
	FileClose($hFile)
	Local $iUnit = Ceiling(_GetUnit())
	Local $iX = 2
	Local $iY = Ceiling(_GetPageHeight() / _GetUnit()) - 1.5
	Local $iPagina = Ceiling(_GetPageWidth() / $iUnit) - $iX
	Local $iWidth = Ceiling($iPagina - $iX)
	Local $lScale
	Local $iRanduri = StringSplit($sText & @CRLF & @CRLF & @CRLF & @CRLF, @CRLF, 3)
	Local $iHR = 0.5 * Ceiling($iY / (10 * $iUnit))
	Local $iPages = Ceiling((UBound($iRanduri)) * $iHR / $iY)
	Local $iNrRanduri = Ceiling(UBound($iRanduri) / $iPages-2)
	Local $nrp
	For $j = 0 To $iPages + 2
		$nrp = _BeginPage()
		_DrawText(_GetPageWidth()/_GetUnit()-1, 1, $nrp, "F1", 10, $PDF_ALIGN_CENTER)
		For $i = 0 To $iNrRanduri - 1
			Local $sLength = Round(_GetTextLength($iRanduri[$i + $j * $iNrRanduri], $sFontAlias, 10))
			Local $iH = $iY - $iHR * ($i + 1)
			Select
				Case $iH < 1
					_EndPage()
				Case $i + $j * $iNrRanduri = UBound($iRanduri) - 1
					_EndPage()
					Return
				Case $sLength > $iWidth - 1
					$lScale = Ceiling($iWidth * 100 / $sLength)
					_SetTextHorizontalScaling($lScale)
					_DrawText($iX, $iH, $iRanduri[$i + $j * $iNrRanduri], $sFontAlias, 10, $PDF_ALIGN_LEFT, 0)
					_SetTextHorizontalScaling(100)
				Case Else
					_DrawText($iX, $iH, $iRanduri[$i + $j * $iNrRanduri], $sFontAlias, 10, $PDF_ALIGN_LEFT, 0)
			EndSelect
		Next
		_EndPage()
	Next
EndFunc   ;==>_Txt2PDF


FileDelete($file1)
FileDelete($file2)
FileDelete($getmac)

Alles anzeigen

Vielleicht könnt ihr mir helfen.

**alpines**

Ist doch klar warum. Die MAC-Adresse wird mit einem Doppelpunkt abgegrenzt und Dateinamen mit Doppelpunkten (bis auf die Laufwerkangabe) sind unzulässig.
StringReplace die ":" mit "-".

Du musst außerdem (wenn du auf .MacAddress) nach der Schleife zugreifen willst das irgendwo zwischenspeichern und dann von dort abrufen da du ja bei _InitPdf schon aus der WMI-For-Schleife raus bist.

Hingo

Habe ich mir angeguckt, check ich nicht was du mir damit sagen willst.

AutoIt

StringReplace("C:\logs\BPCS Checkliste.pdf", ":", "-")

**alpines**

Refresh mal und lies den bearbeiteten Beitrag.

Du sprachst von InitPdf in der SB also musst du die Mac-Adresse StringReplacen wenn du in eine Datei damit schreibst. Nicht einfach den String und trotzdem dahinter noch die Mac-Adresse dransetzen.

**Oscar**

Ich habe Dir Dein Script mal angepasst. Das zwischenspeichern der Teilstrings auf Festplatte ist völlig überflüssig, wenn man die Funktion "_Txt2PDF" etwas anpasst.
Hier mal meine Version:

AutoIt

#include <Date.au3>
#include <MPDF_UDF.au3>
#include <File.au3>


$dir = "C:\logs\"


If Not FileExists($dir) Then DirCreate($dir)


Global $sData = ""
$sData &= "                                                                          BPCS Checkliste" & @CRLF
$sData &= "                     ================================================================" & @CRLF
$sData &= "                      Current Date:                                                                                            " & _NowDate() & @CRLF
$sData &= "                      Current Time:				                                                                                           " & _NowTime() & @CRLF & @CRLF


$sData &= "                      **************************************Computer Data***************************************" & @CRLF
$sData &= "                      Serial number:" & @CRLF






Global $objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Global $colAdapters = $objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration")


$str = ""
$sMacAddress = ""
For $objAdapter In $colAdapters
	If $objAdapter.MacAddress <> Null Then
		$sMacAddress = $objAdapter.MacAddress
		$sData &= "                      Physicaladdress:                                                                         " & $sMacAddress & @CRLF
	EndIf
Next
$sMacAddress = StringReplace($sMacAddress, ":", "_") ; Doppelpunkte sind im Dateinamen nicht zugelassen, deshalb austauschen gegen den Unterstrich




#cs
	======================================================================================================================================================================================================
	;Einstellungen für die PDF Erstellung
	======================================================================================================================================================================================================
#ce
_SetTitle("BPCS Checkliste")
_SetSubject("BPCS Checkliste to pdf")
_SetKeywords("pdf, AutoIt")
_OpenAfter(True);PDF nach Erstellung öffnen
_SetUnit($PDF_UNIT_CM)
_SetPaperSize("A4")
_SetZoomMode($PDF_ZOOM_CUSTOM, 70)
_SetOrientation($PDF_ORIENTATION_PORTRAIT)
_SetLayoutMode($PDF_LAYOUT_CONTINOUS)


;initialize the pdf
_InitPDF("C:\logs\BPCS Checkliste_" & $sMacAddress & ".pdf")
_LoadFontTT("F1", $PDF_FONT_NORMAL)
_Txt2PDF($sData, "F1")


;write the buffer to disk
_ClosePDFFile()


#cs
	#FUNCTION# ===========================================================================================================================================================================================
	Name ..........: _Txt2PDF
	Description ...: Convert a text file to pdf
	======================================================================================================================================================================================================
#ce
Func _Txt2PDF($sFile, $sFontAlias)
	If $sFile = "" Then Return SetError(1, 0, 0)
	Local $sText = ""
	If FileExists($sFile) Then ; wenn $sFile eine Datei ist, dann...
		$sText = FileRead($sFile) ; Datei laden
	Else ; ansonsten...
		$sText = $sFile ; $sFile als Text interpretieren
	EndIf
	Local $iUnit = Ceiling(_GetUnit())
	Local $iX = 2
	Local $iY = Ceiling(_GetPageHeight() / _GetUnit()) - 1.5
	Local $iPagina = Ceiling(_GetPageWidth() / $iUnit) - $iX
	Local $iWidth = Ceiling($iPagina - $iX)
	Local $lScale
	Local $iRanduri = StringSplit($sText & @CRLF & @CRLF & @CRLF & @CRLF, @CRLF, 3)
	Local $iHR = 0.5 * Ceiling($iY / (10 * $iUnit))
	Local $iPages = Ceiling((UBound($iRanduri)) * $iHR / $iY)
	Local $iNrRanduri = Ceiling(UBound($iRanduri) / $iPages - 2)
	Local $nrp
	For $j = 0 To $iPages + 2
		$nrp = _BeginPage()
		_DrawText(_GetPageWidth() / _GetUnit() - 1, 1, $nrp, "F1", 10, $PDF_ALIGN_CENTER)
		For $i = 0 To $iNrRanduri - 1
			Local $sLength = Round(_GetTextLength($iRanduri[$i + $j * $iNrRanduri], $sFontAlias, 10))
			Local $iH = $iY - $iHR * ($i + 1)
			Select
				Case $iH < 1
					_EndPage()
				Case $i + $j * $iNrRanduri = UBound($iRanduri) - 1
					_EndPage()
					Return
				Case $sLength > $iWidth - 1
					$lScale = Ceiling($iWidth * 100 / $sLength)
					_SetTextHorizontalScaling($lScale)
					_DrawText($iX, $iH, $iRanduri[$i + $j * $iNrRanduri], $sFontAlias, 10, $PDF_ALIGN_LEFT, 0)
					_SetTextHorizontalScaling(100)
				Case Else
					_DrawText($iX, $iH, $iRanduri[$i + $j * $iNrRanduri], $sFontAlias, 10, $PDF_ALIGN_LEFT, 0)
			EndSelect
		Next
		_EndPage()
	Next
EndFunc   ;==>_Txt2PDF

Alles anzeigen

Hingo

Jo perfekt.
Danke an euch.

bazii

Hallo Hingo,

ist das Thema hier nun erledigt? Es geht meiner Meinung nach um das gleiche und fast um das selbe Thema. alpines hat Dich bereits darauf angesprochen, das Thema auf gelöst zu setzen.

Hingo

Moin, ich hab das Thema doch schon als erledigt markiert.
Und bei dem anderen Thema ist noch eine Frage offen (der letzte Beitrag von mir).