In Textdatei suchen

DerSchatten

Ich möchte gerne eine Textdatei nach bestimmten begriffen durchsuchen und dementrpechend dann Felder mit diesen Daten füllen.
Dazu habe ich folgendes Script erstellt:

C

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
#include <File.au3>


GUICreate("Konfigurationsdaten", 964, 600)
$label_knummer = GUICtrlCreateLabel("Konfignummer:", 25, 194, 70, 31)
$input_knummer = GUICtrlCreateInput("", 110, 190, 50, 20)


$label_benutzer = GUICtrlCreateLabel("Hauptbenutzer:", 25, 300, 70, 31)
$input_benutzer = GUICtrlCreateInput("", 110, 300, 100, 20)


Local $button_ok = GUICtrlCreateButton("Ok", 40, 75, 60, 20)


GUISetState(@SW_SHOW)


While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $button_ok
				read()
        EndSwitch
WEnd


Func read()
	$datei = FileOpen("Y:\BRZ\PAR\" & GUICtrlRead($input_knummer) & "\config.vrs")
	$cLine = _FileCountLines($datei)


For $i = 0 To $cLine
	Local $zeile = FileReadLine($datei, $i)
;	If Stringleft($zeile,10) = "Benutzer='" then GUICtrlSetData($input_benutzer, StringTrimRight(StringTrimLeft($zeile, 10),1))
	If StringInStr($zeile, "Benutzer='") Then GUICtrlSetData($input_benutzer, StringTrimRight(StringTrimLeft($zeile, 10),1))


Next


;	FileClose($datei)
EndFunc

Alles anzeigen

Funktioniert allerdings noch nicht.

Könnt Ihr mir da weiterhelfen?

Hingo

Moin,
was soll denn in Konfignummer und Hauptbenutzer rein?

**alpines**

Ein kurzer Blick in die Dokumentation von FileReadLine verrät uns das die 1. Zeile keine 0 sondern eine 1 ist.
Wenn es eine 0 wäre hättest du bei deiner For-Schleife eh eine Zeile zu viel.

DerSchatten

danke, aber funkt trotzdem nicht.
Die Schleife läuft nicht mal an.

Die Textdatei sieht in etwa so aus:

Code

[Konfiguration]
DatConfig='2017-01-31'


Kunde='BRZ'
PC#=00009
OS=W7P
UID-PW=J
VERSCHL=N
VERSCHLBEZ=
Pool=N
TestPC=N
TestInstall=J


AutoInst=Ja
AutoInstTest=Nein
AutoKonf=Ja
AlleProd=Nein


Benutzer='Max Mustermann'

Alles anzeigen

Also er soll die Stelle "Benutzer='" suchen und den Text daneben (Max Mustermann) in das Eingabefeld $input_benutzer schreiben.

**AspirinJunkie**

Da der Aufbau dem einer Ini-Datei entspricht, bieten sich die entsprechenden Funktionen hierfür an:

AutoIt

Global $s_IniPath = "Test.ini"


Global $s_Benutzer = IniRead($s_IniPath, "Konfiguration", "Benutzer", '')


MsgBox(0,"", "Benutzer: " & $s_Benutzer)

**alpines**

Ist der Pfad zur Datei überhaupt richtig? Was gibt _FileCountLines zurück?

DerSchatten

Ähm, 0 ?
Kann es sein das mir GUICtrlRead Zahlen mit führenden 0 kürzt?

In $input_knummer wird zb. "00009" eingegeben.

**alpines**

Zitat von DerSchatten

Kann es sein das mir GUICtrlRead Zahlen mit führenden 0 kürzt?

Nein das tut es nicht. Lass dir mal den Pfad in einer MsgBox ausgeben und geh den selben Pfad im Explorer. Ich bin mir sicher das dein Pfad nicht stimmt.
Alleine die Laufwerkangabe verunsichert mich schon ein wenig.

DerSchatten

Nein, also der Pfad passt.
Den habe ich jetzt auch mal direkt eingetragen. Ist ein Netzlaufwerk:

Code

Func read()


	$datei = FileOpen("Y:\BRZ\PAR\00009\CONFIG.VRS")
	$cLine = _FileCountLines($datei)
	MsgBox(0,"",$datei & " " & $cLine)


For $i = 1 To $cLine
  Local $zeile = FileReadLine($datei, $i)
  If StringInStr($zeile, "Benutzer='") Then GUICtrlSetData($input_benutzer, StringTrimRight(StringTrimLeft($zeile, 10),1))
Next


EndFunc

Alles anzeigen

Der Wert von $datei erhöht sich dabei nach jedem Aufruf der Funktion.
$cLine bleibt immer 0. Der Zähler funkt nicht.

**AspirinJunkie**

_FileCountLines akzeptiert nur einen Pfad als String und kein bereits offenes Handle.
Mal davon abgesehen iteriert man nicht durch eine Datei per Zeilenparameter sondern lässt die Funktion selbst immer weiter weiter springen.
Es braucht dann auch kein _FileCountLines mehr vorher.
Kurz: Der zweite Parameter von FileReadline ist böse wenn man alle Zeilen einer Datei durchgehen möchte.

Unabhängig davon brauchst du es, wie ich oben schon schrieb im Grunde überhaupt nicht zeilenweise durchzugehen.

DerSchatten

Super! das funktioniert wirklich perfekt.

Noch eine Frage dazu:

In einem Feld bekomme ich als Ergebniss nur eine Zahl.

Diese zahl möchte ich nun einem Text zuordnen.
Also 11 zb. soll den Wert "Samsung" ergeben.

Wie löse ich das am besten?

Mit einzelnen IF ... THEN wäre das recht umfangreich.

Ich dachte mir so eine Art Daten-Tabelle zu erstellen, aus der einfach der passende Wert herausgelesen wird.

Also:

"11", "Samsung"
"12", "DELL"
"13", "HP"
....

**alpines**

Du könntest ein Array verwenden und den Index als Nummer nehmen oder ein zweidimensionales Array in dem [x][0] Die Markennummer und [x][1] die Marke ist.

**autoiter**

~~Hallo @DerSchatten,~~

~~Du kannst ein Array anlegen.~~

~~$Array[x][2] = ["11", "Samsung"]["12", "Dell"]...~~
~~Dann etwa einfach in For Schleife ein StringReplace oder mit _ArraySearch den Treffer-Index ermitteln und dann die entsprechende Änderung vornehmen.~~

alpines hat es bereits geschrieben.

**alpines**

@autoiter Zu langsam...

DerSchatten

kann ich das in einer extra Funktion erstellen oder muß das in der gleichen sein wo die Datei ausgelesen wird?

**AspirinJunkie**

Alternativ hierzu wäre auch ein Dictionary möglich.
Damit würde das Durchsuchen des Arrays entfallen um den gewünschten Wert zu ermitteln (außer natürlich bei der Methode wo die Zahl=ArrayIndex).
Bsp:

AutoIt

$o_Marken = ObjCreate("Scripting.Dictionary")
$o_Marken("11") = "Samsung"
$o_Marken("12") = "DELL"
$o_Marken("13") = "HP"


$s_Zahl = String(12)


MsgBox(0,"", $s_Zahl & " = " &  $o_Marken($s_Zahl))

treFFnix

Hallo, wo ihr gerade beim Thema "in Textdatei suchen" seid...

habe hier auch einen Beitrag für diese Seite. Es ist ein Tool, was Textdateien durchsucht, und Zeilen, die eine bestimmte Zeichenkette enthalten (einstellbar) in eine andere Datei "Ergebnisdatei" schreibt.

Ich zum Beispiel, habe damit Logdateien mit mehreren Tausenden Zeilen durchsucht und mir wichtige Zeilen rausgefiltert.
Ich habe die erste Version auch mit Zeilenweisen "StringInStr"... das hat aber 100x länger gedauert, als die Lösung die ich gestern mit _ArraySearch erarbeitet habe:

C

#include <Array.au3>
#include <File.au3>


OnAutoItExitRegister("_OnExit")


Global $debugmodus = 0


Global $suchstring
Global $dateiname_Ergebnisdatei
Global $enddateiname


Global $file2


Global $aDatei_eingelesen[1]
Global $aText_extrahiert[1]


Global $Suchoptionen


;Dateien auswählen
Global $files[1], $akt_file = ""
While 1
	$akt_file = ""
	$akt_file = FileOpenDialog("Datei wählen", @ScriptDir, "All (*)", 4)
	If $akt_file = "" Then
		ExitLoop(1)
	ElseIf StringInStr($akt_file, "|") Then
		Local $multiselsected = StringSplit($akt_file, "|")
		For $temp_i = 2 To $multiselsected[0]
			_ArrayAdd($files, $multiselsected[1] & "\" & $multiselsected[$temp_i])
		Next
	Else
		_ArrayAdd($files, $akt_file)
	EndIf
WEnd
_ArrayDelete($files, 0)
$files = _ArrayUnique($files)
If Not IsArray($files) Then
	MsgBox(16, "Beende", "Es wurde keine zu durchsuchenden Dateien angegeben", 2)
	Exit
EndIf


;Eingeben lassen, was gesucht werden soll
Global $akt_suchstring, $suchstrings[1]


$akt_suchstring = InputBox("Zeichenkette", "zu suchende Zeichenkette:")
If $akt_suchstring = "" Then
	MsgBox(16, "Beende", "Es wurde kein Suchstring angegeben", 2)
	Exit
Else
	_ArrayAdd($suchstrings, $akt_suchstring, Default, @CRLF)
	$Suchoptionen = $akt_suchstring
EndIf


While $akt_suchstring <> ""
	$akt_suchstring = InputBox("weitere zu Suchende Zeichenkette eingeben", "zu suchende Zeichenkette angeben: " & @CRLF & "ESC bzw. Abbrechen = keine weitere Zeichenkette")
	If $akt_suchstring <> "" Then
		_ArrayAdd($suchstrings, $akt_suchstring, Default, @CRLF)
		$Suchoptionen &= ", " & $akt_suchstring
	EndIf


WEnd


_ArrayDelete($suchstrings, 0)
$suchstrings = _ArrayUnique($suchstrings)




;Dateiname für die Ergebnisdatei
$dateiname_Ergebnisdatei = InputBox("Dateiname Ergebnisdatei angeben", "Dateiname für die Ergebnisdatei angeben: " & @CRLF & "z.B.: Ergebnisse", "Ergebnisse")
$enddateiname = StringReplace($dateiname_Ergebnisdatei, "\", " ")
$enddateiname = StringReplace($enddateiname, "/", " ")
$enddateiname = StringReplace($enddateiname, ":", " ")
$enddateiname = StringReplace($enddateiname, "*", " ")
$enddateiname = StringReplace($enddateiname, "?", " ")
$enddateiname = StringReplace($enddateiname, "<", " ")
$enddateiname = StringReplace($enddateiname, ">", " ")
$enddateiname = StringReplace($enddateiname, "|", " ")
$enddateiname = StringReplace($enddateiname, Chr(34), " ")
$file2 = @ScriptDir & "\" & $enddateiname & ".txt"














;Jede Datei einlesen und dies nach dem Suchkritieritum durchsuchen
Global $Ergebnis_indexe[1], $trefferanzahl = 0, $akt_pos = -1, $next_hit[1], $pos_gemerkt, $next_pos, $Ergebnisse[1]
For $temp_i = 1 To $files[0]
	If IsArray($aDatei_eingelesen) Then
		ReDim $aDatei_eingelesen[1]
		ReDim $next_hit[1]
	EndIf




	If FileExists($files[$temp_i]) Then
		ToolTip($temp_i & " / " & $files[0] & " - " & $files[$temp_i], MouseGetPos(0), MouseGetPos(1), "Datei einlesen " & $temp_i & " / " & $files[0])
		_FileReadToArray($files[$temp_i], $aDatei_eingelesen)
		If IsArray($aDatei_eingelesen) Then
			redim $Ergebnis_indexe[1]


			For $temp_j = 1 To $suchstrings[0]
				ToolTip("Datei: " & $files[$temp_i] & @CRLF & "Suche nach: " & $suchstrings[$temp_j], MouseGetPos(0), MouseGetPos(1), "Datei durchsuchen: " & $temp_i & " / " & $files[0])


				$akt_pos = _ArraySearch($aDatei_eingelesen, $suchstrings[$temp_j], 0, 0 ,0, 1)
				If $akt_pos <> -1 Then


					_ArrayAdd($Ergebnis_indexe, $akt_pos, Default, @CRLF)
					$trefferanzahl += 1


					While $akt_pos <> -1
						$akt_pos = _ArraySearch($aDatei_eingelesen, $suchstrings[$temp_j], $akt_pos + 1, 0 ,0, 1)
						If $akt_pos <> -1 Then
							_ArrayAdd($Ergebnis_indexe, $akt_pos, Default, @CRLF)
							$trefferanzahl += 1
						EndIf


					WEnd
				EndIf


			Next


			_ArraySort($Ergebnis_indexe)
			If $temp_i = 1 Then
				_ArrayAdd($Ergebnisse, "gesuchte Zeichenfolgen: '" & $Suchoptionen & "'" , Default, @CRLF)
				_ArrayAdd($Ergebnisse, "Insgesamt gefundene Zeilen: " & $trefferanzahl )
				_ArrayAdd($Ergebnisse, "" )
			EndIf


			If UBound($Ergebnis_indexe, 1) - 1 > 0 Then
				_ArrayAdd($Ergebnisse, "[Datei '" & $files[$temp_i] & "' - " & UBound($Ergebnis_indexe, 1) - 1 & " Zeilen]:" )
				For $temp_j = 1 To UBound($Ergebnis_indexe, 1) - 1
					_ArrayAdd($Ergebnisse, $aDatei_eingelesen[$Ergebnis_indexe[$temp_j]], Default, @CRLF)
				Next
				_ArrayAdd($Ergebnisse, "")


			EndIf
		EndIf
	EndIf
Next


;~ _ArrayDisplay($Ergebnisse, "$Ergebnisse")






If $trefferanzahl >= 1 Then
	$Ergebnisse[2] = "Insgesamt gefundene Zeilen: " & $trefferanzahl
	ToolTip("")
	_FileWriteFromArray($file2, $Ergebnisse, 1)
	msgbox(0,"Fertig","Ergebnisdatei wurde erstellt: " & @CRLF & @CRLF &  $file2  & @CRLF & @CRLF & "Anzahl Treffer: " & $trefferanzahl)
Else
	ToolTip("")
	msgbox(0,"Fertig","nichts gefunden...", 2)
EndIf




Func _OnExit()
	Exit
EndFunc

Alles anzeigen

DerSchatten

super, danke euch! Läuft 1A!

**alpines**

Setz beim nächsten Mal bitte den grünen Haken für erledigt / gelöst indem du den 1. Beitrag in diesem Thread bearbeitest damit auch andere Nutzer die Lösung schnell finden.
Ich hab das dieses Mal schon erledigt.