_FileWriteFromArray komisches verhalten

Nachid

Hallo und guten Morgen zusammen !

Ich hab ein kleines Formatierungsproblem.
Die Daten waren vorher richtig formatiert (Problem betrifft nur ö, ä, ü, ß)
und stammen aus einer SAP Auswertung. Da diese Geschäftsintern
sind kann ich Sie leider nicht hier posten.

Die Darstellung der o.g. Buchstaben schlägt nur in Excel fehl.
Bei Bearbeitung mit dem Editor sind alle i.O.

Die Daten werden direkt mit FileReadLine gelesen (ich habe hier kein FileOpen verwendet).

Wenn ich nun die Daten mit folgendem Code wieder in eine CSV ausschreibe :

AutoIt

_FileWriteFromArray(_PathFull(@ScriptDir & "\output.csv"), $values)

ist die Formatierung der oben genannten Umlaute verrissen.

Ich habe danach folgendes Versucht :

Code

$handle = FileOpen(_PathFull(@ScriptDir & "\output.csv"), $FO_ANSI)
_FileWriteFromArray($handle, $values)

Hiermit stürzt das Programm komplett ab.
@error sagt es wäre Fehler 3 - Error writing to file
von _FileWriteFromArray.
Programm wurde als Admin gestartet.

Aktuell funktioniert es mit diesem Workaround :

Code

_FileWriteFromArray(_PathFull(@ScriptDir & "\output.csv"), $values)


Run("notepad "& _PathFull(@ScriptDir & "\output.csv")
Sleep(200)
WinActivate(_PathFull(@ScriptDir & "\output.csv" & " - Editor")
Send("^s")
Sleep(200)
Send("!{F4}")

Was natürlich etwas hässlich wirkt.
Nach dem Workaround werden die Umlaute auch in Excel richtig dargestellt.

Hat hier jemand vielleicht ne Idee ?

Floops

Probier mal

AutoIt

$handle = FileOpen(_PathFull(@ScriptDir & "\output.csv"), BitOR($FO_ANSI, $FO_OVERWRITE))

**alpines**

Zitat von Floops

Probier mal

AutoIt

$handle = FileOpen(_PathFull(@ScriptDir & "\output.csv"), BitOR($FO_ANSI, $FO_OVERWRITE))

Es sollte doch kein Fehler geschmissen werden wenn er in die Datei schreiben kann (auch wenn sie schon existiert).
$FO_ANSI hat standardmäßig den Read-Flag gesetzt -> https://www.autoitscript.com/autoit3/docs/f…ns/FileOpen.htm

**Bitnugger**

Zitat von Nachid

Die Daten werden direkt mit FileReadLine gelesen (ich habe hier kein FileOpen verwendet).

Ohne File-Handle wird die Datei als UTF-8 behandelt.

If (FileReadLine) = $bBadCoise Then $sUseThisFunc = _FileReadToArray

Schau mal hier...

_Example

AutoIt

;-- TIME_STAMP   2017-04-12 19:19:51   v 0.1


#include <File.au3>
#include <WinAPIMisc.au3>


_Example()


Func _Example()
	Local $iRet, $iErr, $aArray, $hFile, $sFile = @ScriptDir & "\Example.csv"


	If Not FileExists($sFile) Then RunWait(@ComSpec & " /c " & "echo 1,2,3,a,b,c,ä,ö,ü,Ä,Ö,Ü,ß>" & $sFile, "", @SW_HIDE)
	; mit Codepage 850 (OEM) gespeichert...
	; 1,2,3,a,b,c,ä,ö,ü,Ä,Ö,Ü,ß


	; ************************************************************************
	; Daten einlesen - mit Handle, wenn sie NICHT als UTF-8 vorliegen
	; ************************************************************************
	$hFile = FileOpen($sFile, BitOR($FO_READ, $FO_ANSI))
	If $hFile = -1 Then Exit -1 + ConsoleWrite('! FileOpen error: ' & $sFile & @CRLF)
	$iRet = _FileReadToArray($hFile, $aArray, 0, ',')
	$iErr = @error
	FileClose($hFile)
	If $iRet = 0 Then Exit $iErr + ConsoleWrite('! _FileReadToArray error: ' & $sFile & @CRLF)
	; ergibt mit $FO_ANSI dann...
	; 1|2|3|a|b|c|„|”||Ž|™|š|á
	_ArrayDisplay($aArray, '$aArray - $FO_ANSI (OEM 850)')


	; ************************************************************************
	; Daten von OEM 850 nach ANSI umwandeln
	; ************************************************************************
	For $i = 0 To UBound($aArray) -1 Step 1
		For $j = 0 To UBound($aArray, 2) -1 Step 1
			$aArray[$i][$j] = _WinAPI_OemToChar($aArray[$i][$j])
		Next
	Next
	; ergibt dann...
	; 1|2|3|a|b|c|ä|ö|ü|Ä|Ö|Ü|ß
	_ArrayDisplay($aArray, '$aArray - OEM 850 > ANSI')


	; ************************************************************************
	; Daten bearbeiten
	; ************************************************************************
	$aArray[0][0] = Random(1,9,1)
	$aArray[0][1] = Random(1,9,1)
	$aArray[0][2] = Random(1,9,1)
	; ...


	; ************************************************************************
	; Daten von ANSI nach OEM 850 umwandeln
	; ************************************************************************
	For $i = 0 To UBound($aArray) -1 Step 1
		For $j = 0 To UBound($aArray, 2) -1 Step 1
			; _WinAPI_CharToOem() ruft die Dll-Funktion "CharToOemW" auf und übergibt einen "wstr"
			; Wir brauchen aber...
			; _CharToOem ...      ruft die Dll-Funktion "CharToOem"  auf und übergibt einen "str"
			$aArray[$i][$j] = _CharToOem($aArray[$i][$j])
		Next
	Next
	_ArrayDisplay($aArray, '$aArray - ANSI > OEM 850')


	; ************************************************************************
	; Daten speichern
	; ************************************************************************
	$hFile = FileOpen($sFile, BitOR($FO_ANSI, $FO_OVERWRITE))
	_FileWriteFromArray($hFile, $aArray, Default, Default, ",")
	FileClose($hFile)
EndFunc   ;==>_Example




; #FUNCTION# ====================================================================================================================
; Author.........: Yashied
; Modified.......: JPM
; ===============================================================================================================================
;~ Func _WinAPI_CharToOem($sStr)
;~ 	Local $aRet = DllCall('user32.dll', 'bool', 'CharToOemW', 'wstr', $sStr, 'wstr', '')
;~ 	If @error Or Not $aRet[0] Then Return SetError(@error + 10, @extended, '')


;~ 	Return $aRet[2]
;~ EndFunc   ;==>_WinAPI_CharToOem


Func _CharToOem($sStr)
	Local $aRet = DllCall('user32.dll', 'bool', 'CharToOem', 'str', $sStr, 'str', '')
	If @error Or Not $aRet[0] Then Return SetError(@error + 10, @extended, '')


	Return $aRet[2]
EndFunc   ;==>_CharToOem

Alles anzeigen