Das aktuelle Wetter aus dem Internet raussuchen

pltnpcs

Ich möchte, dass das Programm mit diesen Befehlen auf irgndeine Seite geht, die Wetter anzeigen lässt. Da das auch mit der Google Suche funktioniert habe ich die Google Suche genommen. Nun weiß ich nicht wie ich die Grad Celsius Anzeige herauslesen kann. So habe ich angefangen:

AutoIt

#include <ie.au3>
#include <MsgBoxConstants.au3>


$ie = ObjCreate("InternetExplorer.Application")
With $ie
   .visible = True
   .navigate("https://www.google.de/")
   While($ie.busy)
   WEnd
   $search = .document.GetElementById("lst-ib")
   $search.value = "Wetter Berlin"
   While($ie.busy)
   WEnd
   sleep(2000)
   $button = .document.getelementbyid("_fZl")
   $button.click()
   While($ie.busy)
   WEnd
   sleep(2000)
   $temp = .document.getelementbyid("wob_tm")
   $tempdata = $temp.GetStyle
   While($ie.busy)
   WEnd
   MsgBox(0, "TEMP","Temperatur ist "&$temp)


EndWith

Alles anzeigen

In Zeile 21 habe ich einen Nefehl ausprobiert, den es aber leider nicht gibt. Gibt es eine alternative?

**alpines**

Hat schon echt Stil die IE.au3 zu includen und dann das Objekt 1. selber zu erstellen und 2. direkt anzusprechen ohne die UDF zu nutzen.

Mit GetElementById holst du dir ein DOM-Objekt welches du mit weiteren Attributen ansprechen musst um auch den Text zu holen der im Objekt enthalten ist.
Normalerweise geschieht das mit .innerText oder .innerHTML. Du solltest aber komplett darauf verzichten das Objekt direkt anzusprechen und lieber die UDF nutzen.

Hier mal ein Beispiel.

AutoIt

#include <IE.au3>


_IEErrorNotify(False)


Do
	$oIE = _IECreate("www.google.de")
Until IsObj($oIE)


$oSearchInput = _IEGetObjById($oIE, "lst-ib")
$oSearchForm = _IEFormGetCollection($oIE, 0)


_IEFormElementSetValue($oSearchInput, "Wetter Berlin")
_IEFormSubmit($oSearchForm)


$oTemp = _IEGetObjById($oIE, "wob_tm")


MsgBox(64, "Wetter Berlin", "Die momentane Temperatur in Berlin beträgt: " & $oTemp.innerText & "°C.")
_IEQuit($oIE)

Alles anzeigen

Du kannst aber auch überlegen direkt auf WinHttp umzusatteln und Wetterdienste so anzusprechen.
Viele Dienster stellen eine gute API bereit mit der man sehr leicht an die gewünschten Daten herankommt.
Alternativ kannst du auch mal schauen ob es vielleicht nicht schon eine UDF gibt mit der man sich die Temperaturen von Städten holen kann.

pltnpcs

@alpines Danke ich weiß jetzt bloß noch nicht wie ich die Seite im Hintergrund öffne

**alpines**

Guck dir mal die Parameter der _IECreate-Funktion genauer an.

**Bitnugger**

https://openweathermap.org/api

NO1 :-)

Zitat von Bitnugger

https://openweathermap.org/api

Ich benutze die Openweathermap API auch, funktioniert wunderbar.

Sonderbaar

Das Thema ist zwar eigentlich erledigt, mich würden aber Eure Scripte interessieren (man muss das Rad ja nicht zwei Mal erfinden)

NO1 :-)

Ich hab vor eine UDF zu schreiben, mit der die Wetterdaten legal ausgelesen werden. Kann allerdings noch etwas dauern, ich werde die UDF dann posten.

Lg NO1

**Bitnugger**

Ich habe kein AutoIT-Script für openweathermap... die API nutze ich normal nur mit Kodi und auf meinem Tablet (beides via Python).

Hier aber mal ein paar Zeilen mit AutoIt, die ich dir auf die Schnelle getippt habe, damit du in etwa sehen kannst, wie die APIs angesprochen werden.

Bevor du das Script startest, musst du dir bei openweathermap einen Account erstellen und ein API-Key generieren!

openweathermap_demo

AutoIt

;-- TIME_STAMP   2017-04-25 01:30:50   v 0.1


#include <Array.au3>
; Diese UDF habe ich einfach mal vorsorglich mit beigelegt, weil die Response von openweathermap im JSON-Format vorliegt.
;~ #Include <Json.au3>


Global $g_sOWM_APIKEY = '' ; sollte etwa so aussehen --> 'b5662e7a0509215413bc03dafa0af87c'


Global $g_sOWM_APICWD = 'http://api.openweathermap.org/data/2.5/weather?'
Global $g_sOWM_APICWG = 'http://api.openweathermap.org/data/2.5/group?'


; api.openweathermap.org/data/2.5/weather?q={city name}
; api.openweathermap.org/data/2.5/weather?q={city name},{country code}
; api.openweathermap.org/data/2.5/weather?id=2172797


; City-IDs: http://bulk.openweathermap.org/sample/city.list.json.gz


; Bis zu 10 IDs pro Query!
Global $g_sCITY_IDs = '2884509,2934691,2886242' ; Krefeld,Duisburg,Koeln,...
Global $g_aCITY_IDs = [2824841,2855047,2925177]	; Sulzbach,Peine,Freiburg
Global $g_aCITY_2Ds = [[2824841, 'Sulzbach'],[2855047, 'Peine'],[2925177, 'Freiburg']]


Example()


Func Example()
	Local $vResult


	; Ludwigshafen am Rhein
	$vResult = _Get_Current_weather('2875376')
	_ArrayDisplay($vResult, '$vResult - Ludwigshafen am Rhein')


	; Krefeld,Duisburg,Koeln
	$vResult = _Get_Current_weather($g_sCITY_IDs)
	_ArrayDisplay($vResult, '$vResult - Krefeld,Duisburg,Koeln')


	; Sulzbach,Peine,Freiburg
	For $i = 0 To UBound($g_aCITY_IDs) -1 Step 1
		$vResult = _Get_Current_weather($g_aCITY_2Ds[$i][0])
		_ArrayDisplay($vResult, '$vResult - ' & $g_aCITY_2Ds[$i][1])
	Next
EndFunc


Func _Get_Current_weather($vIDs)
	If $g_sOWM_APIKEY = '' Then Return SetError(1)
	If $g_sOWM_APICWD = '' Then Return SetError(2)


	If IsArray($vIDs) Then $vIDs = _ArrayToString($vIDs, ',')


	Local $sAPIURL
	If StringInStr($vIDs, ',') Then
		$sAPIURL = StringFormat('%sid=%s&units=metric&APPID=%s', $g_sOWM_APICWG, $vIDs, $g_sOWM_APIKEY)
	Else
		$sAPIURL = StringFormat('%sid=%s&APPID=%s', $g_sOWM_APICWD, $vIDs, $g_sOWM_APIKEY)
	EndIf


	Local $oHttp = ObjCreate("winHttp.winHttpRequest.5.1")
	If Not IsObj($oHttp) Then Return SetError(3)


	$oHttp.open("GET", $sAPIURL)
	$oHttp.send()


	Local $aResponse = StringSplit($oHttp.ResponseText, ',')


	Return $aResponse
EndFunc

Alles anzeigen

openweathermap - Ludwigshafen am Rhein.png

Sonderbaar

bedankt BitNugger, Api-Key habe ich