Daten aus einem DOS Fenster in ein Array übertragen und bearbeiten

daMeier

Hallo,

ich brauch mal wieder Hilfe.

Genaugenommen habe ich gleich mehrere Baustellen.

Aktuell übergebe ich einen Befehl von AutoIt zur Kommandozeile von windows mit RunnWait. Dieser Befehl generiert eine Liste, diese würde ich gerne direkt in ein Array in AutoIT schreiben, da ich das nicht hinbekommen habe, speicher ich es in eine txt-Datei und lade diese ins Array.

Würde diesen Zwischen Schritt gerne einsparen.

Nun im nächsten Schritt sind im Array 100te von Zeilen mit folgendem Inhalt:

a04545454 DLX_DDDFLCX 16555
a04547544 DLX_DDDFLCX 16555
usw.

Aus diesem Inhalt benötige ich nur den ersten Teil z.B. a04547544 kann ich im Array mit Strings arbeiten, wenn ja was wäre der richtige weg?

Das wäre mal meine erster Schritt in diesem neuen Projekt.

Ich hoffe mir kann jemand weiter helfen.

Gruß

**AspirinJunkie**

Du kannst direkt den StdOut-Stream auswerten statt den Umweg über eine Datei zu gehen:

AutoIt

Local $a_Parameter[] = ["/A", "/W"]
$s_Out = RunCmd("dir", $a_Parameter, True)
If @error Then ConsoleWrite("!!!! Error !!!!:" & @CRLF & @error & @CRLF & @extended & @CRLF & @CRLF)


MsgBox(0,"", $s_Out & @CRLF)






; #FUNCTION# ======================================================================================
; Name ..........: RunCmd()
; Description ...: runs commandline programs or cmd-command and return their output
; Syntax ........: RunCmd($s_Cmd, [$sParameter = '', [$b_CmdSpec = False, [$WorkDir = @WorkingDir]]])
; Parameters ....: $s_Cmd        - the command which should be executed (can be full command or without parameters)
;                  $sParameter   - additional parameters for the command (also array of parameters)
;                  $b_CmdSpec    - If true the command is interpreted as a command for cmd.exe
;                  $WorkDir      - the working directory
; Return values .: Success: returns a string with the output
;                  Failure: set @error and returns a debug-string
; Author ........: AspirinJunkie
; =================================================================================================
Func RunCmd($s_Cmd, $sParameter = '', $b_CmdSpec = False, $WorkDir = @WorkingDir)
    Local Static $h_User32DLL = DllOpen('user32.dll')
    If @error Then Return SetError(1, @error, "")


	If $b_CmdSpec Then $s_Cmd = @ComSpec & " /c " & $s_Cmd


	Local $s_Ret, $s_Line, $s_Err


	If $sParameter <> '' Then
		If IsArray($sParameter) Then
			Local $s_Par = ""
			For $j In $sParameter
				$s_Par &= " " & $j
			Next
			$sParameter = $s_Par
		Else
			$sParameter = ' ' & $sParameter
		EndIf
	EndIf


	Local $iPID = Run($s_Cmd & $sParameter, $WorkDir, @SW_HIDE, 0x2 + 0x4)
	If @error Then Return SetError(2, @error, "")


	Do
		Sleep(10)
		$s_Line = StdoutRead($iPID)
		If @extended > 0 Then $s_Ret &= $s_Line
	Until @error


	Do
		Sleep(10)
		$s_Line = StderrRead($iPID)
		If @extended > 0 Then $s_Err &= $s_Line
	Until @error


	$s_Ret = DllCall($h_User32DLL, 'BOOL', 'OemToChar', 'str', $s_Ret, 'str', '')[2]


	If $s_Err <> "" Then
		If $s_Ret <> "" Then Return SetError(3, 0, "------- StdOut -----------" & @CRLF & $s_Ret & @CRLF & @CRLF & "------- StdErr -----------" & @CRLF & $s_Err)
		Return SetError(3, 0, $s_Err)
	EndIf
	Return $s_Ret
EndFunc   ;==>RunCmd

Alles anzeigen

Zitat von daMeier

Nun im nächsten Schritt sind im Array 100te von Zeilen mit folgendem Inhalt:

a04545454 DLX_DDDFLCX 16555
a04547544 DLX_DDDFLCX 16555
usw.

Aus diesem Inhalt benötige ich nur den ersten Teil z.B. a04547544 kann ich im Array mit Strings arbeiten, wenn ja was wäre der richtige weg?

Wenn die Länge des ersten Teiles konstant ist dann zeilenweise durchgehen und per StringLeft das rausschneiden was du benötigst.
Ist es etwas komplexer dann wäre StringRegEx eine andere Methode.
Da bräuchte man aber etwas mehr Infos zum Aufbau.

daMeier

Hallo,

ich bleibe mal beim Beispiel mit dem Umweg über die Datei.

Das laden ins Array funktioniert. Im Array steht dann.

Row|Col 0
[0]|802
[1]|Usage data is 8 minutes old. Next update in 8 minutes.
[2]|
[17]|e1234567 XDT_PLT_UD 2018.1231
[18]|e1231224 XDT_PLT_UD 2018.1231

Der erste Buchstabe ist immer e und dann kommen immer 7 Zahlen. Wenn in der Arrayzeile an stelle 1 kein e steht, soll er die ganze zeile löschen und wenn dort ein e steht, soll er nur e und die 7 Zahlen in die gleiche Zeile schreiben.

Hoffe das ist verständlich? Ich habe noch keinen Code, weis keinen Ansatz.

**alpines**

Das müsste in etwa so klappen, beachte die Indizes und baue sie für dein Skript um!

AutoIt

#include <Array.au3>


Local $aArray[5][2] = [["", 802], ["", "Usage data is 8 minutes old. Next update in 8 minutes."], _
					   ["", ""], ["", "e1234567 XDT_PLT_UD 2018.1231"], ["", "1231224 XDT_PLT_UD 2018.1231"]]


;Indizes müssen angepasst werden, das hier ist nur ein Testskript!
_ArrayDisplay($aArray, "Davor")


For $i = 3 To 4
	If StringLeft($aArray[$i][1], 1) = "e" Then
		$aArray[$i][1] = StringLeft($aArray[$i][1], 1 + 7)
	Else
		$aArray[$i][1] = ""
	EndIf
Next


_ArrayDisplay($aArray, "Danach")

Alles anzeigen

**AspirinJunkie**

Ja wie gesagt - wenn es schon als Array vorliegt durchgehen und per StringLeft extrahieren:

AutoIt

#include <Array.au3>


Global $a_Test[] =[802, "Usage data is 8 minutes old. Next update in 8 minutes.", "", "e1234567 XDT_PLT_UD 2018.1231", "e1231224 XDT_PLT_UD 2018.1231"]
_ArrayDisplay($a_Test, "Array vorher")


For $i = 2 To UBound($a_Test) -1
	$a_Test[$i] = StringLeft($a_Test[$i], 8)
Next
_ArrayDisplay($a_Test, "Array nachher")

Alles anzeigen

Den Umweg über das Array muss man wahrscheinlich aber gar nicht machen.
Die Rückgabe von _RunCmd() gibt die Ausgabe als String zurück.
Diesen kann man direkt mit Stringfunktionen bearbeiten:

AutoIt

#include <Array.au3>
Global $s_String = "Usage data is 8 minutes old. Next update in 8 minutes." & @CRLF & "" & @CRLF &"e1234567 XDT_PLT_UD 2018.1231" & @CRLF &"e1231224 XDT_PLT_UD 2018.1231"


MsgBox(0,"Eingabestring", $s_String)


$a_Ret = StringRegExp($s_String, '(?m)^(e\d{7})\b', 3)
_ArrayDisplay($a_Ret, "Extrahierte Elemente")

**alpines**

Zitat von AspirinJunkie

Ja wie gesagt - wenn es schon als Array vorliegt durchgehen und per StringLeft extrahieren:

Bei dieser Variante hast du vergessen die Zeilen rauszuschmeißen die ein 'e' vorne dran haben.

**AspirinJunkie**

Ah - Aufgabe falsch verstanden

**alpines**

Zitat von AspirinJunkie

Ah - Aufgabe falsch verstanden

Die RegEx-Variante funktioniert aber, und die ist ehrlich gesagt auch schöner. Fragt sich nur ob der TE die nachvollziehen kann.
Wenn man den Output auch direkt holt spart man sich den Umweg über das Dateisystem.

daMeier

hey,

komme nur teilweise klar ...

AutoIt

For $i = 1 To $aArray[0]
	  If StringLeft($aArray[$i][1], 1) = "s" Then
		 $aArray[$i] = StringLeft($aArray[$i], 8)
	  Else
		 _ArrayDelete($aArray, $i)
	  EndIf
   Next

Dachte so würde er prüfen ob die erste Stelle in der Zeile ein "s" ist und würde dann diese auf 8 stellen "beschneiden", wenn nicht würde er diese Zeile löschen.

Aber leider gefällt was am IF StringLeft nicht ... weiß aber nicht wo mein Denkfehler ist...

wo bin ich den auf dem Holzweg?

**autoiter**

Hallo @daMeier,

Stringleft ist Okay. Du musst die Schleife aber rückwärts durchgehen, wenn du Zeilen löschst. Ich weiß ja nicht was genau dein Problem war. Ich erwarte es aber dort.

daMeier

Sorry, der Fehler ist:

Array variable has incorrect number of subscripts or subscript dimension range exceeded.:
If StringLeft($Array[$i][1], 1) = "s" Then
If StringLeft(^ ERROR

**autoiter**

Ja, dann passt das. Schau dir mal nach einem _ArrayDelete das Array an (das Array ist kleiner und alle Elemente nach dem gelöschten wurden um eins nach oben geschoben - es gibt ja keine Leerzeile). Du kommst also irgendwann zu einem Punkt, wo du auf Elemnte zugreifen willst, die es nicht gibt, weil das Array vorher ja verkleinert wurde. Außerdem hast du Elemente/Zeilen übersprungen.
Also rückwärts For $i = $aArray[0] To 1 Step -1

daMeier

AutoIt

For $i = $aArray[0] To 1 Step -1
	  If StringLeft($Array[$i][1], 1) = "s" Then
		 $Array[$i] = StringLeft($Array[$i], 8)
	  Else
		 _ArrayDelete($Array, $i)
	  EndIf
   Next

kommt leider auch ein fehler:

Variable used without being declared.:
For $i = $aArray[0] To 1 Step -1
For $i = ^ ERROR

ist aber declariert:

Local $i

**autoiter**

Schau mal. Ich habe aus $aArray aus deinem vorigen Post verwendet. Deine Variable heißt aber scheinbar nur $Array (?)

PS: $i muss nicht deklariert werden. Es ist in einer For ($i= ..)-Schleife automatisch eine lokale Variable, die nur innerhalb der Schleife existiert.

**Oscar**

Zitat von daMeier

For $i = $aArray[0] To 1 Step -1
If StringLeft($Array[$i][1], 1) = "s" Then

Einmal ein Eindimensionales Array ($aArray) und einmal ein zweidimensionales Array ($Array) und dann auch noch unterschiedliche Namen.
Vielleicht solltest Du Dich erstmal mit den Grundlagen von AutoIt beschäftigen.
Oder eine Beispieldatei posten, damit man Dir vernünftig helfen kann.

daMeier

Hey,

ja sorry, vor lauter lauter...

Code funktioniert jetzt so.

AutoIt

For $i = $Array[0] To 1 Step -1
	  If StringLeft($Array[$i], 1) = "s" Then
		 $Array[$i] = StringLeft($Array[$i], 8)
	  Else
		 _ArrayDelete($Array, $i)
	  EndIf
   Next

Einzig was ich noch nicht weiß, im Original sind es 802 Zeilen, was ja auch im $Array[0] steht. Nach dem löschen sind es nur noch 577 Zeilen, in $Array[0] steht aber immer noch 802. Wenn ich jetzt mit dem Array weiter arbeite wird er im besten fall bei 802 anfangen und 300 ohne Wert machen oder er bringt mir einen Fehler???

Ist das egal? Wie kann ich das richtig machen?

**alpines**

Schreib doch die neue Zahl dann in den 0. Index rein? Wo liegt das Problem?

**Oscar**

Gleich weg damit _ArrayDelete($Array, 0) und UBound verwenden!
Die Anzahl in Index 0 ist doch sowieso eine Unsitte.

**AspirinJunkie**

Wie gesagt - das ganze lässt sich durchaus auch in einer Zeile per Stringfunktionen abhandeln.
Aber du hast dich ja darauf versteift erst den Input in ein Array zu konvertieren und dann entsprechend zu beackern mit allem was da noch dran hängt.

Alles was du brauchst wäre die _RunCmd-Funktion von oben + der bereits gepostete Aufruf von StringRegExp.