GDIPlus - Bereich immun machen

NO1 :-)

Hallo zusammen,

ist es irgendwie möglich, bestimmte Bereiche auf der GUI so gegen GDIPlus immun zu machen, dass man auf diese Bereiche nicht mit GDIPlus zeichnen kann?

Lg NO1

**Kanashius**

Immun machen nicht, aber du könntest eine weitere Gui erstellen mit $WS_CHILD als style und der Gui als Parent, dann passend positionieren.

Mit borderless,... merkt man garnicht, dass dort eine andere Gui ist, und dort sieht man dann nicht, was unter der ChildGui darunter gezeichnet wurde.

Ansonsten, einfach nicht auf der Gui zeichnen, sondern auf einem Bild, das dort eingeblendet wird. Das macht man ja häufig, um bei dem ReDraw, beim Bewegen des Fensters aus dem Bildschirmrand,... das Bild neuzuzeichnen.

Auf dem Bild kann der Bereich ja wieder gelöscht werden, nachdem gezeichnet wurde.

Wenn du den Anwendungsfall genauer beschreibst gibts aber vllt. noch eine bessere Möglichkeit

NO1 :-)

Danke Kanashius... Das mit dem Bild zeichnen klingt interessant...

Also kurz mal ein paar Infos: Ich hab ne maximierte GUI. Auf der GUI befindet sich ein Hintergrundbild, das sich in unbestimmten Intervallen vollständig erneuert und somit auch immer wieder neu "Vollbild" gezeichnet werden muss. An bestimmten Stellen befinden sich Controls (die ich soweit wie möglich mit GDIPlus selbst erstellt hab), ein Control ist aber ein mit _WinAPI_CreateWindowEx erstellter Input. Dieser Input muss natürlich im Vordergrund sein (liegt somit auf dem mit GDI+ gezeichnetem Hintergrundbild) und darf somit auch nicht übermalt werden.

**Mars**

Ich weiß leider nicht mehr genau wie das funktioniert, aber man kann mit RectRgn Bereiche definieren in denen (nicht) gezeichnet wird. Du müsstest also in der Lage sein Ein gfx zu erstellen welches in bestimmten Bereichen nicht überzeichnet wird. (oder eine Bitmap die in diesen Bereichen volltransparent ist).

Einziger Stichpunkt der mir dazu einfällt ist folgendes:

https://www.autoitscript.com/forum/topic/12464-hole-in-gui/

M

NO1 :-)

Ja, da kommen wir der Sache schon näher... Mit RectRgn hab ich mir das auch irgendwie vorgestellt. Ich schau mir jetz mal nochmal das GUIHole Beispiel an...

Danke Mars

**UEZ**

Du musst die Positionen der Controls ermitteln und sie dann ausclippen.

Hier ein älteres Beispiel:

AutoIt

#AutoIt3Wrapper_UseX64=n
;coded by UEZ 2009
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIplus.au3>
#include <WindowsConstants.au3>

Local Const $width = @DesktopWidth / 2
Local Const $height = @DesktopHeight / 2
Opt("GUIOnEventMode", 1)

Local $fps = 0, $fps_diff, $fps_maintimer, $fps_timer, $display_FPS = -15
Local $trig = ACos(-1)  / 180
Local $max_dots = 100
Local $max_speed = 8
Local $iWidth = 10
Local $iHeight = 10
Local $hGUI = GUICreate("Border Collision with " & $max_dots & " objects! 0 FPS", $width, $height, -1, -1, Default, BitOR($WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
Local $Button = GUICtrlCreateButton("Exit", $width / 2 - 50, $height / 2 - 15, 100, 30)
Local $Input = GUICtrlCreateInput("Coded by UEZ", $width / 4, $height - 40, $width / 2, 20, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))

_GDIPlus_Startup()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
$hBitmap = _GDIPlus_BitmapCreateFromGraphics($Width, $Height, $hGraphics)
$hBackbuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hBackbuffer, 2)
Local $hBrush_Clear = _GDIPlus_BrushCreateSolid(0xFF000000)

;~ Global Const $GW_CHILD = 5
;~ Global Const $GW_HWNDNEXT = 2
Global $hRegion = _GDIPlus_RegionCreateFromRect(0, 0, $width, $height)
Global $hChild = _WinAPI_GetWindow($hGUI, $GW_CHILD)
Global $aRect
Do
    $aRect = ControlGetPos($hChild, "", 0)
    _GDIPlus_RegionCombineRect($hRegion, $aRect[0], $aRect[1], $aRect[2], $aRect[3], 3)
    $hChild = _WinAPI_GetWindow($hChild, $GW_HWNDNEXT)
Until Not $hChild
_GDIPlus_GraphicsSetClipRegion($hGraphics, $hRegion)
_GDIPlus_RegionDispose($hRegion)

GUISetState()

GUICtrlSetOnEvent($Button, "Close")


Dim $coordinates[$max_dots][5], $angle
Dim $hBrush[$max_dots]
Initialize()

$fps_maintimer = TimerInit()
Do
    For $x = -0x7FFFFFFF To 0x7FFFFFFF
        $fps_timer = TimerInit()
        Draw_Dots()
        Calculate_New_Position()
        Sleep(30)
        $fps_diff = TimerDiff($fps_timer)
        If TimerDiff($fps_maintimer) > 999 Then ;calculate FPS
            $fps = Round(1000 / $fps_diff, 2)
            $fps_maintimer = TimerInit()
        EndIf
        WinSetTitle($hGUI, "", "Border Collision with " & $max_dots & " objects! " & $fps & " FPS")
    Next
Until False

Func Initialize()
    For $k = 0 To $max_dots - 1
        $hBrush[$k] = _GDIPlus_BrushCreateSolid(Random(0xD0808080, 0xD0FFFFFF, 1))
        New_Coordinates($k)
    Next
EndFunc   ;==>Initialize

Func Draw_Dots()
    Local $i, $temp_x, $temp_y
    _GDIPlus_GraphicsFillRect($hBackbuffer, 0, 0, $width, $height, $hBrush_Clear)
    For $i = 0 To $max_dots - 1
        _GDIPlus_GraphicsFillEllipse($hBackbuffer, $coordinates[$i][0], $coordinates[$i][1], $iWidth, $iHeight, $hBrush[$i])
    Next
    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $width, $height)
EndFunc   ;==>Draw_Dots

Func New_Coordinates($k)
    $coordinates[$k][0] = $width / 2 ;Random($width / 20, $width - $width / 20, 1);start x position
    $coordinates[$k][1] = $height / 2 ;Random($height / 20, $height - $height / 20, 1) ;start y position
    $coordinates[$k][2] = Random(1, $max_speed, 1) ;speed of pixel
    $angle = Random(0, 359, 1)
;~ ConsoleWrite("Angle: " & $angle & "°" & @CRLF)
    $coordinates[$k][3] = $coordinates[$k][2] * Cos($angle * $trig)
    $coordinates[$k][4] = $coordinates[$k][2] * Sin($angle * $trig)
EndFunc   ;==>New_Coordinates

Func Calculate_New_Position()
    Local $k
    For $k = 0 To $max_dots - 1
        $coordinates[$k][0] += $coordinates[$k][3] ;increase x coordinate with appropriate slope
        $coordinates[$k][1] += $coordinates[$k][4] ;increase y coordinate with appropriate slope
        If $coordinates[$k][0] <= 0 Then ;border collision x left
            $coordinates[$k][0] = 1
            $coordinates[$k][3] *= -1
        ElseIf $coordinates[$k][0] >= $width - $iWidth Then ;border collision x right
            $coordinates[$k][0] = $width - ($iWidth + 1)
            $coordinates[$k][3] *= -1
        EndIf
        If $coordinates[$k][1] <= 0 Then ;border collision y top
            $coordinates[$k][1] = 1
            $coordinates[$k][4] *= -1
        ElseIf $coordinates[$k][1] >= $height - $iHeight Then ;border collision y bottom
            $coordinates[$k][1] = $height - ($iHeight + 1)
            $coordinates[$k][4] *= -1
        EndIf
    Next
EndFunc   ;==>Calculate_New_Position

Func close()
    For $k = 0 To $max_dots - 1
        _GDIPlus_BrushDispose($hBrush[$k])
    Next
    _GDIPlus_BrushDispose($hBrush_Clear)
    _GDIPlus_GraphicsDispose($hBackbuffer)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    Exit
EndFunc   ;==>close

Alles anzeigen

NO1 :-)

Danke UEZ,

hab das Beispiel probiert...und es funktioniert...

Werde es mir in nächster Zeit genau anschauen, da es genau das ist, was ich gesucht, habe!

Danke euch allen für die Hilfe