Datum im Dateinamen ändern - Ordnung im Chaos

AutoMit

Hallo,

viele Dateien hier sind hinsichtlich der Namenskonvention im Chaos versunken.

Wie stellt man das am besten an, dass man zum einen die Muster findet (reguläre Suche?) und den neuen Dateinamen erstellt?

Es gibt leider viele Schreibweisen, wie die Dateien benannt wurden. Jetzt soll Ordnung in das Chaos.

Mit welcher Syntax würdet Ihr die Dateinamen so aufsplitten, dass man einen neuen Dateinamen aus Wort und Datum (Jahr-Monat bzw. Jahr-Monat-Tag) erstellen kann? Ich vermute, ich muss Muster mit der regulären Suche suchen, daran scheitere ich.

Alle Dateien in ein Array einlesen und zeilenweise abarbeiten, das bekomme ich hin. Den Dateinamen zerlegen in Name und Erweiterung, auch das klappt. Und dann bin ich mit meinem Latein am Ende. Unten im Codeblock stehen einige der Dateinamen mit einem Datumsmuster, wie ich es auf der Festplatte vorgefunden habe.

Vielleicht kennt sich hier jemand sehr gut mit der regulären Mustersuche aus bzw. es gibt ggf. noch eine alternative Möglichkeit?

Danke und Glückwunsch zum neuen Forums-Design

Code

Beispiele -> so soll der Dateiname lauten


Dateiname 6.17.pdf                     Dateiname 2017-06.pdf


Dateiname 0117.txt                      Dateiname 2017-01.txt


Dateiname 07.17.xls                    Dateiname 2017-07.xls


Dateiname09.2017.pdf                Dateiname 2017-09.pdf

(Achtung - im alten Dateinamen gibt es keine Leerzeichen zwischen Wort und Zahl)


2.17 Dateiname.txt                      Dateiname 2017-02.txt

(Achtung - in diesem Fall steht das Datum vor dem Dateinamen)


Dateiname 06-17de.docx             Dateiname 2017-06.docx

(Achtung, das nachgestellte de hinter dem Datum muss geslöscht werden


0516 Dateiname.xls                      Dateiname 2016-05.xls

(Achtung - in diesem Fall steht das Datum vor dem Dateinamen)

Alles anzeigen

**alpines**

Dazu braucht es keine komplexen Suchmuster, du kannst alle Formate im Regex einzeln finden und dann einfach mit einem Oder verketten (zwar nicht perfekt aber funktioniert).

Allerdings hast du das Problem, dass du bei einigen Dateien nicht weißt ob es sich um den Monat oder das Jahr handelt also können dir einige Schnitzer passieren.

So kriegst du die Gruppen: https://regex101.com/r/TtMs0O/1

Danach kannst du ja schauen wie lang sie sind, wenn sie drei/vier Zeichen lang sind schaust du nach welche Zahl vorne steht und teilst sie nach gewissen Richtlinien auf.

**BugFix**

Hier mal als Muster für die Dateinamen, die mit dem Datum beginnen (0516... / 2.17...)

AutoIt

; Verwende Dateinamen ohne Endung zum Umbau
; Bsp. 2.17 Dateiname.txt
$sFileName = '2.17 Dateiname'
$sExt = '.txt'

; mach es einfach in mehreren Schritten, ist verständlicher, als ein allumfassendes Pattern zu basteln
$aMatch = StringRegExp($sFileName, '^(\d{1,2})\.*(\d+)\s*(.+)$', 3)
; $aMatch[0] = 2
; $aMatch[1] = 17
; $aMatch[2] = Dateiname
$sResult = $aMatch[2] & ' ' & String( 2000 + Number($aMatch[1]) ) & '-' & StringFormat('%02d', $aMatch[0]) & $sExt
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $sResult --> " & $sResult & @LF)

Alles anzeigen

**Oscar**

Da sind zuviele Sonderfälle bei, um sie mit nur einem RegEx-Pattern erfassen zu können.

Ich würde da auch in mehreren Schritten vorgehen:

AutoIt

Global $aFilename[] = ['Dateiname 6.17.pdf', 'Dateiname 0117.txt', 'Dateiname 07.17.xls', 'Dateiname09.2017.pdf', '2.17 Dateiname.txt', 'Dateiname 06-17de.docx', '0516 Dateiname.xls']

Global $sFilename, $sExt, $sDate, $sYear, $sMon, $sNewName
For $i = 0 To UBound($aFilename) - 1
    $aFilename[$i] = StringRegExpReplace($aFilename[$i], '(.*?[0-9\.\-]+)de(\..+)', '$1$2')
    ConsoleWrite(@CRLF & '-> Debug(' & @ScriptLineNumber & ') : Alt = "' & $aFilename[$i] & '"' & @CRLF)
    $sFilename = StringStripWS(StringRegExpReplace($aFilename[$i], '(.*?)[0-9\.\-]+(.*)\..+', '$1$2'), 3)
    $sExt = StringRegExpReplace($aFilename[$i], '.*?[0-9\.\-]+.*(\..+)', '$1')
    $sDate = StringRegExpReplace($aFilename[$i], '.*?([0-9\.\-]+).*\..+', '$1')
    $sMon = StringRegExpReplace($sDate, '(.+)\..+', '$1')
    $sYear = StringRegExpReplace($sDate, '.+\.(.+)', '$1')
    If $sMon = $sDate Then
        $sMon = StringRegExpReplace($sDate, '(.+)\-.+', '$1')
        $sYear = StringRegExpReplace($sDate, '.+\-(.+)', '$1')
    EndIf
    If $sMon = $sDate Then
        $sMon = StringLeft($sDate, 2)
        $sYear = StringMid($sDate, 3)
    EndIf
    If StringLen($sYear) = 2 Then $sYear = '20' & $sYear
    $sNewName = StringFormat('%s %04d-%02d%s', $sFilename, $sYear, $sMon, $sExt)
    ConsoleWrite('+> Debug(' & @ScriptLineNumber & ') : Neu = "' & $sNewName & '"' & @CRLF & @CRLF)
Next

Alles anzeigen

AutoMit

Wow - und vielen Dank. Ich versuche, hinter die Codezeilen von Oscar zu blicken und melde mich dann nochmal.