Hot Hot Hotfolder?

**autoiter**

Deine Beobachtung gilt allgemein für Event-Funktionen. Auf den Hinweis, dass die Event-Funktionen schnell verlassen werden sollen und dort keine blockierende Funktionen wie MsgBox oder _Arraydisplay verwendet werden sollen, stößt man eigentlich immer (denke etwa einfach an ein GUI-Event wie das Auswerten von Klicks in einer Listview).

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

autoiter

Ja, ich hatte es gelesen. Mir war schon klar, worauf das hinausläuft, der Event will seine Nachricht eben "schlagartig" los werden. Nun hatten mich die Konseuenzen interesiert. Die MSGBox z.b funktioniert mit beschriebenen Konseuenzen. Array Dispaly bekommt nichteinmal das hin... Aber das habe ich ja schon in #20 beschrieben.

Da ich den Ordner für pdf Verarbeitung, z.T. Dokumentumwandlung usw. benutzen möchte ist es mir eben ein wenig unwohl - bei diesen Zenario. Zumal tatsächlich keines von den Dokumenten im Datengrab verschwinden darf. Und irgendwie fügt sich das ganze noch nicht.

Aso Danke für Euren "Beistand"

Nehme gerne weitere Vorschläge an.

Peter

**autoiter**

Naja, du könntest das Ganze aufteilen in ein Skript, dass Nichts macht als auf neue PDF zu warten, diese in deinen "Bearbeiten-Ordner" verschiebt und dann ein anderes Skript startet, dass die jeweiligen Dateien bearbeitet.

Ansonsten bleib einfach bei deiner Schleife. Alle x-Sekunden FileFindFirstFile und wenn kein Fehler FileFindNextFile verursacht doch keine wahrnehmbare Last. Dann brauchst du dir auch keine komplizierten Konstrukte ausdenken und kannst auch keine Events verpassen..

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Danke,

auf genau die Idee bin ich - nach Schreiben von #22 auch gekommen :). Ich wollte eigentlich tatsächlich im Ursprung etwas in Richtung File exist / Find File first schreiben. Dann kam mir die Idee - dass das fast schon zu einfach ist --> dieser Thread. Der Hinweis auf schlafende Festplatten und permanenten Spinn Up hat mich dann verunsichert -- kann z.Z. nicht beurteilen ob das auf einem Server überhaupt ein Problem ist. Habe mich dann mit den Eventschleifen auseinandergesetzt -- und war nicht glücklich. Aber die Beiträge regen mich entschieden zum Nachdenken an. Nun habe ich tatsächlich entschieden, den Event zu nehmen - aber es in zwei Programme zu verpacken. Das eine überwacht den Ordner das andere wird im Eventfall aufgerufen - und macht dann die "Drecksarbeit". Damit da nichts schiefgeht - kopiere ich die Dateien in ein Temp Verzeichnis.

Das klingt für mich vielversprechend. Wenn es keine Einwände wegen groben Strukturfehler gibt --> Closed

Danke an alle Helfer

Gruß aus dem extrem windigen Süden

Peter

Raeuber_Hotzenplotz

Oscar ich brauche gerade sowas wie du hier zur verfügung gestellt hast, habe nur eine frage dazu, warum wird die geänderte datei 2mal hintereinander angezeigt, gibt es da einen weg es nur einmal anzeigen zu lassen, ich möchte gerne das script nutzen um ein event auzulösen in meinem script und wenn es das 2 mal auslöst, wäre ärgerlich

Danke

**Oscar**

Zitat von Raeuber_Hotzenplotz

warum wird die geänderte datei 2mal hintereinander angezeigt

Sie wird 2 mal angezeigt, weil ein reinkopieren in das Verzeichnis eben 2 Events auslöst (Create und Update).

Wenn Du die Datei nur einmal in dem Listview haben willst, musst Du Dich für ein Event entscheiden (If-Abfrage mit Event in lParam).

Raeuber_Hotzenplotz

OK danke und noch was, was muss ich einstellen, dass nur eine spezielle Datei überwacht wird. Ist das mit der Methode überhaupt möglich?

Ich habe eine inidatei, die mit neuen Daten gefüllt wird, wird dieser Inhalt geändert, soll der Inhalt ausgegeben werden,

**Oscar**

Zitat von Raeuber_Hotzenplotz

Ich habe eine inidatei, die mit neuen Daten gefüllt wird, wird dieser Inhalt geändert, soll der Inhalt ausgegeben werden

Ja, das ist möglich:

AutoIt

#include <APIShellExConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>

#cs Moegliche Werte bei den Events von _WinAPI_ShellChangeNotify()
    Global Const $SHCNE_ALLEVENTS = 0x7FFFFFFF
    Global Const $SHCNE_ASSOCCHANGED = 0x8000000
    Global Const $SHCNE_ATTRIBUTES = 0x00000800
    Global Const $SHCNE_CREATE = 0x00000002
    Global Const $SHCNE_DELETE = 0x00000004
    Global Const $SHCNE_DRIVEADD = 0x00000100
    Global Const $SHCNE_DRIVEADDGUI = 0x00010000
    Global Const $SHCNE_DRIVEREMOVED = 0x00000080
    Global Const $SHCNE_EXTENDED_EVENT = 0x04000000
    Global Const $SHCNE_FREESPACE = 0x00040000
    Global Const $SHCNE_MEDIAINSERTED = 0x00000020
    Global Const $SHCNE_MEDIAREMOVED = 0x00000040
    Global Const $SHCNE_MKDIR = 0x00000008
    Global Const $SHCNE_NETSHARE = 0x00000200
    Global Const $SHCNE_NETUNSHARE = 0x00000400
    Global Const $SHCNE_RENAMEFOLDER = 0x00020000
    Global Const $SHCNE_RENAMEITEM = 0x00000001
    Global Const $SHCNE_RMDIR = 0x00000010
    Global Const $SHCNE_SERVERDISCONNECT = 0x00004000
    Global Const $SHCNE_UPDATEDIR = 0x00001000
    Global Const $SHCNE_UPDATEIMAGE = 0x00008000
    Global Const $SHCNE_UPDATEITEM = 0x00002000
    Global Const $SHCNE_DISKEVENTS = 0x0002381F
    Global Const $SHCNE_GLOBALEVENTS = 0x0C0581E0
    Global Const $SHCNE_INTERRUPT = 0x80000000
#ce

OnAutoItExitRegister('OnAutoItExit')
Opt('GUIOnEventMode', 1)

Global $sNotifyDir = @ScriptDir ; das zu ueberwachende Verzeichnis
If StringRight($sNotifyDir, 1) <> '\' Then $sNotifyDir &= '\'
Global $bRecursive = False ; True = mit Unterverzeichnisse, False = ohne Unterverzeichnisse
Global $sIniFile = 'test.ini' ; die zu ueberwachende Inidatei (im obigen Verzeichnis)

Global $hGui = GUICreate('Test', 800, 400)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui') ; Funktion die beim schließen des Fensters aufgerufen wird
Global $idEdit = GUICtrlCreateEdit('', 10, 10, 780, 380)

Global $iNotifyMsg = _WinAPI_RegisterWindowMessage('SHELLCHANGENOTIFY') ; die Message bei Windows registrieren
GUIRegisterMsg($iNotifyMsg, 'WM_SHELLCHANGENOTIFY') ; das Fenster für den Empfang der Message registrieren
Global $iID = _WinAPI_ShellChangeNotifyRegister($hGui, $iNotifyMsg, $SHCNE_UPDATEITEM, BitOR($SHCNRF_INTERRUPTLEVEL, $SHCNRF_SHELLLEVEL, $SHCNRF_RECURSIVEINTERRUPT), $sNotifyDir, $bRecursive) ; Windows mitteilen welches Verzeichnis überwacht werden soll
If @error Then ; wenn das fehlschlägt, dann...
    MsgBox(BitOR($MB_ICONERROR, $MB_SYSTEMMODAL), 'Fehler', '"ShellChangeNotifyRegister" ist fehlgeschlagen.')
    Exit ; Programm mit Fehlermeldung beenden
EndIf
GUISetState()
WinWaitClose($hGui) ; warten bis das Fenster geschlossen wird

Func _CloseGui()
    Exit
EndFunc   ;==>_CloseGui

Func OnAutoItExit()
    If $iID Then _WinAPI_ShellChangeNotifyDeregister($iID)
EndFunc   ;==>OnAutoItExit

Func WM_SHELLCHANGENOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    Local $sPath = _WinAPI_ShellGetPathFromIDList(DllStructGetData(DllStructCreate('dword Item1; dword Item2', $wParam), 'Item1'))
    If $sPath = $sNotifyDir & $sIniFile Then
        GUICtrlSetData($idEdit, FileRead($sNotifyDir & $sIniFile))
    EndIf
EndFunc   ;==>WM_SHELLCHANGENOTIFY

Alles anzeigen

**Musashi**

Eine winzige Kleinigkeit am Rande bzgl. : if StringRight($sNotifyDir, 1) <> '\' Then $sNotifyDir &= '\'

Ich verwende zunehmend _WinAPI_PathAddBackslash (falls ich daran denke ), also :

AutoIt

#include <WinAPIShPath.au3>
ConsoleWrite(" => " & @ScriptDir & @CRLF)
ConsoleWrite(" => " & _WinAPI_PathAddBackslash(@ScriptDir) & @CRLF)
ConsoleWrite(" => " & _WinAPI_PathAddBackslash(@ScriptDir & '\') & @CRLF)

Ob das ein weiteres #include rechtfertigt muss wohl jeder selbst entscheiden.

**BugFix**

Zitat von Musashi

Ob das ein weiteres #include rechtfertigt muss wohl jeder selbst entscheiden.

Dann mit RegEx, spart das Include:

AutoIt

Global $sNotifyDir1 = 'C:\bla\blub'
Global $sNotifyDir2 = 'C:\bla\blub\'

ConsoleWrite(StringRegExpReplace($sNotifyDir1, '\\*$', '') & '\' & @CRLF)
ConsoleWrite(StringRegExpReplace($sNotifyDir2, '\\*$', '') & '\' & @CRLF)

Raeuber_Hotzenplotz

Danke euch beiden vielmals

das es doppelte Meldungen gibt, habe ich auch nachstellen können, die Datei lag in meinen Nextcloud Verzeichnis, deswegen wurde wohl eine weitere Benachrichtigung gesendet nachdem Sync Vorgang.
im Arbeitsverzeichnis ist alles wie es soll