Map Deklaration throws error

Slevin

Aloha,

ich verwende zur Informationsweitergabe an den User die Möglichkeit, das Tray-Icon nach belieben zu setzen. Da die Icons in einem separaten Verzeichnis liegen und beim Compilieren nicht in die Exe mit eingebunden werden, möchte ich beim Start des Scripts die Icons auf Availability prüfen. Ein Map wäre da imo die perfekte Lösung, sowohl was das Checken der Icons als auch das logische Einbinden an den entsprechenden Stellen im Code angeht.

Gedacht habe ich mir folgendes:

AutoIt

Global $iconsDir = @ScriptDir & "\Icons\"
Global $icon[]

$icon["live"] = $iconsDir & "icon-live.ico"
$icon["lock"] = $iconsDir & "icon-lock.ico"
$icon["dot"] = $iconsDir & "icon-dot.ico"
$icon["blank"] = $iconsDir & "icon-blank.ico"
$icon["dismount"] = $iconsDir & "icon-dismount.ico"

For i = 1 to 10
   $icon["$i"] = $iconsDir & "icon-" & $i & ".ico"
Next

For i = 0 To UBound($icon) - 1
   If Not FileExists($icon[$i]) Then Exit
Next

Alles anzeigen

Leider schmeisst mir AutoIt beim Starten folgenden Fehler raus:

Global $icon[]

Global $icon[^ ERROR

Error Variable subscript badly formatted.

Kann mir jemand sagen, was ich falsch mache?

Vielen Dank

**alpines**

Welche AutoIt-Version verwendest du denn? Maps wurden in den Stables glaube ich entfernt, du könntest stattdessen ein Enum-Array verwenden oder ein Dictionary.

**Bitnugger**

Maps... wo? Sehe nirgends welche...

Falsch:

Global $icon[]

Richtig:

Global $icon[4]

Falsch:

For i = 1 to 10

Richtig:

For $i = 1 to 10

Falsch:

For i = 0 To UBound($icon) - 1

Richtig:

For $i = 0 To UBound($icon) - 1

Ich würde es so machen...

AutoIt

Global $g_sIconsDir = @ScriptDir & "\Icons\"
Global $g_aIcons = [['live', 'icon-live.ico'], ['lock', 'icon-lock.ico'], ['dot', 'icon-dot.ico'], ['dismount', 'icon-dismount.ico']]

For $i = 0 To UBound($g_aIcons) - 1
    If Not FileExists($g_sIconsDir & $g_aIcons[$i][1]) Then
        Exit MsgBox(16, @ScriptFullPath, StringFormat('Error: Icon für "%s" nicht gefunden!\nPfad: %s', $g_aIcons[$i][0], $g_sIconsDir & $g_aIcons[$i][1]))
    EndIf
Next

**alpines**

Bitnugger dann kannst du aber nicht wie bei Maps die Icons mit Bezeichnern erreichen, das war ja der ursprüngliche Plan.

Dann muss man nämlich innerhalb des Codes nicht immer die Indizes suchen sondern nimmt einfach den Bezeichner oder das Enum und fertig.

AutoIt

;Dictionaryvariante
$oImages = ObjCreate("Scripting.Dictionary")

$oImages("live") = "icon-live.ico"
$oImages("lock") = "icon-lock.ico"

ConsoleWrite("$oImages(""live"") = " & $oImages("live") & @CRLF)
ConsoleWrite("$oImages(""lock"") = " & $oImages("lock") & @CRLF)

ConsoleWrite(@CRLF)

;Enum-Arrayvariante
Global Enum $LIVE, $LOCK
Global $aImages[2]

$aImages[$LIVE] = "icon-live.ico"
$aImages[$LOCK] = "icon-lock.ico"

ConsoleWrite("$aImages[$LIVE] = " & $aImages[$LIVE] & @CRLF)
ConsoleWrite("$aImages[$LOCK] = " & $aImages[$LOCK] & @CRLF)

Alles anzeigen

**Bitnugger**

Zitat von alpines

Bitnugger dann kannst du aber nicht wie bei Maps die Icons mit Bezeichnern erreichen, das war ja der ursprüngliche Plan.

Ah, ja, hast recht... dann würde ich natürlich auch Dictionary verwenden... weil es Maps ja nicht mehr in der Prod gibt.

Slevin

Also Map als Variable gibt es demnach gar nicht? Dann sollte man das vllt auch aus der Referenz rausnehmen^^

Bitnugger:

Wie alpimes richtig erkannt hat, geht es ja darum die Icons mit einer logischen Bezeichnung zu adressieren und nicht mit einem Array rumzuspielen.

Die fehlenden $ sind der Schlampigkeit geschuldet, hier auf die Schnelle den Sinn meines Anliegens darzustellen - sorry dafür

alpines:

Aktuell verwende ich Version 3.3.14.5

Danke für die Alternativen, große Hilfe. Mal schauen, welche der beiden Varianten mir sympathischer rüberkommt

**alpines**

Zitat von Slevin

Also Map als Variable gibt es demnach gar nicht?

Die wurden nicht verlässlich genug implementiert um sie in der Stable zu behalten also waren sie bisher nur in Betas drinne.

Die 3.3.14.5 ist die letzte Stable, demnach sind sie dort nicht vorhanden.

Den Haken für erledige habe ich mal für dich gesetzt.

Yjuq

Lustigerweise stehen die Maps aber noch in der aktuellen doku drinne unter der Language Reference.