Webbrowser mit Tabs

Pad385 · 9. März 2019

Kann da mal bitte jemand drüber schauen und mich in die richtige Richtung schubsen?!

Irgendwie will das mit den Tabs nicht funktionieren, wobei die Tabs erstellt werden jedoch der IE nicht.

Wenn ihr keine Lösung habt erstelle ich halt von Anfang an 10 Tabs wollte ich aber eigentlich nicht machen..muss doch möglich sein..

Die Buttons machen auch was sie wollen habe jetzt schon länger nichts mehr mit autoit gemacht bitte helft mir ein wenig muss ja kein

fertiges Skript sein die Herausforderung soll ja bestehen bleiben^^

Code

#cs ----------------------------------------------------------------------------

    Author: Pad
    Version: beta
    Kommentare: new tabs...

#ce ----------------------------------------------------------------------------

HotKeySet("{LEFT}", "_back")
HotKeySet("{RIGHT}", "_forward")
HotKeySet("{DOWN}", "_refresh")

#include<ButtonConstants.au3>
#include<EditConstants.au3>
#include<GUIConstantsEx.au3>
#include<StaticConstants.au3>
#include<WindowsConstants.au3>
#include<IE.au3>

Global $numTabs = 4
Global $textTabs = "Tab"

$IE1 = _IECreateEmbedded()
$IE2 = _IECreateEmbedded()
$IE3 = _IECreateEmbedded()
$IE4 = _IECreateEmbedded()
$IE5 = _IECreateEmbedded()
$IE6 = _IECreateEmbedded()
$IE7 = _IECreateEmbedded()
$IE8 = _IECreateEmbedded()
$IE9 = _IECreateEmbedded()
$IE10 = _IECreateEmbedded()
$IE11 = _IECreateEmbedded()
$IE12 = _IECreateEmbedded()

$frm_haupt = GUICreate("Webbrowser", 1500, 750, 200, 125)
GUICtrlSetFont(-1, 11, 800, 0, "Palatino Linotype")
$btn_tab = GUICtrlCreateButton("Close All", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_SHOW)
$btn_tab1 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab2 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab3 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab4 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab5 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab6 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab7 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tab8 = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$btn_tabCloseAll = GUICtrlCreateButton("Neuer Tab", 18, 28, 75, 25)
GUICtrlSetState(-1, @SW_HIDE)
$tabbar = GUICtrlCreateTab(15, 5, 1473, 685)
$tab1 = GUICtrlCreateTabItem("Tab 1")
$browser1 = GUICtrlCreateObj($IE1, 16, 56, 1468, 683)
$eingabe1 = GUICtrlCreateInput("", 95, 30, 1313, 21)
$btn_home1 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
$tab2 = GUICtrlCreateTabItem("Tab 2")
$browser2 = GUICtrlCreateObj($IE2, 16, 56, 1468, 683)
$eingabe2 = GUICtrlCreateInput("", 95, 30, 1313, 21)
$btn_home2 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
$tab3 = GUICtrlCreateTabItem("Tab 3")
GUICtrlSetState(-1, $GUI_SHOW)
$browser3 = GUICtrlCreateObj($IE3, 16, 56, 1468, 683)
$eingabe3 = GUICtrlCreateInput("", 95, 30, 1313, 21)
$btn_home3 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)

GUISetState(@SW_SHOW)

_IENavigate($IE1, "start.duckduckgo.com")
$currenthtml1 = _IEPropertyGet($IE1, "locationurl")
GUICtrlSetData($eingabe1, $currenthtml1)
_IENavigate($IE2, "start.duckduckgo.com")
$currenthtml2 = _IEPropertyGet($IE2, "locationurl")
GUICtrlSetData($eingabe2, $currenthtml2)
_IENavigate($IE3, "start.duckduckgo.com")
$currenthtml3 = _IEPropertyGet($IE3, "locationurl")
GUICtrlSetData($eingabe3, $currenthtml3)

AdlibRegister("_update", 10000)

MouseMove(239, 168)
MouseDown("left")
Sleep(50)
MouseUp("left")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $eingabe1
            $html1 = GUICtrlRead($eingabe1)
            _IENavigate($IE1, $html1)
            $currenthtml1 = _IEPropertyGet($IE1, "locationurl")
            GUICtrlSetData($eingabe1, $currenthtml1)
        Case $eingabe2
            $html2 = GUICtrlRead($eingabe2)
            _IENavigate($IE2, $html2)
            $currenthtml2 = _IEPropertyGet($IE2, "locationurl")
            GUICtrlSetData($eingabe2, $currenthtml2)
        Case $eingabe3
            $html3 = GUICtrlRead($eingabe3)
            _IENavigate($IE3, $html3)
            $currenthtml3 = _IEPropertyGet($IE3, "locationurl")
            GUICtrlSetData($eingabe3, $currenthtml3)
        Case $btn_home1
            _IENavigate($IE1, "start.duckduckgo.com")
            $currenthtml1 = _IEPropertyGet($IE1, "locationurl")
            GUICtrlSetData($eingabe1, $currenthtml1)
        Case $btn_home2
            _IENavigate($IE2, "start.duckduckgo.com")
            $currenthtml2 = _IEPropertyGet($IE2, "locationurl")
            GUICtrlSetData($eingabe2, $currenthtml2)
        Case $btn_home3
            _IENavigate($IE3, "start.duckduckgo.com")
            $currenthtml3 = _IEPropertyGet($IE3, "locationurl")
            GUICtrlSetData($eingabe3, $currenthtml3)
        Case $btn_tab
            _newtab4()
        Case $btn_tab1
            _newtab5()
        Case $btn_tab2
            _newtab6()
        Case $btn_tab3
            _newtab7()
        Case $btn_tab4
            _newtab8()
        Case $btn_tab5
            _newtab9()
        Case $btn_tab6
            _newtab10()
        Case $btn_tab7
            _newtab11()
        Case $btn_tab8
            _newtab12()
        Case $btn_tabCloseAll
            _close()
    EndSwitch
WEnd

Func _back()
    $var = InputBox("", "Welcher Tab?", "", "", 100, 125)
    If $var = "1" Then
        _IEAction($IE1, "back")
        If @error Then
            _IENavigate($IE1, "start.duckduckgo.com")
        EndIf
        $currenthtml = _IEPropertyGet($IE1, "locationurl")
        GUICtrlSetData($eingabe1, $currenthtml1)
    EndIf
    If $var = "2" Then
        _IEAction($IE2, "back")
        If @error Then
            _IENavigate($IE2, "start.duckduckgo.com")
        EndIf
        $currenthtm = _IEPropertyGet($IE2, "locationurl")
        GUICtrlSetData($eingabe2, $currenthtml2)
    EndIf
    If $var = "3" Then
        _IEAction($IE3, "back")
        If @error Then
            _IENavigate($IE3, "start.duckduckgo.com")
        EndIf
        $currenthtm3 = _IEPropertyGet($IE3, "locationurl")
        GUICtrlSetData($eingabe3, $currenthtml3)
    EndIf
EndFunc

Func _forward()
    $var = InputBox("","Welcher Tab?")
    If $var = "1" Then
        _IEAction($IE1, "forward")
        If @error Then
            _IEAction($IE1, "refresh")
        EndIf
        $currenthtml = _IEPropertyGet($IE1, "locationurl")
        GUICtrlSetData($eingabe1, $currenthtml1)
    EndIf
    If $var = "2" Then
        _IEAction($IE2, "forward")
        If @error Then
            _IEAction($IE2, "refresh")
        EndIf
        $currenthtm = _IEPropertyGet($IE2, "locationurl")
        GUICtrlSetData($eingabe2, $currenthtml2)
    EndIf
    If $var = "3" Then
        _IEAction($IE3, "forward")
        If @error Then
            _IEAction($IE3, "refresh")
        EndIf
        $currenthtm3 = _IEPropertyGet($IE3, "locationurl")
        GUICtrlSetData($eingabe3, $currenthtml3)
    EndIf
EndFunc

Func _refresh()
    _IEAction($IE1, "refresh")
    $currenthtml = _IEPropertyGet($IE1, "locationurl")
    GUICtrlSetData($eingabe1, $currenthtml)
    _IEAction($IE2, "refresh")
    $currenthtml2 = _IEPropertyGet($IE2, "locationurl")
    GUICtrlSetData($eingabe2, $currenthtml2)
    _IEAction($IE3, "refresh")
    $currenthtml3 = _IEPropertyGet($IE3, "locationurl")
    GUICtrlSetData($eingabe3, $currenthtml3)
EndFunc

Func _update()
    $currenthtml = _IEPropertyGet($IE1, "locationurl")
    GUICtrlSetData($eingabe1, $currenthtml)
    $currenthtml2 = _IEPropertyGet($IE2, "locationurl")
    GUICtrlSetData($eingabe2, $currenthtml2)
    $currenthtml3 = _IEPropertyGet($IE3, "locationurl")
    GUICtrlSetData($eingabe3, $currenthtml3)
EndFunc

Func _newtab4()
    GUICtrlSetState($btn_tab, @SW_HIDE)
    GUICtrlSetState($btn_tab1, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser4 = GUICtrlCreateObj($IE4, 16, 56, 1468, 683)
    $eingabe4 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home4 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab5()
    GUICtrlSetState($btn_tab1, @SW_HIDE)
    GUICtrlSetState($btn_tab2, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser5 = GUICtrlCreateObj($IE5, 16, 56, 1468, 683)
    $eingabe5 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home5 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab6()
    GUICtrlSetState($btn_tab2, @SW_HIDE)
    GUICtrlSetState($btn_tab3, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser6 = GUICtrlCreateObj($IE6, 16, 56, 1468, 683)
    $eingabe6 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home6 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab7()
    GUICtrlSetState($btn_tab3, @SW_HIDE)
    GUICtrlSetState($btn_tab4, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser7 = GUICtrlCreateObj($IE7, 16, 56, 1468, 683)
    $eingabe7 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home7 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab8()
    GUICtrlSetState($btn_tab4, @SW_HIDE)
    GUICtrlSetState($btn_tab5, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser8 = GUICtrlCreateObj($IE8, 16, 56, 1468, 683)
    $eingabe8 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home8 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab9()
    GUICtrlSetState($btn_tab5, @SW_HIDE)
    GUICtrlSetState($btn_tab6, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser9 = GUICtrlCreateObj($IE9, 16, 56, 1468, 683)
    $eingabe9 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home9 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab10()
    GUICtrlSetState($btn_tab6, @SW_HIDE)
    GUICtrlSetState($btn_tab7, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser10 = GUICtrlCreateObj($IE10, 16, 56, 1468, 683)
    $eingabe10 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home10 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab11()
    GUICtrlSetState($btn_tab7, @SW_HIDE)
    GUICtrlSetState($btn_tab8, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser11 = GUICtrlCreateObj($IE10, 16, 56, 1468, 683)
    $eingabe11 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home10 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _newtab12()
    GUICtrlSetState($btn_tab8, @SW_HIDE)
    GUICtrlSetState($btn_tabCloseAll, @SW_SHOW)
    $tabbar = GUICtrlCreateTabItem($textTabs & $numTabs)
    $browser12 = GUICtrlCreateObj($IE12, 16, 56, 1468, 683)
    $eingabe12 = GUICtrlCreateInput("", 95, 30, 1313, 21)
    $btn_home12 = GUICtrlCreateButton("Startseite", 1410, 28, 75, 25)
    $numTabs = $numTabs + 1
EndFunc

Func _close()
    Exit
EndFunc

Alles anzeigen

**alpines** · 9. März 2019

Was soll dein Skript machen und wo willst du es am Ende denn einsetzen? Es gibt doch bestimmt ne bessere Möglichkeit als mit drei IE-Instanzen.

Pad385 · 9. März 2019

ich wollte einfach mal schauen ob ich in autoit nen akzeptablen IE hinbekomme läuft ja soweit nur laden der IE im neu erstellten tab nicht immer und wenn er mal lädt und ich einen neuen tab öffne verschwindet der IE einfach wieder..daher meine frage ist es so wie ich es mir vorstelle überhaupt möglich mit autoit nen IE mit tabs zu erstellen? benutzten werde ich ihn nicht sehr oft nur um automatisierte suchvorgänge zu starten und dann gegebenenfalls mit neuen tabs weiter suchen

der Webbrowser wird mit einem anderen Skript kombiniert

und anbei das leicht veränderte Skript des browsers

mal so nebenbei weis jemand wieso man auf YouTube damit nichts suchen kann? google meint das automatische suchanfragen gesendet werden wenn ich mit dem autoit Webbrowser suche..

**alpines** · 9. März 2019

Zitat von Pad385

nur um automatisierte suchvorgänge zu starten und dann gegebenenfalls mit neuen tabs weiter suchen

Und da stellt sich mir die Frage wo du das machen möchtest, du kannst vielleicht komplett auf die IE.au3 verzichten und alles im Hintergrund laufen lassen.

Pad385 · 9. März 2019

versteh nicht was du meinst..

ich schreibe in eine inputbox (taskbar.exe) einen Suchbegriff dann öffnet die taskbar.exe den Webbrowser.exe und soll danach suchen fertig..

da das zeimlich schnell funktioniert hat wollte ich ein button erstellen mit dem ich neue tabs erstellen kann das funktioniert auch soweit nur erstelle ich damit keinen IE im neuen tab bzw nur vorübergehend der verschwindet einfach mal so...

wie soll ich ohne die IE.au3 ein webbrowser erstellen ?

versteh ich nicht..

ich möchte schon den selbst erstellten browser verwenden das ich das mit anderen Browsern auch kann ist mir klar

**alpines** · 9. März 2019

Wonach genau willst du denn z. B. suchen bzw. was soll passieren wenn du eine Suchseite offen hast? Oder geht es einfach nur darum Google anzuschmeißen mit dem Suchbegriff den du eingetippt hast?

Beim letzteren kannst du dir auch die ganze IE.au3 klemmen und einfach deinen Browser mit einem entsprechenden Link aufmachen.

Die IE.au3 ist teilweise mit einigen Seiten (was Darstellung angeht) inkompatibel und veraltet.

**Bitnugger** · 9. März 2019

Ich habe dein Script mal ein wenig umgestrickt und damit gespielt... doch auf halben Wege hat mich dann die Lust verlassen, weil das Ganze irgendwie keinen Sinn für mich macht... wollte dir das Ergebnis aber nicht vorenthalten.

Eine mit _IECreateEmbedded() erzeugte Instanz kann nur entsorgt werden, wenn die GUI, in der sie erstellt wurde, gelöscht wird. Demzufolge müsste man die Instanzen jeweils in einer eigenen (Child-)GUI starten und diese GUi dann löschen, um die Instanz restlos entsorgen zu können, wenn ein Tab geschlossen wird.

PS: Microsoft rät zudem ausdrücklich an, den IE wegen diverser Sicherheitslücken nicht mehr zu benutzen - somit gilt dies auch für die _IE.au3.

C

;~ Opt('MustDeclareVars', 1)

#cs ----------------------------------------------------------------------------

    Author: Pad
    Version: beta
    Kommentare: new tabs...

#ce ----------------------------------------------------------------------------

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>
#include <IE.au3>
#include <GuiTab.au3>

Global $g_iTabsCount = 0, $g_iCurrentTabIndex = -1
Global $g_sTabsDefTitle = "Tab"

Global Enum $e_iTabItemIndex, $e_oIE, $e_idBrowser, $e_StartURL, $e_sCurrentHTML, $e_aHistory, $e_idInp_Eingabe, $e_idBtn_Home, $e_SizeOff
Global $g_aTabs[0][$e_SizeOff]

Global $g_iUpdateInterval = 10000

Global $g_hGUI, $g_idTab, $g_idBtn_CloseTab, $g_idBtn_NewTab, $g_idBtn_CloseAllTabs

_Main()

Func _Main()
    $g_hGUI = GUICreate("Webbrowser", 1500, 800, 200, 125)
    GUICtrlSetFont(-1, 11, 800, 0, "Palatino Linotype")

    HotKeySet("{LEFT}", "_back")
    HotKeySet("{RIGHT}", "_forward")
    HotKeySet("{DOWN}", "_refresh")

    $g_idBtn_CloseTab = GUICtrlCreateButton("Close current Tab", 18, 750, 110, 25)
    $g_idBtn_NewTab = GUICtrlCreateButton("New Tab", 18 + 110, 750, 110, 25)
    $g_idBtn_CloseAllTabs = GUICtrlCreateButton("Close all Tabs", 18 + 220, 750, 110, 25)

    $g_idTab = GUICtrlCreateTab(15, 5, 1473, 685)

    GUISetState(@SW_SHOW)

    Local $aURL = ["start.duckduckgo.com", "www.google.de", "autoit.de", "www.autoitscript.com"]
    For $i = 0 To 3 Step 1
        _NewTab($aURL[$i])
    Next

    $g_iCurrentTabIndex = 3
    _GUICtrlTab_ActivateTab($g_idTab, $g_iCurrentTabIndex) ; Tab 3 aktivieren

    AdlibRegister("_update", 250)

    Local $nMsg
    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case _GetID($g_iCurrentTabIndex, $e_idInp_Eingabe)
                ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $nMsg --> " & $nMsg & @CRLF)
                _IENavigate($g_aTabs[$g_iCurrentTabIndex][$e_oIE], GUICtrlRead($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe]))
                $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl")
                GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
            Case _GetID($g_iCurrentTabIndex, $e_idBtn_Home)
                _IENavigate($g_aTabs[$g_iCurrentTabIndex][$e_oIE], $g_aTabs[$g_iCurrentTabIndex][$e_StartURL])
                $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl")
                GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
            Case $g_idBtn_CloseTab
                _CloseTab()
            Case $g_idBtn_NewTab
                _NewTab()
            Case $g_idBtn_CloseAllTabs
                _CloseAllTabs()
        EndSwitch
    WEnd
EndFunc  ;==>_Main

Func _GetID($iIndex, $ID)
    Return $g_iTabsCount > $iIndex And $iIndex > -1 ? $g_aTabs[$iIndex][$ID] : -1
EndFunc  ;==>_GetID

Func _back()
    ConsoleWrite('_back()' & @CRLF)
    If $g_iTabsCount > $g_iCurrentTabIndex Then
        Local $aHistory = $g_aTabs[$g_iCurrentTabIndex][$e_aHistory]
        ConsoleWrite("@@ _back()    : $aHistory[" & 0 & "] --> " & $aHistory[0] & '/' & UBound($aHistory) -1 & @CRLF)
        If $aHistory[0] > 1 Then
            $aHistory[0] -= 1
            $g_aTabs[$g_iCurrentTabIndex][$e_aHistory] = $aHistory
            _IEAction($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "back")
            If @error Then _IENavigate($g_aTabs[$g_iCurrentTabIndex][$e_oIE], $g_aTabs[$g_iCurrentTabIndex][$e_StartURL])
            $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl")
            GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
        EndIf
    EndIf
EndFunc  ;==>_back

Func _forward()
    ConsoleWrite('_forward()' & @CRLF)
    If $g_iTabsCount > $g_iCurrentTabIndex Then
        Local $aHistory = $g_aTabs[$g_iCurrentTabIndex][$e_aHistory]
        ConsoleWrite("@@ _forward() : $aHistory[" & 0 & "] --> " & $aHistory[0] & '/' & UBound($aHistory) -1 & @CRLF)
        If UBound($aHistory) > 1 And $aHistory[0] < UBound($aHistory) -1 Then
            $aHistory[0] += 1
            $g_aTabs[$g_iCurrentTabIndex][$e_aHistory] = $aHistory
            _IEAction($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "forward")
            If @error Then _IENavigate($g_aTabs[$g_iCurrentTabIndex][$e_oIE], $g_aTabs[$g_iCurrentTabIndex][$e_StartURL])
            $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl")
            GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
        EndIf
    EndIf
EndFunc  ;==>_forward

Func _refresh()
    ConsoleWrite('_refresh()' & @CRLF)
    If $g_iTabsCount > $g_iCurrentTabIndex Then
        _IEAction($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "refresh")
        $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl")
        GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
        ; CurrentHTML in History eintragen, falls noch nicht vorhanden.
        If _ArraySearch($aHistory, $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML], 1) = -1 Then
            $aHistory[0] = _ArrayAdd($aHistory, $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
            $g_aTabs[$g_iCurrentTabIndex][$e_aHistory] = $aHistory
        EndIf
    EndIf
EndFunc  ;==>_refresh

Func _update()
    If $g_iTabsCount > $g_iCurrentTabIndex Then
        Local $aHistory = $g_aTabs[$g_iCurrentTabIndex][$e_aHistory]
        $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl")
        GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
        ; CurrentHTML in History eintragen, falls noch nicht vorhanden.
        If _ArraySearch($aHistory, $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML], 1) = -1 Then
            $aHistory[0] = _ArrayAdd($aHistory, $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
            $g_aTabs[$g_iCurrentTabIndex][$e_aHistory] = $aHistory
        EndIf
    EndIf
EndFunc  ;==>_update

Func _NewTab($sURL = "start.duckduckgo.com")
    $g_iCurrentTabIndex = _ArrayAdd($g_aTabs, '')
    $g_iTabsCount += 1
    $g_aTabs[$g_iCurrentTabIndex][$e_iTabItemIndex] = _GUICtrlTab_InsertItem($g_idTab, $g_iCurrentTabIndex, "Tab " & $g_iTabsCount) ; $iTabItemIndex
    _GUICtrlTab_ActivateTab($g_idTab, $g_iCurrentTabIndex)

    $g_aTabs[$g_iCurrentTabIndex][$e_oIE] = _IECreateEmbedded() ; $oIE
    Local $aHistory = [0]
    $g_aTabs[$g_iCurrentTabIndex][$e_aHistory] = $aHistory
    $g_aTabs[$g_iCurrentTabIndex][$e_idBrowser] = GUICtrlCreateObj($g_aTabs[$g_iCurrentTabIndex][$e_oIE], 16, 60, 1468, 673) ; $idBrowser
    $g_aTabs[$g_iCurrentTabIndex][$e_StartURL] = $sURL ; $sURL
    _IENavigate($g_aTabs[$g_iCurrentTabIndex][$e_oIE], $g_aTabs[$g_iCurrentTabIndex][$e_StartURL])
    $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML] = _IEPropertyGet($g_aTabs[$g_iCurrentTabIndex][$e_oIE], "locationurl") ; $sCurrentHTML

    $g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe] = GUICtrlCreateInput("$idInp_Eingabe", 16, 30, 1390, 21) ; $idInp_Eingabe
    $g_aTabs[$g_iCurrentTabIndex][$e_idBtn_Home] = GUICtrlCreateButton("Startseite", 1408, 28, 75, 25) ; $idBtn_Home

    GUICtrlSetData($g_aTabs[$g_iCurrentTabIndex][$e_idInp_Eingabe], $g_aTabs[$g_iCurrentTabIndex][$e_sCurrentHTML])
EndFunc  ;==>_NewTab

Func _CloseTab()
    If $g_iTabsCount Then
        GUICtrlDelete($g_aTabs[$g_iCurrentTabIndex][$e_idBrowser])
        _GUICtrlTab_DeleteItem($g_idTab, $g_iCurrentTabIndex)
        _ArrayDelete($g_aTabs, $g_iCurrentTabIndex)
        $g_iCurrentTabIndex -= 1
        $g_iTabsCount -= 1
        _GUICtrlTab_ActivateTab($g_idTab, $g_iCurrentTabIndex)
    EndIf
EndFunc  ;==>_CloseTab

Func _CloseAllTabs()
    For $i = 0 To $g_iTabsCount - 1 Step 1
        GUICtrlDelete($g_aTabs[$i][$e_idBrowser])
    Next
    _GUICtrlTab_DeleteAllItems($g_idTab)
    ReDim $g_aTabs[0][$e_SizeOff]
    $g_iTabsCount = 0
    $g_iCurrentTabIndex = -1
EndFunc  ;==>_CloseAllTabs

Alles anzeigen

Teilen