"gestapelte" Controls - Problem bei der Bk-Farbgebung

De Rand Ere

Hallo zusammen,

ich hab den halben Tag "gebastelt" - leider ohne Erfolg!!

Ich habe ein GUI die ich in einem tollen GELB als "Bk" einfärbe. Darauf lege ich "riesiege" Button. Auch alles noch gut. Da die Kennzeichnung des Hotkey (&Zulauf) doch sehr sparsam ausfällt will ich in meinem "RiesenButton" den Hotkey einfach oben rechts mit einblenden. Ich habe als die Create-Befehle "gestapelt". Das funzt auch alles - nur die Farbe stimmt nicht.

Ich hab das mal ausgeklinkt:

Spoiler anzeigen

#include-once

#include <FontConstants.au3>

#include <GUIConstantsEx.au3>

#include <WindowsConstants.au3>

; -----------------------------------------------------------------------

$hGui = GUICreate("Lable über Button", 500, 400)

GUISetBkColor(0xFFCC01, $hGui) ; gelb

$idZulauf = GUICtrlCreateButton("Zulauf", 250, 150, 220, 100)

GUICtrlSetFont($idZulauf, 40, $FW_BOLD, 0)

$vText = "Es gibt:"&@LF&@LF&"GUISetBkColor - Hintergrundfarbe GUI - genutzt"&@LF&@LF&"GUICtrlSetBkColor - Hintergrundfarbe Contol - genutzt"

GUICtrlCreateLabel($vText,10,20,380,100)

GUICtrlSetFont(-1, 10, $FW_BOLD, 0)

;~ GUICtrlCreateGroup(" HotKey ", 395, 155, 60, 20)

;~ GUIctrlSetBKColor(0xF0F0F0,-1)

$hHKInfo = GUICtrlCreateLabel('"Alt + z"', 400, 160, 50, 15, Default, $WS_EX_TRANSPARENT)

GUICtrlSetFont(-1, 10)

GUICtrlSetBkColor(0xF0F0F0, -1)

;~ GUICtrlCreateGroup("", -99, -99, 1, 1) ; Gruppe schliessen

GUICtrlCreateLabel("Warum scheint das GELB durch?",10,260,380,40)

GUICtrlSetFont(-1, 10, $FW_BOLD, 0)

GUICtrlCreateLabel("Auch wenn ich eine 'Gruppe' dahinterlege (hier als Komentar) ändert sich an dem GELB nix",10,300,480,40)

GUICtrlSetFont(-1, 10, $FW_BOLD, 0)

GUICtrlCreateLabel("Wo ist der Fehler ???? (:-(((",10,350,380,40)

GUICtrlSetFont(-1, 20, $FW_BOLD, 0)

GUISetState(@SW_SHOW, $hGui)

While 1

Switch GUIGetMsg()

Case $GUI_EVENT_CLOSE

ExitLoop

EndSwitch

WEnd

; Ende

Wo ist der Fehler? Warum scheint GELB durch???

Hab ihr eine Idee ?

Vorab schon mal Danke

**chesstiger**

Das Problem ist recht trivial:

GUICtrlSetBkColor akzeptiert zwei Parameter:

1. Die Control-ID des Controls oder -1 für das zuletzt erstellte Control.

2. Die zu setzende Farbe.

Du hast lediglich die Parameter vertauscht, die entsprechende Zeile muss GUICtrlSetBkColor(-1, 0xF0F0F0) lauten.

**Oscar**

Statt ein Label über den Button zu legen, was öfter zu Problemen beim Refresh führt, würde ich lieber den Text auf eine Bitmap schreiben und diese dem Button zuweisen:

C

#include <ButtonConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WinAPIHObj.au3>
#include <WinAPIIcons.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>

Global $hGui = GUICreate("Lable über Button", 500, 400)
GUISetBkColor(0xFFCC01, $hGui) ; gelb

Global $idZulauf = GUICtrlCreateButton('', 250, 150, 220, 100)
_ButtonSetText(-1, 'Zulauf', 'Alt + z', 'Arial', 40, 10)
GUISetState(@SW_SHOW, $hGui)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func _ButtonSetText($idCtrl, $sText1, $sText2, $sFontname, $iFontsize1, $iFontsize2)
    Local $hCtrl, $hParent, $iW, $iH, $hBitmap, $hGraphic, $hBrush, $hFamily, $hFont, $hFormat, $tLayout, $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    $hCtrl = GUICtrlGetHandle($idCtrl) ; das Handle vom Controlelement holen
    If Not $hCtrl Then Return SetError(1, 0, False)
    If Not BitAND(_WinAPI_GetWindowLong($hCtrl, $GWL_STYLE), $BS_BITMAP) Then GUICtrlSetStyle($idCtrl, $BS_BITMAP)
    $iW = _WinAPI_GetWindowWidth($hCtrl)
    $iH = _WinAPI_GetWindowHeight($hCtrl)
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH) ; Eine Bitmap erstellen
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; Graphic-Context der Bitmap holen
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, 4) ; Textrendering festlegen
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000) ; Farbe festlegen (ARGB)
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname) ; Schriftart festlegen
    $hFont = _GDIPlus_FontCreate($hFamily, $iFontsize1, 0) ; Schriftgroesse und -stil fuer Text1 festlegen
    $hFormat = _GDIPlus_StringFormatCreate()
    _GDIPlus_StringFormatSetAlign($hFormat, 1) ; horizontal zentrieren
    _GDIPlus_StringFormatSetLineAlign($hFormat, 1) ; vertikal zentrieren
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH) ; Rechteck fuer Text1
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText1, $hFont, $tLayout, $hFormat, $hBrush)
    _GDIPlus_FontDispose($hFont)
    $hFont = _GDIPlus_FontCreate($hFamily, $iFontsize2, 0) ; Schriftgroesse und -stil fuer Text2 festlegen
    _GDIPlus_StringFormatSetAlign($hFormat, 2) ; rechts ausrichten
    $tLayout = _GDIPlus_RectFCreate(0, 4, $iW - 20, $iFontsize2 * 2) ; Rechteck fuer Text2
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText2, $hFont, $tLayout, $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    $hPrevImage = _SendMessage($hCtrl, $BM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    If $hPrevImage Then
        If Not _WinAPI_DeleteObject($hPrevImage) Then _WinAPI_DestroyIcon($hPrevImage)
    EndIf
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

De Rand Ere

@chesstiger: Danke für die schnelle Antwort ... mitten in der Nacht .... Hab ich heute früh gelesen und mußte erst mal herzhaft lachen. Mit war schon aufgefallen das die zwei Funktionen (GUICtrlSetBkColor und GUISetBkColor) mit ihren Parameter unterschiedlich aufgebaut sind. Find ich ja komisch aber es war nun mal der Wille des Schöpfers. ... und deshalb hab ich hier ca. 2h rumgemährt und noch nen Thema im Forum aufgemacht.

Hab's korrigiert und siehe da es funst nicht so wie gedacht, da das Lable beim Überfahren des Button verschwindet und nicht mehr wieder kommt. Somit ist der Beitrag von @Oscar natürlich berechtigt. Danke @Oscar Das schau ich mir genauer an. Wobei der Code-Aufwand für diese paar Buchstaben gigantisch ist. Dennoch vielen Dank.

**Oscar**

Zitat von De Rand Ere

Wobei der Code-Aufwand für diese paar Buchstaben gigantisch ist.

Ich hab's Dir doch als Funktion geschrieben.

Wenn Du nicht nur einen Button damit benutzt, ist es doch schon wieder wenig Code.

Und im Prinzip könnte man zusätzlich auch noch ein Icon oder so mit auf den Button anzeigen. Solche universellen Buttons bekommt man nunmal nicht "umsonst".

De Rand Ere

@Oscar: Ja, danke noch mal für diese Funktion. Die Code-Länge sah hier im Forum wesentlich größer aus als er sich im SciTE darstellt. Und da ich mehrere Button verwende relativiert sich das wieder. Was mich zum nächsten Punkt bring. Bei einem weiteren Button benutze ich einen mehrzeiligen Text ('Paket"&@CR&@CR&"&Ausgabe').

Die Funktion "_GDIPlus_GraphicsDrawStringEx" setzt diesen String in eine Grafik um, kann aber nicht mit Steuerbefehlen umgehen.
Hier zur Ansicht:

C

#include <ButtonConstants.au3>
#include <FontConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WinAPIHObj.au3>
#include <WinAPIIcons.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>

Global $hGui = GUICreate("Lable über Button", 500, 400)
GUISetBkColor(0xFFCC01, $hGui) ; gelb

;~ Global $idZulauf = GUICtrlCreateButton('', 250, 150, 220, 100)
;~ _ButtonSetText(-1, 'Zulauf', '"Alt + z"', 'Arial', 40, 10)

$idSucheAusgabe1 = GUICtrlCreateButton("Paket"&@CR&@CR&"&Ausgabe", 50 , 150, 183, 215,$BS_MULTILINE)
;~         _ButtonSetText(-1, 'Paket"&@CR&@CR&"&Ausgabe', '"Alt + a"', 'Arial', 40, 10)
        GUICtrlSetFont(-1,30, $FW_BOLD ,0)

$idSucheAusgabe2 = GUICtrlCreateButton("Paket"&@CR&@CR&"&Ausgabe", 250 , 150, 183, 215,$BS_MULTILINE)
        _ButtonSetText(-1, 'Paket"&@CR&@CR&"&Ausgabe', 'HotKey: Alt + a', 'Arial', 40, 10)
GUISetState(@SW_SHOW, $hGui)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func _ButtonSetText($idCtrl, $sText1, $sText2, $sFontname, $iFontsize1, $iFontsize2)
    Local $hCtrl, $hParent, $iW, $iH, $hBitmap, $hGraphic, $hBrush, $hFamily, $hFont, $hFormat, $tLayout, $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    $hCtrl = GUICtrlGetHandle($idCtrl) ; das Handle vom Controlelement holen
    If Not $hCtrl Then Return SetError(1, 0, False)
    If Not BitAND(_WinAPI_GetWindowLong($hCtrl, $GWL_STYLE), $BS_BITMAP) Then GUICtrlSetStyle($idCtrl, $BS_BITMAP)
    $iW = _WinAPI_GetWindowWidth($hCtrl)
    $iH = _WinAPI_GetWindowHeight($hCtrl)
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH) ; Eine Bitmap erstellen
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; Graphic-Context der Bitmap holen
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, 4) ; Textrendering festlegen
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000) ; Farbe festlegen (ARGB)
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname) ; Schriftart festlegen
    $hFont = _GDIPlus_FontCreate($hFamily, $iFontsize1, 0) ; Schriftgroesse und -stil fuer Text1 festlegen
    $hFormat = _GDIPlus_StringFormatCreate()
    _GDIPlus_StringFormatSetAlign($hFormat, 1) ; horizontal zentrieren
    _GDIPlus_StringFormatSetLineAlign($hFormat, 1) ; vertikal zentrieren
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH) ; Rechteck fuer Text1
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText1, $hFont, $tLayout, $hFormat, $hBrush)
    _GDIPlus_FontDispose($hFont)
    $hFont = _GDIPlus_FontCreate($hFamily, $iFontsize2, 0) ; Schriftgroesse und -stil fuer Text2 festlegen
    _GDIPlus_StringFormatSetAlign($hFormat, 2) ; rechts ausrichten
    $tLayout = _GDIPlus_RectFCreate(0, 4, $iW - 20, $iFontsize2 * 2) ; Rechteck fuer Text2
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText2, $hFont, $tLayout, $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    $hPrevImage = _SendMessage($hCtrl, $BM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    If $hPrevImage Then
        If Not _WinAPI_DeleteObject($hPrevImage) Then _WinAPI_DestroyIcon($hPrevImage)
    EndIf
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

Es werden also die Steuerbefehle mit dargestellt. Die Funktion "_GDIPlus_GraphicsDrawStringEx" bringt keine weiteren Möglichkeiten der Textmanipulation mit sich. Bliebe also die Variante für den Button-Text (mehrzeilig) zwei bzw. mehrere "Grafiktexte" zu erstellen und entsprechen anzuordnen. Oder hast Du/Ihr noch ne andere Idee?

Vorab vielen Dank und einen schönen sonnigen Sonntag

**alpines**

OT:

De Rand Ere deine Markierung mit dem @ Zeichen solltest du dir abgewöhnen.

WBB hat bereits eine Funktion implementiert um Nutzer zu benachrichtigen, dazu musst du einfach nur @ schreiben und danach den Nutzernamen (ein Popup taucht auf).

Wenn du das ganze so machst, wird der User auch markiert und kriegt eine Benachrichtigung. Du musst nicht manuell das Profil verlinken und den Namen einfärben.

De Rand Ere

alpines Danke für den Hinweis - wußte ich nicht. Wollte der höflichen Form nachkommen

**Oscar**

Zitat von De Rand Ere

Die Funktion "_GDIPlus_GraphicsDrawStringEx" bringt keine weiteren Möglichkeiten der Textmanipulation mit sich.

Doch, eigentlich schon! Wenn man es richtig macht.

Es wird immer das Rechteck ($tLayout) gefüllt. Für einen Zeilenumbruch muss man aber @LF und nicht @CR verwenden. Unter Windows sowieso am sichersten beides (@CRLF).

Ich habe die Funktion mal so angepasst, dass es dem Original sehr ähnlich sieht:

Code

#include <ButtonConstants.au3>
#include <FontConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WinAPIHObj.au3>
#include <WinAPIIcons.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>

Global $hGui = GUICreate("Lable über Button", 500, 400)
GUISetBkColor(0xFFCC01, $hGui) ; gelb

Global $idZulauf = GUICtrlCreateButton('', 120, 10, 220, 100)
_ButtonSetText(-1, "Zulauf", "HotKey: Alt + z", "Segoe UI", 40, 10)

$idSucheAusgabe1 = GUICtrlCreateButton("Paket" & @CR & @CR & "Ausgabe", 50, 150, 183, 215, $BS_MULTILINE)
GUICtrlSetFont(-1, 30, $FW_BOLD, 0)

$idSucheAusgabe2 = GUICtrlCreateButton("", 250, 150, 183, 215)
_ButtonSetText(-1, "Paket" & @LF & @LF & "Ausgabe", "HotKey: Alt + a", "Segoe UI", 28, 10)
GUISetState(@SW_SHOW, $hGui)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

Func _ButtonSetText($idCtrl, $sText1, $sText2, $sFontname, $iFontsize1, $iFontsize2)
    Local $hCtrl, $hParent, $iW, $iH, $hBitmap, $hGraphic, $hBrush, $hFamily, $hFont, $hFormat, $tLayout, $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    $hCtrl = GUICtrlGetHandle($idCtrl) ; das Handle vom Controlelement holen
    If Not $hCtrl Then Return SetError(1, 0, False)
    If Not BitAND(_WinAPI_GetWindowLong($hCtrl, $GWL_STYLE), $BS_BITMAP) Then GUICtrlSetStyle($idCtrl, $BS_BITMAP)
    $iW = _WinAPI_GetWindowWidth($hCtrl)
    $iH = _WinAPI_GetWindowHeight($hCtrl)
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH) ; Eine Bitmap erstellen
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hBitmap) ; Graphic-Context der Bitmap holen
    _GDIPlus_GraphicsSetTextRenderingHint($hGraphic, 4) ; Textrendering festlegen
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF000000) ; Farbe festlegen (ARGB)
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname) ; Schriftart festlegen
    $hFont = _GDIPlus_FontCreate($hFamily, $iFontsize1, 1) ; Schriftgroesse und -stil fuer Text1 festlegen
    $hFormat = _GDIPlus_StringFormatCreate()
    _GDIPlus_StringFormatSetAlign($hFormat, 1) ; horizontal zentrieren
    _GDIPlus_StringFormatSetLineAlign($hFormat, 1) ; vertikal zentrieren
    $tLayout = _GDIPlus_RectFCreate(1, 4, $iW - 2, $iH - 12) ; Rechteck fuer Text1
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText1, $hFont, $tLayout, $hFormat, $hBrush)
    _GDIPlus_FontDispose($hFont)
    $hFont = _GDIPlus_FontCreate($hFamily, $iFontsize2, 0) ; Schriftgroesse und -stil fuer Text2 festlegen
    _GDIPlus_StringFormatSetAlign($hFormat, 2) ; rechts ausrichten
    $tLayout = _GDIPlus_RectFCreate(0, 4, $iW - 20, $iFontsize2 * 2) ; Rechteck fuer Text2
    _GDIPlus_GraphicsDrawStringEx($hGraphic, $sText2, $hFont, $tLayout, $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    $hPrevImage = _SendMessage($hCtrl, $BM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    If $hPrevImage Then
        If Not _WinAPI_DeleteObject($hPrevImage) Then _WinAPI_DestroyIcon($hPrevImage)
    EndIf
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc   ;==>_ButtonSetText

Alles anzeigen

De Rand Ere

Oscar Geil, sowas von geil ... das freut mich echt. Will noch mal schauen, was Du verändert hast um halbwegs zu verstehen, wie das geht. _GDIPlus ist nicht so meine Welt. Da muß ich mich immer erst neu reindenken.

Nu hab ich den Kanal aber erstmal voll und geh in den Garten ... "eh bissl rumwürschn" und eh Bier trinken.
Gehabt Euch wohl ...