_WM_NOTIFY - _GUICtrlListView_SortItems zu langsam

smaster123

Hallo Zusammen,

ich nutze in meinem Script eine ListView, welche ich durch _GUICtrlListView_RegisterSortCallBack($ListView1), GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY") und eine entsprechende _WM_NOTIFY Funktion sortierbar gemacht habe.

Code

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iCode, $tNMHDR, $hWndListView

    $hWndListView = $ListView1
    If Not IsHWnd($ListView1) Then $hWndListView = GUICtrlGetHandle($ListView1)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode

                Case $LVN_COLUMNCLICK ; A column was clicked
                    Local $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)
                    _GUICtrlListView_SortItems($hWndFrom, DllStructGetData($tInfo, "SubItem"))
                    ;(.....)

Alles anzeigen

Die Zeile _GUICtrlListView_SortItems($hWndFrom, DllStructGetData($tInfo, "SubItem")) sorgt dafür, dass man die Daten nach den Headern auf/absteigend sortieren kann. Dies dann auch mit dem bekannten sortierhäkchen :). Allerdings ist diese Funktion seeeehr seeeehr langsam. aktuell habe ich ca 1000 zeilen im ListView. Hierbei benötigt die Funktion schon ca 2 Sekunden zum Sortieren. Am Ende werden es sicher um die 1500-2000 Zeilen sein.

Hattet hierfür jemand eine Lösung? Mir ist wichtig, dass ich nach den Headern auf/absteigend sortieren kann und dies dann eben entsprechend durch dieses Häkchen angezeigt wird

Danke und LG

**alpines**

Deaktivier das Redrawing der ListView mal während du sortierst, dadurch sollte es ein wenig flotter sein.

_GUICtrlListView_BeginUpdate / EndUpdate

smaster123

Hey,

danke für den Tipp, habe ich eingebaut - hat leider vom Gefühl her nicht wirklich geholfen :P...

Sonst noch eine Idee?

lg

**autoiter**

Ähm kann es sein, dass zweimal sortiert wird?

Kommentiere mal _GUICtrlListView_RegisterSortCallBack( und _GUICtrlListView_UnRegisterSortCallBack aus.

Entweder bin ich gerade verwirrt, oder diese Funktionen würden genau das bereitstellen was du im Codezweig Case $LVN_COLUMNCLICK machst..

Also entweder oder. Wenn du in der _WM_NOTIFY-Funktion nur das machst, dann lass sie weg.

**Oscar**

Zitat von smaster123

Sonst noch eine Idee?

Das habe ich Dir bereits hier gezeigt: ListView Sortierungshäkchen entfernen

Listview-Inhalt komplett löschen, das Daten-Array sortieren und das sortierte Array im Listview anzeigen. Das ist deutlich schneller, als das sortieren im Listview.

smaster123

autoiter um _GUICtrlListView_SortItems nutzen zu können benötige ich _GUICtrlListView_RegisterSortCallBack(. Ohne Funktioniert das gar nicht.

Oscar Ja, da hast du recht. Da ging es aber um eine andere Sortierung (Selbes Programm, andere Stelle :)).

Ich habe das nun mit Hilfe deiner Ideen selbst gelöst.

Ich ziehe das ganze von der Datenbank, direkt so sortiert, wie ich das brauche und spiele es im ListView ein. Durch eine Boolsche variable gebe ich mit ob True oder False und setze somit auch das häckchen :),

Es ist zwar noch immer nicht ultra schnell, aber min 80% schneller als vorher :).

Danke euch!

Code

    Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iCode, $tNMHDR, $hWndListView

    $hWndListView = $ListView1
    If Not IsHWnd($ListView1) Then $hWndListView = GUICtrlGetHandle($ListView1)

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")

    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode

                Case $LVN_COLUMNCLICK ; A column was clicked
                    Local $tInfo = DllStructCreate($tagNMLISTVIEW, $lParam)

;~                     ; Kick off the sort callback
;~                     _GUICtrlListView_BeginUpdate($ListView1)
;~                     _GUICtrlListView_SortItems($hWndFrom, DllStructGetData($tInfo, "SubItem"))
;~                     _GUICtrlListView_EndUpdate($ListView1)
                    ; No return value

                    SQLOPEN()
                    Local $iIndex
                    For $i = 0 To UBound($g_aRadio) - 1
                        If GUICtrlRead($g_aRadio[$i][0]) = 1 Then $iIndex = $i
                    Next
                    $getrecord = _MSSQL_GetRecord($sqlCon, "TabelleA", "*", "Order by " & $headItems[DllStructGetData($tInfo, "SubItem")][0] & " " & $sort)
                    SQLCLOSE()

                    If $sort = "asc" Then
                        updateListView(False, True, DllStructGetData($tInfo, "SubItem"), $HDF_SORTUP)
                        $sort = "desc"
                    ElseIf $sort = "desc" Then
                        updateListView(False, True, DllStructGetData($tInfo, "SubItem"), $HDF_SORTDOWN)
                        $sort = "asc"
                    EndIf
                    ;(......)
    EndFunc

Func updateListView($autosize = true, $setformat = False, $column = 0, $format = 0)

    _GUICtrlListView_BeginUpdate($ListView1)
    _GUICtrlListView_DeleteAllItems($ListView1)
    _ArrayDelete($getrecord, 0)
    _GUICtrlListView_AddArray($ListView1, $getrecord)

;~     SORTIERPFEIL ENTFERNEN UND AUTOSIZE HEADER
    For $i = 0 To _GUICtrlListView_GetColumnCount($ListView1) - 1
        $aInfo = _GUICtrlListView_GetColumn($ListView1, $i)
        _GUICtrlListView_SetColumn($ListView1, $i, $aInfo[5])
        If $autosize = True Then _GUICtrlListView_SetColumnWidth($ListView1, $i, $LVSCW_AUTOSIZE_USEHEADER)
    Next
;~     SETZE SORTIERHÄCKCHEN WENN GEWÜNSCHT
    If $setformat = True Then
        $header = _GUICtrlListView_GetHeader($ListView1)
        $aFormat = _GUICtrlHeader_GetItemFormat($header, $column)
        _GUICtrlHeader_SetItemFormat($header, $column, BitXOR($aFormat, $format))
    EndIf
    _GUICtrlListView_EndUpdate($ListView1)

EndFunc   ;==>updateListView

Alles anzeigen