_MouseTrapCircle

**BugFix** · 11. April 2020

EDIT:

Hinweise von Bitnugger eingearbeitet:

Ein Nebenprodukt aus einem Projekt von mir, vielleicht auch nützlich für euch.

Mit der Funktion _MouseTrapCircle() wird die Maus in einem definierten Kreis gefangen.

~~Ist die Maus bei Aktivieren der Funktion außerhalb des Kreises, wird sie bei der ersten Mausbewegung in den Kreis bewegt und kann diesen nicht wieder verlassen, bis die Funktion deaktiviert wird.~~

Bei Aufruf der Funktion wird die Maus in den Kreis verschoben und kann diesen bis zur Deaktivierung nicht mehr verlassen.

Der Kreis wird definiert über den Mittelpunkt (Standard) oder die linke obere Ecke des umlaufenden Rechtecks sowie dem Durchmesser.

Weiteres Bsp. (Kreis nicht auf Gui) hinzugefügt.

AutoIt: MouseTrapCircle_Bsp.au3

;-- TIME_STAMP   2020-04-12 08:06:53

#include 'MouseTrapCircle.au3'
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)


_Example_1()

Global $g_hPen, $g_hGraphic, $g_hDC
_Example_2()  ; "Strg+Shift+T" - Trap On/Off, "Strg+Shift+0" - Beenden

Func _Example_1()
    Local $hGui, $hGraphic, $dummy, $bTrap = False, $idStatus
    Local $iD = 140 ; Durchmesser

    $hGui = GUICreate('MouseTrapCircle   [Trap: OFF]', 300, 300, 400, 100)
    GUICtrlCreateLabel('"Strg+Shift+T"' & @LF & '(De)Aktiviert das Trapping.', 20, 20, 260, 50)
    GUICtrlSetFont(-1, 12, 400, 0, 'Consolas')
    $idStatus = GUICtrlCreateLabel('Trap: OFF', 20, 260, 100)
    GUICtrlSetFont(-1, 12, 600, 0, 'Consolas')
    GUICtrlSetColor(-1, 0xFF0000)
    $dummy = GUICtrlCreateDummy()
    Local $aAcc[1][2] = [['^+T',$dummy]]
    GUISetAccelerators($aAcc, $hGui)

    GUISetState(@SW_SHOW, $hGui)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
;~     _GDIPlus_GraphicsDrawEllipse($hGraphic, 80, 100, $iD, $iD)        ; draw by edge
    _GDIPlus_GraphicsDrawCircleByCentre($hGraphic, 150, 170, $iD)     ; draw by center

    While True
        Switch GUIGetMsg()
            Case -3
                ExitLoop
            Case $dummy
                $bTrap = Not $bTrap
                If $bTrap Then
;~                     _MouseTrapCircle($hGui, 80, 100, 140, True) ;    by: left-top edge
                    _MouseTrapCircle($hGui, 150, 170, 140)      ; or by: center
                    WinSetTitle($hGui, '', 'MouseTrapCircle   [Trap: ON]')
                    GUICtrlSetData($idStatus, 'Trap: ON')
                    GUICtrlSetColor($idStatus, 0x00BE08)
                Else
                    _MouseTrapCircle()
                    WinSetTitle($hGui, '', 'MouseTrapCircle   [Trap: OFF]')
                    GUICtrlSetData($idStatus, 'Trap: OFF')
                    GUICtrlSetColor($idStatus, 0xFF0000)
                EndIf
        EndSwitch
    WEnd

    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
    GUIDelete($hGui)
EndFunc

Func _GDIPlus_GraphicsDrawCircleByCentre($_hGraphic, $_iX, $_iY, $_iDiameter, $_hPen=0)
    $_iX -= $_iDiameter/2
    $_iY -= $_iDiameter/2
    _GDIPlus_GraphicsDrawEllipse($_hGraphic, $_iX, $_iY, $_iDiameter, $_iDiameter, $_hPen)
EndFunc

;---------------------------------------------------------------------------------------------------

Func _Example_2()
    AdlibRegister('_DrawOnDesktop')
    HotKeySet('^+T', '_SwitchTrap')
    HotKeySet('^+0', '_Exit')
    _GDIPlus_Startup()
    While True
        Sleep(10)
    WEnd
EndFunc

Func _SwitchTrap()
    Local Static $bTrap = False
    $bTrap = Not $bTrap
    If $bTrap Then
        _MouseTrapCircle(-1, 500, 500, 250)  ; by: center
        MsgBox(64, '_MouseTrapCircle', 'MouseTrapCircle   [ ON ]', 2)
    Else
        _MouseTrapCircle()
        MsgBox(64, '_MouseTrapCircle', 'MouseTrapCircle   [ OFF ]', 2)
    EndIf
EndFunc

Func _DrawOnDesktop()
    Local Static $bMinimized = False
    If Not $bMinimized Then
        $bMinimized = True
        Send('#m')
    EndIf
    Local $g_hDC = _WinAPI_GetWindowDC(0) ; DC of entire screen (desktop)
    Local $g_hGraphic = _GDIPlus_GraphicsCreateFromHDC($g_hDC)
    Local $g_hPen = _GDIPlus_PenCreate(0xFF00BE08, 4)
    _GDIPlus_GraphicsDrawCircleByCentre($g_hGraphic, 500, 500, 250, $g_hPen)
    _GDIPlus_PenDispose($g_hPen)
    _GDIPlus_GraphicsDispose($g_hGraphic)
    _WinAPI_ReleaseDC(0, $g_hDC)
EndFunc

Func _Exit()
    AdlibUnRegister('_DrawOnDesktop')
    _GDIPlus_Shutdown()
    Send('#+m')
    Exit
EndFunc

Alles anzeigen

**Bitnugger** · 11. April 2020

Hehe... is ja mal very cool!

Zitat von BugFix

Ist die Maus bei Aktivieren der Funktion außerhalb des Kreises, wird sie bei der ersten Mausbewegung in den Kreis bewegt ...

Besser fände ich, wenn die Maus direkt bei Aktivierung an den Innenrand des Kreises bewegt wird... evtl. auch als optionalen Parameter mit angeben.

Gar nicht gut finde ich, dass die Maus beim Versuch den Kreis zu verlassen, in die Mitte des Kreises bewegt wird.

**BugFix** · 11. April 2020

Zitat von @Bitnugger

Besser fände ich, wenn die Maus direkt bei Aktivierung an den Innenrand des Kreises bewegt wird... evtl. auch als optionalen Parameter mit angeben.

Das sollte kein Problem sein.

Zitat von @Bitnugger

Gar nicht gut finde ich, dass die Maus beim Versuch den Kreis zu verlassen, in die Mitte des Kreises bewegt wird.

OK, wenn ich den ersten Punkt umsetzte lässt sich das auch einfacher machen. Dann kann ich die Abfrage entgegengesetzt ausführen und muss die Maus nicht zurück bewegen. Da sie immer im Kreis ist, verwerfe ich dann einfach die nach außen gehenden Bewegungen. Werde ich morgen erledigen.

**BugFix** · 12. April 2020

Neue Version 0.2.

**autoBert** · 12. April 2020

Hallo BugFix,

bei beiden Beispielen wird der Mauszeiger festgefroren, ein Bewegen ist nicht möglich. Bei Beispiel 1 (wie beschrieben) innerhalb des Kreises (auf dem Mittelpunkt), bei Beispiel 2 etwas rechts unterhalb des Kreises (auf der Verlängerung des Radius).

mfg (auto)Bert

**BugFix** · 12. April 2020

autoBert

Bei mir laufen beide Bsp. fehlerfrei.

Win7 pro x64

Ich habe auch probiert, ob die Position der Taskbar einen Einfluss hat - hat sie aber (jedenfalls bei mir) nicht. Die absoluten Positionen gehen vom sichtbaren Bildschirmbereich ohne Taskbar aus.

Somit weiß ich gar nicht, wo ich jetzt nach Störquellen suchen sollte, da es ja bei mir läuft.

**Musashi** · 12. April 2020

Zitat von BugFix

Somit weiß ich gar nicht, wo ich jetzt nach Störquellen suchen sollte, da es ja bei mir läuft.

_MouseTrapCircle funktioniert auch bei mir problemlos (Win7, AutoIt 3.3.14.0). Ich muss nur versionsbedingt #include <WinAPISys.au3> statt #include <WinAPISysWin.au3> verwenden. Worauf ich allerdings kurz hereingefallen bin ist der Hotkey '^+0' für_Exit. Hier hatte ich auf die Schnelle O (den Buchstaben) und nicht 0 (Null) gelesen, aber das ist ja meine eigene Schuld.

Der Mauszeiger bewegt sich, nach subjektiver Wahrnehmung, bei Trap ON etwas 'ruckeliger'.

**autoBert** · 12. April 2020

Ich benutze AutotoIt 3.3.14.5 zusammen mit:

auf

Beim Versuch das Ergebnis zu dokumentieren wird aber seltsanerweise der Mauszeiger im Kreis gecaptured:

so das dies wohl eine weitere Eigenart meines Systems ist. Ein eingefügtes Consolewrite:

Code

        ConsoleWrite($g__aCircle[0] & @TAB & $g__aCircle[1] & @CRLF)

Code

ergibt: 500    500

mfg (auto)Bert

**Bitnugger** · 12. April 2020

Bei mir laufen auch beide Bsp. fehlerfrei. Unschön ist nur noch, dass der Mauszeiger sich an den nicht ganz runden Stellen festhakt und bei einem flachen Bewegungswinkel der Maus nicht in die entsprechende Richtung rutscht, aber das ist wohl nur schwer zu berechnen.

Win10 x64 Pro, AutoIt 3.3.14.5

Wenn die Maus in Pfeilrichtung bewegt wird: Links im Bild hakt die Maus an dieser Stelle... rechts im Bild die Position, bis wo sie rutschen sollte.

Zitat von autoBert

Ich benutze AutotoIt 3.3.14.5 zusammen mit:

Hihi...

**BugFix** · 12. April 2020

Zitat von Bitnugger

Unschön ist nur noch, dass der Mauszeiger sich an den nicht ganz runden Stellen festhakt und bei einem flachen Bewegungswinkel der Maus nicht in die entsprechende Richtung rutscht, aber das ist wohl nur schwer zu berechnen.

Ich prüfe ja, ob die Position in der errechneten Kreisfläche ist. Ich bin eigentlich recht zufrieden mit dem Ergebnis. Mein Ziel war ja nicht, dass der Benutzer am Kreisrand mit der Maus entlangfährt, sondern dass der nutzbare Bereich auf eine Kreisform beschränkt, also gewissermaßen fokussiert wird.

Ich hatte erst überlegt, die Punkte des Umfangs zu berechnen und zu speichern. Aber sowohl das Berechnen als auch das Auswerten wären zeitlich indiskutabel lang. Die jetzige Berechnung braucht zwar nur ein paar Ticks, führt aber schon dazu, dass bei schneller Bewegung ein geringfügiges Ruckeln sichtbar ist.

autoBert

Hast du die Probleme auch, wenn du das Skript kompilierst?

Im Moment scheint sich das Problem an der "Home"-Version festzumachen. Ich muss mal schauen, ob irgendjemand in der Familie ein Win 10 Home benutzt. Wozu gibts die überhaupt? Ich verwende immer nur Pro-Versionen, da gibt einem M$ wenigstens die Chance das System etwas zu beeinflussen.

**Bitnugger** · 12. April 2020

Bilde ich mir das nur ein, oder hakt es mit _GDIPlus_GraphicsSetSmoothingMode weniger?

AutoIt

Func _Example_1()
    ...
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphic, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;Sets the graphics object rendering quality (antialiasing)
    ...

Bei mir ruckelt es übrigens nicht!

Zitat von BugFix

Ich hatte erst überlegt, die Punkte des Umfangs zu berechnen und zu speichern.

Evtl. geht das mit ..., _GDIPlus_PathAddEllipse, _GDIPlus_PathIsVisiblePoint

**Musashi** · 13. April 2020

Zitat von Bitnugger

Bilde ich mir das nur ein, oder hakt es mit _GDIPlus_GraphicsSetSmoothingMode weniger?

Falls ja, dann bilden wir uns das beide ein. Auch das minimale Ruckeln erscheint mit nun etwas weniger 'ruckelig' .

**autoBert** · 13. April 2020

Zitat von BugFix

autoBert
Hast du die Probleme auch, wenn du das Skript kompilierst?

Ja.

Zitat von BugFix

Im Moment scheint sich das Problem an der "Home"-Version festzumachen.

Ich schiebe es auf mein Touchpad.

Edit: mit Touchscreen funktioniert es.

mfg (auto)Bert

Teilen