Font size ist irgendwie komisch

Professor Bernd

Hallo Leute. Diesmal habe ich mal NICHT vorher recherchiert, sondern frage erstmal hier.

Mir ist aufgefallen, dass die Schriftgröße in Labels nicht mit der "normalen" übereinstimmt, die man in Editoren findet (SciTE, PSPad, Libre Office, ...), wenn man Größen von 8 oder weniger benutzt. Dann sind die Schriften im Label irgendwie kleiner, als üblich. Scheinbar entspricht im AutoIt-Label die 8.5 der normalen Größe 8, aber dazu konnte ich nur optische Vergleiche vornehmen.

Im Screenshot habe ich Libre Office und AutoIt Labels gegenüber gestellt.

Font size 8 und weniger passt nicht.png

Wer sich das Ganze live ansehen will, hier ein Code-Schnipsel.

AutoIt

#include <GUIConstantsEx.au3>

Opt("MustDeclareVars", 1)

Example()

Func Example()

  ; GUI
  Local $hGui = GUICreate("My GUI", 400, 300, 510, 440)
;   GUISetFont(10, Default, Default, "Courier New")

  Local $iTop = 0

  ; Labels mit verschiedener Schriftgöße erstellen.
  For $i = 4 To 14
    $iTop += 20
    GUICtrlCreateLabel("This is a label with font size " & $i, 10, $iTop, 380)
    GUICtrlSetFont(-1, $i, Default, Default, "Courier New")
  Next

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()

            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

Bernd.

Musashi

Zitat von Professor Bernd

wenn man Größen von 8 oder weniger benutzt. Dann sind die Schriften im Label irgendwie kleiner, als üblich.

Hmm, kann ich so nicht feststellen (GUI und Text in OpenOffice)

FontCompare.png

Gruß Musashi

**alpines**

Zitat von Professor Bernd

Diesmal habe ich mal NICHT vorher recherchiert, sondern frage erstmal hier.

Du Frevel, wenn ich das hier nochmal sehe dann gibts was auf die Finger.

Ich hab deinen Post gelesen, aber ich sehe nirgends ein Fragezeichen. Was ist denn deine Frage?

LibreOffice mit AutoIt zu vergleichen ist etwas unpraktisch, denn viele Software benutzen nicht die Standardfont bzw. irgendwas standardmäßiges von Windows wenn sie ihre GUI erzeugen. Siehe Chrome, Steam, Skype, TeamViewer.

Es kann auch noch sein, dass du einige Optionen im LibreOffice Dokument hast die die Schriftart etwas modifizieren: Zoom, DPI und dergleichen.

Wenn du ganz sicher gehen willst, dass es nicht AutoIts Schuld ist, dann nehm direkt die WinAPI-Funktionen um Schriftarten zu erzeugen und zeichne sie so auf deine GUI.

Professor Bernd

Zitat von alpines

Ich hab deinen Post gelesen, aber ich sehe nirgends ein Fragezeichen. Was ist denn deine Frage?

Die (unausgesprochene) Frage ist: Was denkt ihr darüber?

Zitat von alpines

LibreOffice mit AutoIt zu vergleichen ist etwas unpraktisch,

Ok, dann machs mal besser und zeig einen besseren Vergleich.

Wenn du genau hinsiehst, kannst du erkennen, dass der Vergleich mit Libre Office nicht notwendig ist. Er ist nur zur Illustration für diejenigen (wie ich), die gerne sehen, wovon gesprochen wird. Wenn du dir den Screenshot genau ansiehst, genügt die AutoIt Darstellung, dort ist der Unterschied von Größe 10 zu 8 deutlich zu groß. Oder sieh dir den Screenshot von Musashi an, dort ist der Größenunterschied adäquat. Das macht sich in meinem CallTipViewer bemerkbar, weil der CallTip nicht an die richtige Stelle positioniert wird.

@Musashi So wie in deinem Screenshot sollte es eigentlich aussehen. Hast du unter Win 7 getestet? Ist das wieder ein Win 10 Problem?

Kann das jemand unter Win 10 testen?

Bernd.

Musashi

Zitat von Professor Bernd

Musashi So wie in deinem Screenshot sollte es eigentlich aussehen. Hast du unter Win 7 getestet? Ist das wieder ein Win 10 Problem?

Unter Win7 und mit OpenOffice 4.x.

OpenOffice verwendet offenbar die Standardfonts -> siehe Hinweis diesbzgl. von alpines .

Professor Bernd

Ich habe es gerade auf Win 7 getestet, als kompilierte Exe. Das Ergebnis ist wie auf meinem Screenshot! Also mit falscher Schriftgröße bei Einstellung 8. Das legt den Verdacht nahe, dass es mit der AutoIt-Version zu tun haben kann.

@Musashi Meine AutoIt-Version ist 3.3.14.5. Mit welcher AutoIt-Version hast du getestet?

@Alle Hat jemand eine Idee, woran es liegen kann, dass die Schriftgröße in AutoIt-Labels bei Einstellung 8 oder weniger nicht richtig erscheint?

Bernd.

Musashi

Zitat von Professor Bernd

Musashi Meine AutoIt-Version ist 3.3.14.5. Mit welcher AutoIt-Version hast du getestet?

3.3.14.0

Professor Bernd

@Musashi Wärst du so nett, deinen Test-Code zu posten? Dann kann ich den Libre-, Open-, usw. -Vergleich entfernen und deinen Screenshot zum Vergleichen nutzen. (Denn es geht hier nicht um den Vergleich, sondern die Darstellung der Schriftgröße im AutoIt Label.)

Bernd.

Musashi

Zitat von Professor Bernd

Wärst du so nett, deinen Test-Code zu posten?

Du meinst sicher eine von mir mit 3.3.14.0 kompilierte EXE ==> habe ich gezippt angehängt ( EXE kann man aus Gründen der Sicherheit nicht posten).

Ich habe nur die Zeilenabstände etwas verändert, aber das Ergebnis ist ansonsten analog.

Gruß Musashi

Professor Bernd

Ich habe nun AutoIt 3.3.14.0 auf einem Test-PC mit Win 7 installiert (ohne SciTE4AutoIt3), und dann mein Test-Script gestartet. Leider ist das Ergebnis nicht so wie bei Musashi.

---- Zwischezeitlich ist Posting #9 von Musashi erstellt worden. ----

Zitat von Musashi

Du meinst sicher eine von mir mit 3.3.14.0 kompilierte EXE

Vielen Dank dafür, aber ich brauche tatsächlich dein Au3-Script. Vielleicht ist irgendwo ein Komma, oder sonstwas anderes, das man übersehen kann. Deshalb möchte ich mit genau deinem Script testen, weil das (bei dir) die richtigen Schriftgrößen anzeigt.

Musashi

Zitat von Professor Bernd

Vielen Dank dafür, aber ich brauche tatsächlich dein Au3-Script.

OK, hier kommt's :

AutoIt

#include <GUIConstantsEx.au3>

Opt("MustDeclareVars", 1)

Example()

Func Example()

  ; GUI
  Local $hGui = GUICreate("My GUI", 500, 350, 510, 440)
;   GUISetFont(10, Default, Default, "Courier New")

  Local $iTop = 0

  ; Labels mit verschiedener Schriftgöße erstellen.
  For $i = 4 To 14
    $iTop += 15 + $i
    GUICtrlCreateLabel("fontsize " & $i, 10, $iTop, 480)
    GUICtrlSetFont(-1, $i, Default, Default, "Courier New")
  Next

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()

            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>Example

Alles anzeigen

Professor Bernd

Danke Musashi!

Hier nun der Vergleich zwischen der Darstellung auf deinem System mit Win 7, auf meinem System mit Win 7, und auf meinem System mit Win 10. Ich habe jedesmal deine Fonttest.exe aus Posting #9 gestartet und einen Screenshot erstellt. Der Screenshot von deinem System ist von dir aus Posting #2.

FontCompare 1 Musashi u Win 7, 10 Bernd.png

Hat jemand eine Idee, wovon die Abweichungen in der Darstellung kommen?

Bernd.

Musashi

Zitat von Professor Bernd

Hat jemand eine Idee, wovon die Abweichungen in der Darstellung kommen?

Vermutung : Könnte ggf. an den installierten Schriften liegen. Nicht alle unterstützen die fontsizes 4,5,6,7,8,9 usw. Möglicherweise habe ich mir irgendwann mal eine Fontsammlung installiert, die zusätzliche Features mitgebracht hat.

Professor Bernd

Zitat von Musashi

Könnte ggf. an den installierten Schriften liegen.

Interessante Idee. Leider nicht zutreffend. Wie schon eingangs geschrieben, werden in anderen Anwendungen die Schriftgrößen so dargestellt, wie von deinem Test-Script.

**Oscar**

Nein, das denke ich auch nicht. "Courier New" ist eine TTF-Schriftart. Die wird vom Programm skaliert.

Hier scheint AutoIt beim erstellen der Label die Schriftarten "falsch" zu skalieren.

Wenn man GDI+ zum erstellen verwendet, dann stimmen die Werte:

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example1()
Example2()

Func Example1()

    ; GUI
    Local $hGui = GUICreate("My GUI", 500, 800, 100)
    ;   GUISetFont(10, Default, Default, "Courier New")

    Local $iTop = 0

    ; Labels mit verschiedener Schriftgöße erstellen.
    For $i = 4 To 27
        $iTop += 15 + $i
        GUICtrlCreateLabel("fontsize " & $i, 10, $iTop, 480, 15 + $i)
        GUICtrlSetFont(-1, $i, 0, 0, "Courier New")
    Next

    GUISetState(@SW_SHOW)
EndFunc   ;==>Example

Func Example2()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout
    Local $sString, $aInfo, $iTop = 10

    ; Create GUI
    $hGUI = GUICreate("My GUI GDI+", 500, 800, 700)
    GUISetState(@SW_SHOW)

    ; Draw a string
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Courier New")
    For $i = 4 To 27
        $iTop += 15 + $i
        $sString = "fontsize " & $i
        $hFont = _GDIPlus_FontCreate($hFamily, $i, 0)
        $tLayout = _GDIPlus_RectFCreate(10, $iTop, 0, 0)
        $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sString, $hFont, $tLayout, $hFormat)
        _GDIPlus_GraphicsDrawStringEx($hGraphic, $sString, $hFont, $aInfo[0], $hFormat, $hBrush)
        _GDIPlus_FontDispose($hFont)
    Next

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Clean up resources
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

Alles anzeigen

Professor Bernd

Oscar Wow, doppeltes Danke! Erstens für die GDI+ "Kurzeinführung"! Zweitens für die Beweisführung, dass etwas in AutoIt schief läuft.

Hier ein Screenshot mit Musashis Script und halben Schritten für die Schriftgröße auf meinem System. Wie man sehen kann, entspricht die Schriftgröße 8.5 bei mir in etwa der Schriftgröße 8 bei Musashi. Das zeigt, AutoIt kann die Größe richtig skalieren, macht es aber nicht.

Spoiler anzeigen

Fonttest 2 Musashi - halbe Schritte Vergl Musashi, Bernd.png

Zitat von Oscar

Hier scheint AutoIt beim erstellen der Label die Schriftarten "falsch" zu skalieren.

Aber wo liegt der Fehler? Bzw. wie kann man Abhilfe schaffen? Wenn ich mich in GDI+ einarbeite und meinen Code auf GDI+ umstelle, verzögert sich die Veröffentlichung des CallTipViewers nicht um 4 bis 8 Wochen, sondern eher um Monate.

Bei Musashi wird die Schriftgröße der Labels in AutoIt richtig skaliert. (Wie sieht das übrigens bei dir aus?) Bei mir nicht, obwohl ich für die gleichen Voraussetzungen gesorgt habe: Ich habe das gleiche Script benutzt, das Musashi in Posting #11 zur Verfügung stellt. Ich habe getestet auf Win 7 und Win 10, mit AutoIt 3.3.1.0 und 3.3.14.5. Ich habe mit dem Script getestet und mit der von Musashi kompilierten Exe. Und dennoch wird von AutoIt auf meinen Systemen falsch skaliert, und bei Musashi wird richtig skaliert.

Ich kann gerade nicht erkennen, wo der Unterschied liegt. Und es muss einen geben, sonst wären die Skalierungen nicht unterschiedlich.

Bernd.

Professor Bernd

Kann es an der Maßeinheit für die Schriftgröße liegen? (Punkt, Pixel, Inch, ...) Kann man die Maßeinheit für die GUI oder die Labels einstellen? Opt(?)

**Oscar**

Zitat von Professor Bernd

Aber wo liegt der Fehler? Bzw. wie kann man Abhilfe schaffen?

Den Fehler kann ich leider auch nicht erkennen.

Aber eine Abhilfe könnte ich Dir anbieten:

AutoIt

#include <AutoItConstants.au3>
#include <GDIPlus.au3>
#include <SendMessage.au3>
#include <StaticConstants.au3>
#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>

Example1()

Func Example1()
    Local $hGui = GUICreate("My GUI", 500, 800, 100)
    Local $iTop = 0

    ; Labels mit verschiedener Schriftgöße erstellen.
    For $i = 4 To 27
        $iTop += 15 + $i
        GUICtrlCreateLabel("fontsize " & $i, 10, $iTop, 0, 0, $SS_BITMAP) ; Wichtig! $SS_BITMAP als Style
        _GUICtrlSetFont(-1, $i, 0, "Courier New", 0xFF00007F)
    Next
    GUISetState(@SW_SHOW)
    Do
    Until GUIGetMsg() = -3
EndFunc   ;==>Example

Func _GUICtrlSetFont($idCtrl, $iSize, $iStyle, $sFontname, $iColor = 0xFF000000)
    Local $hWnd, $sString, $hBitmap, $hGfxCtx, $hBrush, $hFormat, $hFamily, $hFont, $tLayout, $aInfo
    Local $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    If $iStyle = Default Or $iStyle <= 0 Then $iStyle = 0
    $hWnd = GUICtrlGetHandle($idCtrl)
    If Not IsHWnd($hWnd) Then Return SetError(1)
    $sString = GUICtrlRead($idCtrl)
    Local $iW = 1000, $iH = 100
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $hBrush = _GDIPlus_BrushCreateSolid($iColor)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname)
    $hFont = _GDIPlus_FontCreate($hFamily, $iSize, $iStyle)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    $iW = Ceiling($aInfo[0].Width)
    $iH = Ceiling($aInfo[0].Height)
;~     ConsoleWrite(StringFormat('Width x Height = %i x %i\r\n', $iW, $iH))
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDrawStringEx($hGfxCtx, $sString, $hFont, $aInfo[0], $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    _WinAPI_SetWindowPos($hWnd, $HWND_NOTOPMOST, 0, 0, $iW, $iH, BitOR($SWP_FRAMECHANGED, $SWP_NOMOVE))
    $hPrevImage = _SendMessage($hWnd, $STM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    If $hPrevImage Then _WinAPI_DeleteObject($hPrevImage)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

Professor Bernd

Hmm, schön, ... chinesisch! Werde mich mal durchwurschteln.

...

Oscar Kurz angesehen, sieht gut aus. Da werde ich wohl eine Weile brauchen, um durchzusteigen. Ich arbeite daran!

Professor Bernd

Oscar Genialer Code!

Um den Labels ständig neuen Text zuweisen zu können, habe ich die $sString Variable in die Funktionsdeklaration aufgenommen. Dadurch kann ich deine Funktion aufrufen und ihr einen neuen Text mitgeben. Kannst du dir das Demo angucken und mir sagen, ob ich das in meinem Programm so verwenden kann? Oder müssen da Dinge hinzugefügt, freigegeben, oder sonstwas rein?

Am Ende deines Code werden viele Sachen freigegeben. Wenn ich das in meinem Programm übernehme, muss ich dann am Ende des Programms noch etwas freigeben, oder ist schon alles freigegeben?

AutoIt

#include <AutoItConstants.au3>
#include <GDIPlus.au3>
#include <SendMessage.au3>
#include <StaticConstants.au3>
#include <WinAPIHObj.au3>
#include <WinAPIInternals.au3>
#include <WinAPISysInternals.au3>
#include <GUIConstantsEx.au3> ; Für $GUI_EVENT_CLOSE.

Example1()

Func Example1()
    Local $hGui = GUICreate("My GUI", 400, 800)
    Local $iTop = 0

    ; Labels mit verschiedener Schriftgöße erstellen.
    For $i = 4 To 27
        $iTop += 15 + $i
        GUICtrlCreateLabel("fontsize " & $i, 10, $iTop, 0, 0, $SS_BITMAP) ; Wichtig! $SS_BITMAP als Style
        _GUICtrlSetFont(-1, "fontsize" & $i, $i, 0, "Courier New", 0xFF00007F)
        GUICtrlSetBkColor(-1, 0xCCCCFF)  ; <== Um zu erkennen, wenn sich die Größe des Labels ändert.
    Next
    GUISetState(@SW_SHOW)


    Local $idBtn_1 = GUICtrlCreateButton("Change Label 7 Text", 200, 130, 120)
    Local $sNewText = "    This is a sample text to fill the label."

    While 1
      Switch GUIGetMsg()

        Case $idBtn_1
;           GUICtrlSetData(7, $sNewText)       ; <== Brauche ich das, oder kann ich das weglassen?
          _GUICtrlSetFont(7, $sNewText, 8, 0, "Courier New", 0xFF00007F)
          GUICtrlSetBkColor(7, 0xCCCCAA)       ; <== Nur um zu sehen, ob das hier einen Einfluss hat.

        Case $GUI_EVENT_CLOSE
          ExitLoop
      EndSwitch
    WEnd
EndFunc   ;==>Example
                              ; <== $sString in Funktions-Deklaration aufgenommen.
Func _GUICtrlSetFont($idCtrl, $sString, $iSize, $iStyle, $sFontname, $iColor = 0xFF000000)
    Local $hWnd, $hBitmap, $hGfxCtx, $hBrush, $hFormat, $hFamily, $hFont, $tLayout, $aInfo
    Local $hBMP, $hPrevImage
    _GDIPlus_Startup()
    If $idCtrl = Default Or $idCtrl <= 0 Then $idCtrl = _WinAPI_GetDlgCtrlID(GUICtrlGetHandle($idCtrl))
    If $iStyle = Default Or $iStyle <= 0 Then $iStyle = 0
    $hWnd = GUICtrlGetHandle($idCtrl)
    If Not IsHWnd($hWnd) Then Return SetError(1)
;     $sString = GUICtrlRead($idCtrl) ; <==
    Local $iW = 1000, $iH = 100
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $hBrush = _GDIPlus_BrushCreateSolid($iColor)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate($sFontname)
    $hFont = _GDIPlus_FontCreate($hFamily, $iSize, $iStyle)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    $iW = Ceiling($aInfo[0].Width)
    $iH = Ceiling($aInfo[0].Height)
;~     ConsoleWrite(StringFormat('Width x Height = %i x %i\r\n', $iW, $iH))
    $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    $hGfxCtx = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetTextRenderingHint($hGfxCtx, 4)
    $tLayout = _GDIPlus_RectFCreate(0, 0, $iW, $iH)
    $aInfo = _GDIPlus_GraphicsMeasureString($hGfxCtx, $sString, $hFont, $tLayout, $hFormat)
    _GDIPlus_GraphicsDrawStringEx($hGfxCtx, $sString, $hFont, $aInfo[0], $hFormat, $hBrush)
    $hBMP = _GDIPlus_BitmapCreateDIBFromBitmap($hBitmap)
    _WinAPI_SetWindowPos($hWnd, $HWND_NOTOPMOST, 0, 0, $iW, $iH, BitOR($SWP_FRAMECHANGED, $SWP_NOMOVE))
    $hPrevImage = _SendMessage($hWnd, $STM_SETIMAGE, $IMAGE_BITMAP, $hBMP)
    If $hPrevImage Then _WinAPI_DeleteObject($hPrevImage)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGfxCtx)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
EndFunc

Alles anzeigen

Wie kann man mit dem Code Tabs im Label schreiben?

Bernd.