Screen-PosX von bestimmtem Zeichen, wenn Text Tabs enthält

Professor Bernd

Hallo.

Ich suche nach einer Möglichkeit, die horizontale Screen-Position X zu ermitteln, von einem bestimmten Zeichen in einem Text.

Beispiel: Die Schrift ist "Courier New", also eine Monospace Schrift. Im Text

AutoIt

        MsgBox ( 0, "", "Hallo Welt!", 0, 0)

ist die X-Position vom "a" in "Hallo" bekannt, und es soll die X-Position vom "M" in "MsgBox" ermittelt werden.

Das funktioniert bis hierhin: Ich berechne die Breite in Pixeln vom Teilstring MsgBox(0, "", "H und ziehe sie von der bekannten Position "a" in "Hallo" ab = X-Postition vom "M" in "MsgBox".

Das Problem: Das funktioniert nur, solange keine Tabs (Tabulatoren) im Text sind.

Ich habe schon daran gedacht, die Tabs in Leerzeichen zu wandeln, aber das geht leider nicht, weil Tabs unberechenbar sind. Der Tab springt dann auf eine festgelegte Position, abhängig davon, ob schon andere Zeichen im Text stehen. Z. B. wenn ein Tab mit einer Länge von 4 angezeigt wird, so hat er nur eine Länge von 1, wenn davor 3 andere Zeichen stehen.

Wie kann man die X-Pos vom "M" in "MsgBox ermitteln, wenn Tabs im Text sind?

Bernd.

**alpines**

Zitat von Professor Bernd

Wie kann man die X-Pos vom "M" in "MsgBox ermitteln, wenn Tabs im Text sind?

Gibts da nicht was mit GDI+ um Texte zu measuren?

Professor Bernd

Ich benutze den StringSize Code von Melba 23. Wie gesagt, das Messen der Stringbreite funktioniert soweit, solange keine Tabs darin sind. Mit GDI+ kenne ich mich zu wenig aus, um das mal auf die Schnelle zu testen. Hast du einen Code Schnipsel für mich? Ich kriege noch nicht einmal das Beispiel aus der Hilfe dazu, mit "Courier New" zu laufen, geschweige denn Measurements.

Bernd.

**alpines**

Ich glaube das dürfte dort mit Tabs aber auch nicht hinhauen, aber ich glaube du sägst am falschen Ast.

Was willst du denn erreichen wenn du die Position hast? Was ist das eigentlich Problem?

Professor Bernd

Es geht um das Positionieren des CallTips unter dem Funktionsnamen.

Um Leerzeichen und Tabs gut erkennen zu können, habe ich im Screenshot die Anzeige für Formatierungszeichen eingeschaltet.

In der oberen Bildhälfte ist der CallTip richtig positioniert und direkt unterhalb des Funktionsnamens ausgerichtet. So soll es sein.

In der unteren Bildhälfte enthält der Text im Editor Tabs, weshalb ich den CallTip nicht richtig positionieren kann.

Ich suche eine Möglichkeit, die X-Position des ersten Zeichens vom Funkttionsnamen korrekt zu ermitteln (als Screen-Koordinate).

Bernd.

**alpines**

Kannst du dir in PSPad nicht die Pixel-Koordinate (nicht Zeichen-koordinate) des Zeichens innerhalb des Editcontrols ausgeben lassen?

Professor Bernd

In PSPad kann ich mir die Pixel / Screen-Koordinaten ausgeben lassen, an der das Caret steht. So erhalte ich z. B. die X-Position vom "a" in "Hallo" (siehe Postint #1). Nun könnte ich im Au3 die Pos vom ersten FuncName-Char ermitteln, das Caret in PSPad verschieben, die gewünschte X-Pos auslesen und das Caret zurücksetzen.

Leider ist die Komunikation mit der VBScript-Schnittstelle mehr als bescheiden. Mir ist leider noch kein Weg eingefallen, wie ich dem VBScript mitteilen kann, dass es das oben beschriebene tun soll. Zudem müsste es eine Möglichkeit sein, die für diesen Zeitraum alle anderen CallTip-Meschanismen außer Kraft setzt, denn sonst wird der CallTip ausgeschaltet, sobald das Caret nicht mehr zwischen den Klammern der Funktion steht.

Aber eine interessante Idee ist das schon. Wenn ich jetzt noch die oben beschriebenen Probleme lösen könnte, wäre das eine Möglichkeit.

Hast du noch eine Idee?

Ich denke jetzt mal "laut": Im VBScript läuft zur Kommunikation eine Schleife, sobald der CallTip gestartet wird. Im Au3 wird ein gültiger FuncName ermittelt und auch die Pos vom FuncNameFirstChar. Wenn es mir gelänge, dem VBScript mitzuteilen, dass es dem Au3 die ScreenPosX dazu senden soll, ohne dass das Au3 denkt, es soll mit den neuen Koordinaten vom Caret wieder von vorne anfangen, dann ... Interessant, interessant! Da geh ich mal dran.

Bernd.

**alpines**

Zitat von Professor Bernd

In PSPad kann ich mir die Pixel / Screen-Koordinaten ausgeben lassen, an der das Caret steht. So erhalte ich z. B. die X-Position vom "a" in "Hallo" (siehe Postint #1). Nun könnte ich im Au3 die Pos vom ersten FuncName-Char ermitteln, das Caret in PSPad verschieben, die gewünschte X-Pos auslesen und das Caret zurücksetzen.

Naja nicht unbedingt oder. Wann wird das Calltiperzeugt? Wenn du den Namen der Funktion getippt hast und dann die Klammer öffnest (die optionalen Leerzeichen dazwischen sind mal dahintegestellt...).

Da JEDER Programmierer, der kein absoluter Sozipath ist, monospace Schriftarten verwendet, brauchst du doch nur die Breite eines Zeichens zu ermitteln und einfach die Länge des Funktionsnamens * BreiteZeichen zurückzurechnen. Das Caret steht ja am (

Professor Bernd

Zitat von alpines

Naja nicht unbedingt oder.

Stehe gerade auf dem Schlauch, kannst du das mal übersetzen?

Zitat von alpines

Wann wird das Calltiperzeugt? Wenn du den Namen der Funktion getippt hast und dann die Klammer öffnest

Derzeit ist keine Automatik implementiert, den CallTip gibts nur beim Drücken des Shortcuts.

Zitat von alpines

Da JEDER Programmierer, der kein absoluter Sozipath ist, monospace Schriftarten verwendet,

Das scheint kein Problem zu sein, PSPad unterstütz scheinbar nun monospace Schriftarten (Stichproben gemacht).

Zitat von alpines

brauchst du doch nur die Breite eines Zeichens zu ermitteln und einfach die Länge des Funktionsnamens * BreiteZeichen zurückzurechnen. Das Caret steht ja am (

Genau so mache ich es, und genau da tauchen die Probleme mit Tabs auf. Im Text ist 1 Tab = 1 Zeichen, aber der Editor interpretiert jenach Einstellung entsprechend viele virtuelle Leerzeichen. Aber die virtuellen Leerzeichen sind in der Tat nicht echt, der Editor zieht die Darstellung für 1 Tab auf die eingestellte Länge, aber es ist und bleibt 1 Zeichen. Deshalb funktioniert die genannte Zurückrechnung nicht.

Kleine Ergänzung: Wenn jemand ein Script erstellt hat und hat eine Tabweite von 4, stellt das Script hier im Forum ein und du hast eine Tabweite von 2 wird dein Editor das bei dir entsprechend anders darstellen, als bei dem Script-Ersteller. Und trotzdem ist 1 Tab jedesmal = 1 Zeichen. Alles klar?

~~Ich versuche mal ein Bildchen anzuhängen.~~ Hier der Screenshot.

Bernd.

**alpines**

Zitat von Professor Bernd

Stehe gerade auf dem Schlauch, kannst du das mal übersetzen?

War wohl geistig abwesend. Hab das falsche dazu zitiert.

Zitat von Professor Bernd

Genau so mache ich es, und genau da tauchen die Probleme mit Tabs auf. Im Text ist 1 Tab = 1 Zeichen, aber der Editor interpretiert jenach Einstellung entsprechend viele virtuelle Leerzeichen. Aber die virtuellen Leerzeichen sind in der Tat nicht echt, der Editor zieht die Darstellung für 1 Tab auf die eingestellte Länge, aber es ist und bleibt 1 Zeichen. Deshalb funktioniert die genannte Zurückrechnung nicht.

Kannst du die Einstellung nicht einfach auslesen? Wenn ein Tab 4 Leerzeichen sind verrechnest du das einfach damit. Ich schätze man wird auch die Tablänge einstellen können, und wenn man das einstellen kann, kann man die Einstellung auch sicherlich auslesen.

Professor Bernd

Wie schon geschrieben, funktioniert das leider nicht. Wenn ein Tab auf Weite 4 eingestellt ist, und an einer virtuellen Markierung gesetzt wird, z. B. am Zeilenanfang, dann umfasst er 4 (ich nenne das mal) Einheiten für die Dartstellung im Editor. Wenn aber vor dem Tab z. B. 2 Leerzeichen stehen, wird der Tab quasi gekürzt und umfasst nur die 2 Einheiten bis zu seiner nächsten virtuellen Position. Siehe Screenshot. (schwer zu erklären)

Deshalb kann ich keine korrekte Berechnung oder ein Replace durchführen. Das ist zu komplex (für mich).

Bernd.

**alpines**

Das solltest du doch trotzdem dementsprechend berechen können. Zwei Leerzeichen + Tab = 1 Tab.

Es würde doch reichen Gruppen an x Zeichen zu parsen (x = Tabweite) und die dann einzeln auszurechnen je nachdem was drin ist.

Professor Bernd

Boah, ich sagte doch, das ist zu komplex für mich. Kannst du mir dabei helfen?

Es gibt soviele verschiedene Einstellungen für die Tab-Weite. Die Tab-Weite kann ich aus der PSPad.ini auslesen. Aber wie dann weiter? Da stehen ja nicht nur Leerzeichen, sondern jedes beliebige Zeichen kann die Entfernung bis zum nächsten Tab-Stop (heißt das so?) beeinflussen. Da steht z. B. mitten im String nach 400 Zeichen ein "(2*4)", wie findet man dann raus, welches Zeichen auf der Tab-Stop-Grenze steht? Vielleicht sind vorher schon Tabs im Text, für die müssten alle die Berechnungen gemacht werden.

So und jetzt habe ich auch noch Angst bekommen. Vermutlich wird als nächstes jemand mein Lieblingsthema in die Runde werfen und sagen, "Das ist doch alles ganz easy mit RegEx zu lösen!" Nein, bitte nicht.

Bernd.

**Musashi**

Zitat von Professor Bernd

Vermutlich wird als nächstes jemand mein Lieblingsthema in die Runde werfen und sagen, "Das ist doch alles ganz easy mit RegEx zu lösen!" Nein, bitte nicht.

Off-Topic : Ich befürchte aber, dass es dazu kommen wird und ggf. sogar kommen muss .

Professor Bernd

Da steck ich mich lieber mit Rona an!

**alpines**

Zitat von Professor Bernd

Es gibt soviele verschiedene Einstellungen für die Tab-Weite. Die Tab-Weite kann ich aus der PSPad.ini auslesen. Aber wie dann weiter? Da stehen ja nicht nur Leerzeichen, sondern jedes beliebige Zeichen kann die Entfernung bis zum nächsten Tab-Stop (heißt das so?) beeinflussen.

Wirf die Flinte nicht so schnell ins Korn.

Es ist schon sehr spät und mein Gehirn arbeitet nur noch notdürftig aber ich hab was ekelhaftes zusammenschustern können:

Spoiler anzeigen

Gesucht ist die Position des As. Das soll das Caret sein, aber du kannst ja dann dementsprechend zurückrechnen.

Die Regexe sind alle ausgeschrieben und können ERHEBLICH reduziert werden, da sich dort viele Elemente wiederholen. (siehe Algorithmus unten)

Wenn ich das im Halbschlaf hinbekomme, dann kriegt doch ein kluges Köpfchen wie du, dass auch sauber und vernünftig hin.

Einfach mal überlegen was man beachten muss und das Problem ist einfacher als gedacht.

Tabs sind hier mit Ts ersetzt. Und Code so strukturiert, dass ich das mit StringInStr zurückgeben kann. Ist aber nicht notwendig, geht aber auch anders.

Code

; Tabweite = 4 !!!
Local $aStrings[] = [ _
    "T012" & "3456789A", _
    "0T12" & "3456789A", _
    "01T2" & "3456789A", _
    "012T" & "3456789A", _
    "TT01" & "23456789A", _
    "T0T1" & "23456789A", _
    "T01T" & "23456789A", _
    "0TT1" & "23456789A", _
    "0T1T" & "23456789A", _
    "01TT" & "23456789A", _
    "TTT0" & "123456789A", _
    "T0TT" & "123456789A", _
    "TT0T" & "123456789A", _
    "0TTT" & "123456789A", _
    "TTTT" & "123456789A", _
    "0000" & "0123456789A" _
]

For $i = 0 To UBound($aStrings) - 1
    ConsoleWrite($aStrings[$i] & ":" & StringInStr($aStrings[$i], "A") & "(" & RechneDieVerrueckteDistanzZumAHerausAuchWennEsKomplizierterKlingtAlsEsTatsaechlichIst($aStrings[$i]) & ")" & @CRLF)
Next

Func RechneDieVerrueckteDistanzZumAHerausAuchWennEsKomplizierterKlingtAlsEsTatsaechlichIst($sZeile)
    Local $sNeueZeile = ""

    For $i = 1 To StringLen($sZeile) Step 4
        Local $sSegment = StringMid($sZeile, $i, 4)

        If StringLen($sSegment) = 1 Then $sSegment &= "000"
        If StringLen($sSegment) = 2 Then $sSegment &= "00"
        If StringLen($sSegment) = 3 Then $sSegment &= "0"

        If StringRegExp($sSegment, "T[^T][^T][^T]") Then $sNeueZeile &= "0000" & StringMid($sSegment, 2, 3)
        If StringRegExp($sSegment, "[^T]T[^T][^T]") Then $sNeueZeile &= StringMid($sSegment, 1, 1) & "000" & StringMid($sSegment, 3, 2)
        If StringRegExp($sSegment, "[^T][^T]T[^T]") Then $sNeueZeile &= StringMid($sSegment, 1, 2) & "00" & StringMid($sSegment, 4, 1)
        If StringRegExp($sSegment, "[^T][^T][^T]T") Then $sNeueZeile &= StringMid($sSegment, 1, 3) & "0"

        If StringRegExp($sSegment, "TT[^T][^T]") Then $sNeueZeile &= "0000" & "0000" & StringMid($sSegment, 3, 2)
        If StringRegExp($sSegment, "T[^T]T[^T]") Then $sNeueZeile &= "000" & StringMid($sSegment, 2, 1) & "000" & StringMid($sSegment, 4, 1)
        If StringRegExp($sSegment, "T[^T][^T]T") Then $sNeueZeile &= "0000" & StringMid($sSegment, 2, 1) & StringMid($sSegment, 3, 1) & "000"
        If StringRegExp($sSegment, "[^T]TT[^T]") Then $sNeueZeile &= StringMid($sSegment, 1, 1) & "000" & "0000" & StringMid($sSegment, 4, 1)

        If StringRegExp($sSegment, "[^T]T[^T]T") Then $sNeueZeile &= StringMid($sSegment, 1, 1) & "000" & StringMid($sSegment, 3, 1) & "000"
        If StringRegExp($sSegment, "[^T][^T]TT") Then $sNeueZeile &= StringMid($sSegment, 1, 2) & "00" & "0000"
        If StringRegExp($sSegment, "TTT[^T]") Then $sNeueZeile &= "0000" & "0000" & "0000" & StringMid($sSegment, 4, 1)
        If StringRegExp($sSegment, "T[^T]TT") Then $sNeueZeile &= "0000" & StringMid($sSegment, 2, 1) & "000" & "0000"

        If StringRegExp($sSegment, "TT[^T]T") Then $sNeueZeile &= "0000" & "0000" & StringMid($sSegment, 3, 1) & "000"
        If StringRegExp($sSegment, "[^T]TTT") Then $sNeueZeile &= StringMid($sSegment, 1, 1) & "000" & "0000" & "0000"
        If StringRegExp($sSegment, "TTTT") Then $sNeueZeile &= "0000" & "0000" & "0000" & "0000"
        If StringRegExp($sSegment, "[^T][^T][^T][^T]") Then $sNeueZeile &= $sSegment
    Next

    Return StringInStr($sNeueZeile, "A")
EndFunc

Alles anzeigen

Du kannst dir auch einen einfachen Algorithmus zusammenbasteln, der ist dann etwas platzsparender:

Betrachte ein Textsegment von der Länge 4 (Tabweite).

Tab => 4

A B C D => 4

A Tab BC => 4 + 2 (A fällt weg)

A B Tab C => 4 + 1 (A B fallen weg)

A B C Tab => 4 (A B C fallen weg)

Und das ganze wiederholst du dann einfach immer wieder.

Ein Tab füllt es ja bis zum nächsten 4er Segment auf, deshalb musst du da nichts mitschleppen sondern kannst von dort aus einfach neu draufzählen.

Im Grunde musst du nur den String durchlaufen und prüfen in welchem Teil des Segmentes du gerade bist und je nach Tab dann entsprechend mitzählen.

Vielleicht seh ich mir das morgen nochmal an, aber jez gehts erstmal in die heia

Professor Bernd

Zitat von alpines

Wirf die Flinte nicht so schnell ins Korn.

Auf keinen Fall!

Deinen Code mit RegExps ist für mich wie böhmische Dörfer. Vielleicht muss ich auch erst im Halbschlaf sein, damit es besser geht!? Dennoch danke für die Mühe, ich freue mich!

Zitat von alpines

Du kannst dir auch einen einfachen Algorithmus zusammenbasteln, der ist dann etwas platzsparender:
Betrachte ein Textsegment von der Länge 4 (Tabweite).
Und das ganze wiederholst du dann einfach immer wieder.

Ein Tab füllt es ja bis zum nächsten 4er Segment auf, deshalb musst du da nichts mitschleppen sondern kannst von dort aus einfach neu draufzählen.

Ob du's glaubst oder nicht, ähnliches ist mir urplötzlich klar geworden, so wie bei Doc Brown, als er den Fluxkompensator erfunden hat: Das was hochkomplex und unberechenbar schien, muss aber auch feste Regeln befolgen. Das sind die Tabstops an den n*Tabwidth Positionen. Wenn die Tabwidth 4 ist, wird an jedem 4 "Element" ausgerichtet. So wie du geschrieben hast, kann man die Stelle prüfen, auf ein Vielfaches von Tabwidth auslegen, eventuell vorhandene Zeichen pro 4er-Segment in Abzug bringen und am Schluss 5 Minuten köcheln lassen, et voilá, sollte man in der Summe die zusätzlichen X-Pos erhalten, die man zur erfassten, regulären Textlänge hinzurechnet. ... So, oder so ählich. Werde ich mal testen.

Nachtrag

Zu früh gefreut. Nachdem ich nun lange getestet, überlegt, verworfen, was anderes überlegt und getestet habe, bin ich wieder am Anfang. Ich finde keinen Bezugspunkt, an dem ich die Segmente mit den Koordinaten verbinden könnte, die mir das VBScript liefert. Das VBScript liefert nur die CaretX-Pos. Das ist nicht in Relation mit der Position des ersten FuncNameChar zu bringen, oder zum Zeilenanfang. Es könnte ja z. B. der Zeilenanfang aus dem sichtbaren Bereich des Editor rausgescrollt werden, sogar aus dem Bildschirmbereich.

Hinzu kommt, dass im Text auch Teile in Anführungszeichen stehen können, die Tabs enhalten, oder nur das Wort "@Tabs", die Anführungszeichen noch schön verschachtelt, oder andere Funktionsaufrufe innerhalb des bezogenen Funktionsaufrufes, usw.

Jetzt bin ich aber auch im Halbschlaf. Erst mal

Gutes Nächtle!

Bernd.

**Kanashius**

Ich hab das hier gerade gebastelt... das sollte alle Probleme recht simpel loesen, bis auf das, wo aus dem Bereich gescrollt wird. Dort solltest du mal schauen, ob du herausbekommst, wie weit gescrollt wird,... das folgt dort auch festern regeln... duerfte aber unschoen werden...

AutoIt

#include <Array.au3>
$testData="Some sample code with    many t    ab    s!!    here"&@crlf _
        &"and     we    sell    it    here  t    oo) =)     ds"&@crlf _
        &"and     we    sell    it    here  t    oo) =)     sss"&@crlf _
        &"    "&@crlf

$arTestData=StringSplit($testData,@CRLF,1+2)
ConsoleWrite(StringFormat("%10s","charCount")&StringFormat("%10s","tabs")&StringFormat("%10s","counted")&@crlf)
For $i=0 To UBound($arTestData)-1 Step 1
    $iLen=_getLength($arTestData[$i])
    ConsoleWrite(StringFormat("%10d",StringLen($arTestData[$i]))&StringFormat("%10d",UBound(StringSplit($arTestData[$i],@TAB,1+2))-1)&StringFormat("%10d",$iLen)&@crlf)
Next

Func _getLength($string,$iTabLength=4)
    local $arResult=StringRegExp($string,"([^\t\r\n]{0,"&$iTabLength-1&"}.)",3)
    ;_ArrayDisplay($arResult)
    If UBound($arResult)=0 Then return 0
    return (UBound($arResult)-1)*$iTabLength+(StringInStr($arResult[UBound($arResult)-1],@TAB)<>0?$iTabLength:StringLen($arResult[UBound($arResult)-1]))
EndFunc

Alles anzeigen

Der Ansatz ist der, mit dem regulaeren Ausdruck die Zeichen in Gruppen von 4 (tablength) zeichen zu zerlegen. Die Anzahl wird am Ende gezaehlt und entsprechend multipliziert. Der letzte Eintrag im array ist so lang, wie viele Zeichen enthalten sind, oder wenn ein Tab enthalten ist wieder (4).

Somit musst du nur den Text vom Anfang der Zeile bis zur CaretPosition/Anfang des Wortes dort bekommen.

In regex101 kann man das sehr schoen sehen:

Zum regex: [^\t\r\n] matcht alle Zeichen ausser tab und zeilenumbruch. mit {0,3} wird dies 0 bis 3 mal gemacht und am ende mit dem Punkt ein beliebiges zeichen (also auch tab).

Ich hoffe du kannst das verwenden und das Scrollproblem loesen.

Viel Glueck

**Kanashius**

Ich hab das ganze gerade auch noch mal ohne Regulaeren Ausdruck umgesetzt, da du die ja scheinbar nicht magst
Ist natuerlich etwas laenger+komplexer, fuer die Laufzeit aber evtl. sogar besser

AutoIt

#include <Array.au3>
$testData="Some sample code with    many t    ab    s!!    here"&@crlf _
        &"and     we    sell    it    here  t    oo) =)     ds"&@crlf _
        &"and     we    sell    it    here  t    oo) =)     sss"&@crlf _
        &"    "&@crlf

$arTestData=StringSplit($testData,@CRLF,1+2)
ConsoleWrite(StringFormat("%10s","charCount")&StringFormat("%10s","tabs")&StringFormat("%10s","counted")&StringFormat("%12s","countNoReg")&@crlf)
For $i=0 To UBound($arTestData)-1 Step 1
    $iLen=_getLength($arTestData[$i])
    $iLenNoRegExp=_getLengthNoRegExp($arTestData[$i])
    ConsoleWrite(StringFormat("%10d",StringLen($arTestData[$i]))&StringFormat("%10d",UBound(StringSplit($arTestData[$i],@TAB,1+2))-1)&StringFormat("%10d",$iLen)&StringFormat("%12d",$iLenNoRegExp)&@crlf)
Next

Func _getLength($string,$iTabLength=4)
    local $arResult=StringRegExp($string,"([^\t\r\n]{0,"&$iTabLength-1&"}.)",3)
    ;_ArrayDisplay($arResult)
    If UBound($arResult)=0 Then return 0
    return (UBound($arResult)-1)*$iTabLength+(StringInStr($arResult[UBound($arResult)-1],@TAB)<>0?$iTabLength:StringLen($arResult[UBound($arResult)-1]))
EndFunc

Func _getLengthNoRegExp($string,$iTabLength=4)
    local $arChars=StringSplit($string,"",1+2)
    local $iCount,$iSubCount
    For $i=0 to UBound($arChars)-1 step 1
        If $arChars[$i]=@TAB Then
            $iSubCount=$iTabLength
        Else
            $iSubCount+=1
        EndIf
        If $iSubCount=$iTabLength or $i=UBound($arChars)-1 Then
            $iCount+=$iSubCount
            $iSubCount=0
        EndIf
    Next
    return $iCount
EndFunc

Alles anzeigen

**BugFix**

Und Vorsicht, wenn du irgendwann mit StringLen() arbeitest. Der Tab hat immer die Länge "1", egal ob er 1,2..4 Zeichen weit springt. Dadurch kannst du nicht einfach durch Längenabfrage testen, an welcher Spaltenposition in der Zeile du gerade bist.

Wenn man mit Texten arbeitet stellt man erst mal fest, was für ein böses Konstrukt ein Tab doch ist. Zumal man ihn nicht wirklich benötigt. Die bessere Funktionalität ist eigentlich, dass bei Benutzung von Tab ohne folgenden Text die entsprechende Anzahl an Leerzeichen eingefügt werden bis zum nächsten Tab-Stop (per Einstellung z.B. in SciTE wählbar) und bei vorhandenem Text nur die Positionen angesprungen werden. In diesem Fall sind alle Positionen entweder mit Leerzeichen oder anderen Zeichen belegt und die Positionsermittlung der Tab-Stops ist dann einfach jede n-te Tabweite.