Tomtom Navi prüfen ob Netzwerk aktiv ist

Windi

Hallo Experten,

gibt es eine Möglichkeit zu prüfen, wenn das Navi an USB angeschlossen ist ob

My Drive Connect aktiv ist.

Das Navi wird als Ethernet: Nicht indentifiziertes Netzwerk

erkannt.

Die Verbindung zu TomTom ist unterschiedlich lang.

Ich habe es jetzt mit Sleep (6000) eingestellt, aber manchmal braucht es länger

und dann Läuft mein Scribt ins leere.

Gruß Windi

**Musashi**

Hallo Windi !

Warum verwendest Du immer das Testforum ?

Es handelt sich bei Deiner Frage doch um eine ganz normale Bitte um Hilfe. Poste daher zukünftig besser in das Forum (den Bereich) Hilfe & Unterstützung. So bleibt der Thread langfristig erhalten und die Antworten sind auch für Gäste sichtbar .

Bei Fragen, die nichts mit AutoIt direkt zu tun haben, wähle das Forum Off-Topic oder Talk.

BugFix oder Oscar : Könnte einer von Euch diesen Thread bitte noch mal verschieben ?

Gruß Musashi

**Moombas**

Kannst du dein Skript mal Posten? Ich denke wir können dir dabei gut und gerne helfen.

Windi

OK, Entschuldigung hab gedacht alles neue kommt ins Testforum,

gelobe Besserung und bedenke das hohe Alter.

Muss ich das jetzt verschieben oder neu machen.

Muss aus dem Skript mal alle Demodaten und Zugänge entfernen.

Ich hoffe nur ihr kriegt kein lachanfall wenn ihr meine programmierweise seht.

Gruß Windi

**Moombas**

Windi :Einen Lachanfall sicherlich nicht. Jedem Neuling kann man Hilfe geben, auch was evtl. Vereinfachungen etc. angeht. Daraus kannst du wieder etwas lernen und wird auch immer freundlich erklärt

Windi

Ich fühle mich auch sehr wohl in eurem Forum.

Sehr netter Umgang.

**water**

Zitat von Windi

Ich habe es jetzt mit Sleep (6000) eingestellt, aber manchmal braucht es länger
und dann läuft mein Skript ins leere.

Du könntest statt eines einzigen langen Sleep dies in einer Schleife machen:

Code

$bFound = False
For $I = 1 to 10  ; 10 mal warten 
    Sleep(1000) ; Eine Sekunde warten
    If <Prüfung hier - falls erfolgreich> Then
        $bFound = True ; Damit ich nach dem Loop weiss, ob prüfung erfolgreich war oder nur die maximale Wartezeit erreicht war
        ExitLoop
    EndIf     
Next
If $bFound = False Then ... Aktion, falls die Prüfung nicht erfolgreich war

**Musashi**

Zitat von Windi

OK, Entschuldigung hab gedacht alles neue kommt ins Testforum, gelobe Besserung und bedenke das hohe Alter. Muss ich das jetzt verschieben oder neu machen.

Es gibt nicht den geringsten Grund sich zu entschuldigen, Du hast ja nichts Verbotenes gemacht .

Ich wollte Dich mit meinem Beitrag #2 nur freundlich darauf hinweisen, dass das Testforum nicht unbedingt der geeigneteste Bereich für Deine Fragen ist.

Verschieben (oder neu machen) musst Du auch nichts. Das hat BugFix bereits getan, wie Du an folgender Kennzeichnung sehen kannst :

Gruß Musashi

Windi

Vielen Dank euch allen.

zu Water das mit der For Schleife ist eine gute Idee.

mein Problem ist aber, wo kann ich abfragen ob das Navi verbunden ist.

Mit Sleep, gebe ich ja nur Zeit vor um die Verbindung herzustellen.

Im Taskmanager ist das Programm aktiv bevor es das Navi aktivert.

Ich müßte also eine Abrage vom Ethernet Adapter (Vielleicht heißt das Ding auch anders)

Hab da noch was gefunden im Gerätemanager -> Netzwerkadapter wird TomTom angezeigt.

Wie frage ich das ab?

Vielleicht kann mir jemand helfen.

**Moombas**

Wie gesagt am besten mal dein bisheriges Script posten, dann kann man dir an der richtigen Stelle weiter helfen.

**water**

Wenn die Verbindung zum TomTom physisch erfolgt ist (also eingesteckt) wie stellt sich das Gerät dann in Windows dar (Laufwerksbuchstabe im Windows Explorer, Netzwerk (inactiv), USB-Drive ...)

Wenn MyConnect Drive dann läuft, was ändert sich dann in Windows?

(Meinen Garmin Edge sehe ich als 2 Laufwerke: Den internen Speicher und die SD Karte)

Wenn ich das richtig sehe, dann gibt es auch eine MyConnect Drive Komponente auf dem PC. Kann man hier den Status abfragen?

Wie kriegst Du derzeit die Daten auf's TomTom?

**Bitnugger**

Zitat von Windi

Hab da noch was gefunden im Gerätemanager -> Netzwerkadapter wird TomTom angezeigt.

Dann kannst du ihn mit dieser Funktion finden:

AutoIt: _CI_GetNetworkAdapter.au3

;-- TIME_STAMP   2020-05-14 17:45:33   v 0.1

#include-once
#include <Debug.au3> ; _DebugArrayDisplay

#cs    Firewall-Regeln für WMI aktivieren, um Anfragen von anderen Rechnern durchzulassen.
    Dafür kann die vordefinierte Regelgruppe in der Windows-Firewall aktivieren werden.
    Sehr einfach geht das mit Hilfe von netsh:
    netsh advfirewall firewall set rule group="Windows-Verwaltungsinstrumentation (WMI)" new enable=yes
#ce

; Hier ein paar Bsp.:
Global $aAdapter
$aAdapter = _CI_GetNetworkAdapter('.', '2', 'TomTom') ; IP = ?

;~ $aAdapter = _CI_GetNetworkAdapter()
;~ $aAdapter = _CI_GetNetworkAdapter('.', '2', 'Realtek PCIe GbE Family Controller') ; IP = 192.168.178.26
;~ $aAdapter = _CI_GetNetworkAdapter('.', '> 0') ; IP = 192.168.178.26
;~ $aAdapter = _CI_GetNetworkAdapter('ILLUMINATI') ; IP = 192.168.178.26
;~ $aAdapter = _CI_GetNetworkAdapter('Server') ; IP = 192.168.178.31
;~ $aAdapter = _CI_GetNetworkAdapter('TRECKSTOR') ; IP = 192.168.178.34
If @error Or Not UBound($aAdapter) Then Exit ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $aAdapter --> " & $aAdapter & @CRLF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @CRLF)
_DebugArrayDisplay($aAdapter, '$aAdapter - #Error = ' & @error)
;~     ClipPut(_ArrayToString($aAdapter))
;~     ShellExecute('mailto:Windi@googlemail.com?subject=_CI_GetNetworkAdapter()&body=' & _ArrayToString($aAdapter))

#cs NetConnectionStatus - UInt16

    Qualifiers: CIMTYPE, Description, read, ValueMap, Values

    Die Zeichenfolge "NetConnectionStatus" zeigt den Verbindungsstatus des Netzwerkadapters und dem Netzwerk an. Der Wert der Eigenschaft hat die folgenden Bedeutungen:
     0 - Verbindung getrennt
     1 - Verbindung wird hergestellt
     2 - Verbunden
     3 - Verbindung wird getrennt
     4 - Hardware nicht vorhanden
     5 - Hardware deaktiviert
     6 - Hardwarefehler
     7 - Medien ausgeworfen
     8 - Authentifizieren
     9 - Authentifizierung erfolgreich
    10 - Authentifizierung fehlgeschlagen
    11 - Ungültige Adresse
    12 - Anmeldeinformationen erforderlich
#ce
Func _CI_GetNetworkAdapter($strComputer = '.', $vNetConnectionStatus = '2', $strName = '') ; oder z.B. '> 0'
    Local $aRet = [['HostName', 'Hersteller', 'Name', 'Adapter-Typ', 'Kennung', 'MAC-Adresse', 'IP-Adresse', 'Subnetzmaske', 'Adresstyp', 'DHCP-Server', 'Lease erhalten', 'Lease läuft ab', 'Speed', 'MaxSpeed', 'Standardgateway', 'NetConnectionStatus']]
    Local Const $aNetConnectionStatus = ['Verbindung getrennt', 'Verbindung wird hergestellt', 'Verbunden', 'Verbindung wird getrennt', 'Hardware nicht vorhanden', 'Hardware deaktiviert', 'Hardwarefehler', 'Medien ausgeworfen', 'Authentifizieren', 'Authentifizierung erfolgreich', 'Authentifizierung fehlgeschlagen', 'Ungültige Adresse', 'Anmeldeinformationen erforderlich']
;~     Return
    Local $sComputer = ($strComputer = '.' ? 'localhost' : $strComputer)
    Ping($sComputer, 500)
    If @error Then Return SetError(@error, 1, 'Rechner ' & $sComputer & ' ist nicht erreichbar!')
    Local $x = 0, $objWMIService, $colItems, $colItems2, $iIPAddressCount = 0, $iGatewayCount = 0
    $objWMIService = ObjGet('winmgmts:\\' & $strComputer & '\root\cimv2')
    If Not IsObj($objWMIService) Then Return SetError(@error, 2, 'Fehler bei $objWMIService()!')
    $vNetConnectionStatus = StringRegExpReplace($vNetConnectionStatus, '^(\d{1,2})', ' = \1')
    $colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapter WHERE Netconnectionstatus ' & $vNetConnectionStatus, 'WQL', 0x30)
    If Not IsObj($colItems) Then Return SetError(@error, 3, 'Fehler bei $objWMIService.ExecQuery()')
    For $objItem In $colItems
        If $strName And $strName <> $objItem.Name Then ContinueLoop
        $x += 1
        ReDim $aRet[$x + 1][UBound($aRet, 2)]
        $aRet[$x][1] = $objItem.Manufacturer
        $aRet[$x][2] = $objItem.Name
        $aRet[$x][3] = $objItem.AdapterType
        $aRet[$x][4] = $objItem.NetConnectionID
        $aRet[$x][5] = $objItem.MACAddress
        $aRet[$x][12] = $objItem.Speed ; 1000000000 Bits/s / 1e+6 = 1000 Mbit/s
        $aRet[$x][13] = $objItem.MaxSpeed
        $aRet[$x][15] = $aNetConnectionStatus[$objItem.NetConnectionStatus]
        $colItems2 = $objWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapterConfiguration', 'WQL', 0x30)
        If IsObj($colItems2) Then
            For $objItem2 In $colItems2
                If $objItem.Caption = $objItem2.Caption Then
                    If $objItem2.IPEnabled = -1 Then
                        $aRet[$x][0] = $objItem2.DNSHostName(0)
                        $aRet[$x][6] = $objItem2.IPAddress(0)
                        If $aRet[$x][6] Then $iIPAddressCount += 1
                        $aRet[$x][7] = $objItem2.IPSubnet(0)
                        If $objItem2.DHCPEnabled = -1 Then
                            $aRet[$x][8] = 'von DHCP zugewiesen'
                            $aRet[$x][9] = $objItem2.DHCPServer
                            $aRet[$x][10] = _WMIDateStringToDate($objItem2.DHCPLeaseObtained)
                            $aRet[$x][11] = _WMIDateStringToDate($objItem2.DHCPLeaseExpires)
                        Else
                            $aRet[$x][7] = 'Manuell konfiguriert'
                        EndIf
                        $aRet[$x][14] = $objItem2.DefaultIPGateway(0)
                        If $aRet[$x][14] Then $iGatewayCount += 1
                    EndIf
                EndIf
            Next
        EndIf
    Next
    If UBound($aRet) < 2 Or Not $iIPAddressCount Or Not $iGatewayCount Then
        If $strName Then
            Return SetError(-1, 4, 'Kein Adapter mit dem Namen "' & $strName & '" und NetConnectionStatus "' & $vNetConnectionStatus & '" gefunden! $iIPAddressCount = ' & $iIPAddressCount & ' $iGatewayCount = ' & $iGatewayCount)
        Else
            Return SetError(-1, 4, 'Kein Adapter mit NetConnectionStatus "' & $vNetConnectionStatus & '" gefunden! $iIPAddressCount = ' & $iIPAddressCount & ' $iGatewayCount = ' & $iGatewayCount)
        EndIf
    EndIf
    Return $aRet
EndFunc   ;==>_CI_GetNetworkAdapter

Func _WMIDateStringToDate($dtmDate)
    ; 2019/01/29 15:07:44
    ; $dtmDate = 20190129085216.000000+060
    ; $dtmDate = 20190208085216.000000+060
    Return StringRegExpReplace($dtmDate, '(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2}).+', '\1/\3/\2 \4:\5:\6')
EndFunc   ;==>_WMIDateStringToDate

Alles anzeigen

Windi

Hallo Water,

bei TomTom ist das anders die wird als Netzwerkkarte erkannt und ist nicht in den Laufwerken.Ich denke mal die haben das vor ein paar Jahren gemacht

das man die Karten nicht mehr kopieren kann.

Hallo Bitnugger,

Danke für dein Skript, zeigt leider nicht an ob aktiviert oder inaktiv.

Das steht unten:

>"C:\Program Files (x86)\AutoIt3\SciTE\..\autoit3.exe" /ErrorStdOut "C:\Users\xx2\Desktop\test.au3"

@@ Debug line 22 var: $aAdapter --> Kein Adapter mit dem Namen "TomTom" und NetConnectionStatus " = 2" gefunden! $iIPAddressCount = 1 $iGatewayCount = 0

!@ #Error: -1 #Extended: 4

>Exit code: 185 Time: 0.36

Hab euch einmal Bilder gemacht,

**water**

Lass mal folgendes Skript laufen wenn TomTom angebunden ist. Es erweitert Butnugger's Skript und schreibt alle Infos über alle Adapter in eine Datei auf C:\temp und zeigt sie danach an (erstellt durch Scriptomatic).

Danach kannst Du Deinen Adapter suchen und den Status prüfen:

Code

; Generated by AutoIt Scriptomatic

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = "."

$Output=""
$Output = $Output & "Computer: " & $strComputer  & @CRLF
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapter", "WQL", _
                                          $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

If IsObj($colItems) then
   For $objItem In $colItems
      $Output = $Output & "AdapterType: " & $objItem.AdapterType & @CRLF
      $Output = $Output & "AdapterTypeId: " & $objItem.AdapterTypeId & @CRLF
      $Output = $Output & "AutoSense: " & $objItem.AutoSense & @CRLF
      $Output = $Output & "Availability: " & $objItem.Availability & @CRLF
      $Output = $Output & "Caption: " & $objItem.Caption & @CRLF
      $Output = $Output & "ConfigManagerErrorCode: " & $objItem.ConfigManagerErrorCode & @CRLF
      $Output = $Output & "ConfigManagerUserConfig: " & $objItem.ConfigManagerUserConfig & @CRLF
      $Output = $Output & "CreationClassName: " & $objItem.CreationClassName & @CRLF
      $Output = $Output & "Description: " & $objItem.Description & @CRLF
      $Output = $Output & "DeviceID: " & $objItem.DeviceID & @CRLF
      $Output = $Output & "ErrorCleared: " & $objItem.ErrorCleared & @CRLF
      $Output = $Output & "ErrorDescription: " & $objItem.ErrorDescription & @CRLF
      $Output = $Output & "GUID: " & $objItem.GUID & @CRLF
      $Output = $Output & "Index: " & $objItem.Index & @CRLF
      $Output = $Output & "InstallDate: " & WMIDateStringToDate($objItem.InstallDate) & @CRLF
      $Output = $Output & "Installed: " & $objItem.Installed & @CRLF
      $Output = $Output & "InterfaceIndex: " & $objItem.InterfaceIndex & @CRLF
      $Output = $Output & "LastErrorCode: " & $objItem.LastErrorCode & @CRLF
      $Output = $Output & "MACAddress: " & $objItem.MACAddress & @CRLF
      $Output = $Output & "Manufacturer: " & $objItem.Manufacturer & @CRLF
      $Output = $Output & "MaxNumberControlled: " & $objItem.MaxNumberControlled & @CRLF
      $Output = $Output & "MaxSpeed: " & $objItem.MaxSpeed & @CRLF
      $Output = $Output & "Name: " & $objItem.Name & @CRLF
      $Output = $Output & "NetConnectionID: " & $objItem.NetConnectionID & @CRLF
      $Output = $Output & "NetConnectionStatus: " & $objItem.NetConnectionStatus & @CRLF
      $Output = $Output & "NetEnabled: " & $objItem.NetEnabled & @CRLF
      $strNetworkAddresses = $objItem.NetworkAddresses(0)
      $Output = $Output & "NetworkAddresses: " & $strNetworkAddresses & @CRLF
      $Output = $Output & "PermanentAddress: " & $objItem.PermanentAddress & @CRLF
      $Output = $Output & "PhysicalAdapter: " & $objItem.PhysicalAdapter & @CRLF
      $Output = $Output & "PNPDeviceID: " & $objItem.PNPDeviceID & @CRLF
      $strPowerManagementCapabilities = $objItem.PowerManagementCapabilities(0)
      $Output = $Output & "PowerManagementCapabilities: " & $strPowerManagementCapabilities & @CRLF
      $Output = $Output & "PowerManagementSupported: " & $objItem.PowerManagementSupported & @CRLF
      $Output = $Output & "ProductName: " & $objItem.ProductName & @CRLF
      $Output = $Output & "ServiceName: " & $objItem.ServiceName & @CRLF
      $Output = $Output & "Speed: " & $objItem.Speed & @CRLF
      $Output = $Output & "Status: " & $objItem.Status & @CRLF
      $Output = $Output & "StatusInfo: " & $objItem.StatusInfo & @CRLF
      $Output = $Output & "SystemCreationClassName: " & $objItem.SystemCreationClassName & @CRLF
      $Output = $Output & "SystemName: " & $objItem.SystemName & @CRLF
      $Output = $Output & "TimeOfLastReset: " & WMIDateStringToDate($objItem.TimeOfLastReset) & @CRLF
   Next
   ConsoleWrite($Output)
   FileWrite(@TempDir & "\Win32_NetworkAdapter.TXT", $Output )
   Run(@Comspec & " /c start " & @TempDir & "\Win32_NetworkAdapter.TXT" )
Else
   Msgbox(0,"WMI Output","No WMI Objects Found for class: " & "Win32_NetworkAdapter" )
Endif


Func WMIDateStringToDate($dtmDate)

    Return (StringMid($dtmDate, 5, 2) & "/" & _
    StringMid($dtmDate, 7, 2) & "/" & StringLeft($dtmDate, 4) _
    & " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate,13, 2))
EndFunc

Alles anzeigen

Windi

Auf C:\Temp ist nichts.

Habe nur diese Datei in den Editor bekommen.

**water**

Schaut gut aus. Ab Zeile 522 findet sich der TomTom Adapter. Der NetConnectionStatus steht auf 2 = Connected (https://docs.microsoft.com/en-us/windows/…-networkadapter)

Jetzt stutzen wir das Skript zusammen, um nur die notwendigen Informationen zu kriegen und diese in Deinm Skript zur Verfügung zu stellen.

**Bitnugger**

Zitat von Windi

Auf C:\Temp ist nichts.
Habe nur diese Datei in den Editor bekommen.

Ja, da hat water sich wohl vertan, denn @TempDir liegt in deinem Profilverzeichnis... die Datei findest du ergo hier: C:\Users\Windi\AppData\Local\Temp\Win32_NetworkAdapter.TXT

Hm, wenn ich mir den Inhalt dieser Datei anschaue, dann sollte der aber so gefunden werden, denn er wird ja darin gelistet:

Code

Global $aAdapter
$aAdapter = _CI_GetNetworkAdapter('.', '2', 'TomTom')

Hier der relevante Teil:

TomTom

AdapterType:

AdapterTypeId:

AutoSense:

Availability: 3

Caption: [00000013] TomTom

ConfigManagerErrorCode:

ConfigManagerUserConfig:

CreationClassName: Win32_NetworkAdapter

Description: TomTom

DeviceID: 13

ErrorCleared:

ErrorDescription:

GUID:

Index: 13

InstallDate: // ::

Installed: True

InterfaceIndex: 15

LastErrorCode:

MACAddress:

Manufacturer:

MaxNumberControlled: 0

MaxSpeed:

Name: TomTom

NetConnectionID:

NetConnectionStatus:

NetEnabled:

NetworkAddresses:

PermanentAddress:

PhysicalAdapter: False

PNPDeviceID:

PowerManagementCapabilities:

PowerManagementSupported: False

ProductName: TomTom

ServiceName:

Speed:

Status:

StatusInfo:

SystemCreationClassName: Win32_ComputerSystem

SystemName: DESKTOP-0CN454E

TimeOfLastReset: 05/14/2020 13:19:08

**water**

So müsste der Prüfungsteil für mein obiges Skript aussehen. Der Name ist fix mit "TomTom" vergeben, der Status wird als "Magic Number" angegeben.

Nicht schön, aber selten. Wenn er funktioniert, dann kann er noch verschönert und dokumentiert werden.

AutoIt

If _TomTomStatus() = 2 Then "... Prüfung erfolgreich ..:"

Func _TomTomStatus()
    Local $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    Local $colItems = "", $strComputer = ".", $Output = ""
    $Output = $Output & "Computer: " & $strComputer & @CRLF
    Local $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\")
    $colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapter Where Name="TomTom"', "WQL", _
        $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If IsObj($colItems) Then
        For $objItem In $colItems
            Return $objItem.NetConnectionStatus
        Next
    Else
        Return SetError(1, 0, -1)
    EndIf
EndFunc

Alles anzeigen

**Bitnugger**

Zitat von water

Return & $objItem.NetConnectionStatus

Jeep, voll erwischt!

Ähhh, ja, da kannst du es auch so machen:

AutoIt

If _TomTomConnected() Then ConsoleWrite("... TomTom ist verbunden ..." & @CRLF)

Func _TomTomConnected()
    Local Static $wbemFlagReturnImmediately = 0x10, $wbemFlagForwardOnly = 0x20
    Local $colItems = "", $strComputer = "."
    Local $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\")
    If Not IsObj($objWMIService) Then Return SetError(1, 0, 0)
    $colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_NetworkAdapter Where Name="TomTom" AND NetConnectionStatus=2', "WQL", _
            $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    For $objItem In $colItems
        Return $objItem.NetConnectionStatus
    Next
    Return SetError(2, 0, 0)
EndFunc   ;==>_TomTomConnected

Alles anzeigen

**water**

Ups, ist gefixt

Den NetConnectioNStatus habe ich nicht im Select -Statement eingebaut, damit er ans Hauptskript zurück gegeben wird und dann dort für die Fehleranalyse verwendet werden kann.

BugFix 14. Mai 2020 um 09:29