Tab in einem Tab

Saft · 21. August 2020

Hallo Community,

ich möchte einen Tab in einem Tab erstellen, aber scheinbar ist das nicht möglich.

Bei meiner Suche nach einer Lösung bin ich nur auf alte Themen gestoßen.

Vielleicht gibt es dafür mittlerweile eine Lösung?

Hier ein geshopptes Beispiel, wie es vom Prinzip her aussehen soll:

Gruß,

Saft

Code

#include <GUIConstantsEx.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")

    GuiCtrlCreateTab(5,5,250,300)
    GUICtrlCreateTabItem("Tab 1")
        GuiCtrlCreateTab(15,15,200,200)
        GUICtrlCreateTabItem("Tab 1 - Tab 1")
        GUICtrlCreateTabItem("Tab 1 - Tab 2")
    GUICtrlCreateTabItem("Tab 2")

    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                ExitLoop

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

**autoBert** · 21. August 2020

Leider sind durch div, Fotensoftwareupdates viele schöne Beispiele verlorengegangen, bzw. die Links sind tot. Grundsätzlich kann es nur ein TabControl in einer Gui geben. Man kann aber auf unsichtbaren HilfsGui's (als eigenständige Gui nicht zu erkennen) je ein TabControl platzieren. Die OwnTab-UDF von funkey ermöglicht z.B. TabInTab. Ob Sie unter der aktuellen Autoit-Version noch lauffähig ist weis ich nicht.

Hier ein kleines Beispiel mit Childs:

C

; Example of TAB in TAB ctrl
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIConstants.au3>


Opt('GUIOnEventMode', 1)


Global $main_GUI, $child1, $child2, $main_tab, $ok_button, $cancel_button
_main()


Func _main()
    ; This window has 2 ok/cancel-buttons
    $main_GUI = GUICreate("TAB in TAB", 260, 250, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
    GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
    $ok_button = GUICtrlCreateButton("OK", 40, 200, 70, 20)
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKBOTTOM + $GUI_DOCKSIZE)
    GUICtrlSetOnEvent(-1, '_End')
    $cancel_button = GUICtrlCreateButton("Cancel", 150, 200, 70, 20)
    GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKBOTTOM + $GUI_DOCKSIZE)
    GUICtrlSetOnEvent(-1, '_End')


    ; Create the first child window that is implemented into the main GUI
    $child1 = GUICreate("", 230, 170, 15, 35, BitOR($WS_CHILD, $WS_TABSTOP), -1, $main_GUI)
    $child_tab = GUICtrlCreateTab(2, 5, 225, 165)
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
    $child11tab = GUICtrlCreateTabItem("1")
    $child12tab = GUICtrlCreateTabItem("2")
    GUICtrlCreateLabel('Nur auf Tab2',25,25)
    GUICtrlCreateTabItem("")



    ; Create the second child window that is implemented into the main GUI
    $child2 = GUICreate("", 230, 170, 15, 35, BitOR($WS_CHILD, $WS_TABSTOP), -1, $main_GUI)
    $listview2 = GUICtrlCreateListView("Col1|Col2", 2, 5, 225, 165, -1, $WS_EX_CLIENTEDGE)
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
    GUICtrlCreateListViewItem("ItemLong1|ItemLong12", $listview2)
    GUICtrlCreateListViewItem("ItemLong2|Item22", $listview2)
    GUISetState()


    ; Switch back the main GUI and create the tabs
    GUISwitch($main_GUI)
    $main_tab = GUICtrlCreateTab(10, 10, 240, 180)
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
    GUICtrlSetOnEvent(-1, '_MainTab')
    $child1tab = GUICtrlCreateTabItem("Child1")
    $child2tab = GUICtrlCreateTabItem("Child2")
    $child3tab = GUICtrlCreateTabItem("Child3")
    $listview3 = GUICtrlCreateListView("Noch|eine|LV", 17, 39, 223, 138, -1, $WS_EX_CLIENTEDGE)
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
    GUICtrlCreateListViewItem("Spalte1.1|Spalte1.2|Spalte1.3", $listview3)
    GUICtrlCreateListViewItem("Spalte2.1|Spalte2.2|Spalte2.3", $listview3)


    GUICtrlCreateTabItem("")

    GUIRegisterMsg($WM_SIZE, 'WM_SIZE')


    GUISetState()
    While 1
        Sleep(125)
    WEnd
EndFunc   ;==>_main


Func _End()
    GUIDelete($child1)
    GUIDelete($child2)
    GUIDelete($main_GUI)
    Exit
EndFunc   ;==>_End


Func _MainTab()
    Switch GUICtrlRead($main_tab)
        Case 0
            GUISetState(@SW_HIDE, $child1)
            GUISetState(@SW_SHOW, $child2)


        Case 1
            GUISetState(@SW_HIDE, $child2)
            GUISetState(@SW_SHOW, $child1)
        Case Else
            GUISetState(@SW_HIDE, $child1)
            GUISetState(@SW_HIDE, $child2)
    EndSwitch
EndFunc   ;==>_MainTab


Func WM_SIZE($hWnd, $iMsg, $iWParam, $iLParam)
    $aMGPos = WinGetClientSize($main_GUI)
    WinMove($child1, "", 15, 35, +$aMGPos[0] - 30, +$aMGPos[1] - 80)
    WinMove($child2, "", 15, 35, +$aMGPos[0] - 30, +$aMGPos[1] - 80)
EndFunc   ;==>WM_SIZE

Alles anzeigen

mfg >(auto)Bert

**Musashi** · 21. August 2020

Zitat von autoBert

Leider sind durch div. Forensoftwareupdates viele schöne Beispiele verlorengegangen [...]
Die OwnTab-UDF von funkey ermöglicht z.B. TabInTab. Ob Sie unter der aktuellen Autoit-Version noch lauffähig ist weis ich nicht.

Ja, diese 'toten Links' sind sehr ärgerlich .

Häufig findet man sie aber noch mit Google, sofern man die passenden Suchworte verwendet (hier z.B. "Autoit OwnTab UDF funkey".

Der von Dir angegebene Link scheint auch bereits wieder ein Opfer geworden zu sein.

Du meinst vermutlich : eigenes-tab-register-owntab-udf

EDIT :

Auch interessant : Problem mit OwnTab.au3

EDIT 2:

Hier eine Beispielgrafik aus funkey 's Thread im EN-Forum :

Gruß Musashi

**autoBert** · 22. August 2020

Zitat von Musashi

Häufig findet man sie aber noch mit Google, sofern man die passenden Suchworte verwendet (hier z.B. "Autoit OwnTab UDF funkey".
Der von Dir angegebene Link scheint auch bereits wieder ein Opfer geworden zu sein.
Du meinst vermutlich : eigenes-tab-register-owntab-udf

Ja, wir meinen beide die gleiche UDF.

Zitat von autoBert

Ob Sie unter der aktuellen Autoit-Version noch lauffähig ist weis ich nicht.

Wie befürchtet, ein SCRIPT BREAKING CHANGE in der GDIPlus.au3. Deshalb hier die UDF von funkey (angepasst von mir): OwnTab.au3 und ein Beispiel (original): OwnTab_Example.au3

viel Spass damit (auto)Bert

funkey: Bitte prüfen ob nicht noch weitere Changes nötig sind. (Namen $__g_hGDIPDll wurde angepasst)

xSunLighTx3 · 22. August 2020

Das sieht ja vom Layout echt outdated aus, zumal AutoIt GUI's eh schon vom letzten Jahrtausend sind.

Aber bei mir funktioniert alles, autoBert

gmmg · 24. August 2020

Hier ein Beispiel aus dem engl. Forum.

https://www.autoitscript.com/forum/topic/195488-tab-in-tab/

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)

; Create main GUI
$hGUI = GUICreate("Main", 1000, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Events")

; Create tab in main GUI
$cMain_Tab = GUICtrlCreateTab(10, 10, 980, 400)
GUICtrlSetOnEvent($cMain_Tab, "_Events")
$cSound_Tab = GUICtrlCreateTabItem("Sound")
$cVideo_Tab = GUICtrlCreateTabItem("Video")
$cPicture_Tab = GUICtrlCreateTabItem("Picture")
GUICtrlCreateTabItem("")

; Hide main GUI
GUISetState(@SW_HIDE, $hGUI)

$aPos = WinGetPos($hGUI)
ConsoleWrite($aPos[0] & " - " & $aPos[1] & @CRLF)

; Create child GUIs which will appear on tabs
$hChild_Sound = GUICreate("", 960, 350, 20, 40, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUISetBkColor(0xFFCCCC, $hChild_Sound) ; Using colours just for example
GUISetState(@SW_HIDE, $hChild_Sound)

$hChild_Video = GUICreate("", 960, 350, 20, 40, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUISetBkColor(0xCCFFCC, $hChild_Video)
GUISetState(@SW_HIDE, $hChild_Video)

$hChild_Picture = GUICreate("", 960, 350, 20, 40, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUISetBkColor(0xCCCCFF, $hChild_Picture)
GUISetState(@SW_HIDE, $hChild_Picture)

; Now add tabs to the child GUIs
GUISwitch($hChild_Sound)

$cSound_Sub_Tab = GUICtrlCreateTab(10, 10, 940, 320)
$cSound_Sub_Tab_1 = GUICtrlCreateTabItem("Sound_Sub_1")
$cSound_Sub_Tab_2 = GUICtrlCreateTabItem("Sound_Sub_2")
GUICtrlCreateTabItem("")

GUISwitch($hChild_Video)
$cVideo_Sub_Tab = GUICtrlCreateTab(10, 10, 940, 320)
$cVideo_Sub_Tab_1 = GUICtrlCreateTabItem("Video_Sub_1")
$cVideo_Sub_Tab_2 = GUICtrlCreateTabItem("Video_Sub_2")
$cVideo_Sub_Tab_3 = GUICtrlCreateTabItem("Video_Sub_3")
GUICtrlCreateTabItem("")

GUISwitch($hGUI)

; Show Main and initial child GUIs
GUISetState(@SW_SHOW, $hGUI)
GUISetState(@SW_SHOW, $hChild_Sound)

While 1
    Sleep(10)
WEnd

Func _Events()

    ConsoleWrite(@GUI_CtrlId & @CRLF)

    Switch @GUI_CtrlId
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cMain_Tab
            ; Hide/show child GUIs as required
            Switch GUICtrlRead($cMain_Tab)
                Case 0
                   GUISetState(@SW_SHOW, $hChild_Sound)
                   GUISetState(@SW_HIDE, $hChild_Video)
                   GUISetState(@SW_HIDE, $hChild_Picture)
                Case 1
                   GUISetState(@SW_HIDE, $hChild_Sound)
                   GUISetState(@SW_SHOW, $hChild_Video)
                   GUISetState(@SW_HIDE, $hChild_Picture)
                Case 2
                   GUISetState(@SW_HIDE, $hChild_Sound)
                   GUISetState(@SW_HIDE, $hChild_Video)
                   GUISetState(@SW_SHOW, $hChild_Picture)
            EndSwitch
    EndSwitch

EndFunc

Alles anzeigen

Gruß gmmg

Saft · 26. August 2020

Vielen Dank. Ziemlich umständlich aber klappt.

Zitat von xSunLighTx3

Das sieht ja vom Layout echt outdated aus, zumal AutoIt GUI's eh schon vom letzten Jahrtausend sind.
Aber bei mir funktioniert alles, autoBert

Ist nicht schön, aber einfach und tut was es soll

Tab in einem Tab

Teilen

Ähnliche Themen

Gegenstück zu GUICtrlSetImage

Gibt es eine "Tag"-Eigenschaft für Controls?

Hex to Dec - 0x00000021 zu 33

Suche einfach erweiterbaren Einstellungen-Dialog (Program Settings)

Auslesen von Werten aus einem Fenster