Geheimnis "scripting.dictionary" AutoIt 3.3.14.5

GML · 4. November 2020

Hallo an alle,

ich habe ein - möglicherweise - unlösbares Problem mit dem scripting.dictionary., ja hab ich, werde aber nicht wirklich schlau daraus.

Aufgabenstellung:

Ich lese einen ganzen Verzeichnisbaum ein, durchwandere diesen (anhand vom scripting.dictionary) top down, drucke verschiedene Dateitypen aus (xls,doc,pdf,jpg - alle andere werden übergangen). Jedesmal wenn das Verzeichnis wechselt wird ein Zwischenblatt (aus einem anderem Druckerschacht mit andersfarbigem Papier) mit dem Verzeichnisnamen (letzter Verzeichnisnamenteil des Pfades) in groß drauf, ausgedruckt.

Ein Statusfenster sowie eine Logdatei werden mitgeführt.

Ich verwende das um sehr große Dokumentationen (> 30.000 Seiten) über Nacht auszudrucken (deshalb auch die Log-Funktion ..).

Funktioniert auch soweit ... ABER: die Reihenfolge stimmt nicht ganz.

Ich bekomme:

C:\1AA\2bb,

C:\1AA\2bb\3ab,

C:\1AA\2bb\3ab\verweis auf andere stelle in der doku.pdf, 4 kB

C:\1AA\2bb\3ab\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\3bb, 5 kB

C:\1AA\2bb\3bb\4bb, 5 kB

C:\1AA\2bb\3bb\4bb\5ab, 5 kB

C:\1AA\2bb\3bb\4bb\5ab\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\3bb\4bb\5bb, 5 kB

C:\1AA\2bb\3bb\4bb\5bb\verweis auf andere stelle in der doku.pdf, 4 kB

C:\1AA\2bb\3bb\verweis auf andere stelle in der doku.pdf, 4 kB

c:\1AA\2bb\3bb\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\verweis auf externe doku.pdf, 5 kB

möchte aber:

C:\1AA\2bb,

C:\1AA\2bb\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\3ab,

C:\1AA\2bb\3ab\verweis auf andere stelle in der doku.pdf, 4 kB

C:\1AA\2bb\3ab\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\3bb, 5 kB

C:\1AA\2bb\3bb\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\3bb\verweis auf andere stelle in der doku.pdf, 4 kB

C:\1AA\2bb\3bb\4bb, 5 kB

C:\1AA\2bb\3bb\4bb\5ab, 5 kB

C:\1AA\2bb\3bb\4bb\5ab\verweis auf externe doku.pdf, 5 kB

C:\1AA\2bb\3bb\4bb\5bb, 5 kB

C:\1AA\2bb\3bb\4bb\5bb\verweis auf andere stelle in der doku.pdf, 4 kB

hier habe ich den entscheidenden Schnipsel der das Einlesen - scripting.dictionary - erledigt:

C

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

;
; sort keys in dictionary
; https://stackoverflow.com/questions/35505931/sort-keys-in-dictionary
;

#include-once
#include <FileConstants.au3>
#include <Array.au3>

Global $sFileSelectFolder = FileSelectFolder("Verzeichnis auswählen", "c:\")

; damit bekommen alle Pfade (ohne Dateien) hinten einen \ dazu - damit weiß ich das das ein Directory ==> Verzeichniszwischenblatt, ist
$sFileSelectFolder = $sFileSelectFolder & "\"

Local $oFiles = _FileListToDict($sFileSelectFolder, True, -3, False, 100, 0)

ConsoleWrite(@CRLF & @CRLF)
ConsoleWrite(@extended & " Dateien" & @CRLF)

If Not @error Then
    For $vFiles In $oFiles.Keys
        ConsoleWrite($vFiles & ", " & $oFiles($vFiles) & @CRLF)
    Next
EndIf

MsgBox(0x0, "", 'Items Count : ' & $oFiles.count)

;===============================================================================
;
; Function Name:   _FileListToDict($vFolder[, $bRec[, $iFileInformation[, $bRelative[, $iMaxDepth[, $iFilesAndOrFolders]]]]])
; Description:     Speichert Dateien, optional mit einer gewählten Eigenschaft, in einerm Dictionary-Objekt.
; Parameter(s):    $vFolder = Ein Startverzeichnis oder ein eindimensionales Array von Startverzeichnissen für die Dateisuche.
;                  $bRec = Rekursive Dateisuche bei $bRec = True (Standardwert)
;                  $iFileInformation = In $oFiles.Items kann eine gewählte Datei-Information gespeichert werden.
;                   |-1 = Keine Information. $oFiles.Items = True. (Standardwert).
;                   | 0 = Bearbeitungszeitpunkt
;                   | 1 = Erstellzeitpunkt
;                   | 2 = Letzte Zugriffszeit
;                   |-2 = Dateigröße in bytes
;                   |-3 = Dateigröße in größter erreichter Einheit.
;                  $bRelative = $oFiles.Keys haben relativem Dateipfad bei $bRelative = True (Standardwert = False).
;                  $iMaxDepth = Anzahl der ausgelesenen Unterverzeichnisse unterhalb der/des Startverzeichniss(es) (Standardwert = 100).
;                  $iFilesAndOrFolders = $oFiles.Keys haben relativem Dateipfad bei $bRelative = True (Standardwert = False).
;                   |0 = Dateien und Ordner
;                   |1 = Nur Dateien
;                   |2 = Nur Ordner
; Return Value(s): Zurückgegeben wird ein Objekt mit den kompletten oder relativen Dateipfaden als Key (abhängig von $bRelative)
;                  und in Abhängigkeit von $iFileInformation mit True oder Datei-Information als Item.
;
;                  @error kann folgende Werte annehmen (Kombinationen möglich, BitOr):
;                         0 = kein Fehler aufgetreten, alle Dateien wurden korrekt kopiert
;                         1 = Der übergebene Pfad ist kein existierendes Verzeichnis
;                         2 = Startverzeichnis-Array ist nicht eindimensional
; Author(s):       autoiter
; Modified:
; Remarks:
;===============================================================================                               beides
Func _FileListToDict($vFolder, $bRec = True, $iFileInformation = -1, $bRelative = False, $iMaxDepth = 100, $iFilesOrFolders = 0)

    If $iFileInformation <> -1 Then
        Switch $iFileInformation
            Case 0
                $iFileInformation = $FT_MODIFIED
            Case 1
                $iFileInformation = $FT_CREATED
            Case 2
                $iFileInformation = $FT_ACCESSED
            Case -2, -3 ; FileGetSize
            Case Else
                $iFileInformation = -1
        EndSwitch
    EndIf

    If $bRec Then
        If $iMaxDepth < 1 Or Int($iMaxDepth) = 0 Then $iMaxDepth = 1
    EndIf

    If IsArray($vFolder) Then
        If UBound($vFolder, 2) > 1 Then Return SetError(2)
        Local $iMaxIndex = UBound($vFolder)
        Local $aFolder[$iMaxIndex], $iCount = 0
        For $i = 0 To $iMaxIndex - 1
            If Not StringInStr(FileGetAttrib($vFolder[$i]), "D") Then ContinueLoop
            $aFolder[$iCount] = $vFolder[$i]
            $iCount += 1
        Next
        If $iCount = 0 Then Return SetError(1)
        $iMaxIndex = $iCount
        ReDim $aFolder[$iMaxIndex]
    Else
        Local $iMaxIndex = 1
        Local $aFolder[$iMaxIndex]
        If Not StringInStr(FileGetAttrib($vFolder), "D") Then Return SetError(1)
        $aFolder[0] = $vFolder
    EndIf

    Local $oFiles = ObjCreate("Scripting.Dictionary")

    Local $aSearchFile[256], $sFile, $iDepth, $iInfo, $sFolder, $sStartFolder

    For $i = 0 To $iMaxIndex - 1
        $iDepth = 1

        $sFolder = StringRegExpReplace($aFolder[$i], "\\$", "")

        $sStartFolder = $sFolder ; Startfolder wird zur Bildung des vollen Dateipfades gespeichert.

        $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*.*")
        While $iDepth >= 0 ; In dieser Schleife werden alle Dateien/Ordner abgehandelt
            $sFile = FileFindNextFile($aSearchFile[$iDepth])
            If @extended And $bRec And $iDepth < $iMaxDepth Then ; Wenn es sich um ein Ordner handelt wird in diesem weiter gesucht - solange max. Rekursionstiefe nicht erreicht.
                $iDepth += 1
                $sFolder &= "\" & $sFile
                If $iFilesOrFolders <> 1 Then $oFiles($sFolder) = $iInfo
                $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*.*")
            ElseIf @error Then ; Wenn keine Dateien mehr im Ordner vorhanden sind wird das "Handle" Freigegeben
                FileClose($aSearchFile[$iDepth])
                $iDepth -= 1
                $sFolder = StringRegExpReplace($sFolder, "\\[^\\]*$", "")
            Else
                If $iFilesOrFolders <> 0 Then
                    If $iFilesOrFolders = 1 And StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then ContinueLoop
                    If $iFilesOrFolders = 2 And Not StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then ContinueLoop
                EndIf

                If $iFileInformation <> -1 Then
                    $iInfo = ""
                    Switch $iFileInformation
                        Case 0, 1, 2
                            $iInfo = FileGetTime($sFolder & "\" & $sFile, $iFileInformation, $FT_STRING)
                        Case -2
                            If Not StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then $iInfo = FileGetSize($sFolder & "\" & $sFile)
                        Case -3
                            If Not StringInStr(FileGetAttrib($sFolder & "\" & $sFile), "D") Then $iInfo = __FileListToDict_ByteSuffix(FileGetSize($sFolder & "\" & $sFile))
                    EndSwitch
                    If @error Then ContinueLoop
                    If Not $bRelative Then
                        $oFiles($sFolder & "\" & $sFile) = $iInfo
                    Else
                        $oFiles(StringReplace($sFolder, $sStartFolder, "") & "\" & $sFile) = $iInfo
                    EndIf
                Else
                    If Not $bRelative Then
                        $oFiles($sFolder & "\" & $sFile) = True
                    Else
                        $oFiles(StringReplace($sFolder, $sStartFolder, "") & "\" & $sFile) = True
                    EndIf
                EndIf
            EndIf
        WEnd
    Next
    Return SetError(0, $oFiles.Count, $oFiles)
EndFunc   ;==>_FileListToDict


Func __FileListToDict_ByteSuffix($iBytes) ; Aus der Hilfe zu FileGetSize.
    Local $iIndex = 0, $aArray = [' bytes', ' kB', ' MB', ' GB', ' TB', ' PB', ' EB', ' ZB', ' YB']
    While $iBytes > 1023
        $iIndex += 1
        $iBytes /= 1024
    WEnd
    Return Round($iBytes) & $aArray[$iIndex]
EndFunc   ;==>__FileListToDict_ByteSuffix

Alles anzeigen

Ist das mit dem Objekt scripting.dictionary überhaupt möglich (ohne Umwege über dictionary -> array und wieder zurück zu nehmen)?

Mit _filetoarrayrec würde es funktionieren (getestet ) aber da verliere ich ein paar Möglichkeiten und müßte vor allem das ganze Programm ändern. Natürlich ist mir die Sortierung erst aufgefallen als alles fertig war.

Ich bin schon für Hinweise - geht/geht nicht - dankbar.

Grüße

GML

**water** · 4. November 2020

Die Sortierung ist korrekt. Das Problem liegt darin, dass der Sort-Algo keine Ahnung hat, dass die zu sortierenden Strings eigentlich eine Struktur darstellen.

Das selbe Problem hatte ich mit der OU-Struktur in Active Directory, da nicht alle OU-Namen die selbe Länge hatten. Das Problem konnte ich nur lösen indem ich alle Teile der Struktur auf eine die selbe maximale Länge gebracht habe. Dieses Problem könntest Du auch bekommen, wenn die Verzeichnisnamen unterschiedliche Länge haben.

Dein Problem ist zusätzlich etwas anders gelagert, da Du zwei Datenarten hast: Verzeichnisname und Dateiname.

Kannst Du bitte den Teil Deines Skripts posten in dem Du den Verzeichnisbaum einliest und das Dictionary belegst? Dann können wir testen.

GML · 4. November 2020

Ich habe das eigenständig lauffähige Beispielprogramm in meine obige Nachricht (hoffentlich richtig) eingefügt (und angehängt). Ist direkt im SciTe ausführbar.

Güße

GML

**water** · 4. November 2020

Ups, habe wohl - wie schon öfters - nicht den gesamten Post gelesen.

Hast Du schon mal _FileListToArrayRec geprüft? Falls dort die Sortierung stimmt, könnte man die restlichen Funktionen vieleicht auf das Ergebnis von _FileListToArrayRec draufpropfen?

**AspirinJunkie** · 5. November 2020

Zitat von GML

Mit _filetoarrayrec würde es funktionieren (getestet ) aber da verliere ich ein paar Möglichkeiten und müßte vor allem das ganze Programm ändern.

Auf welche Möglichkeiten kommt es denn konkret an?

Vielleicht finden wir ja eine bessere Alternative, anstatt zu versuchen diese umständlich umzubiegen?

Kanashius · 5. November 2020

Nach dem Beispiel gehend würde ich sagen:

Bei deiner Sortierung kommen Zahlen vor Buchstaben und Ordner vor Dateien, deshalb sind die Dateien bei dir hinter den Ordnern.

Dementsprechend musst du umsortieren.

Dictionaries hab ich aber auch noch nicht genutzt, deshalb kann ich dir da nicht weiterhelfen...

GML · 5. November 2020

Genau das mit der Sortierung ist mein Problem. Die (Datei)Reihenfolge innerhalb eines Ordners ist mir (fast) egal (bzw. wäre Bonus) aber es müssen innerhalb eines Ordners zuerst die Dateien, dann die Sub-Ordner kommen. Durch die alphabetische Sortierung wie Kanashius erwähnt hat, kommen die Ordner (die mit Ziffernfolgen beginnen) zuerst, dann der Rest. D.h. irgendwie müßte ich nach der Eigenschaft Datei/Ordner innerhalb eines Ordner sortieren ... oh mein Gott ... dafür reicht mein Wissen leider nicht.

Das Ziel ist der Ausdruck (auf Drucker bzw. PDF-Drucker) in der richtigen Reihenfolge. So wie jetzt ist es lästig die Seiten durchzuklauben und umzusortieren (die Dokumentation wird digital sowie auf Papier übergeben, kommt nicht gut wenn Papier und digital andere Reihenfolgen haben).

Eigenartigerweise lese ich den Verzeichnisbaum nur ein, sonst nichts. Wenn ich _filelisttoarryrec verwende stimmt die Reihenfolge seltsamerweise (genau wie scripting.dictionary sortiere ich das Array nach dem Einlesen nicht).

_filelisttoarrayrec wäre die letzte Möglichkeit, da mit einiger Arbeit verbunden (und die Dateigröße habe ich dann auch nicht ohne weiteres zur Verfügung ..). Natürlich könnte man das Array erweitern, mehrere Durchläufe machen ... es geht hier immer so um 5.000-12.000 Dateien und Verzeichnisse.

Danke, das mein Problem jemand ansieht!

GML

PS: grad kontrolliert, bei _filelisttoarrayrec gebe ich den sort-Parameter an! Wird also - richtig - sortiert. Das gibts meinen Nachforschungen nach beim scripting.dictionary nicht.

Kanashius · 5. November 2020

Ich hab das ganze mal auf _FileListToArrayRec umgeschrieben. Du bekommst jetzt ein 2Dimensionales Array mit den sortierten Dateien zurück.

In dem Code steht auch, wie du den neuen Ordner vorher ausgeben kannst.

Der zweite Parameter ist zum filtern der Extensions.

Der dritte Parameter sorgt für das Hinzufügen der Extrainfos (TimeLastModified, TimeCreated, TimeLastAccessed, FileSize, FileSizeFormatted).

AutoIt

#include <File.au3>

Global $sFileSelectFolder = FileSelectFolder("Verzeichnis auswählen", "c:\")
If @error Then exit

Local $arFiles = _getFiles($sFileSelectFolder, ".xls|.doc|.pdf|.jpg", BitOR(4, 16))
ConsoleWrite(@CRLF & @CRLF)
ConsoleWrite(UBound($arFiles) & " Dateien" & @CRLF)

If Not @error Then
    local $sOldFolder=""
    For $i=0 to UBound($arFiles)-1 step 1 ; iterate all files
        If $arFiles[$i][0]<>$sOldFolder Then ; Print new folders
            $sOldFolder=$arFiles[$i][0]
            ConsoleWrite($arFiles[$i][0]&@CRLF)
        EndIf
        ConsoleWrite($arFiles[$i][0]&"\"&$arFiles[$i][1]&@CRLF) ; print file
    Next
EndIf

_ArrayDisplay($arFiles)

;sExtensions: All extensions seperated by | (example: .xls|.doc|.pdf|.jpg)
;iFileInformation: 0 Nothing, 1 TimeLastModified, 2 TimeCreated, 4 TimeAccesed, 8 Size, 16 ByteSuffixSize
Func _getFiles($sFolder, $sAllowedExtension=".*", $iFileInformation = 0)
    local $arStoreInfo[5], $iStoreAmount=0, $sPattern="(?m)("&(($sAllowedExtension=".*")?(".*"):(StringReplace($sAllowedExtension,".","\.")))&")$"
    for $i=0 to UBound($arStoreInfo)-1 step 1
        $arStoreInfo[$i]=(BitAND($iFileInformation,2^$i)>0)?(true):(false)
        If $arStoreInfo[$i] Then $iStoreAmount+=1
    next
    local $arFiles=_FileListToArrayRec($sFolder, "*", 1, 1, 1, 2)
    if @error Then SetError(1,@extended,-1)

    local $arFilteredFiles[UBound($arFiles)][2+$iStoreAmount], $iCount=0, $iExtInfoCount=0
    local $sDrive, $sDir, $sFileName, $sExtension
    for $i=0 to UBound($arFiles)-1 step 1
        If StringRegExp($arFiles[$i], $sPattern, 0) Then
            _PathSplit($arFiles[$i], $sDrive, $sDir, $sFileName, $sExtension)
            $arFilteredFiles[$iCount][0]=StringTrimRight($sDrive&$sDir,1)
            $arFilteredFiles[$iCount][1]=$sFileName&$sExtension
            If $arStoreInfo[0] Then __addInformation($arFilteredFiles, $iCount, $iExtInfoCount, FileGetTime($arFiles[$i], 0, 1))
            If $arStoreInfo[1] Then __addInformation($arFilteredFiles, $iCount, $iExtInfoCount, FileGetTime($arFiles[$i], 1, 1))
            If $arStoreInfo[2] Then __addInformation($arFilteredFiles, $iCount, $iExtInfoCount, FileGetTime($arFiles[$i], 2, 1))
            If $arStoreInfo[3] Then __addInformation($arFilteredFiles, $iCount, $iExtInfoCount, FileGetSize($arFiles[$i]))
            If $arStoreInfo[4] Then __addInformation($arFilteredFiles, $iCount, $iExtInfoCount, __FileSize_ByteSuffix(FileGetSize($arFiles[$i])))
            $iExtInfoCount=0
            $iCount+=1
        EndIf
    next
    ReDim $arFilteredFiles[$iCount][UBound($arFilteredFiles,2)]
    return $arFilteredFiles
EndFunc

Func __addInformation( ByRef $array, $iIndex, ByRef $iCounter, $information)
    $array[$iIndex][2+$iCounter]=$information
    $iCounter+=1
EndFunc

Func __FileSize_ByteSuffix($iBytes)
    Local $iIndex = 0, $aArray = [' bytes', ' kB', ' MB', ' GB', ' TB', ' PB', ' EB', ' ZB', ' YB']
    While $iBytes > 1023
        $iIndex += 1
        $iBytes /= 1024
    WEnd
    Return Round($iBytes) & $aArray[$iIndex]
EndFunc   ;==>__FileListToDict_ByteSuffix

Alles anzeigen

GML · 6. November 2020

Vielen Dank an alle Beteiligten.

Ich werden den Vorschlag einbauen und testweise über meine Verzeichnisse drüberlassen.

Schönes Wochenende

GML

bazii · 6. November 2020

Hallo

also ich nutze eine sehr einfache Command-Variante um einen sortierten Index zu erstellen.

Nach der Ausführung des Skriptes werden zwei unterschiedlich sortierte Dateien erstellt und anschließend zum Betrachten gleich geöffnet.

Tip:

Nachdem die Eingabeaufforderung geöffnet wurde, kann man sich über "help dir" die Parameter zur Sortierungsreihenfolge anzeigen lassen.

Wer möchte kann sich damit das Skript gerne auf eigene Bedürfnisse anpassen.

Code

#include <File.au3>

;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Zeitstempel 2020_11_06;;
;; bazii                 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;

; https://autoit.de/thread/87175-geheimnis-scripting-dictionary-autoit-3-3-14-5/

_makeindextxt()

; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +

Func _makeindextxt()

Local $hProcess
Local $hProcess_1

Local $sFileSelectFolder = FileSelectFolder("Verzeichnis auswählen", "c:\")

Local $sFile = $sFileSelectFolder & "\index.txt"
Local $sFile_1 = $sFileSelectFolder & "\index_1.txt"

    $hProcess = RunWait(@ComSpec & ' /c ' & 'dir /b /c /l /n /on /r /s /4 > index.txt' & '"', $sFileSelectFolder, @SW_HIDE)
    Sleep(300)
    $hProcess_1 = RunWait(@ComSpec & ' /c ' & 'dir /c /l /n /on /r /s /4 > index_1.txt' & '"', $sFileSelectFolder, @SW_HIDE)
    Sleep(300)

    _FileWriteToLine($sFile, 1, "++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++" & @CRLF & _
    "Diese Dateiauflistung wurde von " & @UserName & ", " & @ComputerName & " am " & @MDAY & "." & @MON & "." & @YEAR & " um " & @HOUR & ":" & @MIN & " Uhr produziert." & @CRLF & _
    "++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++" & @CRLF, True)

    _FileWriteToLine($sFile_1, 1, "++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++" & @CRLF & _
    "Diese Dateiauflistung wurde von " & @UserName & ", " & @ComputerName & " am " & @MDAY & "." & @MON & "." & @YEAR & " um " & @HOUR & ":" & @MIN & " Uhr produziert." & @CRLF & _
    "++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++" & @CRLF, True)


    _FileWriteToLine($sFile, 4, "", True)
    _FileWriteToLine($sFile_1, 6, "", True)

    FileClose($sFile)
    FileClose($sFile_1)

    ShellExecute($sFile, @SW_MAXIMIZE)
    Sleep(300)
    ShellExecute($sFile_1, @SW_MAXIMIZE)


Exit

EndFunc   ;==>_makeindextxt

; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +

Alles anzeigen

**Bitnugger** · 7. November 2020

Zitat von bazii

$hProcess = RunWait

RunWait liefert kein Handle, sondern den Exitcode des gestarteten Programms. Zudem wird $hProcess/$hProcess_1 an keiner Stelle ausgewertet und ist somit völlig überflüssig.

Zitat von bazii

FileClose($sFile)

FileClose wird nur dann benötigt, wenn zuvor ein File mit FileOpen geöffnet wurde, was hier aber nicht der Fall ist - ist somit auch völlig überflüssig.

Zitat von bazii

_FileWriteToLine($sFile, 4, "", True)
_FileWriteToLine($sFile_1, 6, "", True)

Hier kann ich nicht ganz folgen... wenn ich nicht irre, überschreibt du damit eine leere Zeile mit einer leeren Zeile!?

Hier mal eine deutlich kürzere Version:

AutoIt

#include <File.au3>

_MakeIndexTxt()

Func _MakeIndexTxt()
    Local $sSpacer = '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++' & @CRLF
    Local $sFileSelectFolder = FileSelectFolder("Verzeichnis auswählen", "c:\"), $sFile
    For $i = 0 To 1 Step 1
        $sFile = $sFileSelectFolder & '_index_' & $i + 1 & '.txt'
        If RunWait(@ComSpec & ' /c ' & 'dir ' & ($i = 0 ? '/b ' : '') & '/c /l /n /on /r /s /4 > ' & $sFile & '"', $sFileSelectFolder, @SW_HIDE) Then Exit $i + 1
        _FileWriteToLine($sFile, 1, _
            StringFormat('%sDiese Dateiauflistung wurde von %s@%s am %02d.%02d.%04d um %02d:%02d Uhr produziert.\r\n%s', _
            $sSpacer, @UserName, @ComputerName, @MDAY, @MON, @YEAR, @HOUR, @MIN, $sSpacer), True)
;~      _FileWriteToLine($sFile, $i = 0 ? 4 : 6, "", True) ; Überschreibt eine leere Zeile mit einer leeren Zeile!?
        ShellExecute($sFile, @SW_MAXIMIZE)
    Next
EndFunc   ;==>_MakeIndexTxt

Alles anzeigen

bazii · 7. November 2020

Zitat von Bitnugger

Hier mal eine deutlich kürzere Version:

Dank' Dir für die Infos und das verbesserte Skript. Ich lerne gerne dazu.

Geheimnis "scripting.dictionary" AutoIt 3.3.14.5

GML 4. November 2020

Teilen