Seriennummer auslesen

Moombas · 12. Januar 2021

Moin zusammen,

wir lesen die gespeicherte Seriennummer eines Remote PC's so aus:

AutoIt

Func _Serial_Number($IP)
Local $objItem
Local Const $objWMIService = ObjGet("winmgmts:\\" & $IP & "\root\CIMV2")
    If Not IsObj($objWMIService) Then Return(-1)
Local Const $colItems = $objWMIService.ExecQuery("Select * from Win32_BIOS")
    If Not IsObj($objWMIService) Then Return(-2)

    For $objItem in $colItems
        Return($objItem.SerialNumber)
    Next
EndFunc

Alles anzeigen

Nun funktioniert das bis W7 32Bit einwandfrei. Aber (eigentlich wie erwartet) bei W10 64Bit nicht mehr. Hat jemand damit bereits Erfahrung und kann mir weiter helfen?

~~Vorweg, auf meinem W7 64Bit OS läuft es auch, es muss sich also etwas zu W10 geändert haben.~~

Lokal auf einem W10 64Bit läuft es auch (Localhost anstatt IP).

Bekomme immer "Error: Variable must be of type "Object".

Er steigt gleich bei "ObjGet("winmgmts:\\" & $IP & "\root\CIMV2")" aus mit -2147023174 im @error

Wobei _WinAPI_GetLastError() & ' ' & _WinAPI_GetLastErrorMessage() mir zurück gibt: 0 DER VORGANG WURDE ERFOLGREICH BEENDET.

-.- jetzt bin ich komplett verwirrt.

**Bitnugger** · 12. Januar 2021

Zitat von Moombas

Wobei _WinAPI_GetLastError() & ' ' & _WinAPI_GetLastErrorMessage() mir zurück gibt: 0 DER VORGANG WURDE ERFOLGREICH BEENDET.

_WinAPI_GetLastError() und _WinAPI_GetLastErrorMessage() rufst du auf, wenn du zuvor eine _WinAPI_*-Funktion ausgeführt hast, z.B. _WinAPI_ActivateKeyboardLayout.

Um Fehler bei Objekten abzufangen und auszuwerten, brauchst du einen COM ERROR HANDLER.

Hier ein Bsp. mit _DebugCOMError:

AutoIt

#include <Debug.au3>

Opt('MustDeclareVars', 1)

_DebugSetup(Default, True, 1, Default, True) ; 1 = Write messages with timestamps to the Report Log Window
_DebugCOMError(1)

Local $objWMI, $IP

$objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & @ComputerName & '\root\cimv2:Win32_LogicalDisk="C:"')
ConsoleWrite('> ' & @ComputerName & " Free Diskspace on C: " & $objWMI.FreeSpace & " bytes / " & Round($objWMI.FreeSpace / 1024 ^ 2) & " mb" & @CRLF)
$objWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & 'Server' & '\root\cimv2:Win32_LogicalDisk="C:"')
ConsoleWrite("> Server     Free Diskspace on C: " & $objWMI.FreeSpace & " bytes / " & Round($objWMI.FreeSpace / 1024 ^ 2) & " mb" & @CRLF & @CRLF)

$IP = '192.168.178.26' ; = @ComputerName
ConsoleWrite('+ Serial for ' & $IP & ': ' & _Serial_Number($IP) & @CRLF & @CRLF)
$IP = 'Server' ; = '192.168.178.31'
ConsoleWrite('+ Serial for ' & $IP & ': ' & _Serial_Number($IP) & @CRLF & @CRLF)
$IP = '192.168.178.31' ; = 'Server'
ConsoleWrite('+ Serial for ' & $IP & ': ' & _Serial_Number($IP) & @CRLF & @CRLF)

Func _Serial_Number($IP)
    ConsoleWrite('! $IP: ' & $IP & @CRLF)
    Local $item, $objItem
    Local Const $objWMIService = ObjGet("winmgmts:\\" & $IP & "\root\CIMV2")
    ConsoleWrite('- $objWMIService: ' & VarGetType($objWMIService) & @CRLF)
    If IsObj($objWMIService) Then
        Local Const $colItems = $objWMIService.ExecQuery("Select * from Win32_BIOS")
        ConsoleWrite('- $colItems: ' & VarGetType($colItems) & @CRLF)
        If IsObj($colItems) Then
            For $objItem In $colItems
                ConsoleWrite('- $objItem: ' & VarGetType($objItem) & @CRLF)
                $item = $objItem.SerialNumber
                ConsoleWrite('> $item: ' & $item & @CRLF)

                If $IP = '192.168.178.31' Then
                    ; Provoke a COM error. Function is unknown
                    $colItems.xyz()
                    If @error <> 0 Then Return MsgBox($MB_SYSTEMMODAL, "_DebugCOMError UDF", "Error occurred and handled." & _
                            @CRLF & "@error = " & @error)
                EndIf

                Return ($item)
            Next
        Else
            Return ('Error: ' & @error)
        EndIf
    EndIf
EndFunc   ;==>_Serial_Number

Alles anzeigen

Hier noch eins ohne _DebugCOMError:

AutoIt

#include <WinAPIError.au3> ; __COMErrorFormating(ByRef $oCOMError, $sPrefix = @TAB) -->> #INTERNAL_USE_ONLY#

Opt('MustDeclareVars', 1)

Local $IP

$IP = '192.168.178.26' ; = @ComputerName
ConsoleWrite('+ Serial for ' & $IP & ': ' & _Serial_Number($IP) & @CRLF & @CRLF)
$IP = 'Server' ; = '192.168.178.31'
ConsoleWrite('+ Serial for ' & $IP & ': ' & _Serial_Number($IP) & @CRLF & @CRLF)
$IP = '192.168.178.31' ; = 'Server'
ConsoleWrite('+ Serial for ' & $IP & ': ' & _Serial_Number($IP) & @CRLF & @CRLF)

Func _Serial_Number($IP)
    ; Error monitoring. This will trap all COM errors while alive.
    ; This particular object is declared as local, meaning after the function returns it will not exist.
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")

    ConsoleWrite('! $IP: ' & $IP & @CRLF)
    Local $item, $objItem
    Local Const $objWMIService = ObjGet("winmgmts:\\" & $IP & "\root\CIMV2")
    ConsoleWrite('- $objWMIService: ' & VarGetType($objWMIService) & @CRLF)
    If IsObj($objWMIService) Then
        Local Const $colItems = $objWMIService.ExecQuery("Select * from Win32_BIOS")
        ConsoleWrite('- $colItems: ' & VarGetType($colItems) & @CRLF)
        If IsObj($colItems) Then
            For $objItem In $colItems
                ConsoleWrite('- $objItem: ' & VarGetType($objItem) & @CRLF)
                $item = $objItem.SerialNumber
                ConsoleWrite('> $item: ' & $item & @CRLF)

                If $IP = '192.168.178.31' Then
                    ; Provoke a COM error. Function is unknown
                    $colItems.xyz()
;~                     If @error <> 0 Then Return MsgBox($MB_SYSTEMMODAL, "_DebugCOMError UDF", "Error occurred and handled." & _
;~                             @CRLF & "@error = " & @error)
                EndIf

                Return ($item)
            Next
        Else
            Return ('Error: ' & @error)
        EndIf
    EndIf
EndFunc   ;==>_Serial_Number

; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.

    ; Entweder so... benötigt #include <WinAPIError.au3>
    ConsoleWrite(__COMErrorFormating($oError) & @CRLF & @CRLF)

    ; oder so... selbst ist der Mann
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number          : " & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription  : " & StringStripWS($oError.windescription, $STR_STRIPTRAILING) & @CRLF & _
            @TAB & "err.description     : " & StringStripWS($oError.description, $STR_STRIPTRAILING) & @CRLF & _
            @TAB & "err.source          : " & $oError.source & @CRLF & _
            @TAB & "err.helpfile        : " & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext     : " & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror    : " & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline      : " & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode         : " & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

Alles anzeigen

$IP musst du natürlich anpassen...

**water** · 12. Januar 2021

Ein COM Error Handler gibt Dir genauere Informationen über das Problem. Siehe ObjEvent in der Hilfe.

**Bitnugger** · 12. Januar 2021

Bei einigen PCs wird allerdings keine SerialNumber angezeigt, so auch bei virtuellen Maschinen. Da kann dann z.B. auch To be filled by O.E.M. oder 0 stehen.

Hier ein Bsp. mit Powershell:

PS C:\Users\bitnugger> Get-WmiObject -Class Win32_BIOS

SMBIOSBIOSVersion : A7522MLN.10F

Manufacturer : American Megatrends Inc.

Name : Default System BIOS

SerialNumber :

Version : MEDION - 20100914

Moombas · 14. Januar 2021

Mittlerweile vermute ich ein Problem in der (erlaubten) Kommunikation da, wenn ich das Skript lokal ausführe, es funktioniert.

Ich teste später aber dennoch nochmal das Skript von dir (Bitnugger) ob das eine Änderung bewirkt.

**Bitnugger** · 14. Januar 2021

Zitat von Moombas

Mittlerweile vermute ich ein Problem in der (erlaubten) Kommunikation da, wenn ich das Skript lokal ausführe, es funktioniert.

Das kannst du mit dem Microsoft-Tool wbemtest testen.

https://knowledge.broadcom.com…ectivity-using-micro.html

https://social.technet.microso…forum=winserverManagement

https://www.windowspro.de/wolf…remote-ueber-wmi-auslesen

Zitat von Moombas

Ich teste später aber dennoch nochmal das Skript von dir (Bitnugger) ob das eine Änderung bewirkt.

Ich denke mal ja... denn in deinem Script sind zwei böse Fehler drin...

- Zeile 9 muss vor Zeile 8 stehen

- nach Zeile 8 musst du testen, ob $colItems ein Objekt ist, bevor du darauf zugreifst.

So wäre es korrekt:

AutoIt

Local $sBIOS
$sBIOS = _Serial_Number() ; Lokaler PC, liefert bei mir einen Leerstring - das ist aber kein Fehler!
ConsoleWrite("$sBIOS --> " & $sBIOS & @LF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @LF)
$sBIOS = _Serial_Number('Server') ; Remote PC, hier ist ok.
ConsoleWrite("$sBIOS --> " & $sBIOS & @LF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @LF)
$sBIOS = _Serial_Number('Blablabla') ; Den PC gibt es nicht, Error 1!
ConsoleWrite("$sBIOS --> " & $sBIOS & @LF & "!@ " & @TAB & "#Error: " & @error & @TAB & "#Extended: " & @extended & @LF)


Func _Serial_Number($IP = '.')
    Local Const $objWMIService = ObjGet("winmgmts:\\" & $IP & "\root\CIMV2") ; Ergebnis mus sein Objekt sein.
    If Not IsObj($objWMIService) Then Return SetError(1, 0, False) ; Testen, ob es ein Objekt ist.
    Local Const $colItems = $objWMIService.ExecQuery("Select * from Win32_BIOS") ; Ergebnis mus sein Objekt sein.
    If Not IsObj($colItems) Then Return SetError(2, 0, False) ; Testen, ob es ein Objekt ist.
    For $objItem In $colItems ; Ok, jetzt kann nichts mehr schief gehen...
        Return $objItem.SerialNumber ; Liefert im Idealfall die SerialNumber, kann aber auch ein Leerstring ("") sein, oder z.B. "To be filled by O.E.M." oder 0!
    Next
EndFunc   ;==>_Serial_Number

Alles anzeigen

Moombas · 15. Januar 2021

Da hast du recht, muss zu meiner Schande gestehen, das ich das bereits bei mir geändert hatte, aber hier nicht.

Seriennummer auslesen

Teilen

Ähnliche Themen

Daten von HDD auslesen