ControlGetPos($hControl, '', '')

**Bitnugger** · 16. Januar 2021

So wie im Titel angegeben, mache ich es sehr oft mit ControlGetPos und hatte bis dato kein Problem damit gehabt... aber das hat sich nun geändert!

Die für den "Fehler" relevanten Zeilen:

_WinAPI_SetWindowLong($hEdit, $GWL_HWNDPARENT, $hListView) ; Setzt das Handle des Parentfensters für $hEdit auf $hListView - das allein löst aber keinen Fehler aus!

ControlFocus($hEdit, '', '') ; Das ist der Bösewicht... ControlGetPos($hListView, '', '') und ControlFocus($hListView, '', '') funktionieren danach nicht mehr richtig!

Lege ich den Fokus auf ein anderes Control, z.B. ControlFocus($hOK, '', ''), funktioniert wieder alles...

Was sagt ihr dazu?

Hier das Test-Script:

AutoIt

;-- TIME_STAMP   2021-01-16 03:58:11

#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <WinAPISysWin.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
    Local $hOK = GUICtrlGetHandle($idOK)

    Local $idListview = GUICtrlCreateListView('Test', 2, 2, 300, 300)
    Local $idItem2 = GUICtrlCreateListViewItem("item1", $idListview)
    Local $idItem1 = GUICtrlCreateListViewItem("item2", $idListview)
    Local $idItem3 = GUICtrlCreateListViewItem("item3", $idListview)
    Local $hListview = GUICtrlGetHandle($idListview)


    Local $idEdit = GUICtrlCreateInput('Input', 70, 120, 100, 20)
    Local $hEdit = GUICtrlGetHandle($idEdit)
    _WinAPI_SetWindowLong($hEdit, $GWL_HWNDPARENT, $hListView)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ConsoleWrite("> $hGUI                                : " & $hGUI & @CRLF)
    ConsoleWrite("> $hEdit                               : " & $hEdit & @CRLF)
    ConsoleWrite("> $hListView                           : " & $hListView & @CRLF)
    ConsoleWrite("> _WinAPI_GetParent($hListView)        : " & _WinAPI_GetParent($hListView) & @CRLF)
    ConsoleWrite("> _WinAPI_GetParent($hEdit)            : " & _WinAPI_GetParent($hEdit) & @CRLF)
    ConsoleWrite("> ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF & @CRLF)

    ConsoleWrite("+ ControlGetPos($hEdit, '', '')        : " & _ArrayToString(ControlGetPos($hEdit, '', ''), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos($hListView, '', '')    : " & _ArrayToString(ControlGetPos($hListView, '', ''), ', ') & @CRLF & @CRLF)

    ConsoleWrite("+ ControlFocus($hEdit, '', '')         : " & ControlFocus($hEdit, '', '') & @CRLF)
    ConsoleWrite("+ ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("+ ControlGetPos($hEdit, '', '')        : " & _ArrayToString(ControlGetPos($hEdit, '', ''), ', ') & @CRLF)
    ConsoleWrite("! ControlGetPos($hListView, '', '')    : " & _ArrayToString(ControlGetPos($hListView, '', ''), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos($hGUI, '', $hListView) : " & _ArrayToString(ControlGetPos($hGUI, '', $hListView), ', ') & @CRLF & @CRLF)

    ConsoleWrite("! ControlFocus($hListView, '', '')     : " & ControlFocus($hListView, '', '') & @CRLF)
    ConsoleWrite("! ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("+ ControlGetPos($hEdit, '', '')        : " & _ArrayToString(ControlGetPos($hEdit, '', ''), ', ') & @CRLF)
    ConsoleWrite("! ControlGetPos($hListView, '', '')    : " & _ArrayToString(ControlGetPos($hListView, '', ''), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos($hGUI, '', $hListView) : " & _ArrayToString(ControlGetPos($hGUI, '', $hListView), ', ') & @CRLF & @CRLF)

    ConsoleWrite("+ ControlFocus($hOK, '', '')           : " & ControlFocus($hOK, '', '') & @CRLF)
    ConsoleWrite("+ ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("+ ControlGetPos($hEdit, '', '')        : " & _ArrayToString(ControlGetPos($hEdit, '', ''), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos($hListView, '', '')    : " & _ArrayToString(ControlGetPos($hListView, '', ''), ', ') & @CRLF)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                ExitLoop

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

Professor Bernd · 16. Januar 2021

Hi Bitnugger.

Ich verstehe dein Problem nicht ganz. Wenn ich "ControlFocus()" benutze wie vorgesehen, funktioniert es doch richtig, oder?

ControlFocus($hGUI, '', $idListview)

**Bitnugger** · 16. Januar 2021

Zitat von Professor Bernd

Ich verstehe dein Problem nicht ganz. Wenn ich "ControlFocus()" benutze wie vorgesehen, funktioniert es doch richtig, oder?

Hehe... ja, sicher, wie vorgesehen... das ist ja auch unverwechselbar... nur gibt es halt auch Controls, für die keine ControlID verfügbar ist... deshalb habe ich mir angewöhnt, nur das Handle des Controls zu nehmen... und unter "normalen" Bedingungen funktioniert das ja auch tadellos.

Bei ControlGetPos gebe ich dann ja als ersten Parameter auch das unverwechselbare Handle des Controls an... Text und ID kann ich mir somit ersparen, dachte ich... aber wie man sieht, eben nicht immer... und wie schon erwähnt... was machen, wenn das Control keine ID hat?

ControlGetPos($hGUI, "", "[CLASS:Blabla; INSTANCE n]") wäre eine Möglichkeit... nur blöd, wenn sich die Instanz dann im Laufe des Betriebs ändert...

Das Problem hier ist, dass ControlGetPos($hControl, '', '') nur dann korrekt funktioniert, wenn der Fokus nicht auf einem der Controls liegt, die durch _WinAPI_SetWindowLong() beeinflußt wurden.

Die erste Frage ist also: Was hat ControlGetPos mit dem Fokus zu tun?

BananaJoe · 16. Januar 2021

Zitat von Bitnugger

ControlFocus($hEdit, '', '') ; Das ist der Bösewicht...

Da fehlt die ControlID:

Auszug aus der Hilfe:

ControlFocus ( "title", "text", controlID )

**Bitnugger** · 16. Januar 2021

Zitat von BananaJoe

Da fehlt die ControlID:

Darum geht es doch gar nicht... denn ControlFocus($hEdit, '', '') funktioniert ja... und zwar immer, weil $hEdit ja das Handle des Controls ist und somit auch unverwechselbar ist, weshalb dann für Text und ID ein Leerstring reicht.

Das Problem ist, dass ControlGetPos dann unterschiedlich reagiert, wenn... siehe Post #3.

Professor Bernd · 16. Januar 2021

Zitat von Bitnugger

was machen, wenn das Control keine ID hat?

_WinAPI_SetFocus($hListView)

Zitat von Bitnugger

Das Problem hier ist, dass ControlGetPos($hControl, '', '') nur dann korrekt funktioniert, wenn der Fokus nicht auf einem der Controls liegt, die durch _WinAPI_SetWindowLong() beeinflußt wurden.

Die erste Frage ist also: Was hat ControlGetPos mit dem Fokus zu tun?

Tja, gute Frage. Ich hatte es vor kurzem auch mit "bösen" AutoIt Funktionen zu tun, darunter "WinGetCaretPos()", "ControlGetFocus()" und "ControlGetPos()". Dabei habe ich auch mit jpm (AutoIt Developer) darüber diskutiert und es ging um das Vodergrund-Fenster, das scheinbar durch verschiedene "böse" Funktionen auch mal aktiviert wird.

Der langen Rede kurzer Sinn: Es ist wie's ist, eine Änderung der "bösen" Funktionen ist nicht in Aussicht!

Zum Glück konnten mithilfe der User andere Funktionen gefunden werden, die die "bösen" ersetzen.

**Bitnugger** · 16. Januar 2021

Zitat von Professor Bernd

_WinAPI_SetFocus($hListView)

Ja... der Fokus wird damit korrekt gesetzt...

Professor Bernd · 16. Januar 2021

Also Problem gelöst?

**Bitnugger** · 16. Januar 2021

Zitat von Professor Bernd

Also Problem gelöst?

Es ist weniger ein Problem, sondern vielmehr eine Verständnisfrage... denn im ersten Post habe ich ja bereits im Script gezeigt, wie ich zum korrekten Ergebnis komme.

Zitat von Bitnugger

Was sagt ihr dazu?

Ich formuliere sie mal anders: Wieso beeinflußt der Fokus das Ergebnis von ControlGetPos($hListView, '', '') und wieso wird der Fokus bei ControlFocus($hListView, '', '') auf "Edit1" gesetzt?

Letzteres kann ich ja noch halbwegs nachvollziehen... weil $hListView mit _WinAPI_SetWindowLong zum Parent-Window für $hEdit gemacht wurde...

Professor Bernd · 16. Januar 2021

Das habe ich in Posting #6 beantwortet:

Zitat von Professor Bernd

Ich hatte es vor kurzem auch mit "bösen" AutoIt Funktionen zu tun, darunter "WinGetCaretPos()", "ControlGetFocus()" und "ControlGetPos()". Dabei habe ich auch mit jpm (AutoIt Developer) darüber diskutiert und es ging um das Vodergrund-Fenster, das scheinbar durch verschiedene "böse" Funktionen auch mal aktiviert wird.

Zitat von Bitnugger

Es ist weniger ein Problem, sondern vielmehr eine Verständnisfrage...

Dieses Interesse teile ich mit dir. Wie gesagt, konnte ich keine Antwort darauf erhalten. Ich hatte es aber auch nicht speziell als Verständnisfrage geschrieben. Vielleicht hast du mehr Glück!?

**Bitnugger** · 16. Januar 2021

Allem Anschein nach verhält es sich so:

Alle Control*()-Funktionen erwarten als ersten Parameter etwas, mit dem das Handle eines Windows identifiziert werden kann. Dort kann alternativ auch direkt das Handle eines Controls angegeben werden, solange dieses selbst keine Child-Windows hat. Ist der erste Parameter eindeutig, kann für die beiden folgenden Parameter einfach ein Leerstring übergeben werden, ohne das Probleme zu erwarten sind.

Hat das Control allerdings selbst Child-Windows, kann der Fokus nur auf eines dieser Childs gesetzt werden, was dazu führt, dass dann alle Control*()-Funktionen ebenfalls das Handle des Childs verwenden... also das Handle des Controls, dass den Fokus hat.

Professor Bernd · 17. Januar 2021

Zitat von Bitnugger

Hat das Control allerdings selbst Child-Windows, kann der Fokus nur auf eines dieser Childs gesetzt werden, was dazu führt, dass dann alle Control*()-Funktionen ebenfalls das Handle des Childs verwenden... also das Handle des Controls, dass den Fokus hat.

Scheint mir irgendwie logisch. Dadurch dass ein Control ein Child bekommt wird es zu einem Parent-Window. Wenn man dann "Control...()"-Funktionen benutzt und das Handle des Controls mit dem Child an der Stelle des Parent-Windows einfügt (Param 1) und die Control-ID mit "" angibt (Param 3), wird das Parent-Control als Parent-Window genommen und das Child mit dem Fokus als gesuchtes Control angenommen.

Mir sind auch andere Funktionen begegnet, die einen leeren String "" als aktives Window/Control interpretieren, wie z.B. die "WinGet...()"-Funktionen.

**Oscar** · 17. Januar 2021

Wenn Du bei ControlFocus das Child korrekt setzt: ControlFocus($hEdit, '', $hListView), dann geht ControlGetPos auch mit Leerstrings: ControlGetPos($hListView, '', '').

**Bitnugger** · 17. Januar 2021

Zitat von Oscar

Wenn Du bei ControlFocus das Child korrekt setzt: ControlFocus($hEdit, '', $hListView), dann geht ControlGetPos auch mit Leerstrings: ControlGetPos($hListView, '', '').

Danke für dein Feedback... ich denke zwar, dass es so nicht korrekt ist, obwohl es funktioniert, aber es hat mich dennoch auf den Weg der Erleuchtung gebracht!

Die ersten drei Parameter der Control*()-Funktionen sind ja immer gleich...

Control* ( "title", "text", controlID ...

Parameter	Erklärung	Bemerkung	spez. Beschreibungen
title	The title/hWnd/class of the window to access.	Parent-Window	TITLE, TEXT, REGEXPTITLE, REGEXPCLASS, LAST, ACTIVE, X \ Y \ W \ H, INSTANCE
text	The text of the window to access.	kann in Verbindung mit title angegeben werden	irgendein Text, den AutoIt sehen kann, z.B. von einem Edit, Input, Button. text wird als SubString behandelt. Versteckte Fenster können nur durch den title gefunden werden, wenn text leer ist.
controlID	The control to interact with.	Control	ID, TEXT, CLASS, CLASSNN, NAME, REGEXPCLASS, X \ Y \ W \ H, INSTANCE

Als controlID kann auch das Handle des Controls ($hEdit, $hListView) angegeben werden, was der Hilfe aber nicht zu entnehmen ist... dann dürfen die ersten beiden Parameter auch Leerstrings sein.

AutoIt

;-- TIME_STAMP   2021-01-17 19:24:14

#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <WinAPISysWin.au3>

Example()

Func Example()
    ; Create a GUI with various controls.
    Local $hGUI = GUICreate("Example")
    Local $idOK = GUICtrlCreateButton("OK", 310, 370, 85, 25)
    Local $hOK = GUICtrlGetHandle($idOK)

    Local $idListview = GUICtrlCreateListView('Test', 2, 2, 300, 300)
    Local $idItem2 = GUICtrlCreateListViewItem("item1", $idListview)
    Local $idItem1 = GUICtrlCreateListViewItem("item2", $idListview)
    Local $idItem3 = GUICtrlCreateListViewItem("item3", $idListview)
    Local $hListview = GUICtrlGetHandle($idListview)

    Local $idEdit = GUICtrlCreateInput('Input', 70, 120, 100, 20)
    Local $hEdit = GUICtrlGetHandle($idEdit)
    _WinAPI_SetWindowLong($hEdit, $GWL_HWNDPARENT, $hListView)

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ConsoleWrite("> $hGUI                                : " & $hGUI & @CRLF)
    ConsoleWrite("> $hEdit                               : " & $hEdit & @CRLF)
    ConsoleWrite("> $hListView                           : " & $hListView & @CRLF)
    ConsoleWrite("> _WinAPI_GetParent($hOK)              : " & _WinAPI_GetParent($hOK) & @TAB & _WinAPI_GetClassName(_WinAPI_GetParent($hOK)) & @CRLF)
    ConsoleWrite("> _WinAPI_GetParent($hListView)        : " & _WinAPI_GetParent($hListView) & @TAB & _WinAPI_GetClassName(_WinAPI_GetParent($hListView)) & @CRLF)
    ConsoleWrite("> _WinAPI_GetParent($hEdit)            : " & _WinAPI_GetParent($hEdit) & @TAB & _WinAPI_GetClassName(_WinAPI_GetParent($hEdit)) & @CRLF)
    ConsoleWrite("> ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("> ControlGetPos($hGUI, '', $idOK)      : " & _ArrayToString(ControlGetPos($hGUI, '', $idOK), ', ') & @CRLF)
    ConsoleWrite("> ControlGetPos($hGUI, '', $idEdit)    : " & _ArrayToString(ControlGetPos($hGUI, '', $idEdit), ', ') & @CRLF)
    ConsoleWrite("> ControlGetPos($hGUI, '', $idListView): " & _ArrayToString(ControlGetPos($hGUI, '', $idListView), ', ') & @CRLF & @CRLF)

    ConsoleWrite("+ ControlFocus('', '', $hListView)     : " & ControlFocus('', '', $hListView) & @CRLF)
    ConsoleWrite("+ ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hOK)          : " & _ArrayToString(ControlGetPos('', '', $hOK), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hEdit)        : " & _ArrayToString(ControlGetPos('', '', $hEdit), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hListView)    : " & _ArrayToString(ControlGetPos('', '', $hListView), ', ') & @CRLF & @CRLF)

    ConsoleWrite("+ ControlFocus('', '', $hEdit)         : " & ControlFocus('', '', $hEdit) & @CRLF)
    ConsoleWrite("+ ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hOK)          : " & _ArrayToString(ControlGetPos('', '', $hOK), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hEdit)        : " & _ArrayToString(ControlGetPos('', '', $hEdit), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hListView)    : " & _ArrayToString(ControlGetPos('', '', $hListView), ', ') & @CRLF & @CRLF)

    ConsoleWrite("+ ControlFocus('', '', $hOK)           : " & ControlFocus('', '', $hOK) & @CRLF)
    ConsoleWrite("+ ControlGetFocus($hGUI)               : " & ControlGetFocus($hGUI) & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hOK)          : " & _ArrayToString(ControlGetPos('', '', $hOK), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hEdit)        : " & _ArrayToString(ControlGetPos('', '', $hEdit), ', ') & @CRLF)
    ConsoleWrite("+ ControlGetPos('', '', $hListView)    : " & _ArrayToString(ControlGetPos('', '', $hListView), ', ') & @CRLF & @CRLF)
;~     Exit

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idOK
                ExitLoop

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

ControlGetPos($hControl, '', '')

Teilen

Ähnliche Themen

Firefox

Context Menu Button mit Scrollbar oder vergrößern

Problem mit IE Browser und GUI

Problem mit ControlGetPos + WinMove