Unterstützung für AutoIT Script

shitgettinserious

Hey habe mir ein kleines Script erstellt.

Bin Anfänger und brauche etwas Unterstützung.

Ich wollte fragen, wie es möglich ist, das wenn ich das Dropdown Menü bediene, sich kein neues Fenster mit dem Text öffnet,

sondern wenn ich das Dropdown Menü bediene, die Daten im gleichen Fenster neben dem Dropdown Menü erscheinen.

Ich hoffe es war relativ verständlich.

Ich habe mal noch eine Skizze angefertigt und beigefügt wie es aussehen sollte.

Wenn der Code kopiert wird kann man ja sehen wie es aktuell ist.

Vielen Dank schonmal im voraus.

Beste Grüße

shitgettinserious

C

#include <StaticConstants.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>


;Hier wird ein Fenster erstellt
$Form1 = GUICreate("Minimal requirements", 615, 437, 192, 124)





;Hier werden DropDownMenu, sowie Inhalt des Menus erstellt
$DropDownMenu = GUICtrlCreateCombo("CSGO", 16, 16, 169, 25)
GUICtrlSetData($DropDownMenu, "Valorant|GTA V|The Forest|Apex Legends|League of Legends|Forza Horizon 4|Black Desert Online|Black Squad|Minecraft|Fortnite", "")


;Hier wird ein Button erstellt
$Button = GUICtrlCreateButton("Suchen", 40, 48, 123, 33)
;Hier wird der Button ausgewählt, damit er mit dem Drop Down interagieren kann.
GUICtrlSetState(-1, $GUI_FOCUS)

;Hier werden Button und DropDownMenu verbunden
$label1=GUICtrlCreateLabel(""& GUICtrlRead(0),0,100)

;Zeigt das Fenster bzw. G U I an
GUISetState(@SW_SHOW)

;Hier werden die Seiten für die Daten der erforderlichen Daten erstellt
;CreateLabel steht in dem Fall für den Text der angezeigt wird
;Das habe ich jetzt für jedes Spiel bzw. Punkt im DropDownMenü erstellt.
;SW_HIDE sagt der Seite einfach nur das die Fenster nicht direkt beim Start des Programms geöffnet werden sollen.
$Fortnite = GUICreate("Fortnite/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextFN = GUICtrlCreateLabel("Für Fortnite sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemFN = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenFN = GUICtrlCreateLabel("Windows 7 " , 144, 72, 104, 17)
$CPUFN = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenFN = GUICtrlCreateLabel("Core i3 2.4 Ghz" , 144, 96, 271, 17)
$RAMFN = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenFN = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteFN = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenFN = GUICtrlCreateLabel("Intel HD 4000", 136, 144, 425, 17)
$DIRECTXFN = GUICtrlCreateLabel("FESTPLATTE :", 16, 184, 57, 17)
$DIRECTXDatenFN = GUICtrlCreateLabel("18 GB", 136, 184, 63, 17)
GUISetState(@SW_HIDE)



$Minecraft = GUICreate("Minecraft/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextMC = GUICtrlCreateLabel("Für Apex Legends sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemMC = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenMC = GUICtrlCreateLabel("Windows 7" , 144, 72, 104, 17)
$CPUMC = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenMC = GUICtrlCreateLabel("Intel Core i3-3210/AMD A8-7600 APU" , 144, 96, 271, 17)
$RAMMC = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenMC = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteMC = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenMC = GUICtrlCreateLabel("Intel HD Graphics 4000", 136, 144, 425, 17)
$DIRECTXMC = GUICtrlCreateLabel("FESTPLATTE:", 16, 184, 57, 17)
$DIRECTXDatenMC = GUICtrlCreateLabel("1GB", 136, 184, 63, 17)
GUISetState(@SW_HIDE)



$BlackSquad = GUICreate("Black Squad/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextBS = GUICtrlCreateLabel("Für Apex Legends sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemBS = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenBS = GUICtrlCreateLabel("Windows 7 64Bit" , 144, 72, 104, 17)
$CPUBS = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenBS = GUICtrlCreateLabel("CORE2 DUO 2.2GHZ/AMD Athlon 64 X2 2.66GHz" , 144, 96, 271, 17)
$RAMBS = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenBS = GUICtrlCreateLabel("2 GB", 144, 120, 28, 17)
$GrafikkarteBS = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenBS = GUICtrlCreateLabel("NVIDIA GEFORCE 8600/RADEON HD 6750", 136, 144, 425, 17)
$GrafikkartenDaten2BS = GUICtrlCreateLabel("Und sollte DirectX Kompatibel sein.", 136, 160, 174, 17)
$DIRECTXBS = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenBS = GUICtrlCreateLabel("Version 9.0", 136, 184, 63, 17)
$FestplatteBS = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenBS = GUICtrlCreateLabel("7 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)



$BDO = GUICreate("Black Desert Online/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextBDO = GUICtrlCreateLabel("Für Black Desert Online sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemBDO = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenBDO = GUICtrlCreateLabel("Windows 10" , 144, 72, 104, 17)
$CPUBDO = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenBDO = GUICtrlCreateLabel("Intel Core i3-530 2.9GHz" , 144, 96, 271, 17)
$RAMBDO = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenBDO = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteBDO = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenBDO = GUICtrlCreateLabel("GeForce 9800 GTX/Radeon HD 3870 X2", 136, 144, 425, 17)
$DIRECTXBDO = GUICtrlCreateLabel("FESTPLATTE :", 16, 184, 57, 17)
$DIRECTXDatenBDO = GUICtrlCreateLabel("39 GB", 136, 184, 63, 17)
GUISetState(@SW_HIDE)



$Apex = GUICreate("Apex Legends/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextApex = GUICtrlCreateLabel("Für Apex Legends sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemApex = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenApex = GUICtrlCreateLabel("Windows 7 64Bit" , 144, 72, 104, 17)
$CPUApex = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenApex = GUICtrlCreateLabel("Intel Core i3 6300/AMD FX 4350" , 144, 96, 271, 17)
$RAMApex = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenApex = GUICtrlCreateLabel("6 GB", 144, 120, 28, 17)
$GrafikkarteApex = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenApex = GUICtrlCreateLabel("NVIDIA GeForce® GT 640/AMD Radeon™ HD 7730", 136, 144, 425, 17)
$GrafikkartenDaten2Apex = GUICtrlCreateLabel("Und sollte DirectX Kompatibel sein.", 136, 160, 174, 17)
$DIRECTXApex = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenApex = GUICtrlCreateLabel("Version 11", 136, 184, 63, 17)
$FestplatteApex = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenApex = GUICtrlCreateLabel("56 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)



$LOL = GUICreate("League of Legends/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextLOL = GUICtrlCreateLabel("Für League of Legends sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemLOL = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenLOL = GUICtrlCreateLabel("Windows XP" , 144, 72, 104, 17)
$CPULOL = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenLOL = GUICtrlCreateLabel("2 GHz Prozessor" , 144, 96, 271, 17)
$RAMLOL = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenLOL = GUICtrlCreateLabel("1 GB", 144, 120, 28, 17)
$GrafikkarteLOL = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenLOL = GUICtrlCreateLabel("Shader version 2.0 capable video card", 136, 144, 425, 17)
$GrafikkartenDaten2LOL = GUICtrlCreateLabel("Und sollte DirectX Kompatibel sein.", 136, 160, 174, 17)
$DIRECTXLOL = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenLOL = GUICtrlCreateLabel("Version 9.0c", 136, 184, 63, 17)
$FestplatteLOL = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenLOL = GUICtrlCreateLabel("12 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)



$Forza4 = GUICreate("Forza Horizon 4/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextForza = GUICtrlCreateLabel("Für Forza Horizon 4 sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemForza = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenForza = GUICtrlCreateLabel("Windows 10" , 144, 72, 104, 17)
$CPUForza = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenForza = GUICtrlCreateLabel("Intel i3-4170 @ 3.7Ghz/Intel i5 750 @ 2.67Gh" , 144, 96, 271, 17)
$RAMForza = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenForza = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteForza = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenForza = GUICtrlCreateLabel("2 GB, NVidia 650TI/ AMD R7 250x ", 136, 144, 425, 17)
$GrafikkartenDaten2Forza = GUICtrlCreateLabel("Und sollte DirectX Kompatibel sein.", 136, 160, 174, 17)
$DIRECTXForza = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenForza = GUICtrlCreateLabel("Version 12", 136, 184, 63, 17)
$FestplatteForza = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenForza = GUICtrlCreateLabel("80 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)




$Valorant = GUICreate("Valorant/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextVal = GUICtrlCreateLabel("Für Valorant sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemVal= GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenVal = GUICtrlCreateLabel("Windows 7 64 Bit", 144, 72, 104, 17)
$CPUVal = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenVal = GUICtrlCreateLabel("Intel Core 2 Duo E8400" , 144, 96, 271, 17)
$RAMVal = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenVal = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteVal = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenVal = GUICtrlCreateLabel("Intel HD 4000 (1GB VRAM)", 136, 144, 425, 17)
$DIRECTXVal = GUICtrlCreateLabel("FESTPLATTE :", 16, 184, 57, 17)
$DIRECTXDatenVal = GUICtrlCreateLabel("13 GB", 136, 184, 63, 17)
GUISetState(@SW_HIDE)



$GTAV = GUICreate("GTA V/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextGTA = GUICtrlCreateLabel("Für Grand Theft Auto V sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemGTA = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenGTA = GUICtrlCreateLabel("Windows 7 64 Bit", 144, 72, 104, 17)
$CPUGTA = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenGTA = GUICtrlCreateLabel("Intel Core 2 Quad CPU Q6600 @ 2.40GHz (4 CPUs)" , 144, 96, 271, 17)
$RAMGTA = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenGTA = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteGTA = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenGTA = GUICtrlCreateLabel("NVIDIA 9800 GT 1GB / AMD HD 4870 1GB ", 136, 144, 425, 17)
$GrafikkartenDaten2GTA = GUICtrlCreateLabel("Und sollte DirectX Kompatibel sein.", 136, 160, 174, 17)
$DIRECTXGTA = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenGTA = GUICtrlCreateLabel("Version 10", 136, 184, 63, 17)
$FestplatteGTA = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenGTA = GUICtrlCreateLabel("72 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)


$Theforest = GUICreate("The Forest/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextForest = GUICtrlCreateLabel("Für The Forest sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemForest = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenForest = GUICtrlCreateLabel("Windows 7", 144, 72, 104, 17)
$CPUForest = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenForest = GUICtrlCreateLabel("Intel Dual-Core 2.4 GHz", 144, 96, 271, 17)
$RAMForest = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenForest = GUICtrlCreateLabel("4 GB", 144, 120, 28, 17)
$GrafikkarteForest = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenForest = GUICtrlCreateLabel("NVIDIA GeForce 8800GT", 136, 144, 425, 17)
$GrafikkartenDaten2Forest = GUICtrlCreateLabel("Und DirectX Kompatibel sein.", 136, 160, 174, 17)
$DIRECTXForest = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenForest = GUICtrlCreateLabel("Version 9.0", 136, 184, 63, 17)
$FestplatteForest = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenForest = GUICtrlCreateLabel("5 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)

$CSGO = GUICreate("CSGO/Anforderung", 615, 437, 192, 124)
GUICtrlSetState(-1, $GUI_DISABLE)
$TextCSGO = GUICtrlCreateLabel("Für Counter Strike : Global Offensive sollten Sie mindestens folgendes Setup haben :", 96, 24, 402, 17)
$BetriebsystemCSGO = GUICtrlCreateLabel("BETRIEBSSYSTEM :", 16, 72, 107, 17)
$BetriebsystemdatenCSGO = GUICtrlCreateLabel("Windows 7/Vista/XP", 144, 72, 104, 17)
$CPUCSGO = GUICtrlCreateLabel("CPU :", 16, 96, 32, 17)
$CPUDatenCSGO = GUICtrlCreateLabel("Intel CoreTM 2 Duo E6600 or AMD PhenomTM X3 8750", 144, 96, 271, 17)
$RAMCSGO = GUICtrlCreateLabel("RAM :", 16, 120, 34, 17)
$RAMDatenCSGO = GUICtrlCreateLabel("2 GB", 144, 120, 28, 17)
$GrafikkarteCSGO = GUICtrlCreateLabel("GRAFIKKARTE :", 16, 144, 85, 17)
$GrafikkarteDatenCSGO = GUICtrlCreateLabel("Die Grafikkarte muss mindestens 256 MB haben und sollte mit DirectX 9 Kompatibel sein. ", 136, 144, 425, 17)
$GrafikkartenDaten2CSGO = GUICtrlCreateLabel("Und Pixel Schader 3.0 unterstützen.", 136, 160, 174, 17)
$DIRECTXCSGO = GUICtrlCreateLabel("DIRECTX :", 16, 184, 57, 17)
$DIRECTXDatenCSGO = GUICtrlCreateLabel("Version 9.0c", 136, 184, 63, 17)
$FestplatteCSGO = GUICtrlCreateLabel("FESTPLATTE :", 16, 208, 78, 17)
$FestplatteDatenCSGO = GUICtrlCreateLabel("15 GB", 136, 208, 34, 17)
GUISetState(@SW_HIDE)



;Diese Funktionen sorgen dafür, dass sich das Fenster mit den Betriebsystem Daten öffnet und sich das alte Fenster schließt.
;Also SW_HIDE --> Schließt das Fenster mit dem DropDownMenu
;Und SW_SHOW --> Zeigt das Fenster, was geöffnet werden soll.
;In dem Fall ist es das Fenster mit den Mindestanforderung für Counter Strike : Global Offensive

$var11 = 1 ;Variablen damit der Vorgangfunktioniert.
$var12 = 1



Func CSGO ()
    If $var11 = 1 Then
    GUISetState(@SW_HIDE, $Form1)
    GUISetState(@SW_SHOW, $CSGO)
    EndIf
    $var11 = 2
    $var12 = 1

EndFunc



Func GTA()
    If $var11 = 1 Then
    GUISetState(@SW_HIDE, $Form1)
    GUISetState(@SW_SHOW, $GTAV)
    EndIf
    $var11 = 2
    $var12 = 1

EndFunc



Func Valorant ()
    If $var11 = 1 Then
    GUISetState(@SW_HIDE, $Form1)
    GUISetState(@SW_SHOW, $Valorant)
    EndIf
    $var11 = 2
    $var12 = 1

EndFunc

Func BDO ()

    If $var12 = 1 Then
        GUISetState(@SW_HIDE, $Form1)
        GUISetState(@SW_SHOW, $BDO)
    $var12 = 2
    $var11 = 1
    EndIf


EndFunc

Func BlackSquad ()
    If $var11 = 1 Then
    GUISetState(@SW_HIDE, $form1)
    GUISetState(@SW_SHOW, $BlackSquad)
    EndIf
    $var11 = 2
    $var12 = 1


EndFunc

Func Minecraft ()

    If $var12 = 1 Then
        GUISetState(@SW_HIDE, $Form1)
        GUISetState(@SW_SHOW, $Fortnite)
    $var12 = 2
    $var11 = 1
    EndIf


EndFunc

Func Forza4 ()
    If $var11 = 1 Then
    GUISetState(@SW_HIDE, $Form1)
    GUISetState(@SW_SHOW, $Forza4)
    EndIf
    $var11 = 2
    $var12 = 1

EndFunc

Func TheForest ()
    If $var11 = 1 Then
    GUISetState(@SW_HIDE, $Form1)
    GUISetState(@SW_SHOW, $Theforest)
    EndIf
    $var11 = 2
    $var12 = 1

EndFunc

Func LOL ()

    If $var12 = 1 Then
        GUISetState(@SW_HIDE, $Form1)
        GUISetState(@SW_SHOW, $LOL)
    $var12 = 2
    $var11 = 1
    EndIf


EndFunc


Func Apex ()

    If $var12 = 1 Then
        GUISetState(@SW_HIDE, $Form1)
        GUISetState(@SW_SHOW, $Apex)
    $var12 = 2
    $var11 = 1
    EndIf

EndFunc



;Das ist eine Schleife, damit das Fenster geschlossen werden kann -> Oben Rechts in der Ecke das "x".
While 1000
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

;Hier wird Ausgewählt, wenn im DropDownMenu etwas geklickt wird, welche Seite sich öffnen soll ---> Das Funktioniert über die If-Schleife
    Case $Button
        If GUICtrlRead($DropDownMenu) = "CSGO" Then
    CSGO()
ElseIf GUICtrlRead($DropDownMenu) = "GTA V" Then
    GTA()
ElseIf GUICtrlRead($DropDownMenu) = "Valorant" Then
    Valorant()
ElseIf GUICtrlRead($DropDownMenu) = "Black Desert Online" Then
    BDO()
ElseIf GUICtrlRead($DropDownMenu) = "Black Squad" Then
    BlackSquad()
ElseIf GUICtrlRead($DropDownMenu) = "Minecraft" Then
    Minecraft()
ElseIf GUICtrlRead($DropDownMenu) = "Forza Horizon 4" Then
    Forza4()
ElseIf GUICtrlRead($DropDownMenu) = "The Forest" Then
    TheForest()
ElseIf GUICtrlRead($DropDownMenu) = "League of Legends" Then
    LOL()
ElseIf GUICtrlRead($DropDownMenu) = "Apex Legends" Then
    Apex()
EndIf
EndSwitch
WEnd

Alles anzeigen

**Mars**

Der Trick sind Arrays. Du hast unmengen an redundanten Daten in deinem Programmcode. Immer wenn ein Ablauf nur von verschiedenen Daten, aber nicht von verschiedener "Struktur" abhängt, kann man Arrays nutzen. (z.B. du hast ein Label und willst dort 10 verschiedene Strings anzeigen lassen je nachdem was man anklickt. Dann speicherst du diese 10 Strings in einer Liste und benutzt z.B. Liste[0] um den ersten String zu bekommen).

Trick Nummer 2 sind MEHR ARRAYS

Wenn du einen Datensatz hast (bestehend aus Titel, OS, CPU, GPU, ... etc) ist dieser ein Array. Wenn du viele Datensätze hast, ist das ein Array welches Arrays enthält.

Trick Nummer 3: Generalisierung im Allgemeinen

Immer wenn man in der Programmierung eine Anzahl Probleme (z.B. der große ElseIf Teil, oder eine eigene Funktion für jedes Spiel LOL(), GTA(), ...()) hat, die sich sehr ähnlich sind, versucht man einen Schritt zurückzutreten und "alle" Probleme dieses Typs gleichzeitig zu lösen. Was passiert, wenn du ein Spiel hinzufügen willst? Im Optimalfall ergänzt du in einer Liste ein paar Zeilen und fertig, aber du möchtest keine neuen Funktionen schreiben, keine neuen GUIs erstellen, keine neuen Ctrls erstellen, etc.

Das klingt jetzt als würde ich dich angreifen, will ich aber wirklich nicht. Das sind alles Tips

Man wächst an seinen Aufgaben, und einfache Programme sind super geeignet um etwas zu lernen

Anbei gibt es auch gleich ein Grundgerüst für "eine" Lösung des Problems (es gibt immer sehr viele verschiedene richtige Wege ein Problem zu lösen, hier wird nur "einer" gezeigt. Jeder hat einen eigenen Programmierstil). Das UserInterface (GUI) ist selbstverständlich nicht ausgereift, ich habe auch nicht alle Spiele hinzugefügt und der Text der angezeigt wird ist nicht schön formatiert, vielleicht sind auch noch Bugs drin, habe das jetzt nicht 5 Stunden getestet. Das sind alles Sachen an denen du dich austoben kannst

AutoIt

; Yo

Global $aaInfo[4] ; aaInfo steht für Array of aInfo, also eine Liste die Arrays mit Infos enthält. Verschachteltes Array.
; Wenn du mehr als 4 Spiele unterstützen willst hier aus der [4] irgendwas höheres machen sodass es zur Anzahl Spiele passt.
For $i = 0 To UBound($aaInfo) - 1 Step 1
    $aaInfo[$i] = InfoCreate()
Next

; Das habe ich hier extra so aufgebaut, damit man die Info später einfacher aus einer Ini holen kann wenn man will.
InfoSet($aaInfo[0], 'Titel'         , 'CS:GO')
InfoSet($aaInfo[0], 'Betriebssystem', 'Windows 7/Vista/XP')
InfoSet($aaInfo[0], 'CPU'           , 'Intel CoreTM 2 Duo E6600 or AMD PhenomTM X3 8750')
InfoSet($aaInfo[0], 'RAM'           , '2 GB')
InfoSet($aaInfo[0], 'Grafik'        , 'Die Grafikkarte muss mindestens 256 MB haben und sollte mit DirectX 9 Kompatibel sein, und Pixel Schader 3.0 unterstützen.')
InfoSet($aaInfo[0], 'DirectX'       , 'Version 9.0c')
InfoSet($aaInfo[0], 'Festplatte'    , '15 GB')

InfoSet($aaInfo[1], 'Titel'         , 'League of Legends')
InfoSet($aaInfo[1], 'Betriebssystem', 'Windows XP')
InfoSet($aaInfo[1], 'CPU'           , '2 GHz Prozessor')
InfoSet($aaInfo[1], 'RAM'           , '1 GB')
InfoSet($aaInfo[1], 'Grafik'        , 'Shader version 2.0 & DirectX capable video card.')
InfoSet($aaInfo[1], 'DirectX'       , 'Version 9.0c')
InfoSet($aaInfo[1], 'Festplatte'    , '12 GB')

InfoSet($aaInfo[2], 'Titel'         , 'irgendein Spiel')
InfoSet($aaInfo[2], 'Betriebssystem', 'Windows 95+')
InfoSet($aaInfo[2], 'CPU'           , '7 GHz Prozessor')
InfoSet($aaInfo[2], 'RAM'           , '100 GB')
InfoSet($aaInfo[2], 'Grafik'        , 'Shader version 31.41 & 2TB GDDR8')
InfoSet($aaInfo[2], 'DirectX'       , 'Version 15.0c')
InfoSet($aaInfo[2], 'Festplatte'    , '77 TB')

InfoSet($aaInfo[3], 'Titel'         , 'irgendein Spiel (teil 3)')
InfoSet($aaInfo[3], 'Betriebssystem', 'Windows 94+')
InfoSet($aaInfo[3], 'CPU'           , '9 GHz Prozessor')
InfoSet($aaInfo[3], 'RAM'           , '100 TB')
InfoSet($aaInfo[3], 'Grafik'        , 'Shader version 31.415 & 17TB GDDR0')
InfoSet($aaInfo[3], 'DirectX'       , 'Version 19.0c')
InfoSet($aaInfo[3], 'Festplatte'    , '12345 TB')

; Hier kann man einfach weitere sachen hinzufügen, die sind dann automatisch drin.


; Das UserInterface sah so lustiger aus. Aber das kann jeder so gestalten wie man will.
Global $iW = 320, $iH = 260
Global $hGUI = GUICreate('Ich bin ein Fenster', $iW, $iH)
Global $hDDM = GUICtrlCreateCombo(($aaInfo[0])[0][1], 10, 10, 150, 25) ; Ja man kann verschachtelte Arrays via (aaList[0])[...] ansprechen. Ist nicht sehr performant, ist hier aber egal.
For $i = 1 To UBound($aaInfo) - 1 Step 1
    GUICtrlSetData($hDDM, ($aaInfo[$i])[0][1])
Next
Global $hBTN = GUICtrlCreateButton('Lets Go', 170, 10, 100, 25)
Global $hEDT = GUICtrlCreateEdit('Info', 10, 50, 300, 200, 0, 2048)
GUICtrlSetBkColor($hEDT, 0x404040)
GUICtrlSetFont($hEDT, 11, 400, 0, 'Consolas', 5) ; Wenn Consolas nicht installiert ist einfach Arial hier hinschreiben.
GUICtrlSetColor($hEDT, 0x40EE80)
GUISetBkColor(0x202020, $hGUI)
GUISetState(@SW_SHOW, $hGUI)


While True
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $hBTN
            Local $sRW = GUICtrlRead($hDDM)
            ; In hDDM ist jetzt ein String = Spielname. Der ist auch in (aaInfo[i])[0][1].
            For $i = 0 To UBound($aaInfo) - 1 Step 1
                If ($aaInfo[$i])[0][1] = $sRW Then
                    $sRW = ''
                    For $ii = 0 To UBound($aaInfo[$i]) - 1 Step 1
                        $sRW &= ($aaInfo[$i])[$ii][0] & ': ' & ($aaInfo[$i])[$ii][1] & @CRLF
                    Next
                    GUICtrlSetData($hEDT, $sRW)
                    ExitLoop
                EndIf
            Next
    EndSwitch
WEnd

Func InfoCreate()
    Local $aInfo[7][2] ; Wenn mehr Keys dazukommen, hier aus [6][2] ein [7][2] oder mehr machen.
    $aInfo[0][0] = 'Titel'
    $aInfo[1][0] = 'Betriebssystem'
    $aInfo[2][0] = 'CPU'
    $aInfo[3][0] = 'RAM'
    $aInfo[4][0] = 'Grafikkarte'
    $aInfo[5][0] = 'DirectX'
    $aInfo[6][0] = 'Festplatte'
    Return $aInfo
EndFunc

Func InfoSet(ByRef $aInfo, $sKey, $sValue)
    For $i = 0 To UBound($aInfo) - 1 Step 1
        If StringLeft($aInfo[$i][0], StringLen($sKey)) = $sKey Then ; Lineare Suche (reicht bei wenigen Keys), partial Match geht, also z.B. "Grafik" statt "Grafikkarte" schreiben.
            $aInfo[$i][1] = $sValue
            ExitLoop
        EndIf
    Next
EndFunc

Func InfoGet(ByRef $aInfo, $sKey)
    For $i = 0 To UBound($aInfo) - 1 Step 1
        If StringLeft($aInfo[$i][0], StringLen($sKey)) = $sKey Then Return $aInfo[$i][1]
    Next
EndFunc

Alles anzeigen

lg

M

**Musashi**

shitgettinserious !

Vorab : Man löscht nicht einfach Beiträge, nur weil man etwas verstanden hat !

Hier mal ein alternatives Beispiel (dazu die angehängte Datei in das Skriptverzeichnis speichern) :

AutoIt

#include <File.au3>
#include <Array.au3>
#include <GuiComboBox.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $aGameSpecs, $sFileNameSpecs, $sCurrentComboSelection
$sFileNameSpecs = @ScriptDir & "\GameSpecs.txt"

; Einlesen der GameSpecs aus dem Datafile :
_FileReadToArray($sFileNameSpecs, $aGameSpecs, $FRTA_NOCOUNT, ";")
If @error Then Exit MsgBox(BitOR(4096, 16), "Fehler : ", "Fehler " & @error & " ist aufgetreten")

Global $hGUI, $idComboDropDownMenu, $iSearchIndex
Global $idLblTitel, $idLblSystem, $idLblCPU, $idRAM, $idGraphic, $idDirectX, $idLblHD, $idLblInfo
$hGUI = GUICreate("Minimal requirements", 700, 500, 100, 100)

; Labels anlegen :
$idLblTitel  = GUICtrlCreateLabel("", 10, 60, 600, 30)
GUICtrlSetFont($idLblTitel, 11, 400, 0, 'Consolas', 5)
$idLblSystem = GUICtrlCreateLabel("", 10, 100, 600, 30)
GUICtrlSetFont($idLblSystem, 11, 400, 0, 'Consolas', 5)
$idLblCPU    = GUICtrlCreateLabel("", 10, 140, 600, 30)
GUICtrlSetFont($idLblCPU, 11, 400, 0, 'Consolas', 5)
$idRAM       = GUICtrlCreateLabel("", 10, 180, 600, 30)
GUICtrlSetFont($idRAM, 11, 400, 0, 'Consolas', 5)
$idGraphic   = GUICtrlCreateLabel("", 10, 220, 600, 30)
GUICtrlSetFont($idGraphic, 11, 400, 0, 'Consolas', 5)
$idDirectX   = GUICtrlCreateLabel("", 10, 260, 600, 30)
GUICtrlSetFont($idDirectX, 11, 400, 0, 'Consolas', 5)
$idLblHD     = GUICtrlCreateLabel("", 10, 300, 600, 30)
GUICtrlSetFont($idLblHD, 11, 400, 0, 'Consolas', 5)
$idLblInfo   = GUICtrlCreateLabel("", 10, 340, 600, 30)
GUICtrlSetFont($idLblInfo, 11, 400, 0, 'Consolas', 5)


$idComboDropDownMenu = GUICtrlCreateCombo("", 10, 10, 200, 25)
For $i = 0 To UBound ($aGameSpecs) - 1
    GUICtrlSetData($idComboDropDownMenu, $aGameSpecs[$i][0], "")
Next

$sCurrentComboSelection = ""

GUISetState(@SW_SHOW, $hGUI)
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $idOK
            ExitLoop
    EndSwitch

    If GUICtrlRead($idComboDropDownMenu) <> $sCurrentComboSelection And _GUICtrlComboBox_GetDroppedState($idComboDropDownMenu) = False Then
        $sCurrentComboSelection = GUICtrlRead($idComboDropDownMenu)
        $iSearchIndex = _GUICtrlComboBox_GetCurSel($idComboDropDownMenu)
        _ShowSpecs($iSearchIndex)
    EndIf
    If _GUICtrlComboBox_GetDroppedState($idComboDropDownMenu) Then $sCurrentComboSelection = ""

WEnd
GUIDelete($hGUI)

Func _ShowSpecs($iIndex)
    GUICtrlSetData($idLblTitel,  "Titel ......... : " & $aGameSpecs[$iIndex][0])
    GUICtrlSetData($idLblSystem, "Betriebssystem  : " & $aGameSpecs[$iIndex][1])
    GUICtrlSetData($idLblCPU,    "CPU ........... : " & $aGameSpecs[$iIndex][2])
    GUICtrlSetData($idRAM,       "RAM ........... : " & $aGameSpecs[$iIndex][3])
    GUICtrlSetData($idGraphic,   "Grafikkarte ... : " & $aGameSpecs[$iIndex][4])
    GUICtrlSetData($idDirectX,   "DirectX ....... : " & $aGameSpecs[$iIndex][5])
    GUICtrlSetData($idLblHD,     "Festplatte .... : " & $aGameSpecs[$iIndex][6])
    GUICtrlSetData($idLblInfo,   "Info .......... : " & $aGameSpecs[$iIndex][7])
EndFunc

Alles anzeigen

Weitere Einträge einfach in der Textdatei anfügen.

**BugFix**

Zitat von shitgettinserious

wenn ich das Dropdown Menü bediene, die Daten im gleichen Fenster neben dem Dropdown Menü erscheinen.

Die simpelste Variante:

AutoIt

Global $aDetail[][] = [ _
['Artikel-1', '[Artikel-1];Detail_1: 10;Detail_2: 20;Detail_3: 30;Detail_4: 40;Detail_5: 50;Detail_6: 60'], _
['Artikel-2', '[Artikel-2];Detail_1: 110;Detail_2: 120;Detail_3: 130;Detail_4: 140;Detail_5: 150;Detail_6: 160'], _
['Artikel-3', '[Artikel-3];Detail_1: 210;Detail_2: 220;Detail_3: 230;Detail_4: 240;Detail_5: 250;Detail_6: 260'], _
['Artikel-4', '[Artikel-4];Detail_1: 310;Detail_2: 320;Detail_3: 330;Detail_4: 340;Detail_5: 350;Detail_6: 360']]

Global $hGui = GUICreate('Test', 600, 300)
Global $cCombo = GUICtrlCreateCombo('', 10, 20, 200)
; Daten für Combo erstellen
Global $sCombo = ''
For $i = 0 To UBound($aDetail) -1
    $sCombo &= $aDetail[$i][0] & '|'
Next
$sCombo = StringTrimRight($sCombo, 1) ; letztes '|' abschneiden
GUICtrlSetData($cCombo, $sCombo)
Global $editDetail = GUICtrlCreateEdit('', 220, 20, 340, 250)

GUISetState()

Global $sRead
While True
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $cCombo
            $sRead = GUICtrlRead($cCombo)
            If $sRead <> '' Then _SetDetail($sRead)
    EndSwitch
WEnd

Func _SetDetail($_sKey)
    GUICtrlSetData($editDetail, '')
    Local $sDetail
    For $i = 0 To UBound($aDetail) -1
        If $aDetail[$i][0] = $_sKey Then
            $sDetail = StringReplace($aDetail[$i][1], ';', @CRLF) ; Semikolon durch Zeilenumbruch ersetzen
            GUICtrlSetData($editDetail, $sDetail)
        EndIf
    Next
EndFunc

Alles anzeigen

Besser geeignet wäre aber staat Combo & Anzeige-Control ein Listview.

shitgettinserious

Hallo vielen dank für eure Antworten.

Mir war es besonders wichtig, dass alles zu verstehen und nicht einfach eure Codes zu kopieren.

Ich habe mithilfe euere angefertigten Versionen verstanden, wie es funktioniert und bin selbst zu einem Ergebnis gekommen.

Ich bedanke mich bei euch!

Wünsche allen ein schönes Wochenende.

Unterstützung für AutoIT Script

Ähnliche Themen

Brauche Unterstützung bei AutoIt

Kommunikation zw AutoIt und PSPad's VBScript

Debugger für AutoIt3 - sinnfrei oder sinnvoll?