Microsoft Word: Suche und ersetze Text in den Inhalten der VBA-Progammierung (gelöst)

#include <Word.au3>
#include <MsgBoxConstants.au3>

; ********** Änderungen nur NACH dieser Zeile **********
; Table with search and replace strings to process
Global $aSearchReplace[][] = [ _
                             ["Tester","Master"], _
                             ["True","False"], _
                             ["Maier","Müller"] _
                             ]
; For code with the following strings no replacement will be done at all
Global $aIgnore[] = [ _
                    'ActiveDocument.Bookmarks("Amtsleiter")"', _
                    '.UpdateFieldsAtPrint = True' _
                    ]
Global $sTemplate = @ScriptDir & "\I-Brief" ; Zu verarbeitende Word Vorlagedatei
; ********** Änderungen nur VOR dieser Zeile **********
Global $sExtension = ".dotm"
Global $iTotalProjectCount = 0, $iTotalComponentCount = 0, $iTotalReplacementCount = 0

; Set up debugging
Global $__iWord_Debug = 0 ; Debug level. 0 = no debug information, 1 = Debug info to consWorde, 2 = Debug info to MsgBox, 3 = Debug Info to File
Global $__sWord_DebugFile = @ScriptDir & "\Word_Debug.txt" ; Debug file when $__iWord_Debug is set to 3
Global $__oWord_Error ; COM Error handler

; Start the MS Word application
Global $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_ICONERROR, "Error", "_Word_Create: @error=" & @error & ", @extended=" & @extended)

_Word_ErrorNotify(2)
; Process the Template
_VBAModify($sTemplate)

Exit

Func _VBAModify($sTemplate)

    ; Open the Document
    Global $oDoc = _Word_DocOpen($oWord, $sTemplate & $sExtension)
    If @error Then Exit MsgBox($MB_ICONERROR, "Error", "_Word_DocOpen: @error=" & @error & ", @extended=" & @extended)

    ; Collect statistics and output them to the Console
    ConsoleWrite("PROCESSING: " & $sTemplate & $sExtension & @CRLF)
    ConsoleWrite("  STATISTICS" & @CRLF & "  ==========" & @CRLF)
    For $oVBProject In $oWord.VBE.VBProjects
        ConsoleWrite("  VBProject: " & $oVBProject.Name & ", Typ: " & $oVBProject.Type)
        Switch $oVBProject.Type
            Case 100
                ConsoleWrite(" (vbext_pt_HostProject - Host project)" & @CRLF)
            Case 101
                ConsoleWrite(" (vbext_pt_StandAlone - Standalone Project)" & @CRLF)
            Case Else
                ConsoleWrite(" Unknown Project Type!" & @CRLF)
        EndSwitch
        For $oVBComponent In $oVBProject.VBComponents
            ConsoleWrite("    VBComponent: " & $oVBComponent.Name & ", Typ: " & $oVBComponent.Type)
            Switch $oVBComponent.Type
                Case 1
                    ConsoleWrite(" (vbext_ct_StdModule - Standard module)" & @CRLF)
                Case 2
                    ConsoleWrite(" (vbext_ct_ClassModule - Class module)" & @CRLF)
                Case 3
                    ConsoleWrite(" (vbext_ct_MSForm - Microsoft Form)" & @CRLF)
                Case 11
                    ConsoleWrite(" (vbext_ct_ActiveXDesigner - ActiveX Designer)" & @CRLF)
                Case 100
                    ConsoleWrite(" (vbext_ct_Document - Document Module)" & @CRLF)
                Case Else
                    ConsoleWrite(" Unknown Component Type!" & @CRLF)
            EndSwitch
        Next
    Next

    ; Process all VBProjects and VBComponents
    ConsoleWrite("  SEARCH & REPLACE" & @CRLF & "  ================" & @CRLF)
    For $oVBProject In $oWord.VBE.VBProjects
        ConsoleWrite("  VBProject: " & $oVBProject.Name & @CRLF)
        $iTotalProjectCount += 1
        For $oVBComponent In $oVBProject.VBComponents
            ConsoleWrite("    VBComponent: " & $oVBComponent.Name & @CRLF)
            $iTotalComponentCount += 1
            Switch $oVBComponent.Type
                ; Only Standard Modules and Microsoft Forms will be processed
                Case 1, 3
                    $oCodeModule = $oVBComponent.CodeModule
                    If @error Then Exit MsgBox($MB_ICONERROR, "Error", "CodeModule: @error=" & @error & ", @extended=" & @extended)
                    With $oCodeModule
                        $iReplaceCount = 0
                        For $i = 1 To .CountOfLines
                            $bIgnore = False
                            For $j = 0 To UBound($aIgnore, 1) - 1
                                If StringInStr(.Lines($i, 1), $aIgnore[$j]) Then $bIgnore = True
                            Next
                            If $bIgnore = False Then
                                For $j = 0 To UBound($aSearchReplace, 1) - 1
                                    If StringInStr(.Lines($i, 1), $aSearchReplace[$j][0]) Then
                                        .ReplaceLine($i, StringReplace(.Lines($i, 1), $aSearchReplace[$j][0], $aSearchReplace[$j][1]))
                                        $iReplaceCount = $iReplaceCount + 1
                                    EndIf
                                Next
                            EndIf
                        Next
                        ConsoleWrite("      " & $iReplaceCount & " replacements" & @CRLF)
                        $iTotalReplacementCount = $iTotalReplacementCount + $iReplaceCount
                    EndWith
                Case Else
                    ConsoleWrite("      Not processed!" & @CRLF)
            EndSwitch
        Next
    Next

    ; Send total Statistics for this document to the Console
    ConsoleWrite("  SEARCH & REPLACE - TOTAL STATISTICS" & @CRLF & "  ===================================" & @CRLF)
    ConsoleWrite("  VBProjects processed  : " & $iTotalProjectCount & @CRLF)
    ConsoleWrite("  VBComponents processed: " & $iTotalComponentCount & @CRLF)
    ConsoleWrite("  Replacements done     : " & $iTotalReplacementCount & @CRLF)

    ; Save as new Document
    _Word_DocSaveAs($oDoc, $sTemplate & "-NEW" & $sExtension, $WdFormatXMLTemplateMacroEnabled)
    If @error Then Exit MsgBox($MB_ICONERROR, "Error", "_Word_DocSaveAs: @error=" & @error & ", @extended=" & Hex(@extended))

    ; Close Document
    _Word_DocClose($oDoc)

EndFunc   ;==>_VBAModify

Func _Word_ErrorNotify($iDebug, $sDebugFile = "")
    If $sDebugFile = Default Then $sDebugFile = ""
    If Not IsInt($iDebug) Or $iDebug < -1 Or $iDebug > 4 Then Return SetError(1, 0, 0)
    If $sDebugFile = "" Then $sDebugFile = @ScriptDir & "\Word_Debug.txt"
    Switch $iDebug
        Case -1
            Local $avDebug[4] = [3]
            $avDebug[1] = $__iWord_Debug
            $avDebug[2] = $__sWord_DebugFile
            $avDebug[3] = IsObj($__oWord_Error)
            Return $avDebug
        Case 0
            $__iWord_Debug = 0
            $__sWord_DebugFile = ""
            $__oWord_Error = 0
        Case Else
            $__iWord_Debug = $iDebug
            $__sWord_DebugFile = $sDebugFile
            ; A COM error handler will be initialized only if one does not exist
            If ObjEvent("AutoIt.Error") = "" Then
                $__oWord_Error = ObjEvent("AutoIt.Error", "__Word_ErrorHandler") ; Creates a custom error handler
                If @error <> 0 Then Return SetError(2, @error, 0)
                Return SetError(0, 1, 1)
            ElseIf ObjEvent("AutoIt.Error") = "__Word_ErrorHandler" Then
                Return SetError(0, 0, 1) ; COM error handler already set by a call to this function
            Else
                Return SetError(3, 0, 0) ; COM error handler already set to another function
            EndIf
    EndSwitch
    Return 1
EndFunc   ;==>_Word_ErrorNotify

Func __Word_ErrorHandler()
    Local $sError = "COM Error Encountered in " & @ScriptName & @CRLF & _
            "@AutoItVersion = " & @AutoItVersion & @CRLF & _
            "@AutoItX64 = " & @AutoItX64 & @CRLF & _
            "@Compiled = " & @Compiled & @CRLF & _
            "@OSArch = " & @OSArch & @CRLF & _
            "@OSVersion = " & @OSVersion & @CRLF & _
            "Scriptline = " & $__oWord_Error.Scriptline & @CRLF & _
            "NumberHex = 0x" & Hex($__oWord_Error.Number, 8) & @CRLF & _
            "Number = " & $__oWord_Error.Number & @CRLF & _
            "WinDescription = " & StringStripWS($__oWord_Error.WinDescription, $STR_STRIPTRAILING) & @CRLF & _
            "Description = " & StringStripWS($__oWord_Error.Description, $STR_STRIPTRAILING) & @CRLF & _
            "Source = " & $__oWord_Error.Source & @CRLF & _
            "HelpFile = " & $__oWord_Error.HelpFile & @CRLF & _
            "HelpContext = " & $__oWord_Error.HelpContext & @CRLF & _
            "LastDllError = " & $__oWord_Error.LastDllError
    If $__iWord_Debug > 0 Then
        If $__iWord_Debug = 1 Then ConsoleWrite($sError & @CRLF & "========================================================" & @CRLF)
        If $__iWord_Debug = 2 Then MsgBox($MB_ICONERROR, "Word - Debug Info", $sError)
        If $__iWord_Debug = 3 Then FileWrite($__sWord_DebugFile, @YEAR & "." & @MON & "." & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC & " " & @CRLF & _
                "-------------------" & @CRLF & $sError & @CRLF & "========================================================" & @CRLF)
    EndIf
EndFunc   ;==>__Word_ErrorHandler

#include <File.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <Word.au3>
#include <WordConstants.au3>
 ; https://autoit.de/thread/87817-microsoft-word-suche-und-ersetze-text-in-den-inhalten-der-vba-progammierung-gel%C3%B6/?postID=708429#post708429

;~ #DIESE ROUTINE WIRD ÜBER PARAMETER AUFGERUFEN


Opt("MustDeclareVars", 1)

Local $sSearch_1 = $CmdLine[1]
Local $sSearch_2 = $CmdLine[2]

global $aTags [1]
global $col


;~ File mit den Suchkriterien
global $file_s = "f_search.txt"
_read_file($file_s,1)

;~ File mit den Replace-Strings
global $file_r = $sSearch_2 & ".txt"
_read_file($file_r,2)



Global $sExtension = ".docx" ; Verarbeite nur MS-Word Dokument ohne Macros.
Global $sTemplate = _FileListToArrayRec(@ScriptDir, $sSearch_1 & $sExtension, $FLTAR_FILES, $FLTAR_RECUR, $FLTAR_SORT, $FLTAR_FULLPATH) ; Auflistung der rekursiv zu verarbeitenden MS-Word Dateien
Global $iTotalProjectCount = 0, $iTotalComponentCount = 0, $iTotalReplacementCount = 0


For $i = 1 To $sTemplate[0] ; rekursives Ermitteln der zu verarbeitenden Dateien
    _Main($sTemplate[$i])
Next


;Funktion zum Einlesen der Textefiles in Arrays
Func _read_file($file_x,$col )
FileOpen($file_x, 0)

ReDim $aTags[_FileCountLines($file_x) + 1] [$col]

For $i = 1 To _FileCountLines($file_x)
    $aTags [$i-1][$col-1] = FileReadLine($file_x, $i)
Next
return $aTags
FileClose($file_x)
EndFunc


Func _Main($sTemplate)

    Local $oWord = _Word_Create()
    If @error Then Return SetError(1, 0, MsgBox(16, '_Word_Open', '@error: ' & @error) * 0)
    If Not IsObj($oWord) Then Return SetError(1, 1, MsgBox(16, '_Word_DocOpen', '$oWord is not an Obj') * 0)

    Local $oWordDoc = _Word_DocOpen($oWord, $sTemplate)
    If @error Then Return SetError(2, 0, MsgBox(16, '_Word_DocOpen', '@error: ' & @error) * 0)
    If Not IsObj($oWordDoc) Then Return SetError(2, 0, MsgBox(16, '_Word_DocOpen', '$oWordDoc is not an Obj') * 0)

    For $j = 0 To UBound($aTags, 1) - 1
        _Word_DocFindReplace($oWordDoc, $aTags[$j][0], $aTags[$j][1], Default, -1)
    Next
    consolewrite(@ScriptDir&@CRLF)
    Local $sFileName = @ScriptDir & "\"&$sSearch_1&"-"&$sSearch_2 &".pdf"
    _Word_DocExport($oWordDoc, $sFileName, Default, $wdExportCurrentPage)

    _Word_DocClose($oWordDoc, false) ; speichern nicht vergessen
    If @error Then Return SetError(3, 0, MsgBox(16, '_Word_DocClose', '@error: ' & @error) * 0)

    _Word_Quit($oWord)
    If @error Then Return SetError(4, 0, MsgBox(16, '_Word_Quit', '@error: ' & @error) * 0)

    Return SetError(0, 0, 1)

EndFunc   ;==>_Main