Background Bild und GUI Elemente

casi4712

Hallo allerseits,

ich habe mal eine kleine Frage. Mir ist jetzt schon des öfteren aufgefallen, dass es bei der Verwendung von Hintergrundbildern, die via Fileinstall installiert werden zu Bildfehlern kommt. Dass sieht dann zB so aus, dass bspw. bei comboboxen zunächst nur das innere weisse dargestellt wird, machchmal ist sogar eine vertikale Einschnürung der Box zu sehen, auch der Arrow ist nicht da. Erst wenn mann mit der Maus über das Element streift, ist die Box dann vollständig zu sehen. Dass schaut natürlich ziemlich blöd aus, kennt jemand den Effekt? Ich habe es mit jpg und nmit bmp versucht

lg und schöne Restwoche noch

**Oscar**

Zitat aus der Hilfe: "If a picture is set as a background picture the other controls will overlap, so it is important to disable the pic control: GUICtrlSetState(-1, $GUI_DISABLE)."

casi4712

jo, danke Dir, gelesen hatte ich das auch schon, aber es funktioniert bloss nicht

AutoIt

Func _createButtons()
 GUICtrlSetState(-1, $GUI_DISABLE)


global $combo1 = GUICtrlCreateCombo ("Scripte", 300, 557, 150, 120)
global $btnStart = GUICtrlCreateButton("🟥", 450, 557, 23, 23)
Local $aTest[5][4] = [[4, 0], ["Key One", "V1"], ["Key Two", "V2"], ["Key three", "V3"], ["Key four", "V4"]]
Local $sTest = ""

;Inhalt Combobox
  For $i = 1 To $aTest[0][0]
    $sTest &= "|" & $aTest[$i][0]
  Next
    GUICtrlSetData($Combo1, $sTest)



EndFunc

Alles anzeigen

**Moombas**

Du solltest dich ein wenig mit GUI und der beschäftigen.

Schreib Zeile 2 mal hinter die Zeile, wo das Hintergrundbild festegelegt wird oder setze anstatt der -1 das entsprechende Handle ein.

**Oscar**

Zitat von casi4712

jo, danke Dir, gelesen hatte ich das auch schon, aber es funktioniert bloss nicht

Poste bitte lauffähige Beispiele!

casi4712

Danke noch mal, also ich habs jetzt in 4 versionen gestestet, einmal direkt danach mit -1 und ein mal mit dem Handl $hGui jeweils bei der Button Definition und hinter dem Bildaufruf. Es bleibt immer der selbe Effekt.

AutoIt

; includes ---------------------------------------------------------------------
#include-once

#include "GUIBkImage.au3"
#include "Services.au3"
#include <GDIPlus.au3>
#include <GuiCtrlSetOnHover_UDF.au3>
#include <StaticConstants.au3>
#include <String.au3>
#include <WinApi.au3>
#include <MsgBoxConstants.au3>
#include <ButtonConstants.au3>
#include <StringConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <date.au3>
#include <EditConstants.au3>
#include <Array.au3>
#include <Constants.au3>
#include <FontConstants.au3>
#include <WinAPIGdiDC.au3>
#include <WinAPIGdiInternals.au3>
#include <WinAPIHObj.au3>
#include <WinAPISysInternals.au3>
#include <ComboConstants.au3>
FileInstall("C:\Users\user\Pictures\scr09082022-084252.bmp", "C:\Windows\Temp\hg.bmp", 1)

; opt --------------------------------------------------------------------------
Opt('MustDeclareVars', 1)


;declaration ------------------------------------------------------------------
;GUI Variables
Global $ActiveCheck, $result
Global $ARRAY_COLOR_TOP_MIN[3] = [36, 65, 142]
Global $ARRAY_COLOR_TOP_MAX[3] = [11, 42, 122]
Global $RBOX_EVENT_CLOSE  = 1
Global $ROUNDES = 20, $LastHwnd = 0
Global $LastHwnd
Global $GUIBKCOLOR = 0x738599
Global $SubBack = 0xEAF0E2


; processing ---------------------------------------------------------------------------------------------------------------------------------------------------

Global $hGui = RBoxCreate("Integrator 4 Release 076", 840, 625)

;FunctionCalls---------------------------------------------------------------------------------------------------------------------------------------------------

_createButtons()
;_createLabels()

;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

;------------------------------------------------------------------------------------------------------------------------------------------------
While True
    CheckX($hGui, $RBOX_EVENT_CLOSE, "GuiCtrlSetColor(" & $RBOX_EVENT_CLOSE & ",0xA3A3A3)", "GuiCtrlSetColor(" & $RBOX_EVENT_CLOSE & ",0x555555)")
   local $gMsg = GUIGetMsg()
    Switch $gMsg

        Case $GUI_EVENT_CLOSE, $RBOX_EVENT_CLOSE
            GUIDelete($hGui)

        Case $Combo1 ; Combo fires <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            GUICtrlSetState($btnStart, $GUI_ENABLE) ; Button enabled <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

        Case $btnStart
          IF GUICtrlRead($combo1) = "key one" Then _fu1()
          IF GUICtrlRead($combo1) = "key two" Then _fu2()
          
    EndSwitch
WEnd
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------



;BUTTONS----------------------------------------------------------------------------------------------------------------------------------------------------------
Func _createButtons()
GUICtrlSetState($hgui, $GUI_DISABLE)

global $combo1 = GUICtrlCreateCombo ("Scripte", 300, 557, 150, 120)
global $btnStart = GUICtrlCreateButton("🟥", 450, 557, 23, 23)
Local $aTest[5][4] = [[4, 0], ["Key One", "V1"], ["Key Two", "V2"], ["Key three", "V3"], ["Key four", "V4"]]
Local $sTest = ""

;Inhalt Combobox
  For $i = 1 To $aTest[0][0]
    $sTest &= "|" & $aTest[$i][0]
  Next
    GUICtrlSetData($Combo1, $sTest)

EndFunc
;----------------------------------------------------------------------------------------------------------------------------------------------------------------



;GUI STYLE--------------------------------------------------------------------------------------------------------------------------------------------------------
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func RBoxCreate($Title, $width, $height, $left = -1, $top = -1, $show = 1)
    Local $GUI = GUICreate($Title, $width, $height, $left, $top, $WS_POPUP)
    
    GUICtrlCreatePic('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660)
    ;GUICtrlSetState(-1, $GUI_DISABLE)
    
     GUICtrlSetState(-1, $GUI_DISABLE)
    GUISetBkColor($GUIBKCOLOR, $GUI)
     _GuiRoundCorners($GUI,0,0,$ROUNDES,$ROUNDES)
    $RBOX_EVENT_CLOSE = GUICtrlCreateLabel('X', $width - 20, 3, 25, 25)
    GUICtrlSetCursor($RBOX_EVENT_CLOSE, 0)
    GUICtrlSetBkColor($RBOX_EVENT_CLOSE, -2)
    GUICtrlSetFont($RBOX_EVENT_CLOSE, 15, 800)
    GUICtrlSetColor($RBOX_EVENT_CLOSE, 0x555555)

    $Title &= " "
    Local $hTitle = GUICtrlCreateLabel($Title, 0, 0, $width - 20, 26, $SS_CENTER, $GUI_WS_EX_PARENTDRAG)
    GUICtrlSetFont($hTitle, 17, 400, 0, "Consolas")
    GUICtrlSetBkColor($hTitle, -2)
    Local $Graphic = GUICtrlCreateGraphic(0, 0, $width, 25)
    GUICtrlSetState($Graphic, $Gui_DISABLE)
    If $show = 1 Then GUISetState(@SW_SHOW, $GUI)

    Return $GUI
EndFunc



Func CheckX($hGui, $CtrlID, $sCMD, $eCMD)
    Local $cGui = GUIGetCursorInfo($hGui)
    If Not IsArray($cGui) Then
        Return 0
    EndIf
      If $LastHwnd <> $cGui[4] And $cGui[4] = $CtrlID Then Return Execute($sCMD) + Assign("LastHwnd", $cGui[4])
      If $LastHwnd <> $cGui[4] Then Return Execute($eCMD) + Assign("LastHwnd", $cGui[4])
EndFunc
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
    Dim $pos, $ret, $ret2
    $pos = WinGetPos($h_win)
    $ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3, "long", $i_y3)
        If $ret[0] Then
            $ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
        If $ret2[0] Then
        Return 1
        Else
           Return 0
        EndIf
        Else
           Return 0
        EndIf
EndFunc

Alles anzeigen

Einen schönen Tag noch

lg

**Moombas**

Hmm, kann deinen Fehler nachvollziehen.

Ich konnte es so beheben:

1. Eine Variable für das Handle vom Hintergrund Global setzen. Z.B.: Global $BG (Zeile 34)

2. Der Variable das Handle vom Hintergrund zuweisen: $BG = GUICtrlCreatePic('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660) (Zeile 102)

3. Nach dem _createbuttons bzw. _createLabels foldendes ausführen: GUICtrlSetImage($BG, 'C:\Windows\Temp\hg.bmp') (Zeile52)

Das Ganze funktionierte dann auch ohne GUICtrlSetState(-1, $GUI_DISABLE) aber schaden tut es sicherlich nicht.

**Moombas**

Weitere Tipps:

1. Brauchst du Variableninhalte Global, definiere sie Global und nutze/ändere sie in der Funktion. Idealerweise keine Variablen in einer Funktion Global definieren.

2. kein Dim verwenden, besser ist Local bzw. Global

3. Wenn du schon globale Konstanten definierst (Zeile 34 - 41), setze sie auch auf Global Const, damit sie nicht versehentlich geändert werden können.

casi4712

So, erst mal recht lieben Dank Moombas für die tattkräfrige Unterstützung. Ich habe deine Vorschläge entsprechend eiingarbeitet, er bemeckert aber aus irgend einem Grunde eine angeblich fehlende Klammer,, wahrscheinlich bin blind, daber sewhe da keine Klammer die fehlt. Das ganze schaut jetzt so aus:

AutoIt

#include-once

#include "GUIBkImage.au3"
#include "Services.au3"
#include <GDIPlus.au3>
#include <GuiCtrlSetOnHover_UDF.au3>
#include <StaticConstants.au3>
#include <String.au3>
#include <WinApi.au3>
#include <MsgBoxConstants.au3>
#include <ButtonConstants.au3>
#include <StringConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <date.au3>
#include <EditConstants.au3>
#include <Array.au3>
#include <Constants.au3>
#include <FontConstants.au3>
#include <WinAPIGdiDC.au3>
#include <WinAPIGdiInternals.au3>
#include <WinAPIHObj.au3>
#include <WinAPISysInternals.au3>
#include <ComboConstants.au3>
FileInstall("C:\Users\user\Pictures\scr09082022-084252.bmp", "C:\Windows\Temp\hg.bmp", 1)

; opt --------------------------------------------------------------------------
Opt('MustDeclareVars', 1)


;declaration ------------------------------------------------------------------
;GUI Variables
Global $BG
Global $ActiveCheck, $result
Global $ARRAY_COLOR_TOP_MIN[3] = [36, 65, 142]
Global $ARRAY_COLOR_TOP_MAX[3] = [11, 42, 122]
Global $RBOX_EVENT_CLOSE  = 1
Global $ROUNDES = 20, $LastHwnd = 0
Global $LastHwnd
Global $GUIBKCOLOR = 0x738599
Global $SubBack = 0xEAF0E2


; processing ---------------------------------------------------------------------------------------------------------------------------------------------------

Global $hGui = RBoxCreate("Integrator 4 Release 076", 840, 625)

;FunctionCalls---------------------------------------------------------------------------------------------------------------------------------------------------

_createButtons()
;_createLabels()
GUICtrlSetImage($BG, 'C:\Windows\Temp\hg.bmp')
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

;------------------------------------------------------------------------------------------------------------------------------------------------
While True
    CheckX($hGui, $RBOX_EVENT_CLOSE, "GuiCtrlSetColor(" & $RBOX_EVENT_CLOSE & ",0xA3A3A3)", "GuiCtrlSetColor(" & $RBOX_EVENT_CLOSE & ",0x555555)")
   local $gMsg = GUIGetMsg()
    Switch $gMsg

        Case $GUI_EVENT_CLOSE, $RBOX_EVENT_CLOSE
            GUIDelete($hGui)

        Case $Combo1 ; Combo fires <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
            GUICtrlSetState($btnStart, $GUI_ENABLE) ; Button enabled <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

        Case $btnStart
          IF GUICtrlRead($combo1) = "key one" Then _fu1()
          IF GUICtrlRead($combo1) = "key two" Then _fu2()

    EndSwitch
WEnd
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------



;BUTTONS----------------------------------------------------------------------------------------------------------------------------------------------------------
Func _createButtons()
GUICtrlSetState($hgui, $GUI_DISABLE)

global $combo1 = GUICtrlCreateCombo ("Scripte", 300, 557, 150, 120)
global $btnStart = GUICtrlCreateButton("🟥", 450, 557, 23, 23)
Local $aTest[5][4] = [[4, 0], ["Key One", "V1"], ["Key Two", "V2"], ["Key three", "V3"], ["Key four", "V4"]]
Local $sTest = ""

;Inhalt Combobox
  For $i = 1 To $aTest[0][0]
    $sTest &= "|" & $aTest[$i][0]
  Next
    GUICtrlSetData($Combo1, $sTest)

EndFunc
;----------------------------------------------------------------------------------------------------------------------------------------------------------------



;GUI STYLE--------------------------------------------------------------------------------------------------------------------------------------------------------
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func RBoxCreate($Title, $width, $height, $left = -1, $top = -1, $show = 1)
    Local $GUI = GUICreate($Title, $width, $height, $left, $top, $WS_POPUP)

$BG = ('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660)
    GUICtrlCreatePic ($BG)
    ;GUICtrlSetState(-1, $GUI_DISABLE)

     GUICtrlSetState(-1, $GUI_DISABLE)
    GUISetBkColor($GUIBKCOLOR, $GUI)
     _GuiRoundCorners($GUI,0,0,$ROUNDES,$ROUNDES)
    $RBOX_EVENT_CLOSE = GUICtrlCreateLabel('X', $width - 20, 3, 25, 25)
    GUICtrlSetCursor($RBOX_EVENT_CLOSE, 0)
    GUICtrlSetBkColor($RBOX_EVENT_CLOSE, -2)
    GUICtrlSetFont($RBOX_EVENT_CLOSE, 15, 800)
    GUICtrlSetColor($RBOX_EVENT_CLOSE, 0x555555)

    $Title &= " "
    Local $hTitle = GUICtrlCreateLabel($Title, 0, 0, $width - 20, 26, $SS_CENTER, $GUI_WS_EX_PARENTDRAG)
    GUICtrlSetFont($hTitle, 17, 400, 0, "Consolas")
    GUICtrlSetBkColor($hTitle, -2)
    Local $Graphic = GUICtrlCreateGraphic(0, 0, $width, 25)
    GUICtrlSetState($Graphic, $Gui_DISABLE)
    If $show = 1 Then GUISetState(@SW_SHOW, $GUI)

    Return $GUI
EndFunc



Func CheckX($hGui, $CtrlID, $sCMD, $eCMD)
    Local $cGui = GUIGetCursorInfo($hGui)
    If Not IsArray($cGui) Then
        Return 0
    EndIf
      If $LastHwnd <> $cGui[4] And $cGui[4] = $CtrlID Then Return Execute($sCMD) + Assign("LastHwnd", $cGui[4])
      If $LastHwnd <> $cGui[4] Then Return Execute($eCMD) + Assign("LastHwnd", $cGui[4])
EndFunc
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
    Dim $pos, $ret, $ret2
    $pos = WinGetPos($h_win)
    $ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3, "long", $i_y3)
        If $ret[0] Then
            $ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
        If $ret2[0] Then
        Return 1
        Else
           Return 0
        EndIf
        Else
           Return 0
        EndIf
EndFunc

Alles anzeigen

lg und schönen Sonntag noch

**Bitnugger**

Zitat von casi4712

er bemeckert aber aus irgend einem Grunde eine angeblich fehlende Klammer,,

Wie Oscar dir schon angeraten hat: Poste bitte lauffähige Beispiele!

Andernfalls bürdest du den freiwilligen Helfern unnötige Arbeit auf, die wohl kaum einer leisten will. Dazu gehören importierte UDFs und sonstige benutzte Funktionen bzw. Variablen oder Daten.

Folgendes fehlt:

GUIBkImage.au3, Services.au3, GuiCtrlSetOnHover_UDF.au3, _fu1(), _fu2()

und die hier verwendeten *.bmp...

FileInstall("C:\Users\user\Pictures\scr09082022-084252.bmp", "C:\Windows\Temp\hg.bmp", 1)

casi4712

Hallo,

das lauffähige Beispiel hatte ich doch gepostet, ich habe es doch auch entsprechend den Vorschlägen von Mombass gepostet! Da er ja gesagt hatte, er konnte das Problem nachvollziehen, kann ich nun Deine Einlassung nicht ganz nachvollziehen. Soll ich den Inhalt von den UDFs posten, meinst Du das? Oder das Hintergrundbild? Ich hatte es mit meheren Bildern und Formaten probiert,

lg

**Bitnugger**

Zitat von casi4712

AutoIt

$BG = ('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660)
    GUICtrlCreatePic ($BG)

Hust... was soll dass denn werden?

So macht es Sinn:

$BG = GUICtrlCreatePic('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660)

Zitat von casi4712
AutoIt
global $combo1 = GUICtrlCreateCombo ("Scripte", 300, 557, 150, 120)
global $btnStart = GUICtrlCreateButton("🟥", 450, 557, 23, 23)
Die Deklarationen von globalen Variablen gehören nicht in eine Funktion!

**Musashi**

Zitat von casi4712

... kann Deine Einlassung nicht ganz nachvollziehen. Soll ich den Inhalt von den UDFs posten, meinst Du das? Oder das Hintergrundbild? Ich hatte es mit mehreren Bildern und Formaten probiert,

Ja !

Packe die von Bitnugger genannten Elemente (Fremd-UDF's & Grafik etc.) in eine .zip-Datei und stelle sie uns zur Verfügung.

**Bitnugger**

Zitat von casi4712

das lauffähige Beispiel hatte ich doch gepostet, ich habe es doch auch entsprechend den Vorschlägen von Mombass gepostet! Da er ja gesagt hatte, er konnte das Problem nachvollziehen, kann ich nun Deine Einlassung nicht ganz nachvollziehen. Soll ich den Inhalt von den UDFs posten, meinst Du das? Oder das Hintergrundbild? Ich hatte es mit meheren Bildern und Formaten probiert,

...aber es hat nicht funktioniert.

Hm, ja, das ist dann natürlich schwierig bis unmöglich für dich und auch nicht dein Vergehen, wenn das Forum Zicken wegen zu großer Dateianhänge macht.

Solange Gun-Food das nicht gefixt hat, geht das wohl nicht so, wie Musashi es empfohlen hat. Bis dahin kannst du als Workaround einfach den Inhalt der UDFs posten; aber setzte sie in Code-Tags! Mit Bildern ist es schwieriger... verkleinere sie einfach, damit der Upload klappt, oder verwende Bilder, die mit AutoIt installiert wurden, z.B.: "c:\Program Files (x86)\AutoIt3\Examples\Helpfile\Extras\Compass.bmp"

casi4712

okidoki, dann fehlte das GUICtrlCreatePic, hatte mich schon gwundert. Jetzt schauts sauber aus.

Dann bedanke ich mich noch mal recht herzlich bei euch

lg und schöne Feiertage noch

**Bitnugger**

Zitat von casi4712

GUIDelete($hGui)

Nach dieser Zeile muss ein Exit folgen... denn ohne GUI gibt es auch keine Msg und dein Script funktioniert somit nicht mehr korrekt.

Zitat von casi4712

local $gMsg = GUIGetMsg()

Außerhalb einer Funktion sind alle Variablen Global und es ist dabei völlig egal, ob du sie mit Local oder Global deklarierst!

Zudem sollte die Deklaration besser vor dem While stehen. In deinem Fall ist die Variable aber eh überflüssig, weil du sie ja lediglich einmalig für Switch benötigst... da kannst du es besser so machen:

Switch GUIGetMsg()

**Moombas**

Zitat von Bitnugger

Hust... was soll dass denn werden?
So macht es Sinn:
$BG = GUICtrlCreatePic('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660)

Das muss ich zu 50% auf meine Kappe nehmen. In meinem Beispiel in Post #7 hatte ich beim Copy/Paste einfügen seiner Werte das bereits vorhandene GUICtrlCreatePic überkopiert, was bei ihm scheinbar für verwirrung sorgte. Das habe ich jetzt natürlich angepasst.

casi4712

okidoki, nicht in die Haare kriegen hier in meinem Post lach,, ok dann weiss ich erst mal Bescheid.

Mir ist noch ein ähnlicher Effekt aufgefallen, deswegen zeig ich dass gleich mal hier, denke passt hier gut rein. Bei einer Drive Abfrage soll nur ein Text erscheinen, wenn der Schwellwert unterschritten ist. Ich habe die Set Zeile für den Fall, das dies nicht der Fall ist transparent geschaltet, trotzdem kommt beim Aufruf der Adlib Funktion immer ein störender schwarzer Balken. Dieser Effekt entsteht wiederum nur mit einem Hintegrund. Leider konnte ich diesen Effekt mit der obigen Methode nicht beseitigen. Die AdlibRegister Zeit ist hier sehr kurz eingestellt, nur um diesen Effekt zu verdeutlichen.

AutoIt

; includes ---------------------------------------------------------------------
#include-once
#include "GUIBkImage.au3"
#include <GDIPlus.au3>
#include <GuiCtrlSetOnHover_UDF.au3>
#include <StaticConstants.au3>
#include <String.au3>
#include <WinApi.au3>
#include <MsgBoxConstants.au3>
#include <ButtonConstants.au3>
#include <StringConstants.au3>
#include <GUIConstantsEx.au3>
FileInstall("C:\Users\Riegert\Pictures\TufaSunset-1-2.bmp", "C:\Windows\Temp\hg.bmp", 1)

; opt --------------------------------------------------------------------------
Opt('MustDeclareVars', 1)
;Opt("TrayAutoPause", 0)

;declaration ------------------------------------------------------------------
;GUI Variables
Global $ActiveCheck, $result
Global $ARRAY_COLOR_TOP_MIN[3] = [36, 65, 142]
Global $ARRAY_COLOR_TOP_MAX[3] = [11, 42, 122]
Global $RBOX_EVENT_CLOSE  = 1
Global $ROUNDES = 20, $LastHwnd = 0
Global $LastHwnd
Global $GUIBKCOLOR = 0x738599
Global $SubBack = 0xEAF0E2
Global $BG
Global $SW = 20
global $var_system_drive = StringLeft(@WindowsDir, 2); SystemDrive auslesen
Global Const $drive = StringLeft( $var_system_drive, 3)
global $iFreeSpace = ""
global $fslabel = ""
global $LabelSpace, $labelTemp, $temp

;AdLibRegistering--------------------------------------------------------------------------------------------------------------------------------------------
AdlibRegister('_Testspace', 100)



; processing ---------------------------------------------------------------------------------------------------------------------------------------------------
Global $hGui = RBoxCreate("Integrator 4 Release 076", 840, 625)
_createLabels()
;GUICtrlSetImage($BG, 'C:\Windows\Temp\hg.bmp')
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

;Main Logic-------------------------------------------------------------------------------------------------------------------------------------------------------
While True
    CheckX($hGui, $RBOX_EVENT_CLOSE, "GuiCtrlSetColor(" & $RBOX_EVENT_CLOSE & ",0xA3A3A3)", "GuiCtrlSetColor(" & $RBOX_EVENT_CLOSE & ",0x555555)")

   local $gMsg = GUIGetMsg()
    Switch $gMsg

        Case $GUI_EVENT_CLOSE, $RBOX_EVENT_CLOSE
            GUIDelete($hGui)
            AdlibUnRegister('_Testspace')
            Exit
    EndSwitch
WEnd

;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func _createLabels()
 GUICtrlSetState($hgui, $GUI_DISABLE)
    
    $labelSpace = GUICtrlCreateLabel($FSlabel, 10, 530, 350, 20)
      GUICtrlSetColor(-1, 0xF00404) ; red
      GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
      GUICtrlSetFont(-1, 10, 100) ; bold
EndFunc
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func _Testspace()
global $fslabel = ""
Global $free = DriveSpaceFree($drive) / 1024
Local $rFree = Round($free, 2)

    if $rfree < $SW Then
        GUICtrlSetData($LabelSpace, "freier Speicher auf SystemDrive wird knapp!: ( " & $rfree & "GB)")
    else
        GUICtrlSetData($LabelSpace, "")
    endif
EndFunc
;--------------------------------------------------------------------------------------------------------------------------------------------------------------------




;GUI STYLE--------------------------------------------------------------------------------------------------------------------------------------------------------
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func RBoxCreate($Title, $width, $height, $left = -1, $top = -1, $show = 1)
    Local $GUI = GUICreate($Title, $width, $height, $left, $top, $WS_POPUP)

$BG = GUICtrlCreatePic('C:\Windows\Temp\hg.bmp', 0, 25, 920, 660)
 GUICtrlCreatePic ( $BG, 0, 25, 920, 660 )
    ;GUICtrlSetState($hGUI, $GUI_DISABLE)

     GUICtrlSetState(-1, $GUI_DISABLE)
    GUISetBkColor($GUIBKCOLOR, $GUI)
     _GuiRoundCorners($GUI,0,0,$ROUNDES,$ROUNDES)
    $RBOX_EVENT_CLOSE = GUICtrlCreateLabel('X', $width - 20, 3, 25, 25)
    GUICtrlSetCursor($RBOX_EVENT_CLOSE, 0)
    GUICtrlSetBkColor($RBOX_EVENT_CLOSE, -2)
    GUICtrlSetFont($RBOX_EVENT_CLOSE, 15, 800)
    GUICtrlSetColor($RBOX_EVENT_CLOSE, 0x555555)

    $Title &= " "
    Local $hTitle = GUICtrlCreateLabel($Title, 0, 0, $width - 20, 26, $SS_CENTER, $GUI_WS_EX_PARENTDRAG)
    GUICtrlSetFont($hTitle, 17, 400, 0, "Consolas")
    GUICtrlSetBkColor($hTitle, -2)
    Local $Graphic = GUICtrlCreateGraphic(0, 0, $width, 25)
    GUICtrlSetState($Graphic, $Gui_DISABLE)
    If $show = 1 Then GUISetState(@SW_SHOW, $GUI)

    Return $GUI
EndFunc



Func CheckX($hGui, $CtrlID, $sCMD, $eCMD)
    Local $cGui = GUIGetCursorInfo($hGui)
    If Not IsArray($cGui) Then
        Return 0
    EndIf
      If $LastHwnd <> $cGui[4] And $cGui[4] = $CtrlID Then Return Execute($sCMD) + Assign("LastHwnd", $cGui[4])
      If $LastHwnd <> $cGui[4] Then Return Execute($eCMD) + Assign("LastHwnd", $cGui[4])
EndFunc
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
    Dim $pos, $ret, $ret2
    $pos = WinGetPos($h_win)
    $ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3, "long", $i_y3)
        If $ret[0] Then
            $ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
        If $ret2[0] Then
        Return 1
        Else
           Return 0
        EndIf
        Else
           Return 0
        EndIf
EndFunc

;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func GradientFill($im, $x1, $y1, $width, $height, $left_color, $right_color)
 Local $color0=($left_color[0]-$right_color[0])/$height, $color1=($left_color[1]-$right_color[1])/$height
 local $color2=($left_color[2]-$right_color[2])/$height
   For $Y=0 to $height-1
    local $red=$left_color[0]-floor($Y*$color0)
    local $green=$left_color[1]-floor($Y*$color1)
    local $blue=$left_color[2]-floor($Y*$color2)
    local $col = Dec(Hex($blue,2) & Hex($green,2) & Hex($red,2))
      GUICtrlSetGraphic($im,$GUI_GR_COLOR, $col)
      GUICtrlSetGraphic($im,$GUI_GR_MOVE,0,$Y)
      GUICtrlSetGraphic($im,$GUI_GR_LINE,$width,$Y)
    Next
      GUICtrlSetGraphic($im,$GUI_GR_COLOR, 0x000000)
      GUICtrlSetGraphic($im,$GUI_GR_MOVE,0,$height)
      GUICtrlSetGraphic($im,$GUI_GR_LINE,$width,$height)
      GUICtrlSetGraphic($im,$GUI_GR_REFRESH)
EndFunc
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Alles anzeigen

**Moombas**

Kannst du das Label nicht einfach ausblenden, anstatt es transparent zu machen oder noch einfacher (wohl aber eher eine Notlösung): die Daten '' (leer) und Width/Heigth auf 0 setzen, wenn es nicht angezeigt werden soll, der Weg andersrum wenn es angezeigt werden soll?

**Bitnugger**

Zitat von casi4712

Mir ist noch ein ähnlicher Effekt aufgefallen,

den du sebst verursachst... du hast da ein paar fette Fehler drin... hier mal eine "leicht" korrigierte Version...

PS: GuiCtrlSetOnHover_UDF.au3 ist bei mir GuiCtrlOnHover.au3

AutoIt

;-- TIME_STAMP   2022-10-04 20:09:25

#include-once
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <Constants.au3>
#include <EditConstants.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>
#include <StringConstants.au3>
#include <WindowsConstants.au3>

#include <Array.au3>
#include <Date.au3>
#include <GDIPlus.au3>
#include <String.au3>
#include <WinAPIGdiDC.au3>
#include <WinAPIGdiInternals.au3>
#include <WinAPIHObj.au3>
#include <WinAPISysInternals.au3>
#include <WinApi.au3>

#include "GUIBkImage.au3"
#include "Services.au3"
#include <GuiCtrlOnHover.au3>

;~ FileInstall("C:\Users\user\Pictures\scr09082022-084252.bmp", "C:\Windows\Temp\hg.bmp", 1)
;~ FileInstall("F:\Eigene Dateien\Pictures\GIRLS\Girls - Real\Tricia Helfer\Tricia Helfer 03.bmp", "F:\Eigene Dateien\Pictures\GIRLS\Girls - Real\!-Unsortiert\Adriana Slenkaja.bmp", 1)

Opt('MustDeclareVars', 1)
;Opt("TrayAutoPause", 0)

Global $ActiveCheck, $result
Global $ARRAY_COLOR_TOP_MIN[3] = [36, 65, 142]
Global $ARRAY_COLOR_TOP_MAX[3] = [11, 42, 122]
Global $idLbl_Close = 1
Global $ROUNDES = 20, $LastHwnd = 0
Global $LastHwnd
Global $GUIBKCOLOR = 0x738599
Global $SubBack = 0xEAF0E2
Global $idPic
Global $SW = 20 ; GB
Global Const $sSystemDrive = StringLeft(@WindowsDir, 2) ; SystemDrive auslesen
Global $iFreeSpace = 0
Global $idLabelSpace, $labelTemp, $temp
Global $aPics = ['F:\Eigene Dateien\Pictures\GIRLS\Girls - Real\Tricia Helfer\Tricia Helfer 03.bmp', 'F:\Eigene Dateien\Pictures\GIRLS\Girls - Cyber\Kim_02.bmp']

AdlibRegister('_Testspace', 1000)

Global $hGui = RBoxCreate("Integrator 4 Release 076", 840, 625)

While True
    CheckX($hGui, $idLbl_Close, 0xA3A3A3, 0x555555)

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $idLbl_Close
            GUIDelete($hGui)
            AdlibUnRegister('_Testspace')
            Exit
    EndSwitch
WEnd

Func RBoxCreate($sTitle, $width, $height, $left = -1, $top = -1, $show = 1)
    Local $hGUI = GUICreate($sTitle, $width, $height, $left, $top, $WS_POPUP)
    _GuiRoundCorners($hGUI, 0, 0, $ROUNDES, $ROUNDES)

    $idPic = GUICtrlCreatePic($aPics[0], 0, 25, 920, 660)
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUISetBkColor($GUIBKCOLOR, $hGUI)

;~     _createButtons()
;~     _createLabels()

    $idLbl_Close = GUICtrlCreateLabel('X', $width - 20, 3, 25, 25)
    GUICtrlSetCursor($idLbl_Close, 0)
    GUICtrlSetBkColor($idLbl_Close, -2)
    GUICtrlSetFont($idLbl_Close, 15, 800)
    GUICtrlSetColor($idLbl_Close, 0x555555)

    $sTitle &= " "
    Local $idTitle = GUICtrlCreateLabel($sTitle, 0, 0, $width - 20, 26, $SS_CENTER, $GUI_WS_EX_PARENTDRAG) ; "Integrator 4 Release 076 "
    GUICtrlSetFont($idTitle, 17, 400, 0, "Consolas")
    GUICtrlSetBkColor($idTitle, -2)

    $idLabelSpace = GUICtrlCreateLabel('', 5, 600, 370, 20)
    GUICtrlSetColor(-1, 0xF00404)   ; red
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    GUICtrlSetFont(-1, 10, 100)   ; bold

    GUICtrlSetState(GUICtrlCreateGraphic(0, 0, $width, 25), $GUI_DISABLE) ; Wofür soll das gut sein?

    If $show = 1 Then GUISetState(@SW_SHOW, $hGUI)

    Return $hGUI
EndFunc   ;==>RBoxCreate

Func _Testspace()
    ConsoleWrite('_Testspace()' & @CRLF)
    Local $iFree = Round(DriveSpaceFree($sSystemDrive) / 1024, 2)
    If $iFreeSpace <> $iFree Then
        $iFreeSpace = $iFree

        GUICtrlSetData($idLabelSpace, 'Freier Speicher auf SystemDrive:' & ($iFree < $SW ? ' wird knapp!: ' : ' ') & $iFree & ' GB')
    EndIf
EndFunc   ;==>_Testspace

Func CheckX($hGui, $CtrlID, $sCMD, $eCMD)
    Local $aCursorInfo = GUIGetCursorInfo($hGui)
    If @error Then Return 0
    If $LastHwnd <> $aCursorInfo[4] Then
        $LastHwnd = $aCursorInfo[4]
        Return GUICtrlSetColor($idLbl_Close, $aCursorInfo[4] = $CtrlID ? $sCMD : $eCMD)
    EndIf
EndFunc   ;==>CheckX
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
    Dim $pos, $ret
    $pos = WinGetPos($h_win)
    $ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3, "long", $i_y3)
    If $ret[0] Then
        $ret = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
        Return $ret[0] ? 1 : 0
    EndIf
    Return 0
EndFunc   ;==>_GuiRoundCorners

;-----------------------------------------------------------------------------------------------------------------------------------------------------------------
Func GradientFill($im, $x1, $y1, $width, $height, $left_color, $right_color)
    Local $color0 = ($left_color[0] - $right_color[0]) / $height, $color1 = ($left_color[1] - $right_color[1]) / $height
    Local $color2 = ($left_color[2] - $right_color[2]) / $height
    For $Y = 0 To $height - 1
        Local $red = $left_color[0] - Floor($Y * $color0)
        Local $green = $left_color[1] - Floor($Y * $color1)
        Local $blue = $left_color[2] - Floor($Y * $color2)
        Local $col = Dec(Hex($blue, 2) & Hex($green, 2) & Hex($red, 2))
        GUICtrlSetGraphic($im, $GUI_GR_COLOR, $col)
        GUICtrlSetGraphic($im, $GUI_GR_MOVE, 0, $Y)
        GUICtrlSetGraphic($im, $GUI_GR_LINE, $width, $Y)
    Next
    GUICtrlSetGraphic($im, $GUI_GR_COLOR, 0x000000)
    GUICtrlSetGraphic($im, $GUI_GR_MOVE, 0, $height)
    GUICtrlSetGraphic($im, $GUI_GR_LINE, $width, $height)
    GUICtrlSetGraphic($im, $GUI_GR_REFRESH)
EndFunc   ;==>GradientFill
;-----------------------------------------------------------------------------------------------------------------------------------------------------------------

Alles anzeigen