Background Bild und GUI Elemente

casi4712

hi und danke erstmal,

stimmt das mit dem weglassen war sehr effektiv. blinkt nicht mehr wenn Bedingung nicht erfüllt ist.

AutoIt

...
Func _Testspace()
global $fslabel = ""
Global $free = DriveSpaceFree($drive) / 1024
Local $rFree = Round($free, 2)

    if $rfree < $SW Then
        GUICtrlSetData($LabelSpace, "freier Speicher auf SystemDrive wird knapp!: ( " & $rfree & "GB)")
    else
        ;GUICtrlSetData($LabelSpace, "")
    endif
EndFunc

Alles anzeigen

Dafür is der schwarze Balken wieder da, wenn die BEdingung erfült ist und er das Label zeigen soll.

lgund schönen Abend

**Bitnugger**

Zitat von casi4712

Dafür is der schwarze Balken wieder da, wenn die BEdingung erfült ist und er das Label zeigen soll.

Klar, wenn du 10 x pro Sekunde den Text des Labels änderst, dann flackert es... in meinem letzten Script habe ich es so geändert, das nur dann der neue Text (bzw. Zahl) geschrieben wird, wenn er sich geändert hat. Ist dir wohl entgangen...

casi4712

ich hatte Deinen Ansatz auch probiert Bit, ebenfalls das selbe. Ich hatte ja gesagt, die kurze Zeit war nur um es zu verdeutlichen, wenn ich die Zeit höher stelle ist der Effekt aber auch zu sehen. Ist jetzt nicht direkt ein Funktionsfehler, aber schaut halt blöd aus. Ich habe keinen schwatzen Hintegrund für das Lebel gesetzt.

lg

**Bitnugger**

Zitat von casi4712

ich hatte Deinen Ansatz auch probiert Bit, ebenfalls das selbe.

Ich hatte AdlibRegister auf 1000 gesetzt und bei mir ist der Effekt nicht zu sehen... das Label wird bei mir auch nur etwa 1x / Std. geändert.

AutoIt

Func _Testspace()
    Local $iFree = Round(DriveSpaceFree($sSystemDrive) / 1024, 2)
    If $iFreeSpace <> $iFree Then
        ConsoleWrite('_Testspace('&$iFree&' GB)' & @CRLF)
        $iFreeSpace = $iFree
        GUICtrlSetData($idLabelSpace, 'Freier Speicher auf SystemDrive ('&$sSystemDrive&')' & ($iFree < $SW ? ' wird knapp!: ' : ' : ') & $iFree & ' GB')
    EndIf
EndFunc   ;==>_Testspace

Wenn das bei dir viel öfter passiert, dann ändere die Funktion so ab:

AutoIt

;~     If $iFreeSpace <> $iFree Then ; Zwei Stellen hinter dem Komma vergleichen
    If Int($iFreeSpace) <> Int($iFree) Then ; Nur Ganzzahlen vergleichen
;~     If Round($iFreeSpace, 1) <> Round($iFree, 1) Then ; Eine Stelle hinter dem Komma vergleichen

casi4712

okay, danke Dir werde ich ausprobieren

lg und schönen Abend noch

casi4712

HI,

also nun bin ich ein bisl verwirrt, welchje Zeilen muss ich denn nun ersetzen,

Code

  If $iFreeSpace <> $iFree Then ; Zwei Stellen hinter dem Komma vergleichen    If Int($iFre
;~     If Round($iFreeSpace, 1) <> Round($iFree, 1) Then ; Eine Stelle hinter dem Komma ve

Diese beiden Zeilen sind in dem Script nicht vorhanden, ich denke wir reden von 2 verschiednen Scripten

lg und schönes WE noch

**Bitnugger**

Zitat von casi4712

Diese beiden Zeilen sind in dem Script nicht vorhanden

Das bezieht sich natürlich auf die Funktion in Post #24... wobei dein Quote so nicht richtig ist.

Welche Zeile? Eine von diesen hier; welche, ist deine Wahl.

If $iFreeSpace <> $iFree Then ; Zwei Stellen hinter dem Komma vergleichen

If Int($iFreeSpace) <> Int($iFree) Then ; Nur Ganzzahlen vergleichen

If Round($iFreeSpace, 1) <> Round($iFree, 1) Then ; Eine Stelle hinter dem Komma vergleichen

casi4712

Hallo,

ja ich beziehe mich ja auch auf diesen Post, zumidest diese Zeile:

If Round($iFreeSpace, 1) <> Round($iFree, 1) Then ; Eine Stelle hinter dem Komma vergleichen

ist weder in deinem Vorschlag, noch in meinem Post, das hatte mich nur stutzig gemacht;)

Übrigens noch mal zu Deinem freundlcihen Umbau des Scripts, was ist in dieser Form denn nun der konkrete Vorteil, bzw. was hätte ich für Macken in der Ursprungsform erwarten dürfen? Also dass mit meinem Problem lassen wir mal aussen vor, das dieses Problem ja dadurch auch nicht behoben wurde. Will ja schliesslich auch etwas lernen;)

lg und schönen Sonntag noch

**Bitnugger**

Zitat von casi4712

ja ich beziehe mich ja auch auf diesen Post, zumidest diese Zeile:
If Round($iFreeSpace, 1) <> Round($iFree, 1) Then ; Eine Stelle hinter dem Komma vergleichen
ist weder in deinem Vorschlag, noch in meinem Post, das hatte mich nur stutzig gemacht;)

Verstehe dich nicht... die Zeile ist doch in Post #24... und davon reden wir doch, oder?

Es geht doch lediglich darum, das GUICtrlSetData nur dann ausgeführt wird, wenn sich der freie Speicher geändert hat. Wenn das zu oft passiert, flackert das Label. Damit also nicht jede kleine Änderungen erfasst wird, kann man die Abfrage auf zwei oder nur eine Stelle hinter dem Komma begrenzen, oder auch nur die Zahlen vor dem Komma nehmen.

**BugFix**

Noch zum Punkt Aktualisierungsintervall:

100 ms ist der letzte Wert, bei dem noch ohne Flackern aktualisiert werden kann. Aber trotzdem ist das wenig sinnvoll. Du musst ja noch die Zeit hinzurechnen um den Wert wahrnehmen zu können. Wenn Du sehr gut drauf ist, passiert das in weiteren 100 ms, d.h. wirklich lesbar ist die Anzeige erst bei einer Aktualisierung alle 200 ms.

Kannst du in diesem Bsp. mal selbst probieren, ob du bei 100 ms wirklich jeden neuen Wert erfassen kannst.

AutoIt

#include <GUIConstantsEx.au3>

GUICreate('Test Label-Update')
Global $aLabel[6], $aRadio[6]
$aRadio[4] = GUICtrlCreateRadio(' ', 5, 7, 10, 15)
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlCreateLabel('Update: 1 s (1 Hz)', 20, 10, 150)
$aLabel[4] = GUICtrlCreateLabel('', 160, 10, 120, 17)
$aRadio[3] = GUICtrlCreateRadio(' ', 5, 37, 10, 15)
GUICtrlCreateLabel('Update: 0,5 s (2 Hz)', 20, 40, 150)
$aLabel[3] = GUICtrlCreateLabel('', 160, 40, 120, 17)
$aRadio[2] = GUICtrlCreateRadio(' ', 5, 67, 10, 15)
GUICtrlCreateLabel('Update: 0,2 s (5 Hz)', 20, 70, 150)
$aLabel[2] = GUICtrlCreateLabel('', 160, 70, 120, 17)
$aRadio[1] = GUICtrlCreateRadio(' ', 5, 97, 10, 15)
GUICtrlCreateLabel('Update: 0,1 s (10 Hz)', 20, 100, 150)
$aLabel[1] = GUICtrlCreateLabel('', 160, 100, 120, 17)
$aRadio[5] = GUICtrlCreateRadio(' ', 5, 127, 10, 15)
GUICtrlCreateLabel('Update: 0,08 s (12,5 Hz)', 20, 130, 150)
$aLabel[5] = GUICtrlCreateLabel('', 160, 130, 120, 17)
$aRadio[0] = GUICtrlCreateRadio(' ', 5, 157, 10, 15)
GUICtrlCreateLabel('Update: 0,05 s (20 Hz)', 20, 160, 150)
$aLabel[0] = GUICtrlCreateLabel('', 160, 160, 120, 17)

AdlibRegister(_Intervall005, 50)
AdlibRegister(_Intervall008, 80)

GUISetState()
Do
Until GUIGetMsg() = -3

Func _Intervall005()
    Local Static $aSum[][] = [[0,1],[0,2],[0,4],[0,10],[0,20]]
    For $i = 0 To UBound($aSum) -1
        $aSum[$i][0] += 1
        If $aSum[$i][0] = $aSum[$i][1] Then
            $aSum[$i][0] = 0
            If BitAND(GUICtrlRead($aRadio[$i]), $GUI_CHECKED) Then _
                GUICtrlSetData($aLabel[$i], StringFormat('%02d:%02d:%02d,%03d', @HOUR, @MIN, @SEC, @MSEC))
        EndIf
    Next
EndFunc

Func _Intervall008()
    If Not BitAND(GUICtrlRead($aRadio[5]), $GUI_CHECKED) Then Return
    GUICtrlSetData($aLabel[5], StringFormat('%02d:%02d:%02d,%03d', @HOUR, @MIN, @SEC, @MSEC))
EndFunc

Alles anzeigen

Für Anzeigen von Statusmeldungen, die sich an Schwellwerten orientieren in der Art: "OK", "Geht Noch", "Gefahr", ist m.M.n. die Hintergrundfärbung der Label in Grün/Gelb/Rot viel intuitiver als ein Zahlenwert.

casi4712

WIe gesagt, das niedrige Intervall hatte ich nur um es zu verdeutlichen, der schwarze Flackerbalken ist aber in jedem Falle vorhanden, auch bei einem MinutenIntervall. Mich stört es im Prinzip nicht, aber erfahrungsgemäß ist das das erste was den Leuten unangenehm auffält, oft noch vor funktionellen Fehlern. Aber ich gehe halt mal davon aus dass das noch ein Bug von Autoit ist und hoffe mal darauf dass es in der nächsten Version behoben sein wird. Viellen Dank noch mal füpr den Input, werde die Vorschläge bei weiteren Scripten gerne berücksichtigen

Vielen Dank und schöne Restwoche noch

Velted

Zitat von casi4712

Aber ich gehe halt mal davon aus dass das noch ein Bug von Autoit ist und hoffe mal darauf dass es in der nächsten Version behoben sein wird.

Moin,

da irrst Du gewaltig. AutoIt verändert zwar den Inhalt der Controls durch das Senden entsprechender Nachrichten, um die Darstellung auf dem Bildschirm kümmert sich aber das System, in diesem Fall höchstwahrscheinlich der Desktop Window Manager (DWM), zusammen mit den vom System bereitgestellten Fensterprozeduren für die Windows Standardcontrols. Man kann das nur durch das setzen von Styles bzw. Exstyles beeinflussen.

casi4712

Aber an welcher STelle sagt mein Script denn stelle den TextHintergrund, wenn auch nur für ein Flackern, auf schwarz, ich finde nichts.

lg und schöne Woche noch

Velted

Moin,

wenn Du nichts Anderes bestimmst, werden Label-Controls mit der Hintergrundfarbe des Fensters gezeichnet.

Global $GUIBKCOLOR = 0x738599

Das ist zwar kein Schwarz, erweckt aber beim kurzen Flackern einen recht dunklen Eindruck.

Wenn Du den Fensterhintergrund auf Weiß setzt, siehst Du den Unterschied.

Für GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT) muss AutoIt in den Zeichenprozess eingreifen. Wie das geschieht, bleibt bei "Closed Source" ein Geheimnis.

Das Folgende funktioniert hier recht gut bei 10 Hz (100 ms);

AutoIt

#include <ColorConstants.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Dim $sPic = "C:\Windows\Web\Wallpaper\Theme1\img1.jpg" ; <<<<< ggf. ändern
Dim $sTxt = "Das ist der Text in Version "
Dim $iCount = 1
Dim $hGui = GUICreate("Test", 800, 600, -1, -1, -1, $WS_EX_COMPOSITED)
Dim $idLab = GUICtrlCreateLabel($sTxt & $iCount & ".", 0, 290, 800, 20, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetFont(-1, 10, $FW_BOLD)
GUICtrlSetColor(-1, $CLR_WHITE)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
Dim $idPic = GUICtrlCreatePic($sPic, 0, 0, 800, 600) ; <<<<< Das Hintergrundbild muss nachträglich eingefügt werden!!!
GUISetState(@SW_SHOW)
Dim $hStart = TimerInit()
While True
    If GUIGetMsg() = -3 Then Exit
    If TimerDiff($hStart) > 100 Then
        $iCount += 1
        GUICtrlSetData($idLab, $sTxt & $iCount & ".")
        $hStart = TimerInit()
    EndIf
WEnd
Exit

Alles anzeigen