GUI Menü - klickbar machen?

gmmg

Hallo Zusammen,

per GUICtrlCreateMenu habe ich ein Menü (Menü1) und 2 MenüItems (Menü2 / Exit) erzeugt.

Nun möchte ich, dass wenn Menü1 geklickt wird auch der entsprechende Case zweig reagiert.

Die Menü-Item (Menü2 und Exit) Einträge funktionieren ohne Probleme.

Gibt es da eine Lösung?

AutoIt

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$mM1 = GUICtrlCreateMenu("Menü1")

$mM2 = GUICtrlCreateMenuItem("Menü2",-1)
$mExit = GUICtrlCreateMenuItem("Exit",-1)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExit
            Exit
        Case $mM1
            MsgBox(0, "1", "I can be actioned!")
        Case $mM2
            MsgBox(0, "2", "I can be actioned!")
    EndSwitch
WEnd

Alles anzeigen

Hier hatte ich im englischen Forum ein Beispiel gefudnen, allerdings fehlt da die Unterscheidung der Button.

AutoIt

#include <GUIConstantsEx.au3>
#include <array.au3>
#include <winapi.au3>
#include <WindowsConstants.au3>

$GUI = Guicreate("blabla")
$FileMenu = GUICtrlCreateMenu("&Options")

GUIRegisterMsg($WM_INITMENU,"_menuclick")
Guisetstate()
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case 3
      MsgBox (0,"1","" )
    EndSwitch
WEnd

Func _menuclick($hWndGUI, $MsgID, $WParam, $LParam)
    msgbox(0,"2","")
EndFunc

Alles anzeigen

Danke und allen vorab ein schönes Pfingstwochenende

Gruß gmmg

BananaJoe

Wolltest Du es so haben?

Code

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$mMenu = GUICtrlCreateMenu("Menü")

$mM1 = GUICtrlCreateMenuItem("MenüItem1", $mMenu)
$mM2 = GUICtrlCreateMenuItem("MenüItem2", $mMenu)
$mExit = GUICtrlCreateMenuItem("Exit", $mMenu)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExit
            Exit
        Case $mM1
            MsgBox(0, "1", "I can be actioned!")
        Case $mM2
            MsgBox(0, "2", "I can be actioned!")
    EndSwitch
WEnd

Alles anzeigen

**Moombas**

Meinst du so?

AutoIt

Opt('MustDeclareVars', 1)
#include <GUIConstantsEx.au3>

Global Const $hGUI = GUICreate("Test", 500, 500)

Global Const $mM1 = GUICtrlCreateMenu("Menü1")

Global Const $mM2 = GUICtrlCreateMenuItem("Menü2", $mM1)
Global Const $mExit = GUICtrlCreateMenuItem("Exit", $mM1)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExit
            Exit
        Case $mM1
            MsgBox(0, "1", "I can be actioned!")
        Case $mM2
            MsgBox(0, "2", "I can be actioned!")
    EndSwitch
WEnd

Alles anzeigen

Mist BananaJoe war schneller

BananaJoe

Zitat von Moombas

Mist BananaJoe war schneller

Sonst bin immer ich der, der eine Antwort sieht, kurz bevor ich den "Antworten"-Button drücken will und es mir dann schenke ...

**Alina**

Und hier eine kleine dänische KI-Version.

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <MenuConstants.au3>

Global $hGUI, $hMenu, $hMenuItemExit

$hGUI = GUICreate("Menu Eksempel", 300, 200)

$hMenu = GUICtrlCreateMenu("Menu")
$hSubMenu1 = GUICtrlCreateMenu("Undermenu1", $hMenu)
$hMenuItem1_1 = GUICtrlCreateMenuItem("Undermenu1_1", $hSubMenu1)
$hMenuItem1_2 = GUICtrlCreateMenuItem("Undermenu1_2", $hSubMenu1)

$hSubMenu2 = GUICtrlCreateMenu("Undermenu2", $hMenu)
$hMenuItem2_1 = GUICtrlCreateMenuItem("Undermenu2_1", $hSubMenu2)
$hMenuItem2_2 = GUICtrlCreateMenuItem("Undermenu2_2", $hSubMenu2)

$hMenuItemExit = GUICtrlCreateMenuItem("Afslut", $hMenu)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $hMenuItemExit
            ExitLoop
        Case $hMenuItem1_1
            MsgBox($MB_SYSTEMMODAL, "Undermenu1_1", "Undermenu1_1 blev klikket!")
        Case $hMenuItem1_2
            MsgBox($MB_SYSTEMMODAL, "Undermenu1_2", "Undermenu1_2 blev klikket!")
        Case $hMenuItem2_1
            MsgBox($MB_SYSTEMMODAL, "Undermenu2_1", "Undermenu2_1 blev klikket!")
        Case $hMenuItem2_2
            MsgBox($MB_SYSTEMMODAL, "Undermenu2_2", "Undermenu2_2 blev klikket!")
    EndSwitch
WEnd

GUIDelete($hGUI)
Exit

Alles anzeigen

**Kanashius**

Hi, weil ich im moment so gerne mit Maps programmiere würde ich es so machen:

AutoIt

#include <GUIConstantsEx.au3>

Global $mMainGui[]
$mMainGui.iWidth = 300
$mMainGui.iHeight = 200

$mMainGui.hGui = GUICreate("Menu example", $mMainGui.iWidth, $mMainGui.iHeight)

Global $mMenus[]
_addMenuEntry($mMenus, "menu1", "Menü 1")
_addMenuEntry($mMenus, "menu1_1", "Menü 1.1", "menu1", "_menu1_1")
_addMenuEntry($mMenus, "menu1_2", "Menü 1.2", "menu1", "_menu1_2")
_addMenuEntry($mMenus, "menu1_2_1", "Menü 1.2.1", "menu1_2", "_menu1_2_1")
_addMenuEntry($mMenus, "menu1_2_2", "Menü 1.2.2", "menu1_2")
_addMenuEntry($mMenus, "menu2", "Menü 2", -1, "_menu2")
_addMenuEntry($mMenus, "exit", "exit")
_generateMenu($mMainGui.hGui, $mMenus)

GUISetState(@SW_SHOW, $mMainGui.hGui)

Local $arMenuKeys = MapKeys($mMenus), $iMsg
While 1
    $iMsg = GUIGetMsg()
    If $iMsg<>0 Then
        Switch $iMsg
            Case $GUI_EVENT_CLOSE, $mMenus.exit.control
                GUIDelete($mMainGui.hGui)
                Exit
            Case $mMenus.menu1_2_2.control
                MsgBox(64, "Info", "Menu 1.2.2")
            Case Else
                For $i=0 To UBound($arMenuKeys)-1 Step 1
                    If $iMsg = $mMenus[$arMenuKeys[$i]].control And $mMenus[$arMenuKeys[$i]].func<>-1 Then Call($mMenus[$arMenuKeys[$i]].func)
                Next
        EndSwitch
    EndIf
WEnd

Func _menu1()
    MsgBox(64, "Info", "Menu 1")
EndFunc

Func _menu1_1()
    MsgBox(64, "Info", "Menu 1.1")
EndFunc

Func _menu1_2()
    MsgBox(64, "Info", "Menu 1.2")
EndFunc

Func _menu1_2_1()
    MsgBox(64, "Info", "Menu 1.2.1")
EndFunc

Func _menu2()
    MsgBox(64, "Info", "Menu 2")
EndFunc

Func _generateMenu($hGui, ByRef $mMenuMap)
    Local $hOldGui = GUISwitch($hGui)
    Local $arMenuKeys = MapKeys($mMenuMap)
    For $i=0 To UBound($arMenuKeys)-1 Step 1
        Local $mEntry = $mMenuMap[$arMenuKeys[$i]]
        If $mEntry.hasChilds Then
            $mMenuMap[$arMenuKeys[$i]].control = GUICtrlCreateMenu($mEntry.name, $mEntry.parent<>-1?$mMenuMap[$mEntry.parent].control:-1, $mEntry.index)
        Else
            If $mEntry.parent = -1 Then
                $mMenuMap[$arMenuKeys[$i]].control = GUICtrlCreateMenuItem($mEntry.name, -1, $mEntry.index, $mEntry.radio)
            Else
                $mMenuMap[$arMenuKeys[$i]].control = GUICtrlCreateMenuItem($mEntry.name, $mMenuMap[$mEntry.parent].control, $mEntry.index, $mEntry.radio)
            EndIf
        EndIf
    Next
    GUISwitch($hOldGui)
EndFunc

Func _addMenuEntry(ByRef $mMenuMap, $sKey, $sName, $sParentKey = -1, $sFunc = -1, $iEntryIndex = -1, $bRadioItem = False)
    If Not MapExists($mMenuMap, $sKey) Then
        Local $mMap[]
        $mMenuMap[$sKey] = $mMap
    EndIf
    $mMenuMap[$sKey].name = $sName
    $mMenuMap[$sKey].func = $sFunc
    $mMenuMap[$sKey].parent = $sParentKey
    $mMenuMap[$sKey].index = $iEntryIndex
    $mMenuMap[$sKey].radio = $bRadioItem?1:0
    If Not MapExists($mMenuMap[$sKey], "hasChilds") Then $mMenuMap[$sKey].hasChilds = False
    If $sParentKey<>-1 Then
        If Not MapExists($mMenuMap, $sParentKey) Then
            Local $mParentMap[]
            $mMenuMap[$sParentKey] = $mParentMap
        EndIf
        $mMenuMap[$sParentKey].hasChilds = True
    EndIf
EndFunc

Alles anzeigen

Bei der Methode kannst du dir auch aussuchen, ob du alle Menuitems in der Mainloop abarbeiten möchtest, oder ob du eine extra Funktion definieren willst.

Extra Funktionen haben den Vorteil, dass deine Mainloop nicht groß und unübersichtlich wird und eine Funktionalität ohne Probleme im Menü oder über z.B. einen Button im Fenster ausgelöst werden soll.

Würdest du z.B. "Save" im Menü "File" haben mit der Methode "_save" kannst du die auch automatisch alle 10min. aufrufen, über extra Buttons,...

Deshalb arbeite ich gerne mit Funktionen statt sehr großen Mainloops.

Statt _addMenuEntry($mMenus, "menu1", "Menü 1") solltest du natürlich sinnvolle Namen vergeben, wie z.B. _addMenuEntry($mMenus, "file", "File")

gmmg

Moombas, BananaJoe, Alina

Nein, es sollen keine Untermenü's sein.

@Kanashius

das ist genau das was ich suche, nur bissl viel code für die 2 Button

Vielleicht macht es hier Sinn, einfach nur 2 Button zu nehmen.

Danke für euren Input.

Gruß gmmg

Velted

Moin,

ich hätte nicht damit gerechnet, dass $mM1 = GUICtrlCreateMenuItem("Menü1", -1) das Item direkt der Menüleiste zuweist. Das scheint aber nur dann zu funktionieren, wenn die Menüleiste bereits durch einen Aufruf von GUICtrlCreateMenu() erstellt/initialisiert wurde. Nachdem man alle Items hinzugefügt hat, kann man dieses Menü allerdings wieder löschen:

AutoIt

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$mDummy = GUICtrlCreateMenu("")
$mM1 = GUICtrlCreateMenuItem("Menü1", -1)
$mM2 = GUICtrlCreateMenuItem("Menü2", -1)
$mExit = GUICtrlCreateMenuItem("Exit", -1)
GUICtrlDelete($mDummy)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExit
            Exit
        Case $mM1
            MsgBox(0, "1", "I can be actioned!")
        Case $mM2
            MsgBox(0, "2", "I can be actioned!")
    EndSwitch
WEnd

Alles anzeigen

gmmg

Guten Morgen,

Velted: Superso funktioniert das

Gruß gmmg

gmmg 26. Mai 2023 um 15:20