ListView Ctrl+A alles selektieren

**eukalyptus**

Hallo!

Ich steh grad auf dem Schlauch u Google hilft mir auch nicht weiter!

Wie kann ich in einem ListView erkennen, wenn ein User "Ctrl+A" drückt?

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Opt("GUIOnEventMode", 1)

Global $hGui = GUICreate("Test", 320, 240)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_EVENT_CLOSE")

Global $cLV_Test = GUICtrlCreateListView("Name", 5, 5, 310, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
For $i = 1 To 9
    _GUICtrlListView_AddItem($cLV_Test, "Item" & $i)
Next


GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)



While Sleep(10)
WEnd



Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

    Local $tInfo, $iItem

    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Switch $tNMHDR.Code
        Case $LVN_KEYDOWN
            Switch $tNMHDR.IDFrom
                Case $cLV_Test
                    $tInfo = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    Switch $tInfo.VKey
                        Case 0x2E ;DEL key

                        Case Else
                            ConsoleWrite("! KEY DOWN: " & $tInfo.VKey & @CRLF)

                    EndSwitch

            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY




Func _GUI_EVENT_CLOSE()
    Exit
EndFunc

Alles anzeigen

"A" erkenne ich und "CTRL" auch...

Wie kann ich erkennen, ob "A" und "CTRL" gleichzeitig gedrück sind?

Vielen lieben Dank!

lgE

**BugFix**

~~Wenn man sowas mit einem Hook macht, werden die Flags ausgewertet, um CTRL abzufragen.~~

~~Vielleicht kannst du das ähnlich einbinden.~~

Geht viel einfacher als ich dachte.

Hintergrund ist, dass niemals 2 Tasten gleichzeitig gedrückt werden, sondern immer nacheinander. "Ctrl+A" wird auch nur erkannt, wenn erst "Ctrl" gedrückt wird und dann zusätzlich "A".

Genau diese Folge muss nun abgeprüft werden. Dazu einfach den Wert der zuletzt gedrückten Taste speichern und zum Vergleich nutzen.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Opt("GUIOnEventMode", 1)

Global Const $VK_CONTROL = 0x11
Global Const $VK_A = 0x41

Global $hGui = GUICreate("Test", 320, 240)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_EVENT_CLOSE")

Global $cLV_Test = GUICtrlCreateListView("Name", 5, 5, 310, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
For $i = 1 To 9
    _GUICtrlListView_AddItem($cLV_Test, "Item" & $i)
Next


GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)



While Sleep(10)
WEnd



Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

    Local $tInfo, $iItem
    Local Static $vkLastPressed = 0

    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Switch $tNMHDR.Code
        Case $LVN_KEYDOWN
            Switch $tNMHDR.IDFrom
                Case $cLV_Test
                    $tInfo = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    If $vkLastPressed <> $tInfo.VKey Then
                        If $vkLastPressed = $VK_CONTROL And $tInfo.VKey = $VK_A Then
                            ConsoleWrite('! <CTRL+A> pressed' & @CRLF)
                        EndIf
                    EndIf
                    $vkLastPressed = $tInfo.VKey
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY




Func _GUI_EVENT_CLOSE()
    Exit
EndFunc

Alles anzeigen

**eukalyptus**

Vielen Dank!

Leider funktioniert das bei mir nicht ganz so, wie ich will.

Ich hätte erwähnen sollen, dass ich 9 Listviews nebeneinander hab

Ein KeyUp wird leider auch nicht ausgewertet. (könnte man aber mit einem TimeOut versehen)

Ich hab jetzt mal eine Hook Variante und eine simple Variante mit _IsPressed probiert:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <WinAPI.au3>
#include <Misc.au3>


Opt("GUIOnEventMode", 1)

Global $hGui = GUICreate("Test", 320, 240)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_EVENT_CLOSE")

Global $cLV_Test = GUICtrlCreateListView("Name", 5, 5, 150, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
Global $cLV_Test2 = GUICtrlCreateListView("Name", 160, 5, 150, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
For $i = 1 To 9
    _GUICtrlListView_AddItem($cLV_Test, "Item" & $i)
    _GUICtrlListView_AddItem($cLV_Test2, "Item" & $i)
Next


Global $bCTRLKEYDOWN_L, $bCTRLKEYDOWN_R
Global $hKeyProc = DllCallbackRegister("_KeyProc", "long", "int;wparam;lparam")
Global $hMod = _WinAPI_GetModuleHandle(0)
Global $hHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hKeyProc), $hMod)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)



While Sleep(10)
WEnd




Func _KeyProc($nCode, $wParam, $lParam)
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
    Local $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)

    Switch $wParam
        Case $WM_KEYDOWN
            Switch DllStructGetData($tKEYHOOKS, "vkCode")
                Case 162 ;CTRL L
                    $bCTRLKEYDOWN_L = True
                Case 163 ;CTRL R
                    $bCTRLKEYDOWN_R = True
            EndSwitch

        Case $WM_KEYUP
            Switch DllStructGetData($tKEYHOOKS, "vkCode")
                Case 162 ;CTRL L
                    $bCTRLKEYDOWN_L = False
                Case 163 ;CTRL R
                    $bCTRLKEYDOWN_R = False
            EndSwitch
    EndSwitch

    Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>_KeyProc



Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

    Local $tInfo

    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    Switch $tNMHDR.Code
        Case $LVN_KEYDOWN
            Switch $tNMHDR.IDFrom
                Case $cLV_Test, $cLV_Test2
                    $tInfo = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    Switch $tInfo.VKey
                        Case 0x41 ;A
                            If $bCTRLKEYDOWN_L Or $bCTRLKEYDOWN_R Then
                                ConsoleWrite("! Ctrl + A  LV:" & $tNMHDR.IDFrom & @CRLF)
                            EndIf

                        ;Case 0x41 ;A
                        ;    If _IsPressed("11") Then
                        ;        ConsoleWrite("! Ctrl + A  LV:" & $tNMHDR.IDFrom & @CRLF)
                        ;    EndIf

                    EndSwitch
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY




Func _GUI_EVENT_CLOSE()
    _WinAPI_UnhookWindowsHookEx($hHook)
    DllCallbackFree($hKeyProc)
    Exit
EndFunc   ;==>_GUI_EVENT_CLOSE

Alles anzeigen

Beide Methoden fühlen sich jedoch nicht "elegant" an.

Spricht irgendwas gegen _IsPressed?

vielen Dank!

lgE

**Oscar**

Ich würde einen anderen Weg vorschlagen:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>
#include <WinAPISys.au3>

Opt("GUIOnEventMode", 1)

Global $hGui = GUICreate("Test", 320, 240)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_EVENT_CLOSE")

Global $cLV_Test = GUICtrlCreateListView("Name", 5, 5, 150, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
Global $cLV_Test2 = GUICtrlCreateListView("Name", 160, 5, 150, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
For $i = 1 To 9
    _GUICtrlListView_AddItem($cLV_Test, "Item" & $i)
    _GUICtrlListView_AddItem($cLV_Test2, "Item" & $i)
Next
Global $cDummy = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, '_SelectAll')
Global $aAccelKeys[1][2] = [["^a", $cDummy]]
GUISetAccelerators($aAccelKeys)
GUISetState(@SW_SHOW)

While Sleep(10)
WEnd

Func _GUI_EVENT_CLOSE()
    Exit
EndFunc   ;==>_GUI_EVENT_CLOSE

Func _SelectAll()
    Local $sClassName = ControlGetFocus($hGui)
    If $sClassName <> '' Then
        Local $hActive = ControlGetHandle($hGui, '', $sClassName)
        ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hActive = ' & $hActive & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
    EndIf
EndFunc

Alles anzeigen

**UEZ**

Oder so:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <WinAPIvkeysConstants.au3>
#include <WinAPISys.au3>

Opt("GUIOnEventMode", 1)

Global $hGui = GUICreate("Test", 320, 240)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_EVENT_CLOSE")

Global $cLV_Test = GUICtrlCreateListView("Name", 5, 5, 310, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
For $i = 1 To 9
    _GUICtrlListView_AddItem($cLV_Test, "Item" & $i)
Next

GUISetState(@SW_SHOW)


While Sleep(10)
    If BitAND(BitAND(_WinAPI_GetAsyncKeyState($VK_CONTROL), 0x8000), BitAND(_WinAPI_GetAsyncKeyState($VK_A), 0x8000)) And WinActive($hGui) Then
        ConsoleWrite("Ctrl+A was pressed" & @CRLF)
        While BitAND(BitAND(_WinAPI_GetAsyncKeyState($VK_CONTROL), 0x8000), BitAND(_WinAPI_GetAsyncKeyState($VK_A), 0x8000))
            Sleep(10)
        WEnd
    EndIf
WEnd


Func _GUI_EVENT_CLOSE()
    Exit
EndFunc

Alles anzeigen

Edit: ich weiß nicht warum, aber "Alt Gr + A" funktioniert auch, obwohl $VK_RMENU <> $VK_CONTROL.

Velted

Zitat von UEZ

Edit: ich weiß nicht warum, aber "Alt Gr + A" funktioniert auch, obwohl $VK_RMENU <> $VK_CONTROL.

Moin,

weil AltGr nicht nur $VK_RMENU ist, sondern zusätzlich auch $VK_LCONTROL.

Für ein 'reines' Strg+A müsste man ausschließen, dass zusätzlich eine der anderen Modifikatortasten gedrückt ist.

**eukalyptus**

Vieln Dank euch allen!

Ich werde nun die Accelerators Methode verwenden!

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>

Opt("GUIOnEventMode", 1)

Global $hGui = GUICreate("Test", 320, 240)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUI_EVENT_CLOSE")

Global $cLV_Test = GUICtrlCreateListView("Name", 5, 5, 150, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
Global $cLV_Test2 = GUICtrlCreateListView("Name", 160, 5, 150, 230, BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))
For $i = 1 To 9
    _GUICtrlListView_AddItem($cLV_Test, "Item" & $i)
    _GUICtrlListView_AddItem($cLV_Test2, "Item" & $i)
Next

Global $cDM_CTRLA = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, '_SelectAll')
Global $aAccelKeys[1][2] = [["^a", $cDM_CTRLA]]
GUISetAccelerators($aAccelKeys)

GUISetState(@SW_SHOW)



While Sleep(10)
WEnd



Func _SelectAll()
    Local $sClassName = ControlGetFocus($hGui)
    If $sClassName <> '' Then
        Local $hActive = ControlGetHandle($hGui, '', $sClassName)
        _GUICtrlListView_BeginUpdate($hActive)
        For $i = 0 To _GUICtrlListView_GetItemCount($hActive) - 1
            _GUICtrlListView_SetItemSelected($hActive, $i)
        Next
        _GUICtrlListView_EndUpdate($hActive)
    EndIf
EndFunc   ;==>_SelectAll


Func _GUI_EVENT_CLOSE()
    Exit
EndFunc   ;==>_GUI_EVENT_CLOSE

Alles anzeigen

lgE

**Oscar**

Du brauchst nicht durch alle Items iterieren.

Es reicht: _GUICtrlListView_SetItemSelected($hActive, -1)

"-1" ist für alle Items.

**eukalyptus**

Ja, ich weiß selber, dass ich eingerostet bin